"{ Package: 'stx:libbasic2' }"

Object subclass:#Archiver

	instanceVariableNames:'process temporaryDirectory fileName outStream errorStream

		synchron'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Support-FileFormats'

!

Object subclass:#ArchiverOutputParser

	instanceVariableNames:'firstLineRead archiver'

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver subclass:#GZipArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver subclass:#MultiFileArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#TarArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver subclass:#TarGZipArchive

	instanceVariableNames:'tarArchiver tarFile'

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#ZipArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

!Archiver class methodsFor:'instance creation'!

classForMimeType:aMimeType

    |className|

    aMimeType isNil ifTrue:[^ nil].

    className := (

            #(

                ('application/x-tar-compressed'      TarGZipArchive     )

                ('application/x-tar'                 TarArchive         )

                ('application/x-gzip-compressed'     GZipArchive        )

                ('application/x-zip-compressed'      ZipArchive         )

                ('application/x-squeak-archive'      ZipArchive         )

                ('application/java-archive'          ZipArchive         )

            ) detect:[:entry | entry first = aMimeType] ifNone:#(nil nil)

        ) last.

    className isNil ifTrue:[^ nil].

    ^ self privateClassesAt:className.

    "

     self classForMimeType:'application/x-tar'    

     self classForMimeType:'application/x-foo'    

     self classForMimeType:'application/x-squeak-archive'   

     self classForMimeType:'application/java-archive'   

     'foo.sar' asFilename mimeTypeFromName               

    "

!

newFor:aFilename

    |mimeType archiverClass|

    mimeType := aFilename asFilename mimeTypeFromName.

    archiverClass := self classForMimeType:mimeType.

    archiverClass isNil ifTrue:[^ nil].

    ^ archiverClass with:aFilename

!

with:aFilename

    | instance |

    instance := self new.

    instance fileName:aFilename.

    ^ instance

! !

!Archiver class methodsFor:'classAccess'!

gzipArchive

    ^ GZipArchive

!

tarArchive

    ^ TarArchive

!

tarGZipArchive

    ^ TarGZipArchive

!

zipArchive

    ^ ZipArchive

! !

!Archiver class methodsFor:'columns'!

columns

    self subclassResponsibility

! !

!Archiver class methodsFor:'commandOutputReader'!

commandOutputParser

    ^ self commandOutputParserClass new

!

commandOutputParserClass

    ^ ArchiverOutputParser

! !

!Archiver class methodsFor:'queries'!

canAddFiles

    ^ false

!

canDragnDrop

    ^ true.

!

canExtractFiles

    ^ false

!

canRemoveFiles

    ^ false

!

canViewFile

    ^ false

!

hasTitleLine

    ^ false

! !

!Archiver methodsFor:'accessing'!

errorStream

    "return the value of the instance variable 'errorStream' (automatically generated)"

    ^ errorStream

!

errorStream:something

    "set the value of the instance variable 'errorStream' (automatically generated)"

    errorStream := something.

!

fileName

    "return the value of the instance variable 'fileName' (automatically generated)"

    ^ fileName

!

fileName:something

    "set the value of the instance variable 'fileName' (automatically generated)"

    fileName := something.

!

outStream

    "return the value of the instance variable 'outStream' (automatically generated)"

    ^ outStream

!

outStream:something

    "set the value of the instance variable 'outStream' (automatically generated)"

    outStream := something.

!

process

    "return the value of the instance variable 'process' (automatically generated)"

    ^ process

!

process:something

    "set the value of the instance variable 'process' (automatically generated)"

    process := something.

!

synchron

    "return the value of the instance variable 'synchron' (automatically generated)"

    ^ synchron

!

synchron:something

    "set the value of the instance variable 'synchron' (automatically generated)"

    synchron := something.

!

temporaryDirectory

    "return the value of the instance variable 'temporaryDirectory' (automatically generated)"

    temporaryDirectory isNil ifTrue:[

        temporaryDirectory := Filename newTemporary.

        temporaryDirectory makeDirectory.

    ].

    ^ temporaryDirectory

! !

!Archiver methodsFor:'actions'!

extractFilesTo:aDirectory

    self extractFiles:nil to:aDirectory

!

removeFilesFromArchive:aColOfFiles

    self subclassResponsibility.

! !

!Archiver methodsFor:'actions-basic'!

addFilesToArchive:colOfFiles

    self subclassResponsibility.

!

extractFiles:aColOfFilesOrNil to:aDirectory

    self subclassResponsibility.

! !

!Archiver methodsFor:'actions-private'!

removeTemporaryDirectory

    | tmp |

    temporaryDirectory notNil ifTrue:[

        tmp := self temporaryDirectory.

        (FileDirectory directoryNamed:(tmp directory)) removeDirectory:tmp baseName.

        temporaryDirectory := nil.

    ].

!

stopProcess

    process notNil ifTrue:[

        process terminateWithAllSubprocesses.

        process waitUntilTerminated.

    ].

! !

!Archiver methodsFor:'command execution'!

executeCommand:cmd directory:aDirectory

    synchron isNil ifTrue:[synchron := true].

    synchron ifTrue:[

         OperatingSystem 

            executeCommand:cmd

            inputFrom:nil

            outputTo:outStream

            errorTo:errorStream

            inDirectory:aDirectory

            lineWise:true

            onError:[:status| false].

    ] ifFalse:[

        process := Process for:[

                [ 

                     OperatingSystem 

                        executeCommand:cmd

                        inputFrom:nil

                        outputTo:outStream

                        errorTo:errorStream

                        inDirectory:aDirectory

                        lineWise:true

                        onError:[:status| false].

                ] ensure:[

                    process := nil.

                ].

        ] priority:(Processor systemBackgroundPriority).

        process name:('Archiver command: ', cmd).

        process resume.

    ]

!

isValidOutputLine:line

    "return true, if line contains a valid list-files output line"

    self subclassResponsibility

!

listFilesReader

    |reader|

    reader := ArchiverOutputParser new.

    reader archiver:self.

    ^ reader

!

outStream:aOutStream errorStream:aErrorStream

    outStream := aOutStream.

    errorStream := aErrorStream.

!

outStream:aOutStream errorStream:aErrorStream synchron:aBoolean

    outStream := aOutStream.

    errorStream := aErrorStream.

    synchron := aBoolean

! !

!Archiver methodsFor:'initialization & release'!

release

    self stopProcess.

    self removeTemporaryDirectory.

! !

!Archiver::ArchiverOutputParser class methodsFor:'instance creation'!

new

    ^ self basicNew initialize.

! !

!Archiver::ArchiverOutputParser methodsFor:'accessing'!

archiver:something

    "set the value of the instance variable 'archiver' (automatically generated)"

    archiver := something.

! !

!Archiver::ArchiverOutputParser methodsFor:'initialization'!

initialize

    firstLineRead := false.

! !

!Archiver::ArchiverOutputParser methodsFor:'parsing'!

parseLine:line forItemClass:itemClass

    |words archiverColumns item index key|

    (firstLineRead not and:[archiver class hasTitleLine]) ifTrue:[

        firstLineRead := true.

        ^ nil.

    ].

    (archiver isValidOutputLine:line) ifFalse:[

        ^ nil.

    ].

    words := line asCollectionOfWords.

    archiverColumns := archiver columns.

    item := itemClass new.

    index := 1.

    archiverColumns do:[:colDescr |

        | itemWordCount itemStream itemFieldSelector itemWriter |

        itemWordCount := colDescr second.

        itemFieldSelector := colDescr first.

        itemFieldSelector notNil ifTrue:[

            itemWriter := (itemFieldSelector , ':') asSymbol.

        ].

        itemStream := WriteStream on:''.

        itemWordCount == #rest ifTrue:[

            index to:(words size) do:[:i|

                itemStream nextPutAll:(words at:i).

                itemStream space.

            ].

        ] ifFalse:[

            index to:(index + itemWordCount - 1) do:[:i|

                itemStream nextPutAll:(words at:i).

                itemStream space.

            ].

            index := index + itemWordCount.

        ].

        itemWriter notNil ifTrue:[

        ].

        itemStream close.

    ].

    ((archiverColumns collect:[:el| el first]) includes:#permissions) ifTrue:[

        (item permissions startsWith:$d) ifTrue:[

            key := #directory.

            item isDirectory:true.

        ] ifFalse:[

            key := MIMETypes mimeTypeForFilename:(item fileName asFilename baseName).

            item isDirectory:false.

        ].

    ] ifFalse:[

        key := MIMETypes mimeTypeForFilename:(item fileName asFilename baseName).

    ].

    item icon:(FileBrowser iconForKeyMatching:key).

    ^ item

! !

!Archiver::GZipArchive class methodsFor:'command strings'!

gunzipCommand

    ^ 'gunzip'

!

gzipCommand

    ^ 'gzip'

! !

!Archiver::GZipArchive class methodsFor:'queries'!

canViewFile

    ^ true

!

hasTitleLine

    ^ true

! !

!Archiver::GZipArchive methodsFor:'actions'!

extractFiles:aColOfFilesOrNil to:aDirectory

    self unzipTo:aDirectory

!

unzipTo:aDirectory

    | cmd file newFile|

    (aDirectory exists not) ifTrue:[