"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 2003 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic2' }"

"{ NameSpace: Smalltalk }"

Object subclass:#Archiver

	instanceVariableNames:'process temporaryDirectory fileName outStream errorStream

		synchron'

	classVariableNames:'MimeTypeMapping'

	poolDictionaries:''

	category:'System-Support-FileFormats'

!

Archiver subclass:#MultiFileArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Object subclass:#ArchiverOutputParser

	instanceVariableNames:'firstLineRead archiver'

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver subclass:#CompressedFile

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::CompressedFile subclass:#BZ2Compressed

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver subclass:#CompressedTarArchive

	instanceVariableNames:'tarArchiver tarFile'

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::CompressedFile subclass:#GZipCompressed

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#LZipArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#ArArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#TarArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::CompressedTarArchive subclass:#TarBZ2Archive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::CompressedTarArchive subclass:#TarGZipArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#XarArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

Archiver::MultiFileArchive subclass:#ZipArchive

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:Archiver

!

!Archiver class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2003 by eXept Software AG

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this is a soon to be obsoleted helper class for the fileBrowser.

    it wraps OS-specific command line archivers (tar, zip, rar, etc)

    into a common protocol useful to display an archive's contents.

    will be removed - do not use for your projects.

"

! !

!Archiver class methodsFor:'initialization'!

initializeMimeTypeMapping

    MimeTypeMapping := Dictionary 

        withKeysAndValues:

            #(

                'application/x-tar-compressed'         CompressedTarArchive     "abstract - special handling"

                'application/x-tar-gzip-compressed'    TarGZipArchive       

                'application/x-tar-bzip2-compressed'   TarBZ2Archive        

                'application/x-tar'                    TarArchive          

                'application/x-gzip-compressed'        GZipCompressed      

                'application/gzip'                     GZipCompressed      

                'application/lzip'                     LZipArchive      

                'application/x-zip-compressed'         ZipArchive          

                'application/x-bzip2-compressed'       BZ2Compressed       

                'application/x-squeak-archive'         ZipArchive          

                'application/x-squeak-monticello-archive'     ZipArchive          

                'application/java-archive'             ZipArchive          

                'application/x-xar'                    XarArchive "/ on OSX         

                'application/x-ar-archive'             ArArchive           

                'application/x-ar-library'             ArArchive           

                'application/library'                  ArArchive           

"/       'application/x-rpm'                    RPMArchive          

"/       'application/x-rpm-archive'            RPMArchive          

"/       'application/x-redhat packet manager'  RPMArchive  

                'application/vnd.openxmlformats-officedocument.spreadsheetml.sheet' ZipArchive

                'application/x-expecco-testsuite'   ZipArchive

            ).

    "Modified: / 01-12-2011 / 21:25:08 / cg"

! !

!Archiver class methodsFor:'instance creation'!

classForMimeType:aMimeType fileName:aFileNameOrNil

    |className|

    MimeTypeMapping isNil ifTrue:[

        self initializeMimeTypeMapping

    ].    

    className := MimeTypeMapping at:aMimeType ifAbsent:nil.

    className isNil ifTrue:[

        "/ hard coded heuristics...

        aFileNameOrNil asFilename suffix = 'mcz' ifTrue:[^ ZipArchive].

        ^ nil

    ].

    className = #CompressedTarArchive ifTrue:[

        (aFileNameOrNil notNil and:[aFileNameOrNil suffix = 'bz2']) ifTrue:[

            className := #TarBZ2Archive

        ] ifFalse:[

            "this is the default"

            className := #TarGZipArchive

        ]

    ].

    ^ self privateClassesAt:className.

    "

     self classForMimeType:nil fileName:nil   

     self classForMimeType:'application/x-tar-compressed' fileName:nil   

     self classForMimeType:'application/x-tar' fileName:nil   

     self classForMimeType:'application/x-foo' fileName:nil   

     self classForMimeType:'application/x-squeak-archive' fileName:nil  

     self classForMimeType:'application/java-archive' fileName:nil 

     'foo.sar' asFilename mimeTypeFromName               

     'foo.jar' asFilename mimeTypeFromName               

     'foo.a' asFilename mimeTypeFromName               

    "

    "Modified: / 01-12-2011 / 21:26:24 / cg"

!

new

    ^ super new

!

newFor:aFilename

    |fn mimeType archiverClass|

    fn := aFilename asFilename.

    (mimeType := fn mimeTypeFromName) isNil ifTrue:[

        (mimeType := fn mimeTypeOfContents) isNil ifTrue:[

            self breakPoint:#cg.

        ].

    ].        

    mimeType = 'application/x-zip-compressed' ifTrue:[

        self breakPoint:#cg.

    ].

    archiverClass := self classForMimeType:mimeType fileName:fn.

    archiverClass isNil ifTrue:[^ nil].

    ^ archiverClass with:fn

    "Modified: / 28-11-2018 / 15:31:31 / Claus Gittinger"

!

with:aFilename

    ^ self new fileName:aFilename.

! !

!Archiver class methodsFor:'classAccess'!

arArchive

    ^ ArArchive

!

gzipArchive

    ^ GZipCompressed

!

lzipArchive

    ^ LZipArchive

!

tarArchive

    ^ TarArchive

!

tarGZipArchive

    ^ TarGZipArchive

!

zipArchive

    ^ ZipArchive

! !

!Archiver class methodsFor:'columns'!

columns

    self subclassResponsibility

! !

!Archiver class methodsFor:'command strings'!

stringWithQuotedFileBaseNames:aColOfFiles

    aColOfFiles isNil ifTrue:[^ ''].

    ^ String 

        streamContents:[:str |

            aColOfFiles do:[:fn | 

                str nextPutAll:' "'.

                str nextPutAll:(fn asFilename baseName).

                str nextPutAll:'"'.

            ].

        ]

! !

!Archiver class methodsFor:'commandOutputReader'!

commandOutputParser

    ^ self commandOutputParserClass new

!

commandOutputParserClass

    ^ ArchiverOutputParser

! !

!Archiver class methodsFor:'queries'!

canAddFiles

    ^ false

!

canDragnDrop

    ^ true.

!

canExtractFiles

    ^ false

!

canRemoveFiles

    ^ false

!

canViewFile

    ^ false

!

hasTitleLine

    ^ false

!

isAbstract

    ^ self == Archiver

! !

!Archiver methodsFor:'accessing'!

errorStream

    "return the value of the instance variable 'errorStream' (automatically generated)"

    ^ errorStream

!

errorStream:something

    "set the value of the instance variable 'errorStream' (automatically generated)"

    errorStream := something.

!

fileName

    "return the value of the instance variable 'fileName' (automatically generated)"

    ^ fileName

!

fileName:something

    "set the value of the instance variable 'fileName' (automatically generated)"

    fileName := something.

!

outStream

    "return the value of the instance variable 'outStream' (automatically generated)"

    ^ outStream

!

outStream:something

    "set the value of the instance variable 'outStream' (automatically generated)"

    outStream := something.

!

outStream:anOutStream errorStream:anErrorStream synchron:aBoolean

    outStream := anOutStream.

    errorStream := anErrorStream.

    synchron := aBoolean

!

process

    "return the value of the instance variable 'process' (automatically generated)"

    ^ process

!

process:something

    "set the value of the instance variable 'process' (automatically generated)"

    process := something.

!

synchron

    "return the value of the instance variable 'synchron' (automatically generated)"

    ^ synchron

!

synchron:something

    "set the value of the instance variable 'synchron' (automatically generated)"

    synchron := something.

!

temporaryDirectory

    "return the value of the instance variable 'temporaryDirectory' (automatically generated)"

    temporaryDirectory isNil ifTrue:[

        temporaryDirectory := Filename newTemporaryDirectory.

    ].

    ^ temporaryDirectory

! !

!Archiver methodsFor:'actions'!

extractFilesTo:aDirectory

    self extractFiles:nil to:aDirectory

!

getCommandToListFiles:aColOfFiles

    self subclassResponsibility.

!

listFiles:aColOfFiles

    |cmd dir|

    self fileName isNil ifTrue:[ ^ self].

    dir := self fileName directory.

    cmd := self getCommandToListFiles:aColOfFiles.

    cmd isNil ifTrue:[

        errorStream nextPutLine:'No command to list the archive.'.

        ^ self

    ].

    self executeCommand:cmd directory:dir

    "Modified: / 16-09-2011 / 16:33:50 / cg"

!

removeFilesFromArchive:aColOfFiles

    self subclassResponsibility.

! !

!Archiver methodsFor:'actions-basic'!

addFilesToArchive:colOfFiles

    self subclassResponsibility.

!

extractFiles:aColOfFilesOrNil to:aDirectory

    self subclassResponsibility.

! !

!Archiver methodsFor:'actions-private'!

removeTemporaryDirectory

    temporaryDirectory notNil ifTrue:[

        self temporaryDirectory recursiveRemove.

        temporaryDirectory := nil.

    ].

!

stopProcess

    |p|

    p := process.

    p notNil ifTrue:[

        p terminateGroup.

        p waitUntilFinished.

        process := nil.

    ].

! !

!Archiver methodsFor:'command execution'!

executeCommand:cmd directory:aDirectory

    |osProcess|

    cmd isNil ifTrue:[

        errorStream nextPutAll:'No command for archive operation.'.

        ^ false

    ].

    osProcess := OSProcess new

                    command:cmd directory:aDirectory;

                    lineWise:true;          "do it lineWise, since outStream may be an ActorStream"

                    outStream:outStream;

                    errorStream:errorStream.