"{ Package: 'stx:libbasic2' }"!

!ArithmeticValue methodsFor:'converting'!

asQDouble

    "return a QDouble with same value"

    ^ QDouble fromFloat:self asFloat

    "

     123 asQDouble

     (Fraction basicNew setNumerator:246 denominator:2) asQDouble

     123 asLongFloat asQDouble

     123 asLargeFloat asQDouble

    "

    "Created: / 13-06-2017 / 16:48:24 / cg"

    "Modified (comment): / 25-07-2017 / 16:06:19 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

differenceFromQDouble:aQDouble

    "aQDouble does not know how to subtract the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#- coercing:self

    "Created: / 13-06-2017 / 08:55:38 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

equalFromQDouble:aQDouble

    "aQDouble does not know how to compare to the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#= coercing:self

    "Created: / 13-06-2017 / 08:55:30 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

lessFromQDouble:aQDouble

    "aQDouble does not know how to compare to the receiver -

     Return true if aQDouble < self.

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#< coercing:self

    "Created: / 13-06-2017 / 08:55:20 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

productFromQDouble:aQDouble

    "aQDouble does not know how to multiply the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#* coercing:self

    "Created: / 13-06-2017 / 08:55:07 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

quotientFromQDouble:aQDouble

    "aQDouble does not know how to divide by the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#/ coercing:self

    "Created: / 13-06-2017 / 08:54:55 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

remainderFromQDouble:aQDouble

    "aQDouble does not know how to compute the remainder with the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#rem: coercing:self

    "Created: / 13-06-2017 / 08:54:47 / cg"

! !

!ArithmeticValue methodsFor:'double dispatching'!

sumFromQDouble:aQDouble

    "aQDouble does not know how to add the receiver -

     retry the operation by coercing to higher generality"

    ^ aQDouble retry:#+ coercing:self

    "Created: / 13-06-2017 / 08:54:27 / cg"

! !

!Block methodsFor:'Compatibility-Dolphin'!

deferredValue

    "Dolphin compatibility method - do not use in new code.

     Dolphin's alias for futureValue"

    ^ Future new block:self

    "Modified: / 04-10-2011 / 14:56:27 / cg"

! !

!Block methodsFor:'Compatibility-Dolphin'!

deferredValueAt:priority

    "Dolphin compatibility method - do not use in new code.

     Dolphin's alias for futureValue"

    ^ Future new

	priority:priority block:self

    "Created: / 04-10-2011 / 14:55:56 / cg"

! !

!Block methodsFor:'parallel evaluation'!

futureValue

    "Fork a synchronised evaluation of myself.

     Starts the evaluation in parallel now, but synchronizes

     any access to wait until the result is computed."

    ^ Future new block:self

! !

!Block methodsFor:'parallel evaluation'!

futureValue:aValue

    "Fork a synchronised evaluation of myself.

     Starts the evaluation in parallel now, but synchronizes

     any access to wait until the result is computed."

    ^ Future new block:self value:aValue

! !

!Block methodsFor:'parallel evaluation'!

futureValue:aValue value:anotherValue

    "Fork a synchronised evaluation of myself.

     Starts the evaluation in parallel now, but synchronizes

     any access to wait until the result is computed."

    ^ Future new

	block:self

	value:aValue

	value:anotherValue

! !

!Block methodsFor:'parallel evaluation'!

futureValue:aValue value:anotherValue value:bValue

    "Fork a synchronised evaluation of myself.

     Starts the evaluation in parallel now, but synchronizes

     any access to wait until the result is computed."

    ^ Future new

	block:self

	value:aValue

	value:anotherValue

	value:bValue

! !

!Block methodsFor:'parallel evaluation'!

futureValueWithArguments:anArray

    "Fork a synchronised evaluation of myself.

     Starts the evaluation in parallel now, but synchronizes

     any access to wait until the result is computed."

    ^ Future new

	block:self

	valueWithArguments:anArray

    "Modified (format): / 04-10-2011 / 14:55:40 / cg"

! !

!Block methodsFor:'parallel evaluation'!

lazyValue

    "Return a lazy value object, evaluating myself. 

     Only computes when the result is requested."

    ^ Lazy new block:self

    "Modified (comment): / 09-02-2019 / 15:59:29 / Claus Gittinger"

! !

!Block methodsFor:'parallel evaluation'!

lazyValue:aValue

    "Return a lazy value object, evaluating myself. 

     Only computes when the result is requested."

    ^ Lazy new block:self value:aValue

    "Modified (comment): / 09-02-2019 / 16:00:02 / Claus Gittinger"

! !

!Block methodsFor:'parallel evaluation'!

lazyValue:aValue value:anotherValue

    "Return a lazy value object, evaluating myself. 

     Only computes when the result is requested."

    ^ Lazy new

        block:self

        value:aValue

        value:anotherValue

    "Modified (comment): / 09-02-2019 / 16:00:05 / Claus Gittinger"

! !

!Block methodsFor:'parallel evaluation'!

lazyValue:aValue value:anotherValue value:bValue

    "Return a lazy value object, evaluating myself. 

     Only computes when the result is requested."

    ^ Lazy new

        block:self

        value:aValue

        value:anotherValue

        value:bValue

    "Modified (comment): / 09-02-2019 / 16:00:08 / Claus Gittinger"

! !

!Block methodsFor:'parallel evaluation'!

lazyValueWithArguments:anArray

    "Return a lazy value object, evaluating myself. 

     Only computes when the result is requested."

    ^ Lazy new block:self valueWithArguments:anArray

    "Modified (comment): / 09-02-2019 / 16:00:12 / Claus Gittinger"

! !

!Block methodsFor:'process creation'!

promise

    "create a promise on the receiver. The promise will evaluate the

     receiver and promise to return the value with the #value message.

     The evaluation will be performed as a separate process.

     Asking the promise for its value will either block the asking process

     (if the evaluation has not yet been finished) or return the value

     immediately."

    ^ Promise value:self

    "

     |p|

     p := [1000 factorial] promise.

     'do something else ...'.

     p value

    "

! !

!Block methodsFor:'process creation'!

promiseAt:prio

    "create a promise on the receiver. The promise will evaluate the

     receiver and promise to return the value with the #value message.

     The evaluation will be performed as a separate process running at prio.

     Asking the promise for its value will either block the asking process

     (if the evaluation has not yet been finished) or return the value

     immediately."

    ^ Promise value:self priority:prio

! !

!CharacterArray methodsFor:'matching - phonetic'!

asKoelnerPhoneticCode

    "return a koelner phonetic code.

     The koelnerPhonetic code is for the german language what the soundex code is for english;

     it returns simular strings for similar sounding words.

     There are some differences to soundex, though:

	its length is not limited to 4, but depends on the length of the original string;

	it does not start with the first character of the input.

     Caveat: this phonetic code is especially suited for german words.

	     Please have a look at the other phonetic comparison operators found

	     in PhoneticStringUtilities."

    ^ PhoneticStringUtilities koelnerPhoneticCodeOf:self

    "

     #(

	'Müller'

	'Miller'

	'Mueller'

	'Mühler'

	'Mühlherr'

	'Mülherr'

	'Myler'

	'Millar'

	'Myller'

	'Müllar'

	'Müler'

	'Muehler'

	'Mülller'

	'Müllerr'

	'Muehlherr'

	'Muellar'

	'Mueler'

	'Mülleer'

	'Mueller'

	'Nüller'

	'Nyller'

	'Niler'

	'Czerny'

	'Tscherny'

	'Czernie'

	'Tschernie'

	'Schernie'

	'Scherny'

	'Scherno'

	'Czerne'

	'Zerny'

	'Tzernie'

	'Breschnew'

     ) do:[:w |

	 Transcript show:w; show:'->'; showCR:(w asKoelnerPhoneticCode)

     ].

    "

    "

     'Breschnew' asKoelnerPhoneticCode -> '17863'

     'Breschnew' asKoelnerPhoneticCode -> '17863'

     'Breschneff' asKoelnerPhoneticCode -> '17863'

     'Braeschneff' asKoelnerPhoneticCode -> '17863'

     'Braessneff' asKoelnerPhoneticCode -> '17863'

     'Pressneff' asKoelnerPhoneticCode -> '17863'

     'Presznäph' asKoelnerPhoneticCode -> '17863'

    "

! !

!CharacterArray methodsFor:'matching - phonetic'!

asSoundexCode

    "return a soundex phonetic code or nil.

     Soundex returns similar codes for similar sounding words, making it a useful

     tool when searching for words where the correct spelling is unknown.

     (read Knuth or search the web if you don't know what a soundex code is).

     Caveat: 'similar sounding words' means: 'similar sounding in ENGLISH'

             Please have a look at the other phonetic comparison operators found

             in PhoneticStringUtilities."

    ^ PhoneticStringUtilities soundexCodeOf:self

    "

     'claus' asSoundexCode

     'clause' asSoundexCode

     'close' asSoundexCode

     'smalltalk' asSoundexCode

     'smaltalk' asSoundexCode

     'smaltak' asSoundexCode

     'smaltok' asSoundexCode

     'smoltok' asSoundexCode

     'aa' asSoundexCode

     'by' asSoundexCode

     'bab' asSoundexCode

     'bob' asSoundexCode

     'bop' asSoundexCode

    "

! !

!CharacterArray methodsFor:'printing & storing'!

printf:args

    "Format and print the receiver with <args> formatted in C style,

     as specified in the Unix C-language manual page for printf(3).

     Return the resulting string (i.e actually, this is more like an sprintf).

     For smalltalk specific formats, 

     see documentation in PrintfScanf >> format_printf.

     For copyright information, see goodies/String-printf_scanf.chg"

    |aStream|

    aStream := CharacterWriteStream on:(self species uninitializedNew:self size).

    self printf:args on:aStream.

    ^ aStream contents

    "

     ('%05x %d %f %o' printf:{ 123. 234*5. 1.234. 8r377 } )    

     Transcript showCR:('%05x %d %f %o' printf:{ 123. 234*5. 1.234. 8r377 } )

    "

    "

     Transcript showCR: 'Some examples:'!!

     Transcript show:'''%#x %#X %03o%*.*s'' printf: #(16rABCD 16rEF 5 9 5 ''ghijklmn'') = .'.

     Transcript show: ('%#x %#X %03o%*.*s' printf: #(16rABCD 16rEF 5 9 5 'ghijklmn')).

     Transcript showCR: '.'

     Transcript show: '''%- 10.4s%.2e'' printf: (Array with: ''abcdefghijkl'' with: Float pi) = .'.

     Transcript show: ('%- 10.4s%.2e' printf: (Array with: 'abcdefghijkl' with: Float pi)).

     Transcript showCR: '.'

     Transcript show: '''%8.3f'' printf: (Array with: 200 sqrt negated) = .'.

     Transcript show: ('%8.3f' printf: (Array with: 200 sqrt negated)).

     Transcript showCR: '.'

     Transcript show: '''%c'' printf: #(16r41) = .'.

     Transcript show: ('%c' printf: #(16r41)).

     Transcript showCR: '.'

     Transcript show: '''%f%2s%s%s%s'' sscanf: ''237.0 this is a test'' = '.

     Transcript showCR: ('%f%2s%s%s%s'  sscanf: '237.0 this is a test') printString.

     Transcript show: '''%d%f%s'' sscanf: ''25 54.32e-01 monday'' = '.

     Transcript showCR: ('%d%f%s' sscanf: '25 54.32e-01 monday') printString.

     Transcript show: '''%f%*f %8[A-F0-9]%c%d 0x%x%f'' sscanf: ''12.45 1048.73 AE40Z527 0x75BCD15 34'' = '.

     Transcript showCR: ('%f%*f %8[A-F0-9]%c%d 0x%x%f' sscanf: '12.45 1048.73 AE40Z527 0x75BCD15 34') printString.

    "

    "Modified (comment): / 14-11-2017 / 22:58:01 / cg"

! !

!CharacterArray methodsFor:'printing & storing'!

printf:args on:outStream

    "Format and print the receiver on <outStream> with <args>

     formatted in C style, as specified in the Unix C-language manual page for printf(3).

     For smalltalk specific formats, 

     see documentation in PrintfScanf >> format_printf.

     For copyright information, see goodies/String-printf_scanf.chg"

    PrintfScanf printf:self on:outStream arguments: args

    "

     '%e' printf:{ 1234.567 ] on:Transcript

     '%10s%3d\n' printf:{ 'hello' . 12 } on:Transcript

     '%10s%3d\n' printf:{ '1234567890' . 12 } on:Transcript

     like C's printf, a longer datum may be formatted wider than the formatspec says:

     '%10s%3d\n' printf:{ '12345678901234' . 12 } on:Transcript

     '%10s%3d\n' printf:{ 'hello' . 12 } on:Transcript

     '%10s%03d\n' printf:{ 'hello' . 12 } on:Transcript

    "

    "Modified (comment): / 14-11-2017 / 22:57:58 / cg"

! !

!CharacterArray methodsFor:'printing & storing'!

printfWith:arg1

    "Format and print the receiver with <arg1> formatted in C style,

     as specified in the Unix C-language manual page for printf(3).

     Return the resulting string (i.e actually, this is more like an sprintf).

     For smalltalk specific formats, 

     see documentation in PrintfScanf >> format_printf"

    ^ self printf:(Array with:arg1)

    "

     ('%05x' printfWith:123)

     Transcript showCR:('%05x' printfWith:123)

    "

    "Modified (comment): / 14-11-2017 / 22:58:10 / cg"

! !

!CharacterArray methodsFor:'printing & storing'!

printfWith:arg1 with:arg2

    "Format and print the receiver with <argI> formatted in C style,

     as specified in the Unix C-language manual page for printf(3).

     Return the resulting string (i.e actually, this is more like an sprintf).

     For smalltalk specific formats, see documentation in PrintfScanf >> format_printf."

    ^ self printf:(Array with:arg1 with:arg2)

    "

     Transcript showCR:('%d %05x' printfWith:123 with:234)