"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libbasic2' }"

"{ NameSpace: Smalltalk }"

CharacterArray subclass:#Text

	instanceVariableNames:'string runs'

	classVariableNames:'BackgroundColorEmphasis BoldEmphasis BoldOverlineEmphasis

		BoldUnderlineEmphasis BoldUnderwaveEmphasis ColorEmphasis

		EtchColorEmphasis FontEmphasis ItalicEmphasis

		ItalicUnderlineEmphasis ItalicUnderwaveEmphasis OverlineEmphasis

		ReverseEmphasis StrikeoutColorEmphasis StrikeoutEmphasis

		Subscript Superscript UnderlineColorEmphasis UnderlineEmphasis

		UnderwaveEmphasis'

	poolDictionaries:''

	category:'Collections-Text'

!

!Text class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Texts add emphasis information to a string.

    Texts and strings should behave interchanchably to the outside

    world, except that texts keep per-character emphasis information.

    (strings return nil when asked for an element's emphasis).

    Use #string, to get a text's underlying plain string without any emphasis

    information.

    Currently, the following attributes are supported:

        #bold

        #italic

        #underline

        #underwave

        #strikeout

        (#color -> aColor)

        (#backgroundColor -> aColor)

        (#underlineColor -> aColor)

        (#strikeoutColor -> aColor)

    Attributes may be combined (pass an array of above) as emphasis.

    See examples.

    This class is a hack and may need some massage.

    [author:]

        Claus Gittinger

    [see also:]

        CharacterArray String RunArray

"

!

examples

"

  In a textView:

                                                                        [exBegin]

    |t v|

    t := 'The quick brown fox jumps over the lazy dog' asText.

    t emphasizeFrom:(t findString:'quick')

      count:5 with:#bold.

    t emphasizeFrom:(t findString:'brown')

      count:9 with:(Array with:#color->(Color name:'brown')

                                                     with:#bold).

    t emphasizeFrom:(t findString:'lazy')

      count:4 with:(Array with:#color->(Color red)

                                                      with:#italic).

    t emphasizeFrom:(t findString:'dog')

      count:3 with:#underline.

    v := HVScrollableView for:EditTextView.

    v contents:t.

    v width:450.

    v open.

                                                                        [exEnd]

                                                                        [exBegin]

    |t v|

    t := 'a',('1' emphasizeAllWith:#subscript),'x',('3' emphasizeAllWith:#superscript)

         ,'a',('2' emphasizeAllWith:#subscript),'x',('2' emphasizeAllWith:#superscript)

         ,'a',('3' emphasizeAllWith:#subscript),'x',('n' emphasizeAllWith:#superscript).

    Dialog information:t.

                                                                        [exEnd]

  plain string (for comparison):

                                                                        [exBegin]

    Dialog information:'hello'

                                                                        [exEnd]

  emphasized strings as dialog titles:

                                                                        [exBegin]

    Dialog

        information:((Text string:'hello') allBold)

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello' emphasis:#italic)

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello' emphasis:#(underline))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello' emphasis:#(underwave))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello' emphasis:#(bold underline))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello'

                 emphasis:(Array with:#bold

                                 with:#strikeout

                                 with:(#color->Color red)))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello'

                 emphasis:(Array with:(#color->Color black)

                                 with:#underwave

                                 with:(#underlineColor->Color red)))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello'

                 emphasis:(Array with:#bold

                                 with:#strikeout

                                 with:(#color->Color red)

                                 with:(#backgroundColor->Color yellow)))

                                                                        [exEnd]

                                                                        [exBegin]

    Dialog

        information:(Text string:'hello' color:(Color red))

                                                                        [exEnd]

"

! !

!Text class methodsFor:'initialization'!

initialize

    "initialize the class"

    "

     consider this a kludge:

     I want to inherit behavior from CharacterArray, but not

     its implementation (indexed access).

    "

    self flags:(Behavior flagRegular).

    "/

    "/ although it looks like, these enum-symbols cannot

    "/ be easily renamed (they already found their way into many user-app-classes)

    "/

    BackgroundColorEmphasis := #backgroundColor.

    ColorEmphasis := #color.

    ItalicEmphasis := #italic.

    BoldEmphasis := #bold.

    UnderlineEmphasis := #underline.

    UnderwaveEmphasis := #underwave.

    OverlineEmphasis := #overline. 

    StrikeoutEmphasis := #strikeout.

    ReverseEmphasis := #reverse.

    BoldUnderlineEmphasis := #boldUnderline.

    BoldOverlineEmphasis := #boldOverline. 

    BoldUnderwaveEmphasis := #boldUnderwave.

    ItalicUnderlineEmphasis := #italicUnderline. 

    ItalicUnderwaveEmphasis := #italicUnderwave.

    UnderlineColorEmphasis := #underlineColor. 

    StrikeoutColorEmphasis := #strikeoutColor. 

    EtchColorEmphasis := #etchColor.

    FontEmphasis := #font.

    Superscript := #superscript.

    Subscript := #subscript.

    "

     Text initialize

    "

    "Modified: / 12-05-1996 / 17:53:50 / cg"

    "Modified (comment): / 20-06-2017 / 08:40:53 / cg"

! !

!Text class methodsFor:'instance creation'!

fromString:aString 

    "create a Text instance, for the characters in aString,

     without emphasis."

    ^ super new string:aString emphasis:nil

    "

     Text fromString:'hello'

    "

    "Modified: 12.5.1996 / 17:05:34 / cg"

!

new

    "create a new empty Text instance.

     Redefined for string-protocol compatibility"

    ^ super new string:'' emphasis:nil

    "Text new"

    "Modified: 12.5.1996 / 17:05:17 / cg"

    "Modified: 31.12.1996 / 12:39:57 / stefan"

!

new:size

    "create a new empty Text instance.

     Redefined for string-protocol compatibility"

    ^ self string:(String new:size)

    "Created: 12.5.1996 / 11:57:27 / cg"

    "Modified: 12.5.1996 / 17:05:17 / cg"

!

string:aString 

    "create a Text instance, for the characters in aString,

     without emphasis."

    ^ super new string:aString emphasis:nil

    "

     Text string:'hello'

    "

    "Modified: 12.5.1996 / 17:05:00 / cg"

!

string:aString color:aColor

    "create a Text instance, for the characters in aString,

     which are colored as aColor (only the foregroundColor is affected).

     This is a shortCut for creating an emphasis of (#color->aColor)"

    ^ super new string:aString emphasis:(#color->aColor)

    "

     Dialog

        information:(Text string:'hello' color:(Color red))

    "

    "Created: 12.5.1996 / 17:03:20 / cg"

    "Modified: 27.2.1997 / 10:13:36 / cg"

!

string:aString emphasis:attribute

    "create a Text instance, for the characters in aString,

     which are emphasized as described by attribute."

    ^ super new string:aString emphasis:attribute

    "

     Text string:'hello' emphasis:#bold

     Dialog

        information:(Text string:'hello' emphasis:#bold)

     Dialog

        information:(Text string:'hello' emphasis:#italic)

     Dialog

        information:(Text string:'hello' emphasis:#underline)

     Dialog

        information:(Text string:'hello' emphasis:#strikeout)

    "

    "Modified: 12.5.1996 / 17:16:03 / cg"

!

string:aString emphasisCollection:attributeCollection

    "create a Text instance, for the characters in aString,

     which are individually emphasized as described by attributeCollection."

    ^ super new string:aString emphasisCollection:attributeCollection

    "

     Text 

        string:'hello' 

        emphasisCollection:#(#bold #bold #italic #italic #italic)

     Dialog

        information:(Text 

                        string:'hello' 

                        emphasisCollection:#(#bold #bold #italic #italic #(#underline italic)))

    "

    "Created: 14.5.1996 / 14:02:18 / cg"

    "Modified: 14.5.1996 / 15:01:28 / cg"

!

string:aString foregroundColor:fgColor backgroundColor:bgColor

    "create a Text instance, for the characters in aString,

     which are colored in fgColor on bgColor.

     This is a shortCut for creating an emphasis of 

     #( #color->fgColor) (#backgroundColor->bgColor)"

    ^ super new 

        string:aString 

        emphasis:(Array with:#color->fgColor

                        with:#backgroundColor->bgColor)

    "

     Dialog

        information:(Text string:'hello' 

                          foregroundColor:(Color red)

                          backgroundColor:(Color yellow))

    "

    "Modified: 11.5.1996 / 14:21:01 / cg"

    "Created: 16.5.1996 / 12:37:24 / cg"

!

string:aString runs:aRun

    "create a Text instance, for the characters in aString,

     which are individually emphasized as described by attributeCollection."

    ^ super new string:aString emphasisCollection:aRun.

!

uninitializedNew:size

    "for compatibility only"

    ^ self new:size

!

writeStreamClass

    "the type of stream used in writeStream"

    ^ TextStream

! !

!Text class methodsFor:'emphasis constants'!

backgroundColorEmphasis

    ^ BackgroundColorEmphasis

!

boldEmphasis

    ^ BoldEmphasis

    "Created: / 20-06-2017 / 08:13:07 / cg"

!

colorEmphasis

    ^ ColorEmphasis

    "Created: / 20-06-2017 / 08:12:40 / cg"

!

etchColorEmphasis

    ^ EtchColorEmphasis

    "Created: / 20-06-2017 / 08:14:30 / cg"

!

foregroundColorEmphasis

    ^ ColorEmphasis

!

italicEmphasis

    ^ ItalicEmphasis

    "Created: / 20-06-2017 / 08:12:53 / cg"

!

overlineEmphasis

    ^ OverlineEmphasis

    "Created: / 20-06-2017 / 08:13:43 / cg"

!

reverseEmphasis

    ^ ReverseEmphasis

    "Created: / 20-06-2017 / 08:14:05 / cg"

!

strikeoutEmphasis

    ^ StrikeoutEmphasis

    "Created: / 20-06-2017 / 08:13:53 / cg"

!

subscriptEmphasis

    ^ Subscript

    "Created: / 20-06-2017 / 08:11:41 / cg"

!

superscriptEmphasis

    ^ Superscript

    "Created: / 20-06-2017 / 08:11:27 / cg"

!

underlineEmphasis

    ^ UnderlineEmphasis

    "Created: / 20-06-2017 / 08:13:17 / cg"

!

underwaveEmphasis

    ^ UnderwaveEmphasis

    "Created: / 20-06-2017 / 08:13:30 / cg"

! !

!Text class methodsFor:'emphasis helper'!

addEmphasis:e1 to:e2

    "merge two emphasis's into one"

    |ne|

    e1 isNil ifTrue:[^ e2].

    e2 isNil ifTrue:[^ e1].

    e1 == e2 ifTrue:[^ e1].

    (e1 isSymbol 

     or:[e1 isAssociation]) ifTrue:[

        (e2 isSymbol 

         or:[e2 isAssociation]) ifTrue:[

            ^ Array with:e1 with:e2

        ].

        (e2 includes:e1) ifTrue:[^ e2].

        ^ e2 copyWith:e1

    ].

    (e2 isSymbol 

     or:[e2 isAssociation]) ifTrue:[

        (e1 includes:e2) ifTrue:[^ e1].

        ^ e1 copyWith:e2

    ].

    "/ ould use:

    "/    ^ (e1 asSet addAll:e2; asArray)

    "/ but we do it manually, to preserve the

    "/ order. (should create longer runs, while editing)

    ne := e1.

    e2 do:[:e |

        (ne includes:e) ifFalse:[

           ne := ne copyWith:e

        ]

    ].

    ^ ne.

    "

     Text addEmphasis:#bold to:#bold           

     Text addEmphasis:#bold to:#italic         

     Text addEmphasis:#bold to:#(italic strikeout)