"{ Package: 'stx:libbasic2' }"

"{ NameSpace: Smalltalk }"

Object subclass:#PrintfScanf
	instanceVariableNames:''
	classVariableNames:'Singleton'
	poolDictionaries:''
	category:'System-Support'
!

!PrintfScanf class methodsFor:'documentation'!

documentation
"   
    Contributed by Jan Steinman donated to the community in 1989.

    Provided AS-IS - no warranty, use at your own risk.

    Original comment:

        NAME            printf-scanf
        AUTHOR          Jan Steinman <jans@tekgvs.labs.tek.com>
        FUNCTION        printf and scanf for Smalltalk
        ST-VERSIONS     Tek 2.2.2a 4.0
        PREREQUISITES   CharacterComparing
        CONFLICTS       
        DISTRIBUTION    world
        VERSION         1.1
        DATE            Apr 1989?
        SUMMARY 

    The following methods implement printf and scanf functionality.  They
    are intended to be used to ease porting between Smalltalk and C, and
    for facilitating machine-machine communication.  They are not at all
    intended as replacements for Smalltalk's printOn: functionality.

    Jan Steinman - N7JDB
    Tektronix Electronic Systems Laboratory
    Box 500, MS 50-370, Beaverton, OR 97077
    (w)503/627-5881 (h)503/657-7703

    changes:
        slight changes to make it work with higher precision real numbers
        (i.e. asking for the precision instead of hard-coding it)

        no need for the singleton - classes are already singletons ready to use exactly for that.
        (no need to use C++/Java patterns here in Smalltalk)
"
!

examples
"
    self printf:'%#x %#X %03o%*.*s' arguments: #(16rABCD 16rEF 5 9 5 'ghijklmn')
            -> '0xabcd 0xEF 005    ghijk'

    self printf:'%- 10.4s%.2e' arguments: { 'abcdefghijkl' . Float pi }  
            -> ' abcd      3.14e0'
            
    self printf:'%8.3f' arguments: { 200 sqrt negated }
            -> ' -14.142'

    self printf:'%8.3f' on:Transcript arguments: { 200 sqrt negated }
    self printf:'%10.4f' on:Transcript arguments: { 200 sqrt negated }
    self printf:'%20.10f' on:Transcript arguments: { 200 sqrt negated }

    self printf:'%20.10f' on:Transcript arguments: { 1.234567890123456789f  }
    self printf:'%20.10f' on:Transcript arguments: { 1.234567890123456789q  }

    self printf:'%x' arguments: #(16r41)        -> '41' 
    self printf:'%#x' arguments: #(16r41)       -> '0x41'
    self printf:'%d' arguments: #(16r41)        -> '65'
    self printf:'%b' arguments: #(16r41)        -> '1000001'
    self printf:'%c' arguments: #(16r41)        -> 'A'
    self printf:'%c' arguments: #( $A )         -> 'A'
    self printf:'%s' arguments: #( $A )         -> 'A'
    self printf:'%s' arguments: #( 'hello' )    -> 'hello'
    self printf:'%4s' arguments: #( 'hello' )   -> 'hello'
    self printf:'%7s' arguments: #( 'hello' )   -> '  hello'

    self sscanf:'%f%2s%s%s%s' fromString: '237.0 this is a test' 
            -> OrderedCollection(237.0 'th' 'is' 'is' 'a')

    self sscanf:'%d%f%s' fromString: '25 54.32e-01 monday'
            -> OrderedCollection(25 5.432 'monday')

    self sscanf:'%f%*f %8[A-F0-9]%c%d 0x%x%f' fromString: '12.45 1048.73 AE40Z527 0x75BCD15 34' 
            -> OrderedCollection(12.45 'AE40' 'Z' 527 123456789 34.0)

    '%#x %#X %03o%*.*s' printf: #(16rABCD 16rEF 5 9 5 'ghijklmn') 
            -> '0xabcd 0xEF 005    ghijk'

    '%- 10.4s%.2e' printf: { 'abcdefghijkl' . Float pi }  
            -> ' abcd      3.14e0'

    '%8.3f' printf: { 200 sqrt negated }
            -> ' -14.142'

    '%c' printf: #(16r41)
            -> 'A'

    '%f%2s%s%s%s' sscanf: '237.0 this is a test' 
            -> OrderedCollection(237.0 'th' 'is' 'is' 'a')

    '%d%f%s' sscanf: '25 54.32e-01 monday'
            -> OrderedCollection(25 5.432 'monday')

    '%f%*f %8[A-F0-9]%c%d 0x%x%f' sscanf: '12.45 1048.73 AE40Z527 0x75BCD15 34'
            -> OrderedCollection(12.45 'AE40' 'Z' 527 123456789 34.0)

    '%d\n' printf:{ 1234 } on:Transcript    
    
    '%f\n' printf:{ 1234.0 } on:Transcript        
    '%f\n' printf:{ 1234.0 asShortFloat } on:Transcript        
    '%f\n' printf:{ 1234.0 asLongFloat } on:Transcript        
    '%f\n' printf:{ 1234.0 asQDouble } on:Transcript        
"
! !

!PrintfScanf class methodsFor:'instance creation'!

new
    Singleton isNil ifTrue:[
        Singleton := self basicNew
    ].    
    ^ Singleton
! !

!PrintfScanf class methodsFor:'printing'!

printArgFrom:formatStream to:outStream arguments:argStream
    "Interpret the required number of arguments from <argStream>
     according to the formatting information in <formatStream>.  
     Place the interpretation on <outStream>.  
     The interpretation is C printf(3) style, as described in the UTek manual page for printf(3).  
     <formatStream> is assumed to be positioned just past
     $%, and a complete control string is assumed available.     

     Return when the conversion control string is consumed.  
     Leave <formatStream> pointing past the last character in the conversion control string.

     This code assumes that <formatStream> is formatted according to
     specification, and error checking is minimal.  Unexpected
     results will be obtained by illegal control strings, or when
     argument types do not match conversion codes, but it probably
     won't dump core, like C does in such cases!!!!"    

    |nextArg ljust plus pound width precision pad char arg argString |

    nextArg := [
                    argStream atEnd ifTrue:[
                        self error:'not enough arguments for format string'
                    ].
                    argStream next
               ].

    ljust := plus := pound := false.
    width := 0.
    "/ precision := SmallInteger maxVal.
    precision := nil.
    pad := $ .
    char := formatStream peek.

    char == $% ifTrue:[ 
        ^ outStream nextPut: formatStream next
    ].

    char == $- ifTrue:[
        ljust := true.  
        formatStream next.  
        char := formatStream peek
    ].

    char == $  ifTrue:[
        outStream space.  
        formatStream next.  
        char := formatStream peek
    ].

    char == $+ ifTrue:[
        plus := true.  
        formatStream next. 
        char := formatStream peek
    ].

    char == $# ifTrue:[
        pound := true.  
        formatStream next.  
        char := formatStream peek
    ].

    char == $* ifTrue:[
        width := nextArg value.  
        formatStream next.  
        char := formatStream peek
    ].

    char isDigit ifTrue:[
        char == $0 ifTrue: [pad := $0].
        width := Integer readFrom: formatStream.  
        char := formatStream peek
    ].

    char == $. ifTrue:[
        formatStream next.  char := formatStream peek.
        char == $*
            ifTrue: [precision := nextArg value.  formatStream next.]
            ifFalse: [precision := Integer readFrom: formatStream.].
        char := formatStream peek
    ].

    char == $l ifTrue:[
        "Ignore long specifier."
        formatStream next.  char := formatStream peek
    ].

    ('feg' includes: char) ifTrue:[
        arg := nextArg value.
        arg isLimitedPrecisionReal ifTrue:[
            precision := precision ? (arg class defaultPrintPrecision).
        ] ifFalse:[ 
            arg := arg asFloat.
            precision := precision ? (Float defaultPrintPrecision).
        ].    
        argString := WriteStream on:''.
        char == $g ifTrue: [ 
            self absPrintFloat:arg on: argString digits: precision + 1 ].
        char == $f ifTrue: [ 
            self absDecimalPrintFloat:arg on: argString digits: precision + arg abs log10 + 1].
        char == $e ifTrue: [
            self absScientificPrintFloat:arg on: argString digits: precision + 1].
        argString := argString contents.
        arg < 0
            ifTrue: [argString := '-', argString]
            ifFalse: [plus ifTrue: [argString := '+', argString]].
        (precision = 0 and: [pound not]) ifTrue:[
            (argString includes: $e)
                ifTrue: ["self halt"]
                ifFalse: [
                    argString := arg truncated printString]].
        pound ifTrue:[
            (argString includes: $e)
                ifTrue: ["self halt"]
                ifFalse:[
                    precision - (argString size - (argString indexOf: $.)) 
                        timesRepeat:[
                            argString := argString, '0']]].
        ljust ifTrue: [outStream nextPutAll: argString].
        width - argString size timesRepeat: [outStream nextPut: pad].
        ljust ifFalse: [outStream nextPutAll: argString].
        ^ formatStream next
    ].

    char == $c ifTrue:[
        arg := nextArg value asCharacter asString
    ].
        
    char == $s ifTrue:[
        "Assume the arg is a String or Symbol."
        arg := nextArg value asString
    ].

    char == $d ifTrue:[
        arg := nextArg value asInteger printString.
        plus ifTrue: [arg := '+', arg]
    ].

    char == $u ifTrue:[
        arg := nextArg value asInteger abs printString
    ].

    char == $o ifTrue:[
        arg := nextArg value asInteger abs printStringRadix: 8.
        pound ifTrue: [arg := '0', arg]
    ].

    ('xX' includes: char) ifTrue:[
        arg := nextArg value asInteger abs printStringRadix: 16.
        pound ifTrue: [arg := '0x', arg]
    ].
    ('bB' includes: char) ifTrue:[
        arg := nextArg value asInteger abs printStringRadix: 2.
        pound ifTrue: [arg := '0b', arg]
    ].

    char == $x ifTrue:[
        1 to: arg size do: [:i |
            ('ABCDEF' includes: (arg at: i)) ifTrue:[
                arg at: i put: (arg at: i) asLowercase
            ]
        ]
    ].

    precision := precision ? arg size.
    ljust ifTrue: [outStream nextPutAll: (arg copyFrom: 1 to: precision)].
    width - precision timesRepeat: [outStream nextPut: pad].
    ljust ifFalse: [outStream nextPutAll: (arg copyFrom: 1 to: precision)].
    ^ formatStream next

    "Modified (comment): / 19-06-2017 / 15:46:33 / cg"
!

printf:formatString argument:arg 
    "Format and print the receiver with <arg> formatted in C style, 
     as described in the UTek manual page for printf(3)."

    ^ self printf:formatString arguments:{ arg }

    "
     self printf:'%e' on:Transcript argument:(1.234 asShortFloat)
     self printf:'%e' on:Transcript argument:(1.234 asFloat)     
     self printf:'%e' on:Transcript argument:(1.234 asLongFloat) 
     self printf:'%e' on:Transcript argument:(1.234 asQDouble)   
     self printf:'%e' on:Transcript argument:(1.234 asInteger)   

     self printf:'%10e' on:Transcript argument:(1.234 asShortFloat)
     self printf:'%10e' on:Transcript argument:(1.234 asFloat)     
     self printf:'%10e' on:Transcript argument:(1.234 asLongFloat) 
     self printf:'%10e' on:Transcript argument:(1.234 asQDouble)   
     self printf:'%10e' on:Transcript argument:(1.234 asInteger)   

     self printf:'%010e' on:Transcript argument:(1.234 asInteger)   
     self printf:'%-10e' on:Transcript argument:(1.234 asInteger)   

     self printf:'%10.9f' on:Transcript argument:(1.2345 asShortFloat)
     self printf:'%10.9f' on:Transcript argument:(1.2345 asFloat)     
     self printf:'%10.9f' on:Transcript argument:(1.2345 asLongFloat) 
     self printf:'%10.9f' on:Transcript argument:(1.2345 asQDouble)   
     self printf:'%10.9f' on:Transcript argument:(1.2345 asInteger)   
    "

    "Created: / 16-06-2017 / 14:50:08 / cg"
!

printf:formatString arguments:args 
    "Format and print the receiver with <args> formatted in C style, 
     as described in the UTek manual page for printf(3)."

    |aStream|

    aStream := WriteStream on:(formatString species new:100).
    self printf:formatString on:aStream arguments:args.
    ^ aStream contents

    "
     self printf:'%e' on:Transcript arguments:{ (1.234 asShortFloat) }
     self printf:'%e' on:Transcript arguments:{ (1.234 asFloat)      }
     self printf:'%e' on:Transcript arguments:{ (1.234 asLongFloat)  }
     self printf:'%e' on:Transcript arguments:{ (1.234 asQDouble)    }
     self printf:'%e' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%10e' on:Transcript arguments:{ (1.234 asShortFloat) }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asFloat)      }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asLongFloat)  }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asQDouble)    }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%010e' on:Transcript arguments:{ (1.234 asInteger)    }
     self printf:'%-10e' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asShortFloat) }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asFloat)      }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asLongFloat)  }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asQDouble)    }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asInteger)    }
    "

    "Modified: / 19-06-2017 / 15:21:34 / cg"
!

printf:formatString on:outStream argument: arg
    "Format and print formatString on <outStream> with <arg>
     formatted in C style, as described in the UTek manual page for
     printf(3)."     

    ^ self printf:formatString on:outStream arguments:{ arg }

    "
     self printf:'%e' on:Transcript argument:(1.234 asShortFloat). Transcript cr.
     self printf:'%e' on:Transcript argument:(1.234 asFloat)     . Transcript cr.
     self printf:'%e' on:Transcript argument:(1.234 asLongFloat) . Transcript cr.
     self printf:'%e' on:Transcript argument:(1.234 asQDouble)   . Transcript cr.
     self printf:'%e' on:Transcript argument:(1.234 asInteger)   . Transcript cr.

     self printf:'%10e' on:Transcript argument:(1.234 asShortFloat). Transcript cr.
     self printf:'%10e' on:Transcript argument:(1.234 asFloat)     . Transcript cr.
     self printf:'%10e' on:Transcript argument:(1.234 asLongFloat) . Transcript cr.
     self printf:'%10e' on:Transcript argument:(1.234 asQDouble)   . Transcript cr.
     self printf:'%10e' on:Transcript argument:(1.234 asInteger)   . Transcript cr.

     self printf:'%010e' on:Transcript argument:(1.234 asInteger)  . Transcript cr.
     self printf:'%-10e' on:Transcript argument:(1.234 asInteger)  . Transcript cr.

     self printf:'%10.9f' on:Transcript argument:(1.2345 asShortFloat). Transcript cr.
     self printf:'%10.9f' on:Transcript argument:(1.2345 asFloat)     . Transcript cr.
     self printf:'%10.9f' on:Transcript argument:(1.2345 asLongFloat) . Transcript cr.
     self printf:'%10.9f' on:Transcript argument:(1.2345 asQDouble)   . Transcript cr.
     self printf:'%10.9f' on:Transcript argument:(1.2345 asInteger)   . Transcript cr.
    "

    "Created: / 16-06-2017 / 14:50:40 / cg"
    "Modified (comment): / 19-06-2017 / 15:07:22 / cg"
!

printf:aFormatString on:outStream arguments: args
    "Format and print aFormatString on <outStream> with <args>
     formatted in C style, as described in the UTek manual page for
     printf(3)."     

    | argStream formatStream char escChar |

    argStream := ReadStream on: args.
    formatStream := ReadStream on: aFormatString.
    [formatStream atEnd] whileFalse:[
        (char := formatStream next) == $% ifFalse: [
            char == $\ ifTrue:[
                escChar := formatStream next.
                escChar == $n ifTrue:[ char := Character nl ]
                ifFalse:[ escChar == $t ifTrue:[ char := Character tab ]
                ifFalse:[ escChar == $r ifTrue:[ char := Character return ]
                ifFalse:[ char := escChar ]]]
            ].        
            outStream nextPut:char
        ] ifTrue: [
            self printArgFrom:formatStream to:outStream arguments:argStream
        ]
    ]

    "
     self printf:'%e\n' on:Transcript arguments:{ (1.234 asShortFloat) }
     self printf:'%f\n' on:Transcript arguments:{ (1.234 asShortFloat) }
     self printf:'%g\n' on:Transcript arguments:{ (1.234 asShortFloat) }

     self printf:'%e\n' on:Transcript arguments:{ (1.234 asFloat)      }
     self printf:'%f\n' on:Transcript arguments:{ (1.234 asFloat)      }
     self printf:'%g\n' on:Transcript arguments:{ (1.234 asFloat)      }

     self printf:'%e\n' on:Transcript arguments:{ (1.234 asLongFloat)  }
     self printf:'%e\n' on:Transcript arguments:{ (1.234 asQDouble)    }
     self printf:'%e\n' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%10e' on:Transcript arguments:{ (1.234 asShortFloat) }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asFloat)      }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asLongFloat)  }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asQDouble)    }
     self printf:'%10e' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%010e' on:Transcript arguments:{ (1.234 asInteger)    }
     self printf:'%-10e' on:Transcript arguments:{ (1.234 asInteger)    }

     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asShortFloat) }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asFloat)      }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asLongFloat)  }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asQDouble)    }
     self printf:'%10.9f' on:Transcript arguments:{ (1.2345 asInteger)    }
    "

    "Modified (comment): / 19-06-2017 / 15:49:10 / cg"
! !

!PrintfScanf class methodsFor:'private helpers'!

absDecimalPrintFloat:aFloat on:aStream digits:digits 
    "Place a string representation of the receiver on <aStream>,
     using <digits> significant digits, using decimal notation."
    
    "
     self printf:'%20.10f' on:Transcript arguments: { 1.234567890123456789f  }
     self printf:'%20.10f' on:Transcript arguments: { 1.234567890123456789q  }
    "

    |absVal exp x fuzz i|

    absVal := aFloat abs.

    "x is myself normalized to (1.0, 10.0), exp is my exponent"
    exp := absVal < 1.0 
            ifTrue:[ 
                (10.0 / absVal) log10 floor asInteger negated ] 
            ifFalse:[
                absVal log10 floor asInteger].
    x := absVal / (10.0 raisedTo:exp).
    fuzz := 10.0 raisedTo:1 - digits.
    "round the last digit to be printed"
    x := 0.5 * fuzz + x.
    x >= 10.0 ifTrue:[ 
        "check if rounding has unnormalized x" 
        x := x / 10.0.
        exp := exp + 1
    ].
    
    exp < 0 ifTrue:[
        1 to:(1 - exp) do:[:j | 
            "/ cg: huh - what sort of code is that????
            "/ aStream nextPut:('0.000000000000' at:j)
            aStream nextPut:(j == 2 ifTrue:[$.] ifFalse:[$0])
        ].
        
    ].
    [ x >= fuzz ] whileTrue:[ 
        "use fuzz to track significance" 
        i := x truncated.
        i := i asInteger.
        aStream nextPut:(48 + i) asCharacter.
        x := (x - i) * 10.0.
        fuzz := fuzz * 10.0.
        exp := exp - 1.
        exp = -1 ifTrue:[
            aStream nextPut:$.
        ]
    ].
    [ exp >= -1 ] whileTrue:[
        aStream nextPut:$0.
        exp := exp - 1.
        exp = -1 ifTrue:[
            aStream nextPut:$.
        ]
    ]

    "Modified: / 19-06-2017 / 18:06:51 / cg"
!

absPrintFloat:aFloat on:aStream digits:digits 
    "Place a string representation of the receiver on <aStream>,
     using <digits> significant digits."
    
    (aFloat < 1.0e6 and:[ aFloat > 1.0e-4 ]) ifTrue:[
        self absDecimalPrintFloat:aFloat on:aStream digits:digits
    ] ifFalse:[
        self absScientificPrintFloat:aFloat on:aStream digits:digits
    ]

    "Modified: / 19-06-2017 / 15:03:40 / cg"
!

absScientificPrintFloat:aFloat on:aStream digits:digits 
    "Place a string representation of the receiver on <aStream>,
     using <digits> significant digits, using scientific notation."
    
    |absVal exp fuzz x q i|

    absVal := aFloat abs.
    
    "x is myself normalized to [1.0, 10.0), exp is my exponent"
    exp := absVal < 1.0 
                ifTrue:[
                    (10.0 / absVal) log10 floor asInteger negated]
                ifFalse:[
                    absVal log10 floor asInteger].
    x := absVal / (10.0 raisedTo:exp).
    "round the last digit to be printed"
    fuzz := 10.0 raisedTo:1 - digits.
    x := 0.5 * fuzz + x.
    x >= 10.0 ifTrue:[ "check if rounding has unnormalized x" 
        x := x / 10.0.
        exp := exp + 1
    ].
    q := exp.
    exp := 0.
    [ x >= fuzz ] whileTrue:[
        "use fuzz to track significance" 
        i := x truncated.
        i := i asInteger.
        aStream nextPut:(48 + i) asCharacter.
        x := (x - i) * 10.0.
        fuzz := fuzz * 10.0.
        exp := exp - 1.
        exp = -1 ifTrue:[
            aStream nextPut:$.
        ]
    ].
    [ exp >= -1 ] whileTrue:[
        aStream nextPut:$0.
        exp := exp - 1.
        exp = -1 ifTrue:[
            aStream nextPut:$.
        ]
    ].
    aStream nextPut:$e.
    q printOn:aStream

    "Modified: / 19-06-2017 / 15:57:09 / cg"
!

formatArgCountFor:aFormatString
    "Return the number of arguments required/produced,
     if the argument is interpreted as a printf/scanf format control string."

    |nonConsecutive count|

    nonConsecutive := true.
    count := 0.
    aFormatString do:[:c |
        c == $% ifTrue:[
            nonConsecutive ifTrue:[
                count := count + 1. 
                nonConsecutive := false
            ] ifFalse:[
                count := count - 1. 
                nonConsecutive := true
            ]
        ] ifFalse:[
            nonConsecutive := true
        ]
    ].
    ^ count
!

scanArgFrom:dataStream to:collection format:format 
    "Add to <collection> an object who's representation is found
     in <dataStream> interpreted according to the conversion
     control string in the Stream <format>.  <format> is assumed to
     be positioned just past a $%, and a complete control string is
     assumed available.    

     Return when the conversion control string is consumed.  Leave
     <format> pointing past the last character in the conversion
     control string, leave <dataStream> pointing past any width
     specified in <format>, or at the first character that doesn't
     make sense for the <format>."

    |final width char pos data scanset exclusive return last|

    final := [:retval | 
            collection add:retval.
            data == dataStream ifFalse:[
                dataStream position:dataStream position + data position
            ].
            ^ self
        ].

    char := format peek.
    char == $% ifTrue:[
        ^ dataStream peekFor:char
    ].
    char == $* ifTrue:[
        format next.
        char := format peek.
        final := [:retval | 
                data == dataStream ifFalse:[
                    dataStream position:dataStream position + data position
                ].
                ^ self
            ]
    ].
    width := 0.
    char isDigit ifTrue:[
        width := Integer readFrom:format.
        char := format peek
    ].
    ('slhduoxfeg' includes:char) ifTrue:[
        dataStream skipSeparators
    ].
    width = 0 ifTrue:[
        data := dataStream
    ] ifFalse:[
        pos := dataStream position.
        data := ReadStream on:(dataStream next:width).
        dataStream position:pos
    ].
    char == $s ifTrue:[
        final value:(data upToSeparator)
    ].
    char == $c ifTrue:[
        width = 0 ifTrue:[
            final value:(String with:data next)
        ] ifFalse:[
            final value:data contents
        ]
    ].
    char == $[ ifTrue:[
        "What a mess!!!!" 
        return := CharacterWriteStream on:(String new:8).
        scanset := IdentitySet new.
        format next.
        width = 0 ifTrue:[
            width := SmallInteger maxVal
        ].
        exclusive := format peekFor:$^.
        [
            last := char.
            char := format next.
            char == $]
        ] whileFalse:[
            char == $- ifFalse:[
                scanset add:char
            ] ifTrue:[
                last to:format next do:[:c | 
                    scanset add:c
                ]
            ]
        ].
        [
            data atEnd not and:[ (scanset includes:data peek) xor:exclusive ]
        ] whileTrue:[ return nextPut:data next ].
        final value:return contents
    ].
    ('lh' includes:char) ifTrue:[
        format next.
        char := format peek
    ].
    ('DUdu' includes:char) ifTrue:[
        final value:(Integer readFrom:data)
    ].
    ('FEGfeg' includes:char) ifTrue:[
        final value:(Float readFrom:data)
    ].
    ('Oo' includes:char) ifTrue:[
        final value:(Integer readFrom:data radix:8)
    ].
    ('Xx' includes:char) ifTrue:[
        final value:(Integer readFrom:data radix:16)
    ].
    ('Bb' includes:char) ifTrue:[
        final value:(Integer readFrom:data radix:2)
    ].

    "Created: / 19-06-2017 / 15:53:28 / cg"
! !

!PrintfScanf class methodsFor:'scanning'!

scanf:formatString fromStream:dataStream 
    "Return a Collection of objects found in the Character Stream
     <dataStream> as interpreted according to the receiver.  The
     receiver is assumed to be a conversion control string as
     specified in the UTek manual page for scanf(3)."

    |results format char|

    results := OrderedCollection new.
    format := ReadStream on:formatString.
    [ format atEnd ] whileFalse:[
        char := format next.
        (char == Character space or:[ char == Character tab ]) ifTrue:[
            dataStream skipSeparators.
            format skipSeparators
        ].
        char == $% ifTrue:[
            self scanArgFrom:dataStream to:results format:format
        ] ifFalse:[
            dataStream peekFor:char
        ]
    ].
    ^ results

    "Modified: / 19-06-2017 / 15:53:04 / cg"
!

sscanf:formatString fromString:aString 
    "Return a Collection of objects found in <string> as
     interpreted according to the receiver.  The receiver is
     assumed to be a conversion control string as specified in the
     UTek manual page for scanf(3)."

    ^ self scanf:formatString fromStream:(ReadStream on:aString)

    "Modified: / 19-06-2017 / 15:53:59 / cg"
! !

!PrintfScanf methodsFor:'helpers'!

absDecimalPrintFloat:arg1 on:arg2 digits:arg3
    <resource: #obsolete>
    ^ self class absDecimalPrintFloat:arg1 on:arg2 digits:arg3
!

absPrintFloat:arg1 on:arg2 digits:arg3
    <resource: #obsolete>
    ^ self class absPrintFloat:arg1 on:arg2 digits:arg3
!

absScientificPrintFloat:arg1 on:arg2 digits:arg3
    <resource: #obsolete>
    ^ self class absScientificPrintFloat:arg1 on:arg2 digits:arg3
!

formatArgCountFor:arg
    <resource: #obsolete>
    ^ self class formatArgCountFor:arg
! !

!PrintfScanf methodsFor:'printing'!

printArgFrom:arg1 to:arg2 arguments:arg3
    <resource: #obsolete>
    ^ self class printArgFrom:arg1 to:arg2 arguments:arg3
!

printf:aString arguments:args
    <resource: #obsolete>
 
    "Format and print the receiver with <args> formatted in C style, 
     as described in the UTek manual page for printf(3).
     Returns the formatted printString."
    
    ^ self class printf:aString arguments:args

    "
     self new printf:'%d %x' arguments:#(1234 45054) 
    "

    "Modified: / 19-06-2017 / 15:21:56 / cg"
!

printf:aFormatString on:outStream arguments: args
    <resource: #obsolete>
    "Format and print aFormatString on <outStream> with <args>
     formatted in C style, as described in the UTek manual page for
     printf(3)."     

    self class printf:aFormatString on:outStream arguments: args

    "Modified (comment): / 19-06-2017 / 15:22:15 / cg"
! !

!PrintfScanf methodsFor:'scanning'!

scanArgFrom:dataStream to:collection format:format
    <resource: #obsolete>
 
    "Add to <collection> an object who's representation is found
     in <dataStream> interpreted according to the conversion
     control string in the Stream <format>.  <format> is assumed to
     be positioned just past a $%, and a complete control string is
     assumed available.    

     Return when the conversion control string is consumed.  Leave
     <format> pointing past the last character in the conversion
     control string, leave <dataStream> pointing past any width
     specified in <format>, or at the first character that doesn't
     make sense for the <format>."
    
    ^ self class scanArgFrom:dataStream to:collection format:format

    "Modified: / 19-06-2017 / 15:54:43 / cg"
!

scanf:formatString fromStream:dataStream
    <resource: #obsolete>
 
    "Return a Collection of objects found in the Character Stream
     <dataStream> as interpreted according to the receiver.  The
     receiver is assumed to be a conversion control string as
     specified in the UTek manual page for scanf(3)."
    
    ^ self class scanf:formatString fromStream:dataStream

    "Modified: / 19-06-2017 / 15:54:27 / cg"
!

sscanf:formatString fromString:aString
    <resource: #obsolete>
 
    "Return a Collection of objects found in <string> as
     interpreted according to the receiver.  The receiver is
     assumed to be a conversion control string as specified in the
     UTek manual page for scanf(3)."
    
    ^ self class sscanf:formatString fromString:aString

    "
     self new sscanf:'%d %x' fromString:'1234 affe'
    "

    "Modified: / 19-06-2017 / 15:54:14 / cg"
! !

!PrintfScanf class methodsFor:'documentation'!

version
    ^ '$Header$'
!

version_CVS
    ^ '$Header$'
! !