"

 Copyright (C) Original Authors (Kaehler, Scott Wallace and Dan Ingalls)

 Copyright (C) 2001 eXept Software AG

 Permission is hereby granted, free of charge, to any 

 person obtaining a copy of this software and associated 

 documentation files (the 'Software'), to deal in the 

 Software without restriction, including without limitation 

 the rights to use, copy, modify, merge, publish, distribute, 

 sublicense, and/or sell copies of the Software, and to 

 permit persons to whom the Software is furnished to do so, 

 subject to the following conditions:

 The above copyright notice and this permission notice shall 

 be included in all copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, 

 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES 

 OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. 

 IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY 

 CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, 

 TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE 

 SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

"

"{ Package: 'stx:libbasic3' }"

"{ NameSpace: Smalltalk }"

Object subclass:#MethodFinder

	instanceVariableNames:'data answers selector argMap thisData mapStage mapList

		expressions cachedClass cachedArgNum cachedSelectorLists'

	classVariableNames:'AddAndRemove Approved Blocks BlocksOptional Dangerous'

	poolDictionaries:''

	category:'Interface-Tools'

!

!MethodFinder class methodsFor:'documentation'!

copyright

"

 Copyright (C) Original Authors (Kaehler, Scott Wallace and Dan Ingalls)

 Copyright (C) 2001 eXept Software AG

 Permission is hereby granted, free of charge, to any 

 person obtaining a copy of this software and associated 

 documentation files (the 'Software'), to deal in the 

 Software without restriction, including without limitation 

 the rights to use, copy, modify, merge, publish, distribute, 

 sublicense, and/or sell copies of the Software, and to 

 permit persons to whom the Software is furnished to do so, 

 subject to the following conditions:

 The above copyright notice and this permission notice shall 

 be included in all copies or substantial portions of the Software.

 THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND, 

 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES 

 OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. 

 IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY 

 CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, 

 TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE 

 SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

"

!

documentation

"

  a utility to find implementing methods by example.

  Give it values for a receiver, optional arguments and a desired result,

  and it will find methods which do that for you.

  Please read the online documentation for details,

  or open the MethodFinderView GUI.

  [example:]

    which message, answers 7, given to 4 with an argument of 3,

    and also answers 5, if sent with an arg of 5 to 0

    and 10, if send to 5 with an argument of 5:    

      MethodFinder methodFor: #(

                                (4 3) 7

                                (0 5) 5

                                (5 5) 10

                              )

    You guessed it; it's the '+' message. 

  [author:]

    original squeak version by Ted Kaehler, Scott Wallace and Dan Ingalls.

    ported from Squeak and GUI enhanced 2001 by James Hayes james@exept.de.

    improved by Claus Gittinger.

"

! !

!MethodFinder class methodsFor:'accessing'!

abortAllSignal

    "return the value of the static variable 'AbortAllSignal' (automatically generated)"

    ^ AbortAllSignal

!

abortAllSignal:something

    "set the value of the static variable 'AbortAllSignal' (automatically generated)"

    AbortAllSignal := something.

!

addAndRemove

    "return the value of the static variable 'AddAndRemove' (automatically generated)"

    ^ AddAndRemove

!

addAndRemove:something

    "set the value of the static variable 'AddAndRemove' (automatically generated)"

    AddAndRemove := something.

!

approved

    "return the value of the static variable 'Approved' (automatically generated)"

    ^ Approved

!

approved:something

    "set the value of the static variable 'Approved' (automatically generated)"

    Approved := something.

!

blocks

    "return the value of the static variable 'Blocks' (automatically generated)"

    ^ Blocks

!

blocks:something

    "set the value of the static variable 'Blocks' (automatically generated)"

    Blocks := something.

!

dangerous

    "return the value of the static variable 'Dangerous' (automatically generated)"

    ^ Dangerous

!

dangerous:something

    "set the value of the static variable 'Dangerous' (automatically generated)"

    Dangerous := something.

! !

!MethodFinder class methodsFor:'utilities'!

methodFor: dataAndAnswers

    "Return a Smalltalk expression that computes these answers."

    | resultOC resultString |

    resultOC := (self new) load: dataAndAnswers; findMessage.

    resultString := 

        String streamContents: [:strm |

            resultOC do: [:exp | strm nextPut: $(; nextPutAll: exp; nextPut: $); space]

        ].

    ^ resultString

! !

!MethodFinder methodsFor:'accessing'!

answers

        ^ answers

!

data

        ^ data

!

expressions

        ^ expressions

!

selectors

        "Note the inst var does not have an S on the end"

        ^ selector

! !

!MethodFinder methodsFor:'arg maps'!

argMap

        ^ argMap 

!

makeAllMaps 

        "Make a giant list of all permutations of the args.  To find the function, we will try these permutations of the input data.  receiver, args."

        | ii |

        mapList _ Array new: argMap size factorial.

        ii _ 1.

        argMap permutationsDo: [:perm |

                mapList at: ii put: perm copy.

                ii _ ii + 1].

        mapStage _ 1.   "about to be bumped"

!

mapData 

        "Force the data through the map (permutation) to create the data to test."

        thisData _ data collect: [:realData |

                                        argMap collect: [:ind | realData at: ind]].

!

permuteArgs 

        "Run through ALL the permutations.  First one was as presented."

        data first size <= 1 ifTrue: [^ false]. "no other way"

        mapList isNil ifTrue: [self makeAllMaps].

        mapStage _ mapStage + 1.

        mapStage > mapList size ifTrue: [^ false].

        argMap _ mapList at: mapStage.

        self mapData.

        ^ true

!

thisData

        ^ thisData 

! !

!MethodFinder methodsFor:'find a constant'!

allNumbers

        "Return true if all answers and all data are numbers."

        answers do: [:aa | aa isNumber ifFalse: [^ false]].

        thisData do: [:vec |

                        vec do: [:nn | nn isNumber ifFalse: [^ false]]].

        ^ true

!

const

        | const |

        "See if (^ constant) is the answer"

        "quick test"

        ((const _ answers at: 1) closeTo: (answers at: 2)) ifFalse: [^ false].

        3 to: answers size do: [:ii | (const closeTo: (answers at: ii)) ifFalse: [^ false]].

        expressions add: '^ ', const printString.

        selector add: #yourself.

        ^ true

!

constDiv

        "See if (data1 // C) is the answer"

        self breakPoint:#cg.

        ^ false.

"/        const _ ((thisData at: 1) at: 1) // (answers at: 1).  "May not be right!!"

"/        got _ (subTest _ MethodFinder new copy: self addArg: const) 

"/                                searchForOne isEmpty not.

"/        got ifFalse: [^ false]. 

"/

"/        "replace data2 with const in expressions"

"/        subTest expressions do: [:exp |

"/                expressions add: (exp copyReplaceString: "copyReplaceAll:" 'data2' withString: "with:" const printString)].

"/        selector addAll: subTest selectors.

"/        ^ true

!

constLessThan

        | const subTest got minConst maxConst tt |

        "See if (data1 <= C) or (data1 >= C) is the answer"

        "quick test"

        ((answers at: 1) class superclass == Boolean) ifFalse: [^ false].

        2 to: answers size do: [:ii | 

                ((answers at: ii) class superclass == Boolean) ifFalse: [^ false]].

        minConst _ Float infinity.  maxConst _ minConst negated.

        answers withIndexDo: [:aa :ii |

                aa ifTrue: [tt _ (thisData at: ii) at: 1.

                        minConst _ minConst min: tt.

                        maxConst _ maxConst max: tt]].

        const _ (thisData at: 1) at: 1.

        got _ (subTest _ MethodFinder new copy: self addArg: minConst) 

                                searchForOne isEmpty not.

        got ifFalse: ["try other extreme for <= >= "

                got _ (subTest _ MethodFinder new copy: self addArg: maxConst) 

                                searchForOne isEmpty not]. 

        got ifFalse: [^ false]. 

        "replace data2 with const in expressions"

        subTest expressions do: [:exp |

                expressions add: (exp copyReplaceString: "copyReplaceAll:" 'data2' withString: "with:" const printString)].

        selector addAll: subTest selectors.

        ^ true

!

constLinear

        | const subTest got denom num slope offset |

        "See if (data1 * C1) + C2 is the answer.  In the form  #(C2 C1) polynomialEval: data1 "

        denom _ ((thisData at: 2) at: 1) - ((thisData at: 1) at: 1).

        denom = 0 ifTrue: [^ false].   "will divide by it"

        num _ (answers at: 2) - (answers at: 1).

    slope := (num asFloat / denom) reduce.

    offset := ((answers at: 2) - (((thisData at: 2) at: 1) * slope)) reduce.

        const _ Array with: offset with: slope.

        got _ (subTest _ MethodFinder new copy: self addArg: const) 

                                searchForOne isEmpty not.

        got ifFalse: [^ false]. 

        "replace data2 with const in expressions"

        subTest expressions do: [:exp |

                expressions add: (exp copyReplaceString: "copyReplaceAll:" 'data2' withString: "with:" const printString)].

        selector addAll: subTest selectors.

        ^ true

!

constMod

        | subTest low |

        "See if mod, (data1 \\ C) is the answer"

        low _ answers max.

        low+1 to: low+20 do: [:const |

                subTest _ MethodFinder new copy: self addArg: const.

                (subTest testPerfect: #\\) ifTrue: [

                        expressions add: 'data1 \\ ', const printString.

                        selector add: #\\.

                        ^ true]].

        ^ false

!

constMult

        | const subTest got |

        "See if (data1 * C) is the answer"

        ((thisData at: 1) at: 1) = 0 ifTrue: [^ false].

        const _ ((answers at: 1) asFloat / ((thisData at: 1) at: 1)) reduce.

        got _ (subTest _ MethodFinder new copy: self addArg: const) 

                                searchForOne isEmpty not.

        got ifFalse: [^ false]. 

        "replace data2 with const in expressions"

        subTest expressions do: [:exp |

                expressions add: (exp copyReplaceString: "copyReplaceAll:" 'data2' withString: "with:" const printString)].

        selector addAll: subTest selectors.

        ^ true

!

constPlus

        | const subTest got |

        "See if (data1 + C) is the answer"

        const _ (answers at: 1) - ((thisData at: 1) at: 1).

        got _ (subTest _ MethodFinder new copy: self addArg: const) 

                                searchForOne isEmpty not.

        got ifFalse: [^ false]. 

        "replace data2 with const in expressions"

        subTest expressions do: [:exp |

                expressions add: (exp copyReplaceString: "copyReplaceAll:" 'data2' withString: "with:" const printString)].

        selector addAll: subTest selectors.

        ^ true

! !

!MethodFinder methodsFor:'initialization'!

cleanInputs:dataAndAnswerString 

    "Find and remove common mistakes.  Complain when ill formed."

    |fixed ddd rs places|

    ddd := dataAndAnswerString.

    "/ check if user typed #true / #false instead of true / false

    fixed := false.

    rs := ReadStream on:ddd , ' '.

    places := OrderedCollection new.

    [

        rs upToAll_positionBefore:'#true'.

        rs atEnd

    ] whileFalse:[ places addFirst:rs position ].

    places do:[:pos | 

        ddd := ddd 

                copyReplaceFrom:pos

                to:pos

                with:''.

        fixed := true

    ].

    rs := ReadStream on:ddd.

    places := OrderedCollection new.

    [

        rs upToAll_positionBefore:'#false'.

        rs atEnd

    ] whileFalse:[ places addFirst:rs position ].

    places do:[:pos | 

        ddd := ddd 

                copyReplaceFrom:pos

                to:pos

                with:''.

        fixed := true

    ].

    fixed ifTrue:[

        self 

            information:'#(true false) are Symbols, not Booleans.  

Next time use { true. false }.'

    ].

    "/ check if user typed #nil instead of nil

    fixed := false.

    rs := ReadStream on:ddd.

    places := OrderedCollection new.

    [

        rs upToAll_positionBefore:'#nil'.

        rs atEnd

    ] whileFalse:[ places addFirst:rs position ].

    places do:[:pos | 

        ddd := ddd 

                copyReplaceFrom:pos

                to:pos

                with:''.

        fixed := true

    ].

    fixed ifTrue:[

        self 

            information:'#nil is a Symbol, not the authentic UndefinedObject.  

Next time use nil instead of #nil'

    ].

    ^ ddd

!

initialize

        "The methods we are allowed to use.  (MethodFinder new initialize) "

        Approved _ Set new.

        AddAndRemove _ Set new.

        Blocks _ Set new.

        BlocksOptional := Set new.

        "These modify an argument: longPrintOn: printOn: storeOn: sentTo: storeOn:base: printOn:base: absPrintExactlyOn:base: absPrintOn:base: absPrintOn:base:digitCount: writeOn: writeScanOn: possibleVariablesFor:continuedFrom:"

"Object"  

        #(

    "in class, instance creation" 

        categoryForUniclasses chooseUniqueClassName initialInstance isSystemDefined newFrom: officialClass readCarefullyFrom:

    "accessing" 

        at: basicAt: basicSize bindWithTemp: in: size yourself 

    "testing" 

        basicType ifNil: #'ifNil:ifNotNil:' ifNotNil: #'ifNotNil:ifNil:' 

        isColor isArray isFloat isFraction isInMemory isInteger isMorph isNil isNumber 

        isPoint isPseudoContext isText isTransparent isWebBrowser isCollection

        knownName notNil pointsTo: wantsSteps 

    "comparing" 

        = == closeTo: hash hashMappedBy: identityHash identityHashMappedBy: identityHashPrintString 

        ~= ~~ 

    "copying" 

        clone copy shallowCopy 

    "dependents access" 

        canDiscardEdits dependents hasUnacceptedEdits 

    "updating" 

        "changed changed: okToChange update: windowIsClosing" - not useful 

    "printing" 

        fullPrintString isLiteral longPrintString printString storeString stringForReadout stringRepresentation 

    "class membership" 

        class isKindOf: #'isKindOf:orOf:' isMemberOf: respondsTo: respondsToArithmetic  

    "error handling" 

    "user interface" 

        defaultBackgroundColor defaultLabelForInspector fullScreenSize initialExtent modelWakeUp mouseUpBalk: 

        "newTileMorphRepresentative" windowActiveOnFirstClick windowReqNewLabel: 

    "system primitives"  

        instVarAt: instVarNamed: 

    "private" 

    "associating" -> 

    "converting" 

        as: asOrderedCollection asString 

    "casing" 

        caseOf: #'caseOf:otherwise:' 

    "binding" 

        bindingOf: 

    "macpal" 

        contentsChanged #'ifKindOf:thenDo:' instanceVariableValues  

    "flagging" 

        flag: 

    "translation support" 

    "objects from disk" 

    "finalization" 

    "ST/X converting"

        literalArrayEncoding

        ) do: [:sel | Approved add: sel].