"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Object subclass:#SourceFileLoader

	instanceVariableNames:'myStream currentSource package wantChangeLog currentNameSpace

		usedNameSpaces'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Compiler'

!

!SourceFileLoader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    Instances of this class are created temporary during fileIn.

    They get notified about any errors. Currently, all we

    do here is to output the error on the Transcript;

    eventually, we will open a box showing the position of the error.

    Also, information found in scanned compiler directives is remembered

    here, for later queries (this is required, since the fileIn mechanism

    creates new parsers for every chunk - someone has to remember this

    information across chunks ...).

    [author:]

        Claus Gittinger

"

! !

!SourceFileLoader class methodsFor:'instance creation'!

on:aStream

    ^ self new reader:aStream wantChangeLog:false

! !

!SourceFileLoader methodsFor:'accessing'!

source:aString

    "this is optionally sent by the chunk reader,

     to pass a single chunks source before its evaluated.

     This allows me to show the erronous code in a TextView

     (but this is not yet implemented)"

    currentSource := aString

    "Modified: 5.1.1997 / 03:06:32 / cg"

! !

!SourceFileLoader methodsFor:'compiler queries'!

currentNameSpace

    "sent by the compiler to ask for the current nameSpace.

     This is still to be finished ..."

    currentNameSpace isNil ifTrue:[

        currentNameSpace := Class nameSpaceQuerySignal raise.

        "/ currentNameSpace := Smalltalk defaultNameSpace

    ].

    ^ currentNameSpace

    "Created: 5.11.1996 / 22:05:19 / cg"

    "Modified: 20.12.1996 / 00:01:32 / cg"

!

packageToInstall

    "sent by the compiler to ask in which package new methods/classes

     are to be installed.

     This is still to be finished ..."

    package isNil ifTrue:[

        package := Class packageQuerySignal raise.

        "/ package := Project currentPackageName

    ].

    ^ package

    "Created: 5.11.1996 / 19:56:03 / cg"

    "Modified: 20.12.1996 / 00:01:41 / cg"

!

usedNameSpaces

    "sent by the compiler to ask for a list of used nameSpaces.

     This is still to be finished ..."

    ^ usedNameSpaces

    "Created: 5.11.1996 / 22:05:37 / cg"

!

wantChangeLog

    "sent by the compiler to ask if a changeLog entry should

     be written. Return false here, since SourceFileLaoders are

     used to read existing source files"

    ^ wantChangeLog

! !

!SourceFileLoader methodsFor:'directve processing'!

addUsedSpace:aNameSpace

    "sent by the compiler, whenever it encounters a 'Uses:'

     directive; collect used namespaces here, for later namespace

     queries"

    usedNameSpaces isNil ifTrue:[

        usedNameSpaces := OrderedCollection new.

    ].

    usedNameSpaces add:aNameSpace

    "Created: 19.12.1996 / 22:26:12 / cg"

    "Modified: 5.1.1997 / 03:07:17 / cg"

!

addUsedSpaces:aNameSpaceList

    "sent by the compiler, whenever it encounters a 'Uses:'

     directive; collect used namespaces here, for later namespace

     queries"

    usedNameSpaces isNil ifTrue:[

        usedNameSpaces := OrderedCollection new.

    ].

    aNameSpaceList do:[:aNameSpace |

        usedNameSpaces add:aNameSpace

    ].

    "Created: 19.12.1996 / 22:26:23 / cg"

    "Modified: 5.1.1997 / 03:07:24 / cg"

!

requirePackage:packageName

    "sent by the compiler, whenever it encounters a 'Prerequisites:'

     directive. For now, this is ignored."

    'require package: ' print.

    packageName printCR

    "Modified: 5.1.1997 / 03:08:06 / cg"

!

setNameSpace:aNameSpaceName

    "sent by the compiler, whenever it encounters a 'NameSpace:'

     directive. Remember the namespace for further variable resolving

     and nameSpace queries."

    currentNameSpace := Namespace fullName:aNameSpaceName

    "Modified: 5.1.1997 / 03:08:43 / cg"

!

setPackage:packageName

    "sent by the compiler, whenever it encounters a 'Package:'

     directive. Remember the package for further queries."

    package := packageName asSymbol

    "Modified: 5.1.1997 / 03:09:00 / cg"

! !

!SourceFileLoader methodsFor:'error handling'!

correctableError:aMessage position:position to:endPos from:aCompiler

    "error notification during fileIn.

     This is sent by the compiler/evaluator if it detects errors."

    Transcript show:'**  '; showCR:aMessage.

    self showWherePosition:position to:endPos from:aCompiler.

    ^ false

    "Modified: 8.11.1996 / 18:53:17 / cg"

!

error:aMessage position:position to:endPos from:aCompiler

    "error notification during fileIn.

     This is sent by the compiler/evaluator if it detects errors."

    "

     will eventually open a TextBox here, showing the error ....

    "

    Transcript show:'===>  '; showCR:aMessage.

    self showWherePosition:position to:endPos from:aCompiler.

    ^ false

    "Modified: 8.11.1996 / 18:49:41 / cg"

!

insertAndSelect:aString at:aCharacterPosition

    "ST-80 compatible error notification during fileIn."

    "

     will eventually open a TextBox here, showing the error ....

    "

    Transcript show:'===>  '; showCR:aString.

    ^ false

    "Modified: 18.5.1996 / 15:44:54 / cg"

!

showWherePosition:position to:endPos from:aCompiler

    "show more details about the errors/warnings position."

    |cls sel where|

    "

     will eventually open a TextBox here, showing the error ....

    "

    (cls := aCompiler targetClass) notNil ifTrue:[

        (sel := aCompiler selector) notNil ifTrue:[

            Transcript show:'      when compiling '; show:cls name.

            Transcript show:'>>'; show:sel.

        ] ifFalse:[

            Transcript show:'      when compiling/evaluating for '; show:cls name.

        ].

        Transcript cr.

    ].

    myStream isFileStream ifTrue:[

        Transcript show:'      while reading '; showCR:myStream pathName.

    ].

    (where := aCompiler lastTokenLineNumber) notNil ifTrue:[

        Transcript show:'      at or near line '; showCR:where.

    ].

    "Created: 8.11.1996 / 18:49:08 / cg"

    "Modified: 5.1.1997 / 03:04:05 / cg"

!

warning:aMessage position:position to:endPos from:aCompiler

    "warning notification during fileIn - ignore it.

     This is sent by the compiler/evaluator if it detects errors."

    ^ self

! !

!SourceFileLoader methodsFor:'private access'!

reader:aStream wantChangeLog:aBoolean

    myStream := aStream.

    wantChangeLog := aBoolean

! !

!SourceFileLoader class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libcomp/Attic/SrcFLoader.st,v 1.22 1997-01-31 13:29:28 cg Exp $'

! !