"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libcomp' }"

MessageNode subclass:#BinaryNode

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'System-Compiler-Support'

!

!BinaryNode class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    node for parse-trees, representing binary message sends

    This is a helper class for the compiler.

    [author:]

        Claus Gittinger

"

! !

!BinaryNode methodsFor:'accessing'!

arg

    ^ argArray at:1

! !

!BinaryNode methodsFor:'checks'!

plausibilityCheckIn:aParser

    "check for possible precedence error"

    |rSelector|

    ( #( #'*' #'/' #'//' #'\' #'\\' ) includes:selector) ifTrue:[

        receiver isMessage ifTrue:[

            receiver parenthesized ifFalse:[

                rSelector := receiver selector.

                ( #( #'+' #'-') includes:rSelector) ifTrue:[

                    ^ 'possible precedence error - use parenthesis to make evaluation order explicit.'

                ].

            ].

        ].

    ].

    ^ super plausibilityCheckIn:aParser.

! !

!BinaryNode methodsFor:'code generation'!

codeForSideEffectOn:aStream inBlock:b for:aCompiler

    "generate code for this statement - value not needed"

    (selector == #= 

    or:[selector == #~=

    or:[selector == #==]]) ifTrue:[

        receiver isVariable ifTrue:[

            aCompiler 

                warning:'possible typing error: ''='' instead of '':=''' 

                position:selectorPosition to:selectorPosition.

        ]

    ].

    ^ super codeForSideEffectOn:aStream inBlock:b for:aCompiler

    "Created: 5.8.1997 / 02:32:55 / cg"

    "Modified: 5.8.1997 / 02:50:18 / cg"

!

codeOn:aStream inBlock:b for:aCompiler

    |arg1 recVal argVal code|

    selector := selector asSymbol.

    receiver isSuper ifFalse:[

        (aCompiler isBuiltInSelector:selector forReceiver:receiver) ifTrue:[

            arg1 := argArray at:1.

            receiver isConstant ifTrue:[

                recVal := receiver value.

                (receiver type == #Integer) ifTrue:[

                    ((selector == #==) or:[selector == #~~]) ifTrue:[

                        recVal == 0 ifTrue:[

                            arg1 codeOn:aStream inBlock:b for:aCompiler.

                            (selector == #==) ifTrue:[

                                code := #eq0

                            ] ifFalse:[

                                code := #ne0

                            ].

                            aStream nextPut:code.

                            ^ self

                        ]

                    ].

                ].

                recVal == nil ifTrue:[

                    ((selector == #==) or:[selector == #~~]) ifTrue:[

                        arg1 codeOn:aStream inBlock:b for:aCompiler.

                        (selector == #==) ifTrue:[

                            code := #isNil 

                        ] ifFalse:[

                            code := #notNil 

                        ].

                        aStream nextPut:code. 

                        ^ self

                    ]

                ].

                "/ disabled this, since it is confusing if the error is reported

                "/ by the argument as receiver (i.e. transforms 1+foo into foo+1)

                "/ and it might also be incorrect.

"/                (selector == #+) ifTrue:[

"/                    (recVal == 1) ifTrue:[

"/                        arg1 codeOn:aStream inBlock:b for:aCompiler.

"/                        aStream nextPut:#plus1; nextPut:lineNr.

"/                        ^ self

"/                    ]

"/                ]

            ].

            receiver codeOn:aStream inBlock:b for:aCompiler.

            arg1 isConstant ifTrue:[

                argVal := arg1 value.

                (arg1 type == #Integer) ifTrue:[

                    ((selector == #==) or:[selector == #~~]) ifTrue:[

                        (argVal == 0) ifTrue:[

                            (selector == #==) ifTrue:[

                                code := #eq0

                            ] ifFalse:[

                                code := #ne0

                            ].

                            aStream nextPut:code.

                            ^ self

                        ]

                    ].

                    selector == #> ifTrue:[

                        argVal == 0 ifTrue:[ 

                            aStream nextPut:#gt0; nextPut:lineNr.

                            ^ self

                        ]

                    ].

                    ((selector == #+) or:[selector == #-]) ifTrue:[

                        (argVal == 1) ifTrue:[

                            (selector == #+) ifTrue:[

                                code := #plus1

                            ] ifFalse:[

                                code := #minus1

                            ].

                            aStream nextPut:code; nextPut:lineNr.

                            ^ self

                        ]

                    ]

                ].

                argVal isNil ifTrue:[

                    (selector == #==) ifTrue:[

                        aStream nextPut:#isNil.

                        ^ self

                    ].

                    (selector == #~~) ifTrue:[

                        aStream nextPut:#notNil.

                        ^ self

                    ].

                ]

            ].

            arg1 codeOn:aStream inBlock:b for:aCompiler.

            aStream nextPut:selector.

            (aCompiler hasLineNumber:selector) ifTrue:[

                aStream nextPut:lineNr.

            ].

            ^ self

        ]

    ].

    ^ super codeOn:aStream inBlock:b for:aCompiler

    "Modified: / 4.7.1999 / 19:05:13 / cg"

! !

!BinaryNode methodsFor:'evaluation'!

evaluateIn:anEnvironment

    selector := selector asSymbol.

    receiver isSuper ifTrue:[

        ^ super evaluateIn:anEnvironment

    ].

    ^ (receiver evaluateIn:anEnvironment) 

        perform:selector 

        with:((argArray at:1) evaluateIn:anEnvironment)

! !

!BinaryNode methodsFor:'printing & storing'!

printOn:aStream indent:i 

    |arg|

    receiver printOn:aStream indent:i parenthized:(receiver precedence < self precedence).

    aStream space.

    self printSelectorOn:aStream.

    aStream space.

    arg := self arg.

    arg printOn:aStream indent:i + 4 parenthized:(arg precedence <= self precedence).

    "Modified: / 20-04-2005 / 14:31:43 / cg"

!

printSelectorOn:aStream

    selector printString printOn:aStream.

! !

!BinaryNode methodsFor:'queries'!

isBinaryMessage

    ^ true

!

precedence

    ^ 50

    "Created: / 20-04-2005 / 14:10:44 / cg"

! !

!BinaryNode class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libcomp/BinaryNode.st,v 1.43 2008-05-26 08:35:35 cg Exp $'

! !