"

 COPYRIGHT (c) 1991 by Claus Gittinger

 COPYRIGHT (c) 2015 Jan Vrany

 COPYRIGHT (c) 2021 LabWare

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libcomp' }"

"{ NameSpace: Smalltalk }"

ByteCodeCompiler subclass:#Decompiler

	instanceVariableNames:'hasLineNo bytes literals index listStream outputStream'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Compiler'

!

!Decompiler class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

 COPYRIGHT (c) 2015 Jan Vrany

 COPYRIGHT (c) 2021 LabWare

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    only for stx-debugging. Not for public eyes.

    Decompiler decompile:(someClass compiledMethodAt:#someSelector)

"

! !

!Decompiler class methodsFor:'decompiling'!

decompile:aMethod

    ^ self decompile:aMethod to:Transcript

    "

     Decompiler decompile:(FileBrowser compiledMethodAt:#initialize)

     Decompiler decompile:(Decompiler compiledMethodAt:#decompile:to:)

    "

    "Modified: / 06-08-2006 / 15:31:39 / cg"

!

decompile:aMethod to:aStream

    ^ (self new) decompile:aMethod to:aStream

    "Decompiler decompile:(FileBrowser compiledMethodAt:#initialize)"

    "Created: 16.4.1996 / 20:25:55 / cg"

! !

!Decompiler methodsFor:'decompiling'!

decompile:aMethod to:aStream

    |nBytes byte sym sel lineNr who method insnIndex1 insnIndex2 n nCol|

    nCol := 7.    

    listStream := nil.

    outputStream := aStream.

    (method := aMethod) isNil ifTrue:[

        aStream showCR:'nil method'.

        ^ self

    ].   

    method := method originalMethodIfWrapped.

    aStream cr.

    aStream show:'decompiling '.

    method isMethod ifTrue:[

        who := method who.

        who notNil ifTrue:[

            classToCompileFor := who at:1.

            aStream showCR:(classToCompileFor name , '>>' , (who at:2)).

        ]

    ].

    aStream show:('nA: ' , method argumentCount printString).

    aStream show:(' nV: ' , method numVars printString).

    aStream show:(' nT: ' , method stackSize printString).

    (method size == 1 and: [ (method at:1) isArray ]) ifTrue: [

        aStream show: ('   (using indirect literals)')

    ].

    aStream cr.

    aStream cr.

    bytes := method byteCode.

    bytes isNil ifTrue:[

        method isLazyMethod ifTrue:[

            method := method asExecutableMethod.

            bytes := method byteCode.

            aStream showCR:'(lazyMethod; showing resulting code when compiled on first invokation)'.

            aStream cr.

        ].

    ].

    bytes isNil ifTrue:[

        aStream showCR:'no bytecode'.

        ^ self

    ].

    literals := method literals.

    index := 1.

    nBytes := bytes size.

    [index <= nBytes] whileTrue:[

        listStream := '' writeStream.

        self showPC.

        insnIndex1 := index.

        sym := self symbolicCodeFor:(bytes at:index).

        listStream show:sym.

"

        extra notNil ifTrue:[Transcript show:(extra printString)].

"

        index := index + 1.

        hasLineNo ifTrue:[

            lineNr := bytes at:index.

            index := index + 1.

            sym == #LINE16 ifTrue:[

                lineNr := (lineNr << 8) + (bytes at:index).

                index := index + 1.

            ].

        ] ifFalse:[

            lineNr := nil

        ].

        extra notNil ifTrue:[

            listStream show:' '.

            byte := bytes at:index.

            "compute argument showXXX selector from extra ..."

            sel := 'show' , extra , ':'.

            sel at:5 put:(sel at:5) asUppercase.

            self perform:sel asSymbol with:byte

        ].

        insnIndex2 := index-1.

        insnIndex1 to:insnIndex2 do:[:i |

            outputStream show:((bytes at:i) hexPrintString:2).

            outputStream show:' '.

        ].

        n := (insnIndex2-insnIndex1) * 3.

        outputStream spaces:(nCol*3 - n).

        outputStream show:(listStream contents).

        lineNr notNil ifTrue:[

            aStream show:' ['; show:lineNr; show:']'

        ].

        aStream showCR:''

    ]

    "Created: / 16-04-1996 / 20:27:18 / cg"

    "Modified: / 22-10-2010 / 11:48:15 / cg"

    "Modified: / 12-04-2013 / 01:35:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 16-02-2021 / 08:07:43 / Jan Vrany <jan.vrany@labware.com>"

!

showAbsOffset:byte

    |offs b2|

    index := index + 1.

    b2 := (bytes at:index).

    offs := byte + (b2 bitShift:8).

    index := index + 1.

    listStream show:offs printString.

    listStream show:' ('.

    listStream show:offs printString.

    listStream show:')'

    "Modified: 16.4.1996 / 20:27:53 / cg"

!

showAbsOffsetLevel:byte

    |offs b2|

    index := index + 1.

    b2 := (bytes at:index).

    offs := byte + (b2 bitShift:8).

    index := index + 1.

    listStream show:offs printString.

    listStream show:' ('.

    listStream show:offs printString.

    listStream show:')'.

    self showNvarNargsAt:index.

    index := index + 2

    "Modified: 16.4.1996 / 20:27:57 / cg"

!

showExtraOp:op

    "/ listStream show:(op printString); show:' '.

    index := index + 1.

    op == 0 ifTrue:[

        listStream show:'SEND_VL '.

        self showLineNo:(bytes at:index).

        listStream show:' nargs:' , (bytes at:index) printString; show:' '.

        index := index + 1.

        self showLiteral32:0.

        ^ self.

    ].

    op == 1 ifTrue:[

        listStream show:'SUPERSEND_VL '.

        self showLineNo:(bytes at:index).

        listStream show:' nargs:' , (bytes at:index) printString; show:' '.

        index := index + 1.

        self showLiteral32:0.

        self showLiteral32:0.

        ^ self.

    ].

    op == 2 ifTrue:[

        listStream show:'PUSH_VL_LIT '.

        self showLiteral32:0.

        ^ self.

    ].

    self shouldImplement.

    op == 3 ifTrue:[

    ].

    op == 4 ifTrue:[

    ].

!

showIndex:byte

    listStream show:byte printString.

    index := index + 1

    "Modified: 16.4.1996 / 20:27:59 / cg"

!

showIndexLevel:byte

    self showIndex:byte.

    self showNvarNargsAt:index.

    index := index + 2

!

showInstvarIndex:byte

    listStream show:byte printString.

    classToCompileFor notNil ifTrue:[

        listStream show:'('.

        listStream show:(classToCompileFor allInstVarNames at:byte ifAbsent:'???? [' , byte printString ,']').

        listStream show:')'.

    ].

    index := index + 1

    "Modified: 16.4.1996 / 20:28:06 / cg"

!

showLevelIndex:byte

    |lvl idx|

    lvl := byte.

    index := index + 1.

    idx := bytes at:index.

    listStream show:idx printString.

    index := index + 1.

    listStream show:' lvl: '; show:lvl printString.

!

showLineNo:byte

    listStream show:' line:' , byte printString.

    index := index + 1

    "Modified: 16.4.1996 / 20:28:10 / cg"

!

showLit1:ignored

    self showLit:1

!

showLit2:ignored

    self showLit:2

!

showLit3:ignored

    self showLit:3

!

showLit4:ignored

    self showLit:4

!

showLit5:ignored

    self showLit:5

!

showLit6:ignored

    self showLit:6

!

showLit7:ignored

    self showLit:7

!

showLit8:ignored

    self showLit:8

!

showLit9:ignored

    self showLit:9

!

showLit:litIndex

    |lit|

    lit := literals at:litIndex ifAbsent:'*** badIndex ***'.

    lit isBehavior ifTrue:[

        listStream show:lit name

    ] ifFalse:[

        lit isBlock ifTrue:[

            listStream show:'[a block]'

        ] ifFalse:[

            (lit isNumber or:[lit isString or:[lit isSymbol]]) ifTrue:[

                listStream show:lit storeString

            ] ifFalse:[

                listStream show:'{', lit printString , '}'

            ]

        ]

    ]

    "Modified: / 08-08-2006 / 00:45:46 / cg"

!

showLiteral16:byte

    |litIndex|

    litIndex := bytes unsignedInt16At:index MSB:false.

    listStream show:litIndex printString; space.

    self showLit:litIndex.

    index := index + 2

!

showLiteral32:byte

    |litIndex|

    litIndex := bytes unsignedInt32At:index MSB:false.

    listStream show:litIndex printString; space.

    self showLit:litIndex.

    index := index + 4

!

showLiteral:byte

    index := index + 1.

    listStream show:byte printString; space.

    self showLit:byte

!

showLiteralAt:index

    |offs|

    offs := bytes at:index.

    self showLit:offs

!

showLongOffset:byte

    |offs|

    index := index + 1.

    (byte > 127) ifTrue:[

        offs := byte - 256 - 128

    ] ifFalse:[

        offs := byte + 128

    ].

    listStream show:offs printString.

    listStream show:' ('.

    listStream show:(index + offs) printString.

    listStream show:')'

    "Modified: 16.4.1996 / 20:28:30 / cg"

!

showLongOffsetLevel:byte

    self showLongOffset:byte.

    self showNvarNargsAt:index.

    index := index + 2

!

showLsendArgs:byte

    |litIndex|

    listStream show:byte printString.

    listStream show:' '.

    index := index + 1.

    litIndex := bytes unsignedInt16At:index MSB:false.

    listStream show:(literals at:litIndex) printString.

    index := index + 2

    "Modified: 16.4.1996 / 20:28:35 / cg"

!

showLsuperSendArgs:byte

    |litIndex|

    listStream show:byte printString.

    listStream show:' '.

    index := index + 1.

    litIndex := bytes unsignedInt16At:index MSB:false.

    listStream show:(literals at:litIndex) printString.

    index := index + 2.

    litIndex := bytes unsignedInt16At:index MSB:false.

    listStream show:(literals at:litIndex) printString.

    index := index + 2

!

showNumber16:byte

    listStream show:(bytes signedInt16At:index MSB:false) printString.

    index := index + 2

    "Modified: 16.4.1996 / 20:28:37 / cg"

!

showNumber:byte

    listStream show:byte signExtendedByteValue printString.

    index := index + 1

    "Modified: 16.4.1996 / 20:28:38 / cg"

!

showNvarNargsAt:index

    listStream show:' nv='.

    listStream show:(bytes at:index) printString.

    listStream show:' na='.

    listStream show:(bytes at:(index + 1)) printString

    "Modified: 16.4.1996 / 20:28:40 / cg"

!

showOffset:byte

    |offs|

    index := index + 1.

    (byte > 127) ifTrue:[

        offs := byte - 256

    ] ifFalse:[

        offs := byte

    ].

    listStream show:(offs printString).

    listStream show:' ('.

    listStream show:(index + offs) printString.

    listStream show:')'

    "Modified: 16.4.1996 / 20:28:43 / cg"

!

showOffsetLevel:byte

    self showOffset:byte.

    self showNvarNargsAt:index.

    index := index + 2

!

showPC

    outputStream show:(index printStringRadix:10 size:3 fill:(Character space)).

    outputStream show:': '.

    "Modified: 4.6.1997 / 12:07:33 / cg"

!

showSendArgs:byte

    listStream show:byte printString.

    listStream show:' '.

    index := index + 1.

    self showLiteralAt:index.