"

 COPYRIGHT (c) 1989 by Claus Gittinger

 COPYRIGHT (c) 2015 Jan Vrany

 COPYRIGHT (c) 2018 Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libcomp' }"

"{ NameSpace: Smalltalk }"

Object subclass:#ParseNode

	instanceVariableNames:'parent type comments parenthized startPosition endPosition

		attributes'

	classVariableNames:''

	poolDictionaries:''

	category:'System-Compiler-Support'

!

!ParseNode class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

 COPYRIGHT (c) 2015 Jan Vrany

 COPYRIGHT (c) 2018 Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    node for parse-trees; abstract class

    This is a helper class for the compiler.

    [author:]

        Claus Gittinger

"

! !

!ParseNode class methodsFor:'instance creation'!

type:t

    ^ (self basicNew) type:t

! !

!ParseNode methodsFor:'RBParser compatibility'!

bestNodeFor: anInterval 

    (self intersectsInterval: anInterval) ifFalse: [^nil].

    (self containedBy: anInterval) ifTrue: [^self].

    self childrenDo:[:each | 

        | node |

        node := each bestNodeFor: anInterval.

        node notNil ifTrue: [^node]

    ].

    ^ nil

!

children

    |children|

    children := OrderedCollection new.

    self childrenDo:[:each |

        self assert:(each notNil).

        children add:each

    ].

    ^ children.

!

childrenDo:aBlock

    ^ self

!

containedBy:anInterval

    "true if the interval contains me completely"

    startPosition isNil ifTrue:[^ false].

    endPosition isNil ifTrue:[^ false].

    ^ anInterval first <= startPosition and:[anInterval last >= endPosition]

!

intersectsInterval: anInterval 

    |myStart myStop ivStart ivStop|

    myStart := startPosition.

    myStop := endPosition.

    ivStart := anInterval first.

    ivStop := anInterval last.

    (myStart notNil and:[ivStop < myStart]) ifTrue:[^ false].

    (myStop notNil and:[ivStart > myStop]) ifTrue:[^ false].

    ^ true

!

nodesDo:aBlock 

    aBlock value: self.

    self children do: [:each | each nodesDo: aBlock]

!

start

    "for RBToken compat."

    ^ self startPosition

!

whichNodeIntersects: anInterval 

    | selectedChildren nChildren |

    (self intersectsInterval: anInterval) ifFalse: [^nil].

    selectedChildren := self children select:[:each | 

                            each intersectsInterval: anInterval

                        ].

    nChildren := selectedChildren size.

    nChildren == 0 ifTrue:[

        ^ self "/ I intersect

    ].

    nChildren == 1 ifTrue:[

        ^ selectedChildren first whichNodeIntersects: anInterval

    ].

"/ self halt:'should this happen ?'.

    ^ self "/ I intersect

!

whichNodeIsContainedBy:anInterval 

    |firstChildInInterval|

    (self intersectsInterval: anInterval) ifFalse: [^nil].

    (self containedBy: anInterval) ifTrue: [^self].

    self childrenDo:[:each | 

        (each intersectsInterval:anInterval) ifTrue:[

            firstChildInInterval notNil ifTrue:[

                "/ ouch: multiple children in interval

                ^ self

            ].

            firstChildInInterval := each

        ].

    ].

    firstChildInInterval isNil ifTrue:[

        "/ no children in interval; so it must be me

        ^ self

    ].

    "/ look deeper

    ^ firstChildInInterval whichNodeIsContainedBy:anInterval.

! !

!ParseNode methodsFor:'accessing'!

enclosingBlock

    "Return closest enclosing block node or nil"

    | block |

    block := parent.

    [ block notNil and:[block realNode isBlockNode not] ] whileTrue:[

        block := block realNode parent.

    ].

    ^block.

    "Created: / 16-02-2012 / 22:46:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

endPosition

    "the node's last character position in the original source"

    ^ endPosition

!

endPosition:aCharacterPosition

    self assert:aCharacterPosition > 0.

    endPosition := aCharacterPosition

    "Modified: / 28-07-2011 / 10:03:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

line

    "Compatibility"

    ^self lineNumber

    "Created: / 09-07-2011 / 22:30:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

lineNumber

    ^nil

    "Created: / 09-07-2011 / 22:30:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

lineNumber:dummy

    "set linenumber - ignored here"

    ^ self

!

parent

    ^parent

    "Created: / 11-07-2011 / 17:36:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parent: aParseNode

    parent := aParseNode

    "Created: / 11-07-2011 / 17:36:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

parenthesized

    ^ parenthized ? false

!

parenthesized:aBoolean

    parenthized := aBoolean

!

parenthized

    "obsolete - typo in message name - use parenthesized"

    ^ parenthized ? false

!

parenthized:aBoolean

    "obsolete - typo in message name - use parenthesized:"

    parenthized := aBoolean

!

realNode

    ^ self

!

selectorPartPositions:selectorPartPositions

    "/ ignored here, but implemented because sent without checking 

    "/ when parsing keyword messages to an optimized messageNode

    "/ (which become optimized to a constantNode by the folder)

    "Created: / 28-08-2013 / 21:17:22 / cg"

!

selectorPosition:aCharacterPosition

    "ignored here"

    "Created: 5.8.1997 / 16:32:17 / cg"

!

startPosition

    "the node's character position in the original source"

    ^ startPosition

!

startPosition:start

    self assert:start > 0.

    startPosition := start

    "Modified: / 08-04-2011 / 22:03:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

startPosition:start endPosition:end

    (start == -1 and:[end == -1]) ifTrue:[

        "/ a synthetic node

        "/ self halt.

    ] ifFalse:[

        "/ nil end means: up-to-end (but only for error nodes)

        self assert:(start notNil and:[start > 0]).

        end isNil ifTrue:[

            self assert:(self isErrorNode)

        ] ifFalse:[

            self assert:(end >= start).

        ].

    ].

    startPosition := start.

    endPosition := end.

    "Created: / 11-07-2011 / 17:44:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 15-02-2019 / 14:39:10 / Claus Gittinger"

!

type

    "return the nodes type"

    ^ type

! !

!ParseNode methodsFor:'attributes access'!

objectAttributes

    "return a Collection of attributes - nil if there is none."

    ^attributes

    "Created: / 09-07-2011 / 12:17:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 18-06-2020 / 12:20:25 / cg"

!

objectAttributes: anObject

    attributes := anObject

    "Created: / 09-07-2011 / 12:18:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ParseNode methodsFor:'checks'!

plausibilityCheckIn:aParser

    ^ nil

! !

!ParseNode methodsFor:'code generation'!

codeForSideEffectOn:aStream inBlock:b for:aCompiler

    "generate code for this statement - value not needed"

    self codeThenDropOn:aStream inBlock:b for:aCompiler 

!

codeForSimpleReturnOn:aStream inBlock:b lineNumber:lineNrOrNil for:aCompiler

    "generate code to return myself as a simple method return"

    self codeOn:aStream inBlock:b for:aCompiler.

    lineNrOrNil notNil ifTrue:[

        self codeLineNumber:lineNrOrNil on:aStream for:aCompiler

    ].

    aStream nextPut:#retTop.

!

codeInlineOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler

    "generate code for this statement - value is needed"

    self codeOn:aStream inBlock:b for:aCompiler.

!

codeLineNumber:nr on:codeStream for:aCompiler

    "generate lineNumber information"

    aCompiler codeLineNumber:nr on:codeStream

!

codeOn:aStream inBlock:codeBlock for:aCompiler

    ^ self subclassResponsibility

!

codeSourcePosition:nr on:codeStream for:aCompiler

    "generate source position information"

    aCompiler codeSourcePosition:nr on:codeStream

    "Created: / 31-05-2015 / 03:45:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

codeThenDropOn:aStream inBlock:b for:aCompiler

    "generate code for this statement - value not needed"

    self codeOn:aStream inBlock:b for:aCompiler.

    aStream nextPut:#drop

! !

!ParseNode methodsFor:'code generation helpers'!

emitPushGlobalWithLiteralIndex:litIndex on:aTokenCodeStream for:aCompiler

    litIndex <= 255 ifTrue:[

        aTokenCodeStream nextPut:#pushGlobalS; nextPut:litIndex

    ] ifFalse:[

        litIndex <= 16rFFFF ifTrue:[

            aTokenCodeStream nextPut:#pushGlobalL; nextPut:litIndex; nextPut:0

        ] ifFalse:[

            aTokenCodeStream nextPut:#pushGlobalVL; nextPut:0; nextPut:litIndex; nextPut:0; nextPut:0; nextPut:0

        ].

    ].

!

emitPushLiteral:value on:aTokenCodeStream for:aCompiler

    |index|

    index := aCompiler addLiteral:value.

    self emitPushLiteralIndex:index on:aTokenCodeStream for:aCompiler

!

emitPushLiteralIndex:index on:aTokenCodeStream for:aCompiler

    index <= 8 ifTrue:[

        aTokenCodeStream 

            nextPut:(#(pushLit1 pushLit2 pushLit3 pushLit4

                       pushLit5 pushLit6 pushLit7 pushLit8) at:index).

    ] ifFalse:[

        index <= 255 ifTrue:[

            aTokenCodeStream nextPut:#pushLitS; nextPut:index

        ] ifFalse:[

            index <= 16rFFFF ifTrue:[

                aTokenCodeStream nextPut:#pushLitL; nextPut:index; nextPut:0

            ] ifFalse:[

                aTokenCodeStream nextPut:#pushLitVL; nextPut:0; nextPut:index; nextPut:0; nextPut:0; nextPut:0

            ]

        ].

    ].

!

emitSendLiteralIndex:litIndex numArgs:nargs line:lineNr on:aStream for:aCompiler

    lineNr >= 255 ifTrue:[

        self codeLineNumber: lineNr on: aStream for:aCompiler.  

    ].

    (litIndex <= 255) ifTrue:[

        nargs <= 3 ifTrue:[

            aStream 

                nextPut:(#(send0 send1 send2 send3) at:(nargs+1)); nextPut:lineNr; 

                nextPut:litIndex.

            ^ self.

        ].

        aStream 

            nextPut:#send; nextPut:lineNr; 

            nextPut:litIndex; 

            nextPut:nargs.

        ^ self.

    ].

    (litIndex <= 16rFFFF) ifTrue:[

        aStream 

            nextPut:#sendL; nextPut:lineNr; 

            nextPut:litIndex; nextPut:0; 

            nextPut:nargs.

        ^ self.

    ].

    aStream 

        nextPut:#sendVL; nextPut:0; nextPut:lineNr; 

        nextPut:litIndex; nextPut:0; nextPut:0; nextPut:0; 

        nextPut:nargs.

    "Modified: / 13-04-2013 / 11:02:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

emitStoreGlobalWithLiteralIndex:litIndex on:aTokenCodeStream for:aCompiler

    litIndex <= 255 ifTrue:[

        aTokenCodeStream nextPut:#storeGlobalS; nextPut:litIndex

    ] ifFalse:[

        litIndex <= 16rFFFF ifTrue:[

            aTokenCodeStream nextPut:#storeGlobalL; nextPut:litIndex; nextPut:0

        ] ifFalse:[

            aTokenCodeStream nextPut:#storeGlobalVL; nextPut:0; nextPut:litIndex; nextPut:0; nextPut:0; nextPut:0; nextPut:0

        ].

    ].

!

emitSuperSendLiteralIndex:litIndex classLiteralIndex:clsLitIndex numArgs:nargs line:lineNr on:aStream for:aCompiler

    lineNr >= 255 ifTrue:[

        self codeLineNumber: lineNr on: aStream for:aCompiler.  

    ].

    (litIndex <= 255 and:[clsLitIndex <= 255]) ifTrue:[

        aStream 

            nextPut:#superSend; nextPut:lineNr; 

            nextPut:litIndex; 

            nextPut:nargs; 

            nextPut:clsLitIndex.

    ] ifFalse:[

        (litIndex <= 16rFFFF and:[clsLitIndex <= 16rFFFF]) ifTrue:[

            aStream 

                nextPut:#superSendL; nextPut:lineNr; 

                nextPut:litIndex; nextPut:0; 

                nextPut:nargs; 

                nextPut:clsLitIndex; nextPut:0.

        ] ifFalse:[

            aStream 

                nextPut:#superSendVL; nextPut:0; nextPut:lineNr; 

                nextPut:litIndex; nextPut:0; nextPut:0; nextPut:0;

                nextPut:nargs; 

                nextPut:clsLitIndex; nextPut:0; nextPut:0; nextPut:0.

        ].