"
 COPYRIGHT (c) 1989 by Claus Gittinger
              All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

MessageNode subclass:#CascadeNode
       instanceVariableNames:''
       classVariableNames:''
       poolDictionaries:''
       category:'System-Compiler-Support'
!

CascadeNode comment:'

COPYRIGHT (c) 1989 by Claus Gittinger
              All Rights Reserved

$Header: /cvs/stx/stx/libcomp/Attic/CascadeNd.st,v 1.4 1994-01-16 03:51:33 claus Exp $
'!

!CascadeNode methodsFor: 'code generation'!

codeOn:aStream inBlock:b valueNeeded:valueNeeded
    receiver codeForCascadeOn:aStream inBlock:b.
    self codeSendOn:aStream inBlock:b valueNeeded:valueNeeded
!

codeForCascadeOn:aStream inBlock:b
    receiver codeForCascadeOn:aStream inBlock:b.
    aStream nextPut:#dup.
    self codeSendOn:aStream inBlock:b valueNeeded:false
! !

!CascadeNode methodsFor: 'evaluating'!

evaluate
    |t argValueArray|

    receiver isSuper ifTrue:[
        ^ super evaluate
    ].

    t := receiver evaluateForCascade.
    argArray isNil ifTrue:[
        t perform:selector.
        ^ t
    ].
    argValueArray := argArray collect:[:arg | arg evaluate].
    ^ t perform:selector withArguments:argValueArray
!

evaluateForCascade
    |t argValueArray|

    receiver isSuper ifTrue:[
        ^ super evaluateForCascade
    ].

    t := receiver evaluateForCascade.
    argArray isNil ifTrue:[
        t perform:selector.
        ^ t
    ].
    argValueArray := argArray collect:[:arg | arg evaluate]. 
    t perform:selector withArguments:argValueArray.
    ^ t
! !