"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

ParseNode subclass:#StatementNode
       instanceVariableNames:'expression nextStatement'
       classVariableNames:''
       poolDictionaries:''
       category:'System-Compiler-Support'
!

StatementNode comment:'
COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

$Header: /cvs/stx/stx/libcomp/Attic/StatNode.st,v 1.7 1995-07-23 02:24:45 claus Exp $
'!

!StatementNode class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

version
"
$Header: /cvs/stx/stx/libcomp/Attic/StatNode.st,v 1.7 1995-07-23 02:24:45 claus Exp $
"
!

documentation
"
    node for parse-trees, representing statements
"
! !

!StatementNode class methodsFor:'instance creation'!

expression:e
    ^ (self basicNew) expression:e
! !

!StatementNode methodsFor:'evaluating'!

evaluateExpression
    ^ expression evaluate
!

evaluate
    |lastValue thisStatement|

    "this could be done more elegant - but with lots of recursion"
    thisStatement := self.
    [thisStatement notNil] whileTrue:[
	lastValue := thisStatement evaluateExpression.
	thisStatement := thisStatement nextStatement
    ].
    ^ lastValue
! !

!StatementNode methodsFor:'code generation'!

codeOn:aStream inBlock:b
    "generate code for this statement"

    expression codeOn:aStream inBlock:b
!

codeForSideEffectOn:aStream inBlock:b
    "generate code for this statement - value not needed"

    expression codeForSideEffectOn:aStream inBlock:b
! !

!StatementNode methodsFor:'accessing'!

last
    "return the last statement in a list"

    |last this|

    "this could be done more elegant - but with lots of recursion"
    last := self.
    this := self.
    [this notNil] whileTrue:[
	last := this.
	this := this nextStatement
    ].
    ^ last
!

nextStatement:s
    nextStatement := s
!

nextStatement
    ^ nextStatement
!

expression:e
    expression := e
!

expression
    ^ expression
! !

!StatementNode methodsFor:'queries'!

isConstant
    nextStatement notNil ifTrue:[^ false].
    ^ expression isConstant
! !

!StatementNode methodsFor:'printing'!

printOn:aStream indent:i
    expression printOn:aStream indent:i.
!

printAllOn:aStream 
    self printAllOn:aStream indent:4
!

printAllOn:aStream indent:i
    |thisStatement|

    thisStatement := self.
    [thisStatement notNil] whileTrue:[
	aStream spaces:i.
	thisStatement printOn:aStream indent:i.
	thisStatement nextStatement notNil ifTrue:[
	    aStream nextPut:$..
	    aStream cr.
	].
	thisStatement := thisStatement nextStatement
    ]
! !