"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
"{ Package: 'stx:libcomp' }"
ParseNode subclass:#MessageNode
instanceVariableNames:'receiver selector argArray lineNr selectorPosition'
classVariableNames:''
poolDictionaries:''
category:'System-Compiler-Support'
!
!MessageNode class methodsFor:'documentation'!
copyright
"
COPYRIGHT (c) 1989 by Claus Gittinger
All Rights Reserved
This software is furnished under a license and may be used
only in accordance with the terms of that license and with the
inclusion of the above copyright notice. This software may not
be provided or otherwise made available to, or used by, any
other person. No title to or ownership of the software is
hereby transferred.
"
!
documentation
"
node for parse-trees, representing message sends
This is a helper class for the compiler.
[author:]
Claus Gittinger
"
! !
!MessageNode class methodsFor:'instance creation'!
receiver:recNode selector:selectorString
^ (self basicNew) receiver:recNode selector:selectorString args:nil lineno:0
!
receiver:recNode selector:selectorString arg1:arg1Node arg2:arg2Node
^ self receiver:recNode selector:selectorString arg1:arg1Node arg2:arg2Node fold:nil
!
receiver:recNode selector:selectorString arg1:argNode1 arg2:argNode2 fold:folding
|result recVal argVal selector|
"
This is just a demonstration - of how complex constants can be folded.
This was inspired by some discussion in c.l.s about enhancing the language - I prefer
enhancing the compiler ....
The following optimization will convert '#(...) with:#(...) collect:[...]' into an array constant,
allowing constant arrays of complex objects.
Notice: this method is normally disabled - its just a demo after all.
"
folding notNil ifTrue:[
"/
"/ do constant folding ...
"/
(recNode isConstant and:[argNode1 isConstant]) ifTrue:[
"check if we can do it ..."
selector := selectorString asSymbolIfInterned.
selector notNil ifTrue:[
recVal := recNode evaluate.
(recVal respondsTo:selector) ifTrue:[
"
we could do much more here - but then, we need a dependency from
the folded selectors method to the method we generate code for ...
limit optimizations to those that will never change
(or - if you change them - you will crash so bad ...)
"
argVal := argNode1 evaluate.
((recVal isMemberOf:Array) and:[argVal isMemberOf:Array]) ifTrue:[
folding == #full ifTrue:[
(selector == #with:collect:) ifTrue:[
(argNode2 isBlock) ifTrue:[
SignalSet anySignal handle:[:ex |
^ 'error in constant expression (' , ex description , ')'
] do:[
result := recVal perform:selector with:argVal with:(argNode2 evaluate).
].
^ ConstantNode type:(ConstantNode typeOfConstant:result) value:result
]
]
]
]
]
]
]
].
^ (self basicNew) receiver:recNode selector:selectorString args:(Array with:argNode1 with:argNode2) lineno:0
"Modified: 28.6.1997 / 15:16:01 / cg"
!
receiver:recNode selector:selectorString arg:argNode
^ self receiver:recNode selector:selectorString arg:argNode fold:nil
!
receiver:recNode selector:selectorString arg:argNode fold:folding
|result recVal argVal selector globalName canFold|
"
The constant folding code can usually not optimize much
- this may change when some kind of constant/macro declaration is added to smalltalk,
so that constant classVars can be inlined.
"
folding notNil ifTrue:[
selector := selectorString asSymbolIfInterned.
selector notNil ifTrue:[
"/
"/ do constant folding ...
"/
canFold := false.
(recNode isGlobal and:[argNode isConstant]) ifTrue:[
globalName := recNode name.
recVal := recNode evaluate.
(globalName = 'SmallInteger') ifTrue:[
( #( bitMaskFor: ) includes:selector)
ifTrue:[
canFold := true
]
].
].
(recNode isConstant and:[argNode isConstant]) ifTrue:[
"check if we can do it ..."
recVal := recNode evaluate.
"
we could do much more here - but then, we need a dependency from
the folded selectors method to the method we generate code for ...
limit optimizations to those that will never change
(or - if you change them - you will crash so bad ...)
"
argVal := argNode evaluate.
(recVal respondsToArithmetic and:[argVal respondsToArithmetic]) ifTrue:[
( #( + - * / // \\ min: max: quo:) includes:selector) ifTrue:[
(#( / // \\ ) includes:selector) ifTrue:[
argVal = 0 ifTrue:[
^ 'division by zero in constant expression'
].
].
canFold := true
].
( #( @ ) includes:selector) ifTrue:[
canFold := (folding == #full)
]
].
(recVal isInteger and:[argVal isInteger]) ifTrue:[
( #( bitShift: bitOr: bitAnd: ) includes:selector) ifTrue:[
canFold := true
]
].
(recVal isMemberOf:String) ifTrue:[
(argVal isInteger and:[selector == #at:]) ifTrue:[
canFold := folding isSymbol
and:[(folding >= #level2) or:[folding == #full]].
].
selector == #',' ifTrue:[
(argVal isMemberOf:String) ifTrue:[
canFold := folding isSymbol
and:[(folding >= #level2) or:[folding == #full]].
].
(argVal isMemberOf:Character) ifTrue:[
canFold := folding isSymbol
and:[(folding >= #level2) or:[folding == #full]].
].
]
].
].
canFold ifTrue:[
(recVal respondsTo:selector) ifTrue:[
SignalSet anySignal handle:[:ex |
^ 'error in constant expression (' , ex description , ')'
] do:[
result := recVal perform:selector with:argVal.
].
^ ConstantNode type:(ConstantNode typeOfConstant:result) value:result
]
]
].
"/
"/ #perform with a constant selector
"/
(selector == #perform:
and:[argNode isConstant]) ifTrue:[
argVal := argNode evaluate.
argVal isSymbol ifTrue:[
^ UnaryNode receiver:recNode selector:argVal fold:folding
]
].
].
^ (self basicNew) receiver:recNode selector:selectorString args:(Array with:argNode) lineno:0
"Modified: / 16.11.1999 / 21:50:33 / cg"
!
receiver:recNode selector:selectorString args:anArray
^ self receiver:recNode selector:selectorString args:anArray fold:nil
!
receiver:recNode selector:selectorString args:argArray fold:folding
|numArgs arg1 arg1Val|
folding notNil ifTrue:[
numArgs := argArray size.
numArgs > 0 ifTrue:[
arg1 := (argArray at:1).
(numArgs == 1) ifTrue:[
^ self receiver:recNode selector:selectorString arg:arg1 fold:folding
].
"/
"/ #perform:... with a constant selector
"/
numArgs <= 6 ifTrue:[
(#(nil
#'perform:with:'
#'perform:with:with:'
#'perform:with:with:with:'
#'perform:with:with:with:with:'
#'perform:with:with:with:with:with:'
#'perform:with:with:with:with:with:with:'
) at:numArgs) = selectorString
ifTrue:[
arg1 isConstant ifTrue:[
arg1Val := arg1 evaluate.
arg1Val isSymbol ifTrue:[
^ MessageNode
receiver:recNode
selector:arg1Val
args:(argArray copyFrom:2)
fold:folding
]
]
]
].
].
(numArgs == 2) ifTrue:[
^ self receiver:recNode selector:selectorString arg1:arg1 arg2:(argArray at:2) fold:folding
].
numArgs > Method maxNumberOfArguments ifTrue:[
^ 'too many arguments for current VM implementation'.
].
].
^ (self basicNew) receiver:recNode selector:selectorString args:argArray lineno:0
"Modified: / 3.9.1995 / 16:41:39 / claus"
"Modified: / 15.5.1998 / 15:32:05 / cg"
! !
!MessageNode methodsFor:'accessing'!
arg1
^ argArray at:1
!
args
^ argArray
!
arguments
^ argArray ? #()
"Created: 19.6.1997 / 17:31:14 / cg"
"Modified: 19.6.1997 / 17:32:25 / cg"
!
lineNumber
^ lineNr
!
lineNumber:num
lineNr := num
!
receiver
^ receiver
!
receiver:r selector:s args:a lineno:l
receiver := r.
"/ selector := s asSymbolIfInterned ? s.
selector := s asSymbol.
argArray := a.
lineNr := l.
self checkInlinability.
"Modified: 2.7.1997 / 17:01:24 / cg"
!
selector
^ selector
!
selector:s
"/ selector := s asSymbolIfInterned ? s.
selector := s asSymbol.
!
selectorPosition
"return the value of the instance variable 'selectorPosition' (automatically generated)"
^ selectorPosition
"Created: 5.8.1997 / 02:49:27 / cg"
!
selectorPosition:something
"set the value of the instance variable 'selectorPosition' (automatically generated)"
selectorPosition := something.
"Created: 5.8.1997 / 02:49:27 / cg"
! !
!MessageNode methodsFor:'checks'!
checkInlinability
"early check for possible inlinability"
|numArgs arg1 arg2 arg3|
(numArgs := argArray size) >= 1 ifTrue:[
arg1 := argArray at:1.
].
numArgs == 0 ifTrue:[
(selector == #whileTrue
or:[selector == #whileFalse]) ifTrue:[
receiver isBlock ifTrue:[
receiver possiblyInlined:true
].
].
(selector == #value) ifTrue:[
receiver isBlock ifTrue:[
receiver possiblyInlined:true
].
].
((selector == #repeat) or:[selector == #loop]) ifTrue:[
receiver isBlock ifTrue:[
receiver possiblyInlined:true
].
].
].
numArgs == 1 ifTrue:[
(selector == #or:
or:[selector == #and:]) ifTrue:[
arg1 isBlock ifTrue:[
arg1 possiblyInlined:true
].
].
(selector == #ifTrue:
or:[selector == #ifFalse:
or:[selector == #ifNil:
or:[selector == #ifNotNil:]]]) ifTrue:[
arg1 isBlock ifTrue:[
arg1 possiblyInlined:true
].
].
(selector == #whileTrue:
or:[selector == #whileFalse:]) ifTrue:[
arg1 isBlock ifTrue:[
arg1 possiblyInlined:true
].
receiver isBlock ifTrue:[
receiver possiblyInlined:true
].
].
selector == #timesRepeat: ifTrue:[
arg1 isBlock ifTrue:[
arg1 possiblyInlined:true withSelector:selector.
]
].
^ self
].
numArgs >= 2 ifTrue:[
arg2 := argArray at:2.
].
numArgs == 2 ifTrue:[
(selector == #ifTrue:ifFalse:
or:[selector == #ifFalse:ifTrue:
or:[selector == #ifNil:ifNotNil:
or:[selector == #ifNotNil:ifNil:]]]) ifTrue:[
(arg1 isBlock
and:[arg2 isBlock]) ifTrue:[
arg1 possiblyInlined:true.
arg2 possiblyInlined:true.
].
].
selector == #to:do: ifTrue:[
arg2 isBlock ifTrue:[
arg2 possiblyInlined:true withSelector:selector.
].
].
^ self
].
numArgs >= 3 ifTrue:[
arg3 := argArray at:3.
].
numArgs == 3 ifTrue:[
selector == #to:by:do: ifTrue:[
arg3 isBlock ifTrue:[
arg3 possiblyInlined:true withSelector:selector.
].
].
^ self
].
^ self
"Created: / 2.7.1997 / 17:01:10 / cg"
"Modified: / 2.4.1998 / 19:08:54 / cg"
!
plausibilityCheck
|rec arg1 arg2 arg1Value operand|
(argArray size > 0) ifTrue:[
arg1 := argArray at:1
].
"
it once took me almost an hour, to find a '==' which
should have been an '=' (you cannot compare floats with ==)
(well, I looked at the '==' at least 50 times -
- but didn't think about it ...).
thats reason enough to add this check here.
I will add more as heuristic knowledge increases ...
(send me comments on common programming errors ...)
"
"
check #== applied to Floats, Strings or Fractions
"
((selector == #==) or:[selector == #~~]) ifTrue:[
receiver isConstant ifTrue:[
rec := receiver evaluate.
((rec isMemberOf:String) or:[
(rec isMemberOf:Float) or:[
(rec isMemberOf:Fraction)]]) ifTrue:[
operand := rec
].
].
arg1 isConstant ifTrue:[
arg1Value := arg1 evaluate.
((arg1Value isMemberOf:String) or:[
(arg1Value isMemberOf:Float) or:[
(arg1Value isMemberOf:Fraction)]]) ifTrue:[
operand := arg1Value
].
].
operand notNil ifTrue:[
(selector == #==) ifTrue:[
^ 'identity compare is unsafe here'
].
^ 'identity compare will usually return true here'
]
].
"
[...] ifTrue:...
an error often occuring when you are a beginner ...
"
((selector == #ifTrue:) or:[selector == #ifFalse:]) ifTrue:[
receiver isBlock ifTrue:[
(Block canUnderstand:selector) ifFalse:[
^ 'blocks usually do not respond to ' , selector , ' messages'
].
].
arg1 isBlock ifFalse:[
arg1 isConstant ifFalse:[
^ 'will fail at runtime, if argument to ' , selector , ' does not evaluate to a block or respond reasonable to #value'
].
]
].
((selector == #ifTrue:ifFalse:) or:[selector == #ifFalse:ifTrue:]) ifTrue:[
receiver isBlock ifTrue:[
(Block canUnderstand:selector) ifFalse:[
^ 'blocks usually do not respond to ' , selector , ' messages'
].
].
arg1 isBlock ifFalse:[
arg1 isConstant ifFalse:[
^ 'will fail at runtime, if 1st. argument to ' , selector , ' does not evaluate to a block or respond reasonable to #value'
]
].
arg2 := argArray at:2.
arg2 isBlock ifFalse:[
arg2 isConstant ifFalse:[
^ 'will fail at runtime, if 2nd. argument to ' , selector , ' does not evaluate to a block or respond reasonable to #value'
]
]
].
"
(...) whileTrue:[
"
((selector == #whileTrue:) or:[selector == #whileFalse:]) ifTrue:[
receiver isBlock ifFalse:[
"
only warn, if code was originally parenthized
"
receiver parenthized ifTrue:[
^ 'will fail at runtime, if receiver of ' , selector , ' does not evaluate to a block or respond reasonable to #value'
]
].
arg1 isBlock ifFalse:[
^ 'will fail at runtime, if argument to ' , selector , ' does not evaluate to a block or respond reasonable to #value'
].
].
argArray size > 0 ifTrue:[
"/ check for a beginners error (using super as arg)
"/ as in (something ? super) foo
argArray do:[:arg | arg isSuper ifTrue:[
^ 'super special semantic only with receiver of message sends'
]
].
].
"/ receiver isBlock ifTrue:[
"/ ([] respondsTo:selector) ifFalse:[
"/ ^ 'blocks do not respond to ' , selector , '; Missing ''.'' between statements ?'
"/ ].
"/ ].
^ nil
"Modified: / 16.7.1998 / 20:29:53 / cg"
! !
!MessageNode methodsFor:'code generation'!
codeAndIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x and:[y]) ifxxx:[ ... ] ifyyy:[ ... ]"
|theByteCode optByteCode theReceiver theArg pos1 pos2 pos3 code here jmp
block1 block2|
aCompiler addLiteral:#and:.
theByteCode := #falseJump.
theReceiver := receiver receiver.
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode
].
"/ code the left-of the and-part
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
aStream nextPut:theByteCode.
pos1 := aStream position1Based. "/ remember branch target of left-fail branch
aStream nextPut:0.
"/ code the right of the and-part
theReceiver := receiver arg1.
theReceiver codeInlineOn:aStream inBlock:b for:aCompiler.
(selector == #ifTrue:ifFalse:) ifTrue:[
jmp := #falseJump
] ifFalse:[
jmp := #trueJump
].
aStream nextPut:jmp.
pos2 := aStream position1Based. "/ remember branch target of right-fail branch
aStream nextPut:0.
code := aStream contents.
(selector == #ifFalse:ifTrue:) ifTrue:[
code at:pos1 put:(aStream position1Based)
].
"/ code the if-block
block1 := argArray at: 1.
self codeBlockEvaluation:block1 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
aStream nextPut:#jump.
pos3 := aStream position1Based.
aStream nextPut:0.
here := aStream position1Based.
(selector == #ifTrue:ifFalse:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here.
"/ code the else-block
block2 := argArray at: 2.
self codeBlockEvaluation:block2 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code at:pos3 put:(aStream position1Based)
"Created: 6.9.1996 / 12:56:23 / cg"
!
codeAndIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x and:[y]) ifxxx:[ ... ]"
|theByteCode optByteCode andBlock theArg pos1 pos2 pos3 code here jmp
receiver1 receiver2 optByteCode2 theArg2 block|
aCompiler addLiteral:#and:.
theByteCode := #falseJump.
receiver1 := receiver receiver.
optByteCode := self optimizedConditionFor:receiver1 with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := receiver1 arg1
].
receiver1 := receiver1 receiver.
theByteCode := optByteCode
].
receiver1 codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
aStream nextPut:theByteCode.
pos1 := aStream position1Based.
aStream nextPut:0.
andBlock := receiver arg1. "/ the and:-block
(selector == #ifTrue:) ifTrue:[
jmp := #falseJump
] ifFalse:[
jmp := #trueJump
].
andBlock statements nextStatement isNil ifTrue:[
"/ simple - one statement
receiver2 := andBlock statements expression.
optByteCode2 := self optimizedConditionFor:receiver2 with:jmp for:aCompiler.
].
optByteCode2 notNil ifTrue:[
((optByteCode2 == #eqJump) or:[optByteCode2 == #notEqJump]) ifTrue:[
theArg2 := receiver2 arg1
].
receiver2 := receiver2 receiver.
receiver2 codeOn:aStream inBlock:b for:aCompiler.
theArg2 notNil ifTrue:[
theArg2 codeOn:aStream inBlock:b for:aCompiler
].
jmp := optByteCode2.
] ifFalse:[
andBlock codeInlineOn:aStream inBlock:b for:aCompiler.
].
aStream nextPut:jmp.
pos2 := aStream position1Based.
aStream nextPut:0.
code := aStream contents.
(selector == #ifFalse:) ifTrue:[
code at:pos1 put:(aStream position1Based)
].
block := argArray at: 1.
self codeBlockEvaluation:block on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
valueNeeded ifTrue:[
aStream nextPut:#jump.
pos3 := aStream position1Based.
aStream nextPut:0.
here := aStream position1Based.
(selector == #ifTrue:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here.
aStream nextPut:#pushNil.
code at:pos3 put:(aStream position1Based)
] ifFalse:[
here := aStream position1Based.
(selector == #ifTrue:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here
]
!
codeAndOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x and:[y])"
|pos1 rightExpr|
aCompiler addLiteral:#and:.
receiver codeOn:aStream inBlock:b for:aCompiler.
valueNeeded ifTrue:[
aStream nextPut:#dup.
].
aStream nextPut:#falseJump.
pos1 := aStream position1Based.
aStream nextPut:0.
valueNeeded ifTrue:[
aStream nextPut:#drop.
].
rightExpr := argArray at:1.
rightExpr codeInlineOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
(aStream contents) at:pos1 put:(aStream position1Based)
"Created: 17.6.1996 / 15:46:42 / cg"
"Modified: 17.6.1996 / 15:47:44 / cg"
!
codeBlockEvaluation:aBlock on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"gen code to evaluate a block"
(aBlock isBlock and:[aBlock isInlinable]) ifTrue:[
aBlock codeInlineOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
] ifFalse:[
aBlock codeOn:aStream inBlock:b for:aCompiler.
aBlock isConstant ifFalse:[
self codeValueSendOn:aStream for:aCompiler.
].
valueNeeded ifFalse:[
aStream nextPut:#drop
].
].
!
codeForCascadeOn:aStream inBlock:b for:aCompiler
"like codeOn, but always leave the receiver instead of the result"
|nargs isBuiltIn code codeL litIndex cls clsLitIndex isSuper realReceiver noSendDrop|
noSendDrop := aCompiler class newCodeSet == true.
realReceiver := self realReceiver.
isSuper := realReceiver isSuper.
argArray isNil ifTrue:[
nargs := 0
] ifFalse:[
nargs := argArray size
].
isBuiltIn := false.
isSuper ifFalse:[
(nargs == 0) ifTrue:[
isBuiltIn := aCompiler isBuiltInUnarySelector:selector forReceiver:receiver
].
(nargs == 1) ifTrue:[
isBuiltIn := aCompiler isBuiltIn1ArgSelector:selector forReceiver:receiver
].
(nargs == 2) ifTrue:[
isBuiltIn := aCompiler isBuiltIn2ArgSelector:selector forReceiver:receiver
].
].
receiver codeOn:aStream inBlock:b for:aCompiler.
aStream nextPut:#dup.
"can we use a send-bytecode ?"
isBuiltIn ifTrue:[
(nargs > 0) ifTrue:[
(argArray at:1) codeOn:aStream inBlock:b for:aCompiler.
(nargs > 1) ifTrue:[
(argArray at:2) codeOn:aStream inBlock:b for:aCompiler
]
].
aStream nextPut:selector.
(aCompiler hasLineNumber:selector) ifTrue:[
aStream nextPut:lineNr.
].
aStream nextPut:#drop.
^ self
].
"no - generate a send"
argArray notNil ifTrue:[
argArray do:[:arg |
arg codeOn:aStream inBlock:b for:aCompiler
]
].
litIndex := aCompiler addLiteral:selector.
isSuper ifTrue:[
cls := aCompiler targetClass.
realReceiver isHere ifTrue:[
code := #hereSend.
codeL := #hereSendL.
] ifFalse:[
code := #superSend.
codeL := #superSendL.
cls := cls superclass.
].
clsLitIndex := aCompiler addLiteral:cls.
(litIndex <= 255 and:[clsLitIndex <= 255]) ifTrue:[
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:nargs; nextPut:clsLitIndex; nextPut:#drop.
^ self
].
"need 16bit litIndex"
aStream nextPut:codeL; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs; nextPut:clsLitIndex; nextPut:0; nextPut:#drop.
^ self
].
litIndex <= 255 ifTrue:[
(nargs <= 3) ifTrue:[
noSendDrop ifTrue:[
code := #(send0 send1 send2 send3) at:(nargs+1).
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex.
aStream nextPut:#drop.
] ifFalse:[
code := #(sendDrop0 sendDrop1 sendDrop2 sendDrop3) at:(nargs+1).
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex.
].
^ self
].
noSendDrop ifTrue:[
aStream nextPut:#send; nextPut:lineNr; nextPut:litIndex; nextPut:nargs.
aStream nextPut:#drop.
] ifFalse:[
aStream nextPut:#sendDrop; nextPut:lineNr; nextPut:litIndex; nextPut:nargs.
].
^ self
].
"need 16bit litIndex"
true "noSendDrop" ifTrue:[
aStream nextPut:#sendL; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs.
aStream nextPut:#drop.
] ifFalse:[
aStream nextPut:#sendDropL; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs
].
"Modified: / 4.7.1999 / 19:06:53 / cg"
!
codeForSideEffectOn:aStream inBlock:b for:aCompiler
self codeOn:aStream inBlock:b valueNeeded:false for:aCompiler
!
codeForSimpleReturnOn:aStream inBlock:b lineNumber:lineNrOrNil for:aCompiler
|arg1 rightExpr pos1|
(selector == #and:
or:[selector == #or:]) ifTrue:[
arg1 := argArray at:1.
"/ for now:
"/ only do it for non-blocks, since
"/ the JIT compiler is smart enough to
"/ specially optimize the resulting code
"/ (and not smart enough to optimized the
"/ other - actually more efficient - code)
(arg1 isBlock not
"/ or:[arg1 isInlinable]
) ifTrue:[
"/ encode #and: as:
"/
"/ eLeft
"/ jmp_false LBL
"/ eRight
"/ retTop
"/ LBL:
"/ retFalse
"/ encode #or: as:
"/
"/ eLeft
"/ jmp_true LBL
"/ eRight
"/ retTop
"/ LBL:
"/ retTrue
receiver codeOn:aStream inBlock:b for:aCompiler.
selector == #and: ifTrue:[
aStream nextPut:#falseJump.
] ifFalse:[
aStream nextPut:#trueJump.
].
pos1 := aStream position1Based.
aStream nextPut:0.
rightExpr := argArray at:1.
rightExpr isBlock ifTrue:[
rightExpr codeInlineOn:aStream inBlock:b valueNeeded:true for:aCompiler.
] ifFalse:[
rightExpr codeOn:aStream inBlock:b for:aCompiler.
].
aStream nextPut:#retTop.
(aStream contents) at:pos1 put:(aStream position1Based).
selector == #and: ifTrue:[
aStream nextPut:#retFalse.
] ifFalse:[
aStream nextPut:#retTrue
].
^ self.
].
].
super
codeForSimpleReturnOn:aStream
inBlock:b
lineNumber:lineNrOrNil
for:aCompiler
!
codeIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for x ifxxx:[ ... ] yyy:[ ...]"
|pos pos2 theReceiver theArg theByteCode optByteCode subsel code needLineNr
needJump block1 block2|
theReceiver := receiver.
theReceiver isConstant ifTrue:[
(self tryFoldedIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler) ifTrue:[
^ self
].
].
(theReceiver isMessage) ifTrue:[
subsel := theReceiver selector.
(subsel == #and:) ifTrue:[
self codeAndIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ self
].
(subsel == #or:) ifTrue:[
self codeOrIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ self
]
].
(selector == #ifTrue:ifFalse:) ifTrue:[
theByteCode := #falseJump
] ifFalse:[
theByteCode := #trueJump
].
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode
].
theReceiver codeOn:aStream inBlock:b for:aCompiler.
needLineNr := true.
theArg isNil ifTrue:[
theReceiver isMessage ifTrue:[
(aCompiler hasLineNumber:(theReceiver selector)) ifTrue:[
theReceiver lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
]
] ifFalse:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
needLineNr ifTrue:[
(lineNr between:1 and:255) ifTrue:[
aStream nextPut:#lineno; nextPut:lineNr.
]
].
aStream nextPut:theByteCode.
pos := aStream position1Based.
aStream nextPut:0.
block1 := argArray at:1.
self codeBlockEvaluation:block1 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
needJump := true.
(block1 isBlock and:[block1 endsWithReturn]) ifTrue:[
needJump := false
].
needJump ifTrue:[
aStream nextPut:#jump.
pos2 := aStream position1Based.
aStream nextPut:0.
].
code := aStream contents.
code at:pos put:(aStream position1Based).
block2 := (argArray at:2).
self codeBlockEvaluation:block2 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
needJump ifTrue:[
code at:pos2 put:(aStream position1Based)
]
"Modified: 9.11.1996 / 19:53:52 / cg"
!
codeIfNilNotNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for x ifNil:[ ... ] ifNotNil:[...]
or: x ifNil:const1 ifNotNil:const2"
|pos pos2 theReceiver theArg theByteCode code
needLineNr block1 block2|
theReceiver := receiver.
(selector == #ifNil:ifNotNil:) ifTrue:[
theByteCode := #notNilJump
] ifFalse:[
theByteCode := #nilJump
].
theReceiver codeOn:aStream inBlock:b for:aCompiler.
needLineNr := true.
theArg isNil ifTrue:[
theReceiver isMessage ifTrue:[
(aCompiler hasLineNumber:(theReceiver selector)) ifTrue:[
theReceiver lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
]
].
needLineNr ifTrue:[
(lineNr between:1 and:255) ifTrue:[
aStream nextPut:#lineno; nextPut:lineNr.
]
].
aStream nextPut:theByteCode.
pos := aStream position1Based.
aStream nextPut:0.
block1 := argArray at: 1.
self codeBlockEvaluation:block1 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
aStream nextPut:#jump.
pos2 := aStream position1Based.
aStream nextPut:0.
code := aStream contents.
code at:pos put:(aStream position1Based).
block2 := argArray at: 2.
self codeBlockEvaluation:block2 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code := aStream contents.
code at:pos2 put:(aStream position1Based)
"Modified: / 11.2.2000 / 12:50:36 / cg"
!
codeIfNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for x ifNil:[ ... ]"
|pos theReceiver theByteCode code needLineNr|
theReceiver := receiver.
(selector == #ifNil:) ifTrue:[
theByteCode := #notNilJump
] ifFalse:[
theByteCode := #nilJump
].
theReceiver codeOn:aStream inBlock:b for:aCompiler.
needLineNr := true.
theReceiver isMessage ifTrue:[
(aCompiler hasLineNumber:(theReceiver selector)) ifTrue:[
theReceiver lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
].
needLineNr ifTrue:[
(lineNr between:1 and:255) ifTrue:[
aStream nextPut:#lineno; nextPut:lineNr.
]
].
valueNeeded ifTrue:[
aStream nextPut:#dup.
].
aStream nextPut:theByteCode.
pos := aStream position1Based.
aStream nextPut:0.
valueNeeded ifTrue:[
aStream nextPut:#drop.
].
self codeBlockEvaluation:(argArray at: 1) on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code := aStream contents.
code at:pos put:(aStream position1Based)
"Modified: / 28.10.1997 / 18:33:42 / cg"
!
codeIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for x ifxxx:[ ... ]"
|pos pos2 theReceiver theArg theByteCode optByteCode subsel code
needLineNr block|
theReceiver := receiver.
theReceiver isConstant ifTrue:[
(self tryFoldedIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler) ifTrue:[
^ self
].
].
(theReceiver isMessage) ifTrue:[
subsel := theReceiver selector.
(subsel == #and:) ifTrue:[
theReceiver arg1 isBlock ifTrue:[
self codeAndIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ self
]
].
(subsel == #or:) ifTrue:[
theReceiver arg1 isBlock ifTrue:[
self codeOrIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ self
]
].
].
(selector == #ifTrue:) ifTrue:[
theByteCode := #falseJump
] ifFalse:[
theByteCode := #trueJump
].
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode
].
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
needLineNr := true.
theArg isNil ifTrue:[
theReceiver isMessage ifTrue:[
(aCompiler hasLineNumber:(theReceiver selector)) ifTrue:[
theReceiver lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
]
].
needLineNr ifTrue:[
(lineNr between:1 and:255) ifTrue:[
aStream nextPut:#lineno; nextPut:lineNr.
]
].
aStream nextPut:theByteCode.
pos := aStream position1Based.
aStream nextPut:0.
block := (argArray at:1).
self codeBlockEvaluation:block on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code := aStream contents.
valueNeeded ifTrue:[
aStream nextPut:#jump.
pos2 := aStream position1Based.
aStream nextPut:0.
code at:pos put:(aStream position1Based).
aStream nextPut:#pushNil.
code at:pos2 put:(aStream position1Based)
] ifFalse:[
code at:pos put:(aStream position1Based)
]
"Modified: / 28.10.1997 / 18:33:42 / cg"
!
codeOn:aStream inBlock:b for:aCompiler
self codeOn:aStream inBlock:b valueNeeded:true for:aCompiler
!
codeOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
|recType nargs isBuiltIn litIndex cls clsLitIndex code isSpecial
specialCode stackTop arg1 arg2 arg3 isSuper realReceiver noSendDrop|
"/ must be added for search to work on optimized nodes
aCompiler addLiteral:selector.
noSendDrop := aCompiler class newCodeSet == true.
realReceiver := self realReceiver.
isSuper := realReceiver isSuper.
argArray isNil ifTrue:[
nargs := 0
] ifFalse:[
nargs := argArray size.
nargs > 0 ifTrue:[
arg1 := argArray at:1.
nargs > 1 ifTrue:[
arg2 := argArray at:2.
nargs > 2 ifTrue:[
arg3 := argArray at:3.
]
]
].
].
isBuiltIn := isSpecial := false.
recType := receiver type.
(nargs == 0) ifTrue:[
(recType == #ThisContext) ifTrue:[
valueNeeded ifFalse:[
"for now, only do it in methods"
b isNil ifTrue:[
(selector == #restart) ifTrue:[
aStream nextPut:#jump; nextPut:1. "jump to start"
^ self
].
].
(selector == #return) ifTrue:[ "^ nil"
aStream nextPut:#retNil.
^ self
].
]
].
(receiver isBlock
and:[receiver numArgs == 0
and:[receiver isInlinable]]) ifTrue:[
selector == #value ifTrue:[
receiver codeInlineOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ self
].
((selector == #whileTrue) or:[selector == #whileFalse]) ifTrue:[
^ self codeWhileOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
((selector == #repeat) or:[selector == #loop]) ifTrue:[
valueNeeded ifFalse:[
^ self codeRepeatOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
]
].
].
isSuper ifFalse:[
isBuiltIn := aCompiler isBuiltInUnarySelector:selector forReceiver:receiver.
]
].
(nargs == 1) ifTrue:[
(recType == #ThisContext) ifTrue:[
valueNeeded ifFalse:[
(selector == #return:) ifTrue:[
arg1 codeOn:aStream inBlock:b for:aCompiler. "^ value"
aStream nextPut:#retTop.
^ self
].
].
].
((selector == #ifNil:) or:[selector == #ifNotNil:]) ifTrue:[
receiver isBlock ifFalse:[
(arg1 isBlock not
or:[arg1 numArgs == 0]) ifTrue:[
^ self codeIfNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
(arg1 isConstant or:[arg1 isVariable]) ifTrue:[
^ self codeIfNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
].
].
(arg1 isBlock
and:[arg1 isInlinable
and:[arg1 numArgs == 0]]) ifTrue:[
((selector == #ifTrue:) or:[selector == #ifFalse:]) ifTrue:[
receiver isBlock ifFalse:[
^ self codeIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
].
(selector == #or:) ifTrue:[
^ self codeOrOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
(selector == #and:) ifTrue:[
^ self codeAndOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
(selector == #timesRepeat:) ifTrue:[
"/ now, always inline #timesRepeat:;
"/ the receiver must understand #> and #-
^ self codeTimesRepeatOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
((selector == #whileTrue:) or:[selector == #whileFalse:]) ifTrue:[
(receiver isBlock
and:[receiver isInlinable
and:[receiver numArgs == 0]]) ifTrue:[
^ self codeWhileOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
]
]
].
((selector == #ifTrue:) or:[selector == #ifFalse:]) ifTrue:[
(arg1 isConstant or:[arg1 isVariable]) ifTrue:[
^ self codeIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
].
selector == #? ifTrue:[
"/ only do short-circuit optimization, if arg is not a message;
"/ (could have side-effects)
"/
arg1 isMessage ifFalse:[
^ self codeQuestOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
]
].
isSuper ifFalse:[
isBuiltIn := aCompiler isBuiltIn1ArgSelector:selector forReceiver:receiver.
]
].
(nargs == 2) ifTrue:[
receiver isBlock ifFalse:[
(arg1 isBlock
and:[arg1 isInlinable
and:[arg1 numArgs == 0
and:[arg2 isBlock
and:[arg2 isInlinable
and:[arg2 numArgs == 0]]]]]) ifTrue:[
((selector == #ifTrue:ifFalse:) or:[selector == #ifFalse:ifTrue:]) ifTrue:[
^ self codeIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
((selector == #ifNil:ifNotNil:) or:[selector == #ifNotNil:ifNil:]) ifTrue:[
^ self codeIfNilNotNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
]
].
((arg1 isConstant or:[arg1 isVariable])
and:[arg2 isConstant or:[arg2 isVariable]]) ifTrue:[
((selector == #ifTrue:ifFalse:) or:[selector == #ifFalse:ifTrue:]) ifTrue:[
^ self codeIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
].
((selector == #ifNil:ifNotNil:) or:[selector == #ifNotNil:ifNil:]) ifTrue:[
^ self codeIfNilNotNilOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
]
].
].
selector == #to:do: ifTrue:[
(arg2 isBlock
and:[arg2 isInlinable
and:[arg2 numArgs == 1]]) ifTrue:[
^ self codeToDoOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
]
].
isSuper ifFalse:[
isBuiltIn := aCompiler isBuiltIn2ArgSelector:selector forReceiver:receiver.
]
].
(nargs == 3) ifTrue:[
selector == #to:by:do: ifTrue:[
"/ step must be a constant (need to know how to compare)
(arg2 isConstant
and:[arg2 type == #Integer
and:[arg3 isBlock
and:[arg3 isInlinable
and:[arg3 numArgs == 1]]]]) ifTrue:[
^ self codeToByDoOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
]
].
].
isSuper ifFalse:[
isBuiltIn ifFalse:[
specialCode := aCompiler specialSendCodeFor:selector.
isSpecial := specialCode notNil.
].
].
"can we use a send-bytecode ?"
(isBuiltIn or:[isSpecial]) ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler.
(nargs > 0) ifTrue:[
arg1 codeOn:aStream inBlock:b for:aCompiler.
(nargs > 1) ifTrue:[
arg2 codeOn:aStream inBlock:b for:aCompiler
]
].
aStream nextPut:selector.
(aCompiler hasLineNumber:selector) ifTrue:[
aStream nextPut:lineNr.
].
isSpecial ifTrue:[
aStream nextPut:specialCode
].
valueNeeded ifFalse:[
aStream nextPut:#drop
].
^ self
].
((nargs == 0) and:[selector == #yourself]) ifTrue:[
"yourself is often added to get the receiver -
we get it without the yourself-message"
valueNeeded ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler
].
^ self
].
"no - generate a send"
isSuper ifTrue:[
cls := aCompiler targetClass.
realReceiver isHere ifTrue:[
code := #hereSend.
] ifFalse:[
code := #superSend.
cls := cls superclass.
].
clsLitIndex := aCompiler addLiteral:cls.
] ifFalse:[
clsLitIndex := 0.
].
litIndex := aCompiler addLiteral:selector.
(litIndex <= 255 and:[clsLitIndex <= 255]) ifTrue:[
stackTop := nil.
(recType ~~ #Self) ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler.
receiver isConstant ifTrue:[
stackTop := receiver
]
].
argArray notNil ifTrue:[
argArray do:[:arg |
(stackTop notNil
and:[arg canReuseAsArg:stackTop]) ifTrue:[
aStream nextPut:#dup.
"/ 'reuse:' print. stackTop print. ' in ' print. aCompiler selector printNL.
] ifFalse:[
arg codeOn:aStream inBlock:b for:aCompiler.
stackTop := arg.
]
]
].
isSuper ifTrue:[
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:nargs; nextPut:clsLitIndex.
valueNeeded ifFalse:[
aStream nextPut:#drop
].
^ self
].
(nargs <= 3) ifTrue:[
|codes|
(noSendDrop or:[valueNeeded]) ifTrue:[
(recType == #Self) ifTrue:[
codes := #(sendSelf0 sendSelf1 sendSelf2 sendSelf3)
] ifFalse:[
codes := #(send0 send1 send2 send3)
]
] ifFalse:[
(recType == #Self) ifTrue:[
codes := #(sendSelfDrop0 sendSelfDrop1 sendSelfDrop2 sendSelfDrop3)
] ifFalse:[
codes := #(sendDrop0 sendDrop1 sendDrop2 sendDrop3)
]
].
aStream nextPut:(codes at:(nargs + 1)); nextPut:lineNr; nextPut:litIndex.
(valueNeeded not and:[noSendDrop]) ifTrue:[
aStream nextPut:#drop
].
^ self
].
(recType == #Self) ifTrue:[
code := #sendSelf
] ifFalse:[
(noSendDrop or:[valueNeeded]) ifTrue:[
code := #send
] ifFalse:[
code := #sendDrop
]
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:nargs.
valueNeeded ifFalse:[
(noSendDrop or:[recType == #Self]) ifTrue:[
aStream nextPut:#drop
].
].
^ self
].
"needs 16bit literal index"
isSuper ifTrue:[
argArray notNil ifTrue:[
argArray do:[:arg |
arg codeOn:aStream inBlock:b for:aCompiler
]
].
realReceiver isHere ifTrue:[
code := #hereSendL
] ifFalse:[
code := #superSendL.
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs; nextPut:clsLitIndex; nextPut:0.
] ifFalse:[
recType ~~ #Self ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler.
].
argArray notNil ifTrue:[
argArray do:[:arg |
arg codeOn:aStream inBlock:b for:aCompiler
]
].
recType == #Self ifTrue:[
code := #sendSelfL
] ifFalse:[
code := #sendL
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs.
].
valueNeeded ifFalse:[
aStream nextPut:#drop
].
"Modified: / 3.9.1995 / 12:55:42 / claus"
"Modified: / 11.2.2000 / 12:47:45 / cg"
!
codeOrIfElseOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x or:[y]) ifxxx:[ ... ] ifyyy:[ ... ]"
|theByteCode optByteCode theReceiver theArg pos1 pos2 pos3 code here jmp
block1 block2 optJmp blockExpr|
aCompiler addLiteral:#or:.
theByteCode := #trueJump.
theReceiver := receiver receiver.
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode
].
"/ code the left-of the or-part
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
aStream nextPut:theByteCode.
pos1 := aStream position1Based. "/ remember branch target of left-ok branch
aStream nextPut:0.
"/ code the right of the or-part
(selector == #ifTrue:ifFalse:) ifTrue:[
jmp := #falseJump
] ifFalse:[
jmp := #trueJump
].
theReceiver := receiver arg1.
theArg := nil.
optJmp := nil.
(theReceiver isBlock
and:[theReceiver statements notNil
and:[theReceiver statements nextStatement isNil]]) ifTrue:[
blockExpr := theReceiver statements expression.
optJmp := self optimizedConditionFor:blockExpr with:jmp for:aCompiler.
optJmp notNil ifTrue:[
((optJmp == #eqJump) or:[optJmp == #notEqJump]) ifTrue:[
theArg := blockExpr arg1
].
theReceiver := blockExpr receiver.
jmp := optJmp
].
].
optJmp notNil ifTrue:[
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
]
] ifFalse:[
theReceiver codeInlineOn:aStream inBlock:b for:aCompiler.
].
aStream nextPut:jmp.
pos2 := aStream position1Based. "/ remember branch target of right-fail branch
aStream nextPut:0.
code := aStream contents.
(selector == #ifTrue:ifFalse:) ifTrue:[
code at:pos1 put:(aStream position1Based)
].
"/ code the if-block
block1 := argArray at: 1.
self codeBlockEvaluation:block1 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
aStream nextPut:#jump.
pos3 := aStream position1Based.
aStream nextPut:0.
here := aStream position1Based.
(selector == #ifFalse:ifTrue:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here.
"/ code the else-block
block2 := argArray at: 2.
self codeBlockEvaluation:block2 on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code at:pos3 put:(aStream position1Based)
"Created: 6.9.1996 / 13:08:52 / cg"
!
codeOrIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x or:[y]) ifxxx:[ ... ]"
|theByteCode optByteCode theReceiver theArg pos1 pos2 pos3 code here jmp
block|
aCompiler addLiteral:#or:.
theByteCode := #trueJump.
theReceiver := receiver receiver.
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode
].
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
aStream nextPut:theByteCode.
pos1 := aStream position1Based.
aStream nextPut:0.
theReceiver := receiver arg1.
theArg := nil.
"new:"
(selector == #ifTrue:) ifTrue:[
theByteCode := #falseJump
] ifFalse:[
theByteCode := #trueJump
].
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
optByteCode notNil ifTrue:[
theReceiver isBlock ifTrue:[
theReceiver := theReceiver statements expression
].
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := theReceiver arg1
].
theReceiver := theReceiver receiver.
theByteCode := optByteCode.
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
].
aStream nextPut:theByteCode.
] ifFalse:[
"org"
theReceiver codeInlineOn:aStream inBlock:b for:aCompiler.
(selector == #ifTrue:) ifTrue:[
jmp := #falseJump
] ifFalse:[
jmp := #trueJump
].
aStream nextPut:jmp
].
pos2 := aStream position1Based.
aStream nextPut:0.
(selector == #ifTrue:) ifTrue:[
(aStream contents) at:pos1 put:(aStream position1Based)
].
block := argArray at: 1.
self codeBlockEvaluation:block on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
code := aStream contents.
valueNeeded ifTrue:[
aStream nextPut:#jump.
pos3 := aStream position1Based.
aStream nextPut:0.
here := aStream position1Based.
(selector == #ifFalse:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here.
aStream nextPut:#pushNil.
code at:pos3 put:(aStream position1Based)
] ifFalse:[
here := aStream position1Based.
(selector == #ifFalse:) ifTrue:[
code at:pos1 put:here
].
code at:pos2 put:here
]
"Modified: 9.11.1996 / 19:52:26 / cg"
!
codeOrOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for (x or:[y])"
|pos1 rightExpr|
aCompiler addLiteral:#or:.
receiver codeOn:aStream inBlock:b for:aCompiler.
valueNeeded ifTrue:[
aStream nextPut:#dup.
].
aStream nextPut:#trueJump.
pos1 := aStream position1Based.
aStream nextPut:0.
valueNeeded ifTrue:[
aStream nextPut:#drop.
].
rightExpr := argArray at:1.
rightExpr codeInlineOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
(aStream contents) at:pos1 put:(aStream position1Based)
"Created: 17.6.1996 / 15:40:22 / cg"
"Modified: 17.6.1996 / 15:47:22 / cg"
!
codeQuestOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for x ? y.
However, this is only done for non-send args."
|pos code|
aCompiler addLiteral:#'?'.
receiver codeOn:aStream inBlock:b for:aCompiler.
aStream nextPut:#dup.
aStream nextPut:#notNilJump.
pos := aStream position1Based.
aStream nextPut:0.
aStream nextPut:#drop.
(argArray at: 1) codeOn:aStream inBlock:b for:aCompiler.
code := aStream contents.
code at:pos put:(aStream position1Based).
valueNeeded ifFalse:[
aStream nextPut:#drop.
].
"Created: / 10.11.1996 / 18:28:57 / cg"
"Modified: / 28.10.1997 / 18:16:20 / cg"
!
codeRepeatOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for
[ ... ] repeat
and:
[ ... ] loop
"
|pos|
pos := aStream position1Based.
receiver codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
aStream nextPut:#jump; nextPut:pos.
"Created: 29.8.1997 / 08:14:58 / cg"
!
codeSendOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"like code on, but assumes that receiver has already been
coded onto stack - needed for cascade"
|nargs isBuiltIn code codeL litIndex cls clsLitIndex isSuper realReceiver noSendDrop|
noSendDrop := aCompiler class newCodeSet == true.
realReceiver := self realReceiver.
isSuper := realReceiver isSuper.
argArray isNil ifTrue:[
nargs := 0
] ifFalse:[
nargs := argArray size
].
isBuiltIn := false.
isSuper ifFalse:[
(nargs == 0) ifTrue:[
isBuiltIn := aCompiler isBuiltInUnarySelector:selector forReceiver:receiver
].
(nargs == 1) ifTrue:[
isBuiltIn := aCompiler isBuiltIn1ArgSelector:selector forReceiver:receiver
].
(nargs == 2) ifTrue:[
isBuiltIn := aCompiler isBuiltIn2ArgSelector:selector forReceiver:receiver
].
].
"can we use a send-bytecode ?"
isBuiltIn ifTrue:[
(nargs > 0) ifTrue:[
(argArray at:1) codeOn:aStream inBlock:b for:aCompiler.
(nargs > 1) ifTrue:[
(argArray at:2) codeOn:aStream inBlock:b for:aCompiler
]
].
aStream nextPut:selector.
(aCompiler hasLineNumber:selector) ifTrue:[
aStream nextPut:lineNr.
].
valueNeeded ifFalse:[
aStream nextPut:#drop
].
^ self
].
argArray notNil ifTrue:[
argArray do:[:arg |
arg codeOn:aStream inBlock:b for:aCompiler
]
].
isSuper ifTrue:[
cls := aCompiler targetClass.
realReceiver isHere ifTrue:[
code := #hereSend.
codeL := #hereSendL
] ifFalse:[
code := #superSend.
codeL := #superSend.
cls := cls superclass.
].
clsLitIndex := aCompiler addLiteral:cls.
litIndex := aCompiler addLiteral:selector.
(litIndex <= 255 and:[clsLitIndex <= 255]) ifTrue:[
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:nargs; nextPut:clsLitIndex.
] ifFalse:[
aStream nextPut:codeL; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs; nextPut:clsLitIndex; nextPut:0.
].
valueNeeded ifFalse:[
aStream nextPut:#drop
].
^ self
].
(nargs == 0) ifTrue:[
(selector == #yourself) ifTrue:[
"yourself is often added to get the receiver -
we get it without the yourself-message"
valueNeeded ifFalse:[
aStream nextPut:#drop
].
^ self
].
].
litIndex := aCompiler addLiteral:selector.
litIndex <= 255 ifTrue:[
(nargs <= 3) ifTrue:[
(noSendDrop or:[valueNeeded]) ifTrue:[
code := #(send0 send1 send2 send3) at:(nargs+1).
] ifFalse:[
code := #(sendDrop0 sendDrop1 sendDrop2 sendDrop3) at:(nargs+1).
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex.
(valueNeeded not and:[noSendDrop]) ifTrue:[
aStream nextPut:#drop
].
^ self
].
(noSendDrop or:[valueNeeded]) ifTrue:[
code := #send
] ifFalse:[
code := #sendDrop
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:nargs.
(valueNeeded not and:[noSendDrop]) ifTrue:[
aStream nextPut:#drop
].
^ self
].
true "(noSendDrop or:[valueNeeded])" ifTrue:[
code := #sendL
] ifFalse:[
code := #sendDropL
].
aStream nextPut:code; nextPut:lineNr; nextPut:litIndex; nextPut:0; nextPut:nargs.
(valueNeeded not and:[noSendDrop]) ifTrue:[
aStream nextPut:#drop
].
"Modified: / 16.7.1998 / 20:26:52 / cg"
!
codeTimesRepeatOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for n timesRepeat:[ ... ]"
|pos1 pos2 lateEval loopCount|
lateEval := false.
receiver isConstant ifTrue:[
loopCount := receiver evaluate.
(loopCount isMemberOf:SmallInteger) ifFalse:[
loopCount := nil.
] ifTrue:[
loopCount <= 0 ifTrue:[
"/ thats it - all we need is the receiver on the stack
valueNeeded ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler.
].
^ self
]
].
].
receiver codeOn:aStream inBlock:b for:aCompiler.
valueNeeded ifTrue:[
"/ easily reconstructable - no need to keep on stack
loopCount notNil ifTrue:[
lateEval := true.
].
lateEval ifFalse:[
aStream nextPut:#dup
].
].
loopCount isNil ifTrue:[
aStream nextPut:#pushgt0; nextPut:lineNr; nextPut:#falseJump.
pos2 := aStream position1Based.
aStream nextPut:0.
].
pos1 := aStream position1Based.
(argArray at:1) codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
aStream nextPut:#minus1; nextPut:lineNr.
aStream nextPut:#pushgt0; nextPut:lineNr.
aStream nextPut:#trueJump; nextPut:pos1.
pos2 notNil ifTrue:[
(aStream contents) at:pos2 put:(aStream position1Based).
].
aStream nextPut:#drop. "/ drop run variable
lateEval ifTrue:[
receiver codeOn:aStream inBlock:b for:aCompiler.
]
"Modified: 27.5.1997 / 14:28:49 / cg"
!
codeToByDoOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for a to:b by:c do:[:arg | ... ]"
|pos pos2 start stop step lateEval theBlock loopVarIndex
stepVal stopVarIndex|
"/ NOTICE: could compile it as a timesRepeat-like loop, if
"/ the loop-counter is not accessed within the loop-block.
"/ This generates somewhat (15%) faster code, but makes
"/ debugging somewhat difficult (no loop-value seen in debugger).
start := receiver.
stop := (argArray at:1).
step := (argArray at:2).
"/ stop isConstant ifFalse:[self error:'should not happen' mayProceed:true].
"/ (stop evaluate isMemberOf:SmallInteger) ifFalse:[self error:'should not happen' mayProceed:true].
step isConstant ifFalse:[self error:'should not happen' mayProceed:true].
stepVal := step evaluate.
(stepVal isMemberOf:SmallInteger) ifFalse:[
self error:'should not happen' mayProceed:true
].
start codeOn:aStream inBlock:b for:aCompiler.
lateEval := false.
valueNeeded ifTrue:[
"/ easily reconstructable - no need to keep on stack
start isConstant ifTrue:[
(start evaluate isMemberOf:SmallInteger) ifTrue:[
lateEval := true.
]
].
lateEval ifFalse:[
aStream nextPut:#dup
].
].
"/ if stop is not constant, and not an argVar,
"/ evaluate it into a temp slot ...
(stop isConstant and:[stop type == #Integer]) ifFalse:[
"/ a method/blockArg is constant as well ...
(stop isVariable and:[stop isArgument]) ifFalse:[
stop codeOn:aStream inBlock:b for:aCompiler.
b isNil ifTrue:[
stopVarIndex := aCompiler addTempVar.
aStream nextPut:#storeMethodVar; nextPut:stopVarIndex.
] ifFalse:[
stopVarIndex := b addTempVar.
aStream nextPut:#storeBlockVar; nextPut:stopVarIndex.
].
]
].
pos := aStream position1Based.
aStream nextPut:#dup.
stopVarIndex notNil ifTrue:[
b isNil ifTrue:[
aStream nextPut:#pushMethodVar; nextPut:stopVarIndex.
] ifFalse:[
aStream nextPut:#pushBlockVar; nextPut:stopVarIndex.
]
] ifFalse:[
stop codeOn:aStream inBlock:b for:aCompiler.
].
stepVal >= 0 ifTrue:[
aStream nextPut:#>.
] ifFalse:[
aStream nextPut:#<.
].
(aCompiler hasLineNumber:selector) ifTrue:[
aStream nextPut:lineNr.
].
aStream nextPut:#trueJump.
pos2 := aStream position1Based.
aStream nextPut:0.
theBlock := argArray at:3.
"/ need a temporary in the outer context for
"/ the loop ...
b isNil ifTrue:[
loopVarIndex := aCompiler addTempVar.
aStream nextPut:#dup.
aStream nextPut:#storeMethodVar; nextPut:loopVarIndex.
] ifFalse:[
loopVarIndex := b addTempVar.
aStream nextPut:#dup.
aStream nextPut:#storeBlockVar; nextPut:loopVarIndex.
].
theBlock indexOfFirstTemp:loopVarIndex.
theBlock codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
"/ increment/decrement counter & jump back.
stepVal == 1 ifTrue:[
aStream nextPut:#plus1; nextPut:lineNr.
] ifFalse:[
stepVal == -1 ifTrue:[
aStream nextPut:#minus1; nextPut:lineNr.
] ifFalse:[
step codeOn:aStream inBlock:b for:aCompiler.
aStream nextPut:#+.
(aCompiler hasLineNumber:#+) ifTrue:[
aStream nextPut:lineNr.
].
]
].
aStream nextPut:#jump; nextPut:pos.
(aStream contents) at:pos2 put:(aStream position1Based).
aStream nextPut:#drop. "/ drop run variable
lateEval ifTrue:[
start codeOn:aStream inBlock:b for:aCompiler.
].
"/ no need to nil-out loop-tempVar to help GC
"/ (its integer, anyway).
b isNil ifTrue:[
aCompiler removeTempVar
] ifFalse:[
b removeTempVar
].
stopVarIndex notNil ifTrue:[
b isNil ifTrue:[
aCompiler removeTempVar
] ifFalse:[
b removeTempVar
]
].
"Created: 27.6.1997 / 12:48:18 / cg"
"Modified: 27.6.1997 / 13:43:06 / cg"
!
codeToDoOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for n to:n do:[:unusedArg | ... ]"
|pos pos2 start stop lateEval theBlock loopVarIndex
stopVarIndex|
"/ NOTICE: could compile it as a timesRepeat, if
"/ the loop-counter is not accessed within the loop-block.
"/ This generates somewhat (15%) faster code, but makes
"/ debugging somewhat difficult (no loop-value seen in debugger).
start := receiver.
stop := (argArray at:1).
"/ stop isConstant ifFalse:[self halt:'should not happen'].
"/ (stop evaluate isMemberOf:SmallInteger) ifFalse:[self halt:'should not happen'].
start codeOn:aStream inBlock:b for:aCompiler.
lateEval := false.
valueNeeded ifTrue:[
"/ easily reconstructable - no need to keep on stack
start isConstant ifTrue:[
(start evaluate isMemberOf:SmallInteger) ifTrue:[
lateEval := true.
]
].
lateEval ifFalse:[
aStream nextPut:#dup
].
].
"/ if stop is not constant, and not an argVar,
"/ evaluate it into a temp slot ...
(stop isConstant and:[stop type == #Integer]) ifFalse:[
"/ a method/blockArg is constant as well ...
(stop isVariable and:[stop isArgument]) ifFalse:[
stop codeOn:aStream inBlock:b for:aCompiler.
b isNil ifTrue:[
stopVarIndex := aCompiler addTempVar.
aStream nextPut:#storeMethodVar; nextPut:stopVarIndex.
] ifFalse:[
stopVarIndex := b addTempVar.
aStream nextPut:#storeBlockVar; nextPut:stopVarIndex.
].
]
].
pos := aStream position1Based.
aStream nextPut:#lineno; nextPut:lineNr.
aStream nextPut:#dup.
stopVarIndex notNil ifTrue:[
b isNil ifTrue:[
aStream nextPut:#pushMethodVar; nextPut:stopVarIndex.
] ifFalse:[
aStream nextPut:#pushBlockVar; nextPut:stopVarIndex.
]
] ifFalse:[
stop codeOn:aStream inBlock:b for:aCompiler.
].
aStream nextPut:#>.
(aCompiler hasLineNumber:selector) ifTrue:[
aStream nextPut:lineNr.
].
aStream nextPut:#trueJump.
pos2 := aStream position1Based.
aStream nextPut:0.
theBlock := argArray at:2.
"/ need a temporary in the outer context for
"/ the loop ...
b isNil ifTrue:[
loopVarIndex := aCompiler addTempVar.
aStream nextPut:#dup.
aStream nextPut:#storeMethodVar; nextPut:loopVarIndex.
] ifFalse:[
loopVarIndex := b addTempVar.
aStream nextPut:#dup.
aStream nextPut:#storeBlockVar; nextPut:loopVarIndex.
].
theBlock indexOfFirstTemp:loopVarIndex.
theBlock codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
"/ increment counter & jump back.
aStream nextPut:#plus1; nextPut:lineNr; nextPut:#jump; nextPut:pos.
(aStream contents) at:pos2 put:(aStream position1Based).
aStream nextPut:#drop. "/ drop run variable
lateEval ifTrue:[
start codeOn:aStream inBlock:b for:aCompiler.
].
"/ no need to nil-out loop-tempVar to help GC
"/ (its integer, anyway).
b isNil ifTrue:[
aCompiler removeTempVar
] ifFalse:[
b removeTempVar
].
stopVarIndex notNil ifTrue:[
b isNil ifTrue:[
aCompiler removeTempVar
] ifFalse:[
b removeTempVar
]
].
"Created: 26.6.1997 / 10:58:47 / cg"
"Modified: 19.10.1997 / 01:31:40 / cg"
!
codeValueSendOn:aStream for:aCompiler
"/ send #value to the top of the stack ...
aStream nextPut:#value.
(aCompiler hasLineNumber:#value) ifTrue:[
aStream nextPut:lineNr.
]
!
codeWhileOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for
[...] whileXXX:[ ... ]
and also
[...] whileXXX
"
|pos pos2 theReceiver theArg theByteCode optByteCode needLineNr blockExpr
hasLoopBlock fastReceiver condStats constCondition|
hasLoopBlock := true.
(selector == #whileTrue:) ifTrue:[
theByteCode := #falseJump.
] ifFalse:[
(selector == #whileFalse:) ifTrue:[
theByteCode := #trueJump
] ifFalse:[
hasLoopBlock := false.
(selector == #whileTrue) ifTrue:[
theByteCode := #trueJump
] ifFalse:[
theByteCode := #falseJump
].
]
].
theReceiver := receiver.
(receiver isBlock
and:[(condStats := receiver statements) notNil
and:[condStats nextStatement isNil
and:[condStats expression notNil]]])
ifTrue:[
fastReceiver := receiver statements expression.
optByteCode := self optimizedConditionFor:fastReceiver with:theByteCode for:aCompiler.
] ifFalse:[
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
].
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := receiver statements expression arg1
].
theReceiver := receiver statements expression receiver.
theByteCode := optByteCode
].
"/ OLD:
"/ valueNeeded ifTrue:[aStream nextPut:#pushNil].
"/
needLineNr := true.
pos := aStream position1Based.
"/ aCompiler lineNumberInfo == #full ifTrue:[
self codeLineNumber:lineNr on:aStream for:aCompiler.
needLineNr := false.
"/ ].
optByteCode notNil ifTrue:[
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
]
] ifFalse:[
(fastReceiver notNil
and:[fastReceiver isConstant]) ifTrue:[
constCondition := fastReceiver evaluate.
theByteCode == #trueJump ifTrue:[
constCondition == true ifTrue:[
theByteCode := #jump
] ifFalse:[
constCondition == false ifTrue:[
theByteCode := #never
]
]
] ifFalse:[
theByteCode == #falseJump ifTrue:[
constCondition == false ifTrue:[
theByteCode := #jump
] ifFalse:[
constCondition == true ifTrue:[
theByteCode := #never
]
]
]
]
].
(theByteCode ~~ #jump and:[theByteCode ~~ #never]) ifTrue:[
theReceiver codeInlineOn:aStream inBlock:b for:aCompiler.
].
"/
"/ cannot enable code below
"/ (tiny loops would not be debuggable with next, since lineNo remains the same)
"/ think about it ...
"/
blockExpr := theReceiver simpleSendBlockExpression.
blockExpr notNil ifTrue:[
blockExpr isMessage ifTrue:[
(aCompiler hasLineNumber:(blockExpr selector)) ifTrue:[
blockExpr lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
]
].
].
needLineNr ifTrue:[
ParseNode codeLineNumber:lineNr on:aStream for:aCompiler.
].
hasLoopBlock ifFalse:[
"/ simple [...] whileXXX
theByteCode ~~ #never ifTrue:[
aStream nextPut:theByteCode; nextPut:pos.
].
valueNeeded ifTrue:[aStream nextPut:#pushNil].
^ self
].
"/ [...] whileXXX:[...]
theByteCode ~~ #never ifTrue:[
aStream nextPut:theByteCode.
pos2 := aStream position1Based.
aStream nextPut:0.
].
(argArray at:1) codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
aStream nextPut:#jump; nextPut:pos.
theByteCode ~~ #never ifTrue:[
(aStream contents) at:pos2 put:(aStream position1Based).
].
valueNeeded ifTrue:[aStream nextPut:#pushNil].
"Modified: 22.10.1996 / 21:34:37 / cg"
!
new_codeWhileOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
"generate code for
[...] whileXXX:[ ... ]
and also
[...] whileXXX
This generates the check at the end and should generate better
code (only 1 conditional-branch at the end instead of 2 branches).
However, for now, it is disabled, since the JIT has special provisions
to detect loops and actually generates better machine code for the
old bytecode sequence ... (sigh)
"
|pos pos0 theReceiver theArg theByteCode optByteCode needLineNr blockExpr
hasLoopBlock fastReceiver condStats constCondition|
hasLoopBlock := true.
(selector == #whileTrue:) ifTrue:[
theByteCode := #trueJump.
] ifFalse:[
(selector == #whileFalse:) ifTrue:[
theByteCode := #falseJump
] ifFalse:[
hasLoopBlock := false.
(selector == #whileTrue) ifTrue:[
theByteCode := #trueJump
] ifFalse:[
theByteCode := #falseJump
].
]
].
theReceiver := receiver.
(receiver isBlock
and:[(condStats := receiver statements) notNil
and:[condStats nextStatement isNil
and:[(fastReceiver := condStats expression) notNil]]])
ifTrue:[
optByteCode := self optimizedConditionFor:fastReceiver with:theByteCode for:aCompiler.
] ifFalse:[
optByteCode := self optimizedConditionFor:theReceiver with:theByteCode for:aCompiler.
].
optByteCode notNil ifTrue:[
((optByteCode == #eqJump) or:[optByteCode == #notEqJump]) ifTrue:[
theArg := receiver statements expression arg1
].
theReceiver := receiver statements expression receiver.
theByteCode := optByteCode
].
needLineNr := true.
hasLoopBlock ifTrue:[
(argArray at:1) isEmptyBlock ifFalse:[
aStream nextPut:#jump.
pos0 := aStream position1Based.
aStream nextPut:0.
pos := aStream position1Based.
(argArray at:1) codeInlineOn:aStream inBlock:b valueNeeded:false for:aCompiler.
(aStream contents) at:pos0 put:(aStream position1Based).
]
] ifFalse:[
pos := aStream position1Based.
].
optByteCode isNil ifTrue:[
blockExpr := theReceiver simpleSendBlockExpression.
blockExpr notNil ifTrue:[
blockExpr isMessage ifTrue:[
(aCompiler hasLineNumber:(blockExpr selector)) ifTrue:[
blockExpr lineNumber == lineNr ifTrue:[
needLineNr := false
]
]
]
].
].
needLineNr ifTrue:[
self codeLineNumber:lineNr on:aStream for:aCompiler.
].
needLineNr := false.
optByteCode notNil ifTrue:[
theReceiver codeOn:aStream inBlock:b for:aCompiler.
theArg notNil ifTrue:[
theArg codeOn:aStream inBlock:b for:aCompiler
]
] ifFalse:[
(fastReceiver notNil
and:[fastReceiver isConstant]) ifTrue:[
constCondition := fastReceiver evaluate.
theByteCode == #trueJump ifTrue:[
constCondition == true ifTrue:[
theByteCode := #jump
] ifFalse:[
constCondition == false ifTrue:[
theByteCode := #never
]
]
] ifFalse:[
theByteCode == #falseJump ifTrue:[
constCondition == false ifTrue:[
theByteCode := #jump
] ifFalse:[
constCondition == true ifTrue:[
theByteCode := #never
]
]
]
]
].
(theByteCode ~~ #jump and:[theByteCode ~~ #never]) ifTrue:[
theReceiver codeInlineOn:aStream inBlock:b for:aCompiler.
].
].
hasLoopBlock ifFalse:[
"/ simple [...] whileXXX
theByteCode ~~ #never ifTrue:[
aStream nextPut:theByteCode; nextPut:pos.
].
valueNeeded ifTrue:[aStream nextPut:#pushNil].
^ self
].
"/ [...] whileXXX:[...]
theByteCode ~~ #never ifTrue:[
aStream nextPut:theByteCode.
aStream nextPut:pos.
].
valueNeeded ifTrue:[aStream nextPut:#pushNil].
"Modified: 22.10.1996 / 21:34:37 / cg"
!
optimizedConditionFor:aReceiver with:aByteCode for:aCompiler
|rec sel stats|
rec := aReceiver.
(rec isBlock) ifTrue:[
(stats := rec statements) notNil ifTrue:[
stats nextStatement isNil ifTrue:[
rec := rec statements expression
]
]
].
(rec isUnaryMessage) ifTrue:[
sel := rec selector.
(sel == #isNil) ifTrue:[
"/
"/ isNil trueJmp -> nilJump
"/ isNil falseJmp -> notNilJump
"/
aCompiler addLiteral:#isNil.
(aByteCode == #trueJump) ifTrue:[^ #nilJump].
(aByteCode == #falseJump) ifTrue:[^ #notNilJump]
].
(sel == #notNil) ifTrue:[
"/
"/ notNil trueJmp -> notNilJump
"/ notNil falseJmp -> nilJump
"/
aCompiler addLiteral:#notNil.
(aByteCode == #trueJump) ifTrue:[^ #notNilJump].
(aByteCode == #falseJump) ifTrue:[^ #nilJump]
].
(sel == #not) ifTrue:[
"/
"/ not trueJmp -> falseJump
"/ not falseJmp -> trueJump
"/
aCompiler addLiteral:#not.
(aByteCode == #trueJump) ifTrue:[^ #falseJump].
(aByteCode == #falseJump) ifTrue:[^ #trueJump]
].
^ nil
].
(rec isBinaryMessage) ifTrue:[
sel := rec selector.
rec arg1 isConstant ifTrue:[
(rec arg1 value == 0) ifTrue:[
"/
"/ ==0 trueJmp -> zeroJump
"/ ==0 falseJmp -> notZeroJump
"/
(sel == #==) ifTrue:[
aCompiler addLiteral:#==.
(aByteCode == #trueJump) ifTrue:[^ #zeroJump].
(aByteCode == #falseJump) ifTrue:[^ #notZeroJump]
].
"/
"/ ~~0 trueJmp -> notZeroJump
"/ ~~0 falseJmp -> zeroJump
"/
(sel == #~~) ifTrue:[
aCompiler addLiteral:#~~.
(aByteCode == #falseJump) ifTrue:[^ #zeroJump].
(aByteCode == #trueJump) ifTrue:[^ #notZeroJump]
].
^ nil
]
].
(sel == #==) ifTrue:[
"/
"/ == trueJmp -> eqJump
"/ == falseJmp -> notEqJump
"/
aCompiler addLiteral:#==.
(aByteCode == #trueJump) ifTrue:[^ #eqJump].
(aByteCode == #falseJump) ifTrue:[^ #notEqJump]
].
(sel == #~~) ifTrue:[
"/
"/ ~~ trueJmp -> notEqJump
"/ ~~ falseJmp -> eqJump
"/
aCompiler addLiteral:#~~.
(aByteCode == #falseJump) ifTrue:[^ #eqJump].
(aByteCode == #trueJump) ifTrue:[^ #notEqJump]
]
].
^ nil
!
tryFoldedIfOn:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler
|rVal branch|
receiver isConstant ifTrue:[
rVal := receiver evaluate.
rVal == true ifTrue:[
(selector == #ifFalse:) ifTrue:[
valueNeeded ifTrue:[
"/ true ifFalse:[] - evaluates to nil.
aStream nextPut:#pushNil
].
^ true.
].
((selector == #ifTrue:) or:[selector == #ifTrue:ifFalse:]) ifTrue:[
branch := (argArray at: 1).
].
(selector == #ifFalse:ifTrue:) ifTrue:[
branch := (argArray at: 2).
].
].
rVal == false ifTrue:[
(selector == #ifTrue:) ifTrue:[
valueNeeded ifTrue:[
"/ false ifTrue:[] - evaluates to nil.
aStream nextPut:#pushNil
].
^ true.
].
((selector == #ifFalse:) or:[selector == #ifFalse:ifTrue:]) ifTrue:[
branch := (argArray at: 1).
].
(selector == #ifTrue:ifFalse:) ifTrue:[
branch := (argArray at: 2).
].
].
branch notNil ifTrue:[
self codeBlockEvaluation:branch on:aStream inBlock:b valueNeeded:valueNeeded for:aCompiler.
^ true.
]
].
^ false
! !
!MessageNode methodsFor:'enumerating'!
nodeDo:anEnumerator
"helper for parse tree walking"
|args|
args := argArray ? #().
^ anEnumerator doMessage:self receiver:receiver selector:selector arguments:args
"Created: 19.6.1997 / 16:46:39 / cg"
"Modified: 19.6.1997 / 17:08:28 / cg"
! !
!MessageNode methodsFor:'evaluation'!
evaluateForCascadeIn:anEnvironment
|r a1 a2 a3 nargs argValueArray class|
receiver isSuper ifTrue:[
r := receiver value.
class := receiver definingClass.
receiver isHere ifFalse:[
class := class superclass.
].
argArray notNil ifTrue:[
argValueArray := argArray collect:[:arg | arg evaluateIn:anEnvironment].
] ifFalse:[
argValueArray := #()
].
r perform:selector inClass:class withArguments:argValueArray.
^ r
].
r := receiver evaluateIn:anEnvironment.
argArray isNil ifTrue:[
r perform:selector.
^ r
].
nargs := argArray size.
a1 := (argArray at:1) evaluateIn:anEnvironment.
(nargs == 1) ifTrue:[
r perform:selector with:a1.
^ r
].
a2 := (argArray at:2) evaluateIn:anEnvironment.
(nargs == 2) ifTrue:[
r perform:selector with:a1
with:a2.
^ r
].
a3 := (argArray at:3) evaluateIn:anEnvironment.
(nargs == 3) ifTrue:[
r perform:selector with:a1
with:a2
with:a3.
^ r
].
argValueArray := Array new:nargs.
argValueArray at:1 put:a1.
argValueArray at:2 put:a2.
argValueArray at:3 put:a3.
3 to:nargs do:[:idx |
|argVal|
argVal := (argArray at:3) evaluateIn:anEnvironment.
argValueArray at:idx put:argVal.
].
r perform:selector withArguments:argValueArray.
^ r
!
evaluateIn:anEnvironment
|r a1 a2 a3 nargs argValueArray class|
receiver isSuper ifTrue:[
r := receiver value.
receiver isHere ifTrue:[
class := receiver definingClass.
] ifFalse:[
class := receiver definingClass superclass.
].
argArray notNil ifTrue:[
argValueArray := argArray collect:[:arg | arg evaluateIn:anEnvironment].
] ifFalse:[
argValueArray := #()
].
^ r perform:selector inClass:class withArguments:argValueArray
].
r := receiver evaluateIn:anEnvironment.
argArray isNil ifTrue:[
^ r perform:selector
].
nargs := argArray size.
(nargs == 0) ifTrue:[
^ r perform:selector
].
a1 := (argArray at:1) evaluateIn:anEnvironment.
(nargs == 1) ifTrue:[
^ r perform:selector with:a1
].
a2 := (argArray at:2) evaluateIn:anEnvironment.
(nargs == 2) ifTrue:[
^ r perform:selector with:a1 with:a2
].
a3 := (argArray at:3) evaluateIn:anEnvironment.
(nargs == 3) ifTrue:[
^ r perform:selector with:a1 with:a2 with:a3
].
argValueArray := Array new:nargs.
argValueArray at:1 put:a1.
argValueArray at:2 put:a2.
argValueArray at:3 put:a3.
4 to:nargs do:[:idx | argValueArray at:idx put:((argArray at:idx) evaluateIn:anEnvironment)].
^ r perform:selector withArguments:argValueArray
! !
!MessageNode methodsFor:'printing & storing'!
printOn:aStream indent:i
|needParen selectorParts index index2 arg|
(#(whileTrue: whileFalse:) includes:selector) ifTrue:[
receiver isBlock ifTrue:[
^ self printWhileOn:aStream indent:i
].
].
index := 1.
selectorParts := OrderedCollection new.
[index == 0] whileFalse:[
index2 := selector indexOf:$: startingAt:index.
index2 ~~ 0 ifTrue:[
selectorParts add:(selector copyFrom:index to:index2).
index2 := index2 + 1
].
index := index2
].
needParen := false.
receiver isMessage ifTrue:[
receiver isUnaryMessage ifFalse:[
receiver isBinaryMessage ifFalse:[
needParen := true
].
].
].
needParen ifTrue:[
aStream nextPutAll:'('
].
receiver printOn:aStream indent:i.
needParen ifTrue:[
aStream nextPutAll:')'
].
1 to:(argArray size) do:[:argIndex |
aStream cr.
aStream spaces:i+4.
(selectorParts at:argIndex) printOn:aStream.
"/ aStream space.
arg := argArray at:argIndex.
needParen := false.
arg isMessage ifTrue:[
arg isBinaryMessage ifFalse:[
arg isUnaryMessage ifFalse:[
needParen := true
]
].
].
needParen ifTrue:[
aStream nextPutAll:'('
].
arg printOn:aStream indent:i+4.
needParen ifTrue:[
aStream nextPutAll:') '
].
]
!
printWhileOn:aStream indent:i
|needParen arg|
"special handling of whileTrue/whileFalse"
aStream nextPutAll:'['.
receiver statements printOn:aStream indent:i.
aStream nextPutAll:'] whileTrue: '.
arg := argArray at:1.
needParen := false.
arg isMessage ifTrue:[
arg isBinaryMessage ifFalse:[
arg isUnaryMessage ifFalse:[
needParen := true
]
].
].
needParen ifTrue:[
aStream nextPutAll:'('
].
arg printOn:aStream indent:i.
needParen ifTrue:[
aStream nextPutAll:') '
].
! !
!MessageNode methodsFor:'queries'!
collectBlocksInto:aCollection
receiver collectBlocksInto:aCollection.
argArray size > 0 ifTrue:[
argArray do:[:arg |
arg collectBlocksInto:aCollection.
]
].
"Created: 23.10.1996 / 15:44:49 / cg"
"Modified: 23.10.1996 / 16:03:46 / cg"
!
isCascade
^ false
"Created: / 16.7.1998 / 20:03:42 / cg"
!
isMessage
^ true
!
numArgs
^ argArray size
!
realReceiver
receiver isCascade ifTrue:[
^ receiver realReceiver
].
self isCascade ifTrue:[
^ receiver receiver
].
^ receiver
"Modified: / 17.7.1998 / 02:09:05 / cg"
! !
!MessageNode class methodsFor:'documentation'!
version
^ '$Header: /cvs/stx/stx/libcomp/MessageNode.st,v 1.136 2003-10-08 15:31:47 cg Exp $'
! !