"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

"{ Package: 'stx:libjava/tools' }"

Object subclass:#JavaSourceHighlighter

	instanceVariableNames:'preferences cachedStringEmphasis cachedStringColor sourceText

		sourceIndex'

	classVariableNames:''

	poolDictionaries:''

	category:'Languages-Java-Tools-Source'

!

Object subclass:#Indexer

	instanceVariableNames:'index types fields locals'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaSourceHighlighter

!

Object subclass:#Marker

	instanceVariableNames:'highlighter'

	classVariableNames:'MARK_KEYWORD MARK_NUMBER MARK_STRING MARK_CHARACTER MARK_COMMENT

		MARK_JAVADOC MARK_KEYWORD_FLOW MARK_SELECTOR MARK_FIELD

		MARK_FIELD_ASSIGNED MARK_LOCAL MARK_CLASS'

	poolDictionaries:''

	privateIn:JavaSourceHighlighter

!

JavaScanner subclass:#Scanner

	instanceVariableNames:'buffer bufferFirst bufferLast highlighter'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaSourceHighlighter

!

!JavaSourceHighlighter class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

!

documentation

"

    A syntax highligter for Java. This highlighter is SmallSense-aware and

    supports incremental highlighting.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!JavaSourceHighlighter class methodsFor:'formatting'!

_formatClassDefinition:newCode line: ln number: lnr in:cls

    ^self new formatClassDefinition:newCode line: ln number: lnr in:cls.

    "Created: / 21-09-2013 / 04:22:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

_formatMethod:mthd source:newCode line: ln number: lnr in:cls using:syntaxPreferences

    ^ self new formatMethod:mthd source:newCode line: ln number: lnr in:cls using:syntaxPreferences

    "Created: / 21-09-2013 / 04:22:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatClass: javaClass

    ^self new formatClassDefinition: javaClass source in: javaClass

    "Created: / 15-12-2011 / 21:54:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatClassDefinition:source in:class

    ^self new formatClassDefinition:source in:class

    "Created: / 04-08-2011 / 23:44:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatClassDefinition:source in:class elementsInto: elements

    ^self new formatClassDefinition:source in:class elementsInto: elements

    "Created: / 04-08-2011 / 23:44:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatExpression:source in:class

    ^self new formatExpression:source in:class

    "Created: / 04-08-2011 / 23:45:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatExpression:source in:class elementsInto: elements

    ^self new formatExpression:source in:class elementsInto: elements

    "Created: / 04-08-2011 / 23:43:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mth source:source in:class

    ^self formatMethod: mth source: source in: class using: UserPreferences current

    "Created: / 11-02-2012 / 18:18:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mth source:source in:class using: preferences

    ^self new formatMethod:mth source:source in:class using: preferences

    "Created: / 04-08-2011 / 23:45:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mth source:source in:class using: preferences elementsInto: elements

    ^self new formatMethod:mth source:source in:class using: preferences elementsInto: elements

    "Created: / 04-08-2011 / 23:42:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceHighlighter methodsFor:'formatting'!

_formatClassDefinition:newCode line: line number: lnr in:cls

    | scanner |

    line isEmptyOrNil ifTrue:[ ^  nil ].

    sourceText := line asText.

    preferences isNil ifTrue:[

        preferences := UserPreferences current.

    ]. 

    scanner := Scanner for: line asString.

    scanner highlighter: self.

    [

        [ scanner nextToken ~~ #EOF ] whileTrue.

    ] on: Error do:[

    ].

    ^ sourceText

    "Created: / 21-09-2013 / 04:19:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

_formatMethod:mthd source:newCode line: line number: lnr in:cls using:syntaxPreferences

    | scanner |

    line isEmptyOrNil ifTrue:[ ^  nil ].

    sourceText := line asText.

    preferences := syntaxPreferences.

    preferences isNil ifTrue:[

        preferences := UserPreferences current.

    ]. 

    scanner := Scanner for: line asString.

    scanner highlighter: self.

    [

        [ scanner nextToken ~~ #EOF ] whileTrue.

    ] on: Error do:[

    ].

    ^ sourceText

    "Created: / 21-09-2013 / 04:20:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatClassDefinition:source in:class

    | marker cacheIt document sourceUnit parser tree resolve loader |

    "Optimization - if full class source is to be formatted,

     consult cache - when browsing the code or debugging, very 

     often same same source is to be highlighted"

    preferences isNil ifTrue:[

        preferences := UserPreferences current.

    ].

    cacheIt := class notNil and: [class isBehavior and:[class theNonMetaclass isJavaClass]].

    cacheIt ifTrue:[

        document := JavaSourceDocument cachedDocumentFor: class theNonMetaclass.

        document notNil ifTrue:[

            (document sourceText notNil and:[document sourceText string = source]) ifTrue:[

                (sourceIndex notNil and:[document sourceTreeIndex notNil]) ifTrue:[

                     sourceIndex addAll: document sourceTreeIndex.

                     sourceIndex tree:  document sourceTreeIndex tree.

                     sourceIndex source: document sourceText.

                ].

                ^ document sourceText copy.

            ].

        ] ifFalse:[

            document := JavaSourceDocument for: class theNonMetaclass.

            (sourceIndex isNil and:[SmallSense::ParseTreeIndex notNil]) ifTrue:[

                 sourceIndex := SmallSense::ParseTreeIndex new.

            ].

            JavaSourceDocument cachedDocumentFor: class theNonMetaclass put: document.  

        ].

    ].

    marker := Marker new.

    marker highlighter: self.

    sourceText := source isText 

                    ifTrue:[source copy] 

                    ifFalse:[source asText].

    self doLexicalHighlightingOnly ifTrue:[          

        sourceText := self format: source string.

    ] ifFalse:[

        JavaVM booted ifFalse:[JavaVM boot].

        sourceUnit := (Java classForName:'stx.libjava.tools.Source') new.

        sourceUnit setContents: source string.

        JavaCompiler synchronized:[

            parser := (Java classForName:'stx.libjava.tools.text.Highlighter') new.

        ].

        parser setMarker: marker.

        (sourceIndex notNil and:[sourceIndex isKindOf: SmallSense::ParseTreeIndex]) ifTrue:[

            | indexer |

            indexer := Indexer new.

            indexer index: sourceIndex.

            parser setIndexer: indexer.

        ].

        "/ Following is support JImport expecco plugin. For classes loaded by

        "/ JImport plugin, do not resolve classes. The LookupEnvironment cannot

        "/ find them as they are not installed in class registry...

        resolve := class isNil or:[ (loader := class theNonMetaclass classLoader isNil) or:[loader isJavaObject] ] .

        tree := parser parse: sourceUnit diet: false resolve: resolve.

        (sourceIndex notNil and:[sourceIndex isKindOf: SmallSense::ParseTreeIndex]) ifTrue:[

            sourceIndex tree: tree. 

            sourceIndex source: sourceText.

        ].

    ].

    ^ cacheIt ifTrue:[

        document sourceText: sourceText.

        document sourceTreeIndex: sourceIndex.

        sourceText copy

    ] ifFalse:[

        sourceText

    ]

    "Created: / 04-08-2011 / 23:44:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-04-2014 / 09:54:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatClassDefinition:source in:class elementsInto: els

    sourceIndex := els.

    ^self formatClassDefinition:source in:class

    "Created: / 04-08-2011 / 23:44:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatExpression:source in:class

    ^ self format: source

    "Created: / 04-08-2011 / 23:45:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 03-10-2013 / 20:19:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatExpression:source in:class elementsInto: els

    sourceIndex := els.

    ^self formatExpression:source in:class

    "Created: / 04-08-2011 / 23:43:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mth source:source in:class using: prefs

    preferences := prefs.

    preferences isNil ifTrue:[

        preferences := UserPreferences current.

    ].

    JavaMethod showFullSource ifTrue:[

        ^self formatClassDefinition: source in: class

    ].   

    sourceText := source asText.

    self doLexicalHighlightingOnly ifTrue:[

        sourceText := self format: source

    ] ifFalse:[

        | document type parser marker nodes debug |

        JavaVM booted ifFalse:[JavaVM boot].

        document := JavaSourceDocument cachedDocumentFor: class theNonMetaclass.

        document isNil ifTrue:[

            document := JavaSourceDocument for: class theNonMetaclass.

            JavaSourceDocument cachedDocumentFor: class theNonMetaclass put: document.  

        ].

        document resolve.

        type := document sourceTreeForClass: class theNonMetaclass.

        marker := Marker new.

        marker highlighter: self. 

        JavaCompiler synchronized:[

            parser := (Java classForName:'stx.libjava.tools.text.Highlighter') new.

        ].

        parser setMarker: marker.

        debug :=  false.

        nodes := parser parseClassBodyDeclarations: source string unit: document sourceTree copy type: type copy resolve: debug.

        debug ifTrue:[

            nodes inspect.

        ]

    ].

    ^ sourceText

    "Created: / 04-08-2011 / 23:45:10 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 26-11-2013 / 23:04:31 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mth source:source in:class using: prefs elementsInto: els

    preferences := prefs.

    sourceIndex := els.

    ^self formatMethod:mth source:source in:class using: prefs

    "Created: / 04-08-2011 / 23:42:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

formatMethod:mthd source:newCode line: line number: lnr in:cls using:syntaxPreferences

    | scanner |

    line isEmptyOrNil ifTrue:[ ^  nil ].

    sourceText := line asText.

    preferences := syntaxPreferences.

    preferences isNil ifTrue:[

        preferences := UserPreferences current.

    ]. 

    scanner := Scanner for: line asString.

    scanner highlighter: self.

    [

        [ scanner nextToken ~~ #EOF ] whileTrue.

    ] on: Error do:[

    ].

    ^ sourceText

    "Created: / 04-08-2013 / 00:26:16 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceHighlighter methodsFor:'formatting-private'!

format: source

    "Simple formatting based on lexical structure only"

    | scanner token lastToken0 lastToken1 lastValue0 lastValue1 lastPosition0 lastPosition1 |

    sourceText := source asText.

    scanner := Scanner for: source string.

    scanner highlighter: self.

    [

        [ (token := scanner nextToken) ~~ #EOF ] whileTrue:[

            "/ Here, try to guess what's selector...

            token == $( ifTrue:[

                lastPosition0 == #Identifier ifTrue:[

                    self markSelectorFrom: lastPosition0  to: lastPosition0 + lastValue0 size - 1.

                ].

            ].

            lastToken1 := lastToken0.

            lastValue1 := lastValue0.

            lastPosition1  := lastPosition0.

            lastToken0 := token.

            lastValue0 := scanner tokenValue.

            lastPosition0 := scanner tokenStartPosition.

        ].

    ] on: Error do:[:ex|

    ].   

    ^ sourceText

    "Created: / 03-10-2013 / 20:19:15 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceHighlighter methodsFor:'queries'!

doLexicalHighlightingOnly

    "/ For now, in debugger always use lexical highlighting. Makes highlighter debugging easier"

    | process wgroups |

    process := Processor activeProcess.

    wgroups := WindowGroup scheduledWindowGroups.

    [ process notNil ] whileTrue:[

        | groups wg application |

        groups := wgroups select:[:wg | wg process == process ].

        groups notEmpty ifTrue:[

            wg := groups detect:[:wg | wg isModal] ifNone:nil.

            wg isNil ifTrue:[

                wg := groups anElement

            ].

            (wg mainView class == DebugView) ifTrue:[ ^ true ].

            (wg mainView notNil and:[(application := wg mainView application) notNil]) ifTrue:[

                application class == (Smalltalk at: #'JDI::DebuggerApplication') ifTrue:[ ^ true ].

                application class == Tools::NewSystemBrowser ifTrue:[ ^ false ].

            ]

        ].

        process := process parentProcess.                    

    ].

    ^ false

    "Created: / 09-09-2013 / 02:25:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 25-03-2014 / 13:32:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaSourceHighlighter methodsFor:'syntax detection'!

markArgumentIdentifierFrom:pos1 to:pos2

    self 

        markFrom:pos1 to:pos2 

        withEmphasis:(preferences argumentIdentifierEmphasis) color:(preferences argumentIdentifierColor)

!

markBadIdentifierFrom:pos1 to:pos2

    self 

        markFrom:pos1 to:pos2 

        withEmphasis:(preferences badIdentifierEmphasis) 

        color:(preferences badIdentifierColor)

!

markClassVariableIdentifierFrom:pos1 to:pos2

    self 

        markFrom:pos1 to:pos2 

        withEmphasis:(preferences classVariableIdentifierEmphasis) color:(preferences classVariableIdentifierColor)

    "Modified: / 31.3.1998 / 18:02:14 / cg"

!

markCommentFrom:pos1 to:pos2

    self 

        markFrom:pos1 to:pos2 

        withEmphasis:(preferences commentEmphasis) color:(preferences commentColor)

!

markConstantFrom:pos1 to:pos2

    self 

        markFrom:pos1 to:pos2 

        withEmphasis:(preferences constantEmphasis) color:(preferences constantColor)

!

markFrom:pos1 to:pos2 withEmphasis:fontEmp color:clrIn

    |e p2 clr|

    clr := clrIn onDevice:Screen current.

    clr = Color black ifTrue:[

        e := fontEmp

    ] ifFalse:[

        fontEmp isNil ifTrue:[

            e := (#color->clr)

        ] ifFalse:[

            e := Text addEmphasis:fontEmp to:(#color->clr).

        ]

    ].

    (p2 := pos2) isNil ifTrue:[

        p2 := sourceText size