"

 COPYRIGHT (c) 2010-2015 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libjava' }"

"{ NameSpace: Smalltalk }"

Object subclass:#JavaNativeMethodImpl_OpenJDK6

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:'JavaVMData'

	category:'Languages-Java-Support-Java 6'

!

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2010-2015 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class implements all native methods of Open JDK 6.

    [author:]

        Jan Vrany <jan.vrany@fit.cvut.cz>

    [instance variables:]

    [class variables:]

    [see also:]

        JavaVM

        JavaVMData

"

! !

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'helpers'!

nativeContext

    "Return a context (JavaContext) of the native method

     being executed. Should be used only by certain methods

     like getCallingClassLoader or so"

    | ctx mthd |

    ctx := thisContext sender.

    [

        mthd := ctx method.

        mthd notNil and:[mthd isJavaMethod].

    ] whileFalse:[

        ctx := ctx sender.

    ].

    self assert: mthd isNative.

    ^ctx.

    "Created: / 30-01-2013 / 14:11:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-01-2013 / 12:59:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'helpers - awt - UNPORTED'!

commonReshapeComponent: nativeContext

    |view x y width height ext menu|

    view := self viewForWPeer: nativeContext.

    x := nativeContext argAt:1.

    y := nativeContext argAt:2.

    width := nativeContext argAt:3.

    height := nativeContext argAt:4.

    ext := width@height.

"/    'pReshape ' print. view print.

"/    ' ' print. x print. '/' print. y print.

"/    ' extent: ' print. ext printNL.

    view isPopUpView ifTrue:[

	view origin:x@y extent:ext.

    ] ifFalse:[

	(view isTopView

	or:[view isMemberOf:JavaEmbeddedFrameView]) ifTrue:[

	    "/

	    "/ dont allow setting the origin

	    "/

	    menu := self topViewsMenu:view.

	    menu notNil ifTrue:[

		"/ must add the menus height

		height := height + menu height.

		ext := width@height.

	    ].

	    "/ to prevent a view from not being visible/closable

	    "/ in case Java goes mad ..

	    (width < 30

	    or:[height < 10]) ifTrue:[

		"/ self halt.

		width := 30.

		height := 20.

		ext := width@height.

	    ].

	    view extent:ext.

	    (view isKindOf:ModalBox) ifTrue:[

		view preferredExtent:ext

	    ].

	    "/ adjust non-resizable views min/max

	    view isTopView ifTrue:[

		view minExtent notNil ifTrue:[

		    view minExtent:ext.

		    view maxExtent:ext

		].

	    ]

	] ifFalse:[

	    (view superView notNil

	    and:[view superView isTopView]) ifTrue:[

		menu := self topViewsMenu:view superView.

		menu notNil ifTrue:[

		    "/ must add menus height to yPos

		    y := y + menu height.

		]

	    ] ifFalse:[

		"/ post a configuration event

		EventTrace == true ifTrue:[

		    'JAVA: configure: need event' printCR.

		]

	    ].

	    (x isNil or:[y isNil]) ifTrue:[

		Transcript showCR:'bad args to reshape'.

	    ] ifFalse:[

		view origin:x@y extent:ext.

	    ]

	].

    ].

    view isJavaView ifTrue:[

	view invalidate.

    ].

    ^ nil

    "Created: / 4.1.1998 / 18:00:52 / cg"

    "Modified: / 5.12.1998 / 13:34:20 / cg"

!

createdWindowsView:aView for:aJavaPeer

    "this is only sent with the sun.awt.windows toolkit"

    aJavaPeer instVarNamed:'pData' put:aView.

    JavaWindowGroup isNil ifTrue:[

	JavaWindowGroup := WindowGroup new.

	JavaWindowGroup isForModalSubview:true.

    ].

    aView windowGroup:JavaWindowGroup.

    JavaWindowGroup addView:aView.

    KnownWindows isNil ifTrue:[

	KnownWindows := IdentityDictionary new.

    ].

    KnownWindows at:aJavaPeer put:aView.

    FirstWindowCreationSemaphore signalIf.

"/'*** ' print. aJavaPeer print. ' -> ' print. aView printCR.

"/(aView isKindOf:ModalBox) ifTrue:[

"/    self halt.

"/].

    "Created: / 4.1.1998 / 17:57:16 / cg"

    "Modified: / 28.1.1998 / 22:40:19 / cg"

!

gcForWGraphics: nativeContext

    |jGraphics gc orgX orgY trans tX tY|

    jGraphics := nativeContext receiver.

    O_WGgraphics_pData isNil ifTrue:[

	O_WGgraphics_pData := (jGraphics class instVarIndexFor:'pData').

    ].

    O_WGgraphics_originX isNil ifTrue:[

	O_WGgraphics_originX := (jGraphics class instVarIndexFor:'originX').

    ].

    O_WGgraphics_originY isNil ifTrue:[

	O_WGgraphics_originY := (jGraphics class instVarIndexFor:'originY').

    ].

    gc := jGraphics instVarAt:O_WGgraphics_pData.

    trans := gc translation.

    tX := trans x.

    tY := trans y.

"/    tX := gc translationX.

"/    tY := gc translationY.

    orgX := jGraphics instVarAt:O_WGgraphics_originX.

    orgY := jGraphics instVarAt:O_WGgraphics_originY.

    ((orgX ~~ tX) or:[orgY ~~ tY]) ifTrue:[

	gc translation:orgX@orgY

    ].

    ^ gc

    "Created: / 8.1.1998 / 00:16:38 / cg"

    "Modified: / 23.12.1998 / 20:27:35 / cg"

!

jPeerForView:aView

    ^ KnownWindows keyAtValue:aView ifAbsent:nil

    "Created: / 15.1.1998 / 13:48:01 / cg"

    "Modified: / 15.1.1998 / 13:48:43 / cg"

!

pReshape: nativeContext

    |jFramePeer view x y width height menu|

    jFramePeer := nativeContext receiver.

    view := jFramePeer instVarNamed:'pData'.

    x := nativeContext argAt:1.

    y := nativeContext argAt:2.

    width := nativeContext argAt:3.

    height := nativeContext argAt:4.

"/    'pReshape ' print. view print.

"/    ' ' print. x print. '/' print. y print.

"/    ' extent: ' print. width print. '/' print. height printNL.

    view isPopUpView ifTrue:[

	self halt.

    ].

    (view isTopView

    or:[view isMemberOf:JavaEmbeddedFrameView]) ifTrue:[

	"/

	"/ dont allow setting the origin

	"/

	menu := self topViewsMenu:view.

	menu notNil ifTrue:[

	    "/ must add the menus height

	    height := height + menu height

	].

	view extent:width@height.

    ] ifFalse:[

	(view superView notNil

	and:[view superView isTopView]) ifTrue:[

	    menu := self topViewsMenu:view superView.

	    menu notNil ifTrue:[

		"/ must add menus height to yPos

		y := y + menu height.

	    ]

	].

	view origin:x@y extent:width@height.

    ].

    ^ nil

    "Created: / 7.1.1998 / 21:47:11 / cg"

    "Modified: / 5.12.1998 / 13:47:52 / cg"

!

replacementFontFor:name style:styleNr size:size

    |font family style|

    style := 'roman'.

    styleNr = 0 ifTrue:[

        style := 'roman'

    ].

    font := Font family:name style:style size:size.

    font notNil ifTrue:[^ font].

    name = 'Dialog' ifTrue:[

        family := 'helvetica'

    ] ifFalse:[

        family := 'courier'

    ].

    ^ Font family:name style:style size:size.

!

topViewsMenu:view

    |idx|

    view isTopView ifTrue:[

	view subViews size > 0 ifTrue:[

	    (idx := view subViews findFirst:[:v | v isMemberOf:MenuPanel]) ~~ 0 ifTrue:[

		"/ must add the menus height

		^ view subViews at:idx

	    ]

	].

    ].

    ^ nil

    "Modified: / 4.8.1997 / 01:23:06 / cg"

    "Created: / 4.1.1998 / 18:01:42 / cg"

!

viewForWPeer: nativeContext

    |jPeer|

    jPeer := nativeContext receiver.

    "/ sigh; pData was renamed to pNativeWidget in jdk1.2 ...

    O_FramePeer_pNativeWidget isNil ifTrue:[

        O_FramePeer_pNativeWidget := (jPeer class instVarIndexFor:'pNativeWidget').

        O_FramePeer_pNativeWidget isNil ifTrue:[

            O_FramePeer_pNativeWidget := 0.

            O_FramePeer_pData isNil ifTrue:[

                O_FramePeer_pData := (jPeer class instVarIndexFor:'pData').

            ].

        ]

    ].

    O_FramePeer_pNativeWidget > 0 ifTrue:[

        "/ ok, we are < 1.2

        ^ jPeer instVarAt:O_FramePeer_pNativeWidget.

    ].

    ^ jPeer instVarAt:O_FramePeer_pData.

    "Modified: / 19.11.1998 / 01:43:20 / cg"

! !

!JavaNativeMethodImpl_OpenJDK6 class methodsFor:'helpers - io'!

addOpenFile:aStream

    "Given a stream, adds it into the open file table. Returns a

     (fake) file descriptor number"

    | fd |

    OpenFileTableLock critical:[

        fd := OpenFileTable indexOf: nil.

        fd ~~ 0 ifTrue:[

            OpenFileTable at: fd put: aStream.

            fd := fd - 1.

        ] ifFalse:[

            OpenFileTable add:aStream.

            fd := OpenFileTable size - 1.

        ].

    ].

    ^fd

    "Created: / 02-01-1998 / 18:32:59 / cg"

    "Modified (comment): / 18-07-2012 / 23:00:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

anyStream_read: jstream bytes: bytes offset: offset count: count

    | stream nRead|

    stream := self validateFile: jstream.

    "/ should always be bytes

    bytes class isBytes ifFalse:[

        self halt.

    ].

    stream == Stdin ifTrue:[

        stream := StdinReplacementFileQuerySignal raiseRequest.

        stream isNil ifTrue:[

            ^ -1 "/ 0  EOF

        ]

    ].

    FileIOTrace ifTrue:[

        Logger 

              log:('JAVA: read ' , count printString , ' bytes from ' , stream pathName)

              severity:Logger severityTRACE

              facility:#JVM.

    ].

    stream isPositionable ifFalse:[

        "/ mhmh - some kind of socket or pipe

        stream readWait.

    ].

    count == 0 ifTrue:[^0].

    Stream readErrorSignal handle:[:ex |

        nRead := -1

    ] do:[

        nRead := stream nextAvailableBytes:count into:bytes startingAt:offset+1.

    ].

    nRead == 0 ifTrue:[

        stream atEnd ifTrue:[

            FileIOTrace ifTrue:[

                Logger 

                      log:('JAVA: at EOF ' , nRead printString)

                      severity:Logger severityTRACE

                      facility:#JVM.

            ].

            ^ -1

        ].

    ].

    count ~~ nRead ifTrue:[

        FileIOTrace ifTrue:[

            Logger 

                  log:('JAVA: only got ' , nRead printString)

                  severity:Logger severityTRACE

                  facility:#JVM.

        ]

    ].

    ^ nRead

    "Created: / 30-01-2013 / 17:55:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

anyStream_write: jstream bytes: bytes offset: offset count: count append: append

    | stream |

    stream := self validateFile:jstream.

    append ifTrue:[ stream setToEnd ].

    FileIOTrace ifTrue:[

        stream isFileStream ifTrue:[

            Logger log: ('write ' , count printString , ' bytes to ' , stream pathName) severity: Logger severityTRACE facility: 'JVM'.

        ] ifFalse:[

            stream ~~ Stdout ifTrue:[

                stream ~~ Stderr ifTrue:[

                    Logger log: ('write ' , count printString , ' bytes to ' , stream displayString) severity: Logger severityTRACE facility: 'JVM'.

                ]

            ]

        ]

    ].

    "/ should always be bytes

    Stream writeErrorSignal handle:[:ex |

        ex return

    ] do:[

        Socket brokenConnectionSignal handle:[:ex |

            ex return

        ] do:[

            stream isBinary ifTrue:[

                stream nextPutBytes:count from:bytes startingAt:offset+1

            ] ifFalse:[

                stream nextPutAll: (bytes asString copyFrom: offset + 1 to: offset + count).

            ]

        ].

        stream == Transcript ifTrue:[

            Transcript endEntry

        ]

    ].

    "Created: / 08-02-2013 / 11:53:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 02-03-2015 / 14:03:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

checkWritePermissionOfDirectory:dir message:msg

    |answer|

    (PermittedDirectories notNil

    and:[PermittedDirectories includes:dir]) ifFalse:[

	FileOpenConfirmation ifTrue:[

	    answer := Dialog

		    confirmWithCancel:msg withCRs

			       labels:#('no' 'grant')

			       values:#(false true)

			      default:2.

	    answer == false ifTrue:[

		^ false

	    ].

	    (self confirm:('JAVA Security check\\Always permit writes in this directory (''' , dir pathName , ''') ?') withCRs)

	    ifTrue:[

		PermittedDirectories isNil ifTrue:[

		    PermittedDirectories := Set new

		].

		PermittedDirectories add:dir.

	    ]

	]

    ].

    ^ true

    "Created: / 3.12.1998 / 15:07:56 / cg"

    "Modified: / 3.12.1998 / 15:16:55 / cg"

!

commonClose: jstream

    | fdobj fd stream |

    fdobj := (jstream instVarNamed: #fd).

    fd    := fdobj instVarNamed: #fd.

    fd == -1 ifTrue:[

        "Never opened or already closed"

        ^self.

    ].

    stream := self getOpenFileAt:fd.

    stream notNil ifTrue:[

        stream isView ifTrue:[

            "Some applications close stdout/stderr (such as Apache Tomcat).

             We don't want that, so ignore a close in that case"

            stream ~~ Transcript ifTrue:[

                self breakPoint: #jv.

            ].

        ] ifFalse:[

            (stream ~~ Stdout and:[stream ~~ Stderr and:[stream ~~ Stdin]]) ifTrue:[

                stream close.

            ]

        ]

    ] ifFalse:[

        self breakPoint: #jv.

    ].

    self setOpenFile: nil at: fd.

    fdobj instVarNamed:#fd put: -1.