"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

"{ Package: 'stx:libjava/tools' }"

PPCompositeParser subclass:#JavaParser_Old

	instanceVariableNames:'builder classBody'

	classVariableNames:''

	poolDictionaries:''

	category:'Languages-Java-Parser'

!

PPParser subclass:#SubParser

	instanceVariableNames:'masterParser'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

JavaParser_Old::SubParser subclass:#MultilineCommentParser

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

PPParser subclass:#LineNumberParser

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

ReadStream subclass:#LineNumberStream

	instanceVariableNames:'eolPositions lastPosition previousWasCR'

	classVariableNames:'CR LF'

	poolDictionaries:''

	privateIn:JavaParser_Old

!

JavaParser_Old::MultilineCommentParser subclass:#JavaDocParser

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

JavaParser_Old::SubParser subclass:#SingleLineCommentParser

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

JavaParser_Old::SubParser subclass:#StatementParser

	instanceVariableNames:'brackets'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

JavaParser_Old::SubParser subclass:#BlockParser

	instanceVariableNames:'openBlockChar closeBlockChar innerBlockCount'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaParser_Old

!

!JavaParser_Old class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996-2011 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2011 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

! !

!JavaParser_Old class methodsFor:'parsing'!

methodsIn: sourceCode

    ^ (self parse: sourceCode) methods.

    "Created: / 08-01-2011 / 15:42:24 / Jan Kurs <kurs.jan@post.cz>"

!

parse: code

    ^ JavaParseResult from: (super parse: code).

    "Created: / 08-01-2011 / 16:05:01 / Jan Kurs <kurs.jan@post.cz>"

    "Modified: / 07-04-2011 / 22:07:25 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaParser_Old methodsFor:'accessing'!

builder

    ^ builder

!

builder:something

    builder := something.

!

lineNumber

    ^ LineNumberParser new.

    "Created: / 29-12-2010 / 22:14:02 / Jan Kurs <kurs.jan@post.cz>"

    "Modified: / 07-04-2011 / 22:05:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

start

	^ self javaFile end.

! !

!JavaParser_Old methodsFor:'grammar'!

annotation

	^ $@ asParser, self identifier, self annotationBlock optional 

!

annotationBlock

        ^ BlockParser new

                openBlockChar: $(;

                closeBlockChar: $);

                yourself;

        trim

    "Modified: / 07-04-2011 / 21:46:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

argument

        ^ (

            self finalKW optional, self type, self threeDotsKW optional, self typeIdentifier, 

            "JV@2012-03-09: This one is funny, C style array definition seems to be supported.

            Look at java/lang/String.java"

            '[]' asParser optional

            ) trim

    "Modified: / 09-03-2012 / 18:47:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

argumentList

	^ (self argument separatedBy:  ($, asParser trim) ==> [:token | nil]) ==> [: token | token select: [:each | each notNil ]].

!

block

        ^ BlockParser new trim

    "Modified: / 07-04-2011 / 21:46:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

classBody

        ^ (${ asParser trim, self classContents star, $} asParser trim) 

        foldLeft: [:a :contents :b | contents select: [:each | each notNil ]]

    "Modified: / 30-12-2010 / 11:21:09 / Jan Kurs <kurs.jan@post.cz>"

!

classContents 

        ^       self methodDecl trim / 

                self constructor trim /

                self staticInitializer trim / 

                self comment /

                "Since classes may be nested recursively we have to use this syntax - without self" 

                self innerClassDecl trim /

                "TODO JK: This will cause problems - sooner or later"

                self statement.

    "Modified: / 29-12-2010 / 22:12:11 / Jan Kurs <kurs.jan@post.cz>"

    "Modified: / 09-03-2012 / 19:29:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

classDecl

        ^       self classModifiers, 

                (self classKW / self interfaceKW), 

                (self identifier, self genericBlock optional) flatten,

                (self extends optional),

                (self implements optional),

                classBody

    "Modified: / 09-03-2012 / 19:32:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

classModifiers

    ^(

        self publicKW /

        self privateKW /

        self abstractKW /

        self finalKW

    ) trim star

    "Modified: / 09-03-2012 / 18:09:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

comment

    ^ (self oneLineComment / self multilineComment)

    "Modified: / 30-12-2010 / 11:20:56 / Jan Kurs <kurs.jan@post.cz>"

    "Modified (format): / 09-03-2012 / 16:55:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

constructor

        ^ (     

                self lineNumber,

                self javadoc optional, 

                self methodModifiers optional, 

                self identifier, 

                self methodArguments,

                self throwsStatement optional,

                self methodBody optional) trim

                        foldLeft: [:startLine :javadoc :modifiers :name :arguments :throws :body | 

                                JavaMethodDeclarationNode new

                                        startLine: startLine;

                                        javadoc: javadoc;

                                        modifiers: modifiers;

                                        retval: nil;

                                        methodName: name;

                                        arguments: arguments

                        ].

    "Modified: / 08-01-2011 / 16:27:25 / Jan Kurs <kurs.jan@post.cz>"

    "Modified: / 09-03-2012 / 18:55:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

extends

	^ self extendsKW, self type

!

fileHeader

	^ self comment star, self package optional, self imports optional, self comment star

!

fullIdentifier

	^ (self identifier separatedBy: $. asParser) trim flatten

!

genericBlock

        ^ BlockParser new

                openBlockChar: $<;

                closeBlockChar: $>;

                yourself;

        trim

    "Modified: / 07-04-2011 / 21:46:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

identifier

	^ (#letter asParser, #word asParser star) trim flatten

!

implements

	^ self implementsKW, (self type separatedBy: $, asParser trim)

!

import

    ^ self comment star, self importKW , self statement.

    "Modified (format): / 09-03-2012 / 18:04:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

imports

	^ self import star

!

innerClassDecl

    ^   self innerClassModifiers, 

        (self classKW / self interfaceKW), 

        (self identifier, self genericBlock optional) flatten,

        (self extends optional),

        (self implements optional),

        classBody

    "Created: / 09-03-2012 / 19:28:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

innerClassModifiers

    ^(

        self publicKW /

        self privateKW /

        self protectedKW /

        self staticKW /

        self abstractKW /

        self finalKW

    ) trim star

    "Created: / 09-03-2012 / 19:29:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

javaFile

        ^ (self fileHeader, self classDecl trim) foldLeft: [:header :c | c ]

    "Modified: / 09-03-2012 / 19:31:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

javadoc

    ^ (JavaDocParser for: self) trim

    "Modified: / 09-03-2012 / 16:59:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

methodArguments

	^ ($( asParser, self argumentList optional, $) asParser) trim foldLeft: [:a :args :b | args].

!

methodBody

	^ self block.

!

methodDecl

        ^ (    

                self lineNumber,

                self javadoc optional, 

                self methodModifiers optional, 

                self genericBlock optional,

                self methodRetval, 

                self identifier, 

                self methodArguments,

                self throwsStatement optional, 

                self methodBody optional) trim

                        foldLeft: [:startLine :javadoc :modifiers :generic :retval :name :arguments :throws :body | 

                                JavaMethodDeclarationNode new

                                        javadoc: javadoc;

                                        modifiers: modifiers;

                                        retval: retval;

                                        methodName: name;

                                        arguments: arguments;

                                        startLine: startLine

                        ].

    "Modified: / 29-12-2010 / 22:47:53 / Jan Kurs <kurs.jan@post.cz>"

!

methodModifiers 

    ^(

        self publicKW /

        self staticKW /

        self abstractKW /

        self privateKW /

        self protectedKW /

        self nativeKW /

        self finalKW /

        self synchronizedKW /

        "JV@2012-03-09: Is that correct?"

        self annotation

    ) trim star

    "Modified: / 09-03-2012 / 18:32:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

methodRetval

	^ self type

!

multilineComment

    ^ (MultilineCommentParser for: self) trim

    "Modified: / 09-03-2012 / 16:59:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

nameToken

	^ #word asParser 

!

oneLineComment

    ^ (SingleLineCommentParser for: self) trim

    "Modified: / 09-03-2012 / 20:26:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

otherClassContent 

	^ self statement.

!

package

        ^ self packageKW, self statement.

    "Modified: / 09-03-2012 / 19:35:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

primitiveType

        ^ ( 'int' asParser / 

            'byte' asParser /

            'boolean' asParser /

            'float' asParser /

            'double' asParser /

            'char' asParser / 

            'long' asParser

        ) trim

    "Modified: / 09-03-2012 / 18:41:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

reference

	^ self fullIdentifier 

!

statement

        ^ StatementParser new trim ==> [: token | nil ].

    "Modified: / 30-12-2010 / 11:20:45 / Jan Kurs <kurs.jan@post.cz>"

    "Modified: / 07-04-2011 / 22:05:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

staticInitializer 

        ^ 'static' asParser trim, BlockParser new ==> [:token | nil]

    "Modified: / 07-04-2011 / 21:47:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

throwsStatement 

	^ self throwsKW, (self identifier separatedBy: $, asParser trim)

!

type

	^ 

	(

		('void' asParser / self primitiveType / self reference) trim, 

		 self genericBlock optional,

		'[]' asParser optional

	) 

	flatten 

!

typeIdentifier 

	^ self identifier 

! !

!JavaParser_Old methodsFor:'keywords'!

abstractKW

    ^'abstract' asParser trim

    "Created: / 09-03-2012 / 18:08:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

classKW

	^ 'class' asParser trim

!

extendsKW

	^ 'extends' asParser trim

!

finalKW

	^ 'final' asParser trim

!

implementsKW

	^ 'implements' asParser trim

!

importKW

    ^'import' asParser trim

    "Created: / 09-03-2012 / 18:03:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

interfaceKW

	^ 'interface' asParser trim

!

nativeKW

    ^'native' asParser trim

    "Created: / 09-03-2012 / 18:07:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

packageKW

        ^ 'package' asParser trim

    "Created: / 09-03-2012 / 19:35:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

privateKW

    ^ 'private' asParser

    "Created: / 09-03-2012 / 18:05:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

protectedKW

    ^ 'protected' asParser

    "Created: / 09-03-2012 / 18:05:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"