"{ Package: 'stx:libjava' }"!

!Behavior methodsFor:'queries'!

isInterface

    "return true, if the receiver is a Java interface"

    ^ false

    "

     True isInterface

    "

    "Created: / 22-02-2012 / 21:53:20 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Behavior methodsFor:'queries'!

isJavaPrimitiveType

    ^ false

    "

	(Java classForName:'java.lang.Class') isJavaPrimitiveType

	ByteArray isJavaPrimitiveType

    "

    "Created: / 20-12-2010 / 21:52:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 14-02-2017 / 10:18:21 / stefan"

! !

!Boolean class methodsFor:'queries'!

isJavaPrimitiveType

    ^true

    "Created: / 25-02-2011 / 08:22:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'queries'!

javaArrayClass

    ^ JavaBooleanArray

    "Created: / 25-02-2011 / 08:27:07 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 31-01-2014 / 12:31:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'autoboxing support'!

javaBox: anObject

    | wrapper |

    wrapper := (JavaVM classForName: 'java.lang.Boolean') new.

    wrapper perform: #'<init>(Z)V' with: anObject.

    ^ wrapper

    "Created: / 16-08-2011 / 09:58:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'accessing'!

javaName

    ^'boolean'.

    "Modified: / 25-02-2011 / 18:58:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'autoboxing support'!

javaUnbox: object onError: errorBlock

    | value |

    (object class binaryName = 'java/lang/Boolean') ifFalse:[

	errorBlock value.

    ].

    value := object instVarNamed: #value.

    (value ~~ 0 and:[value ~~ 1]) ifTrue:[

	errorBlock value.

    ].

    ^value

    "Created: / 22-11-2011 / 11:52:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 08-10-2013 / 22:41:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'autoboxing support'!

javaUnwrap: zeroOrOne

    ^zeroOrOne == 1

    "Created: / 10-12-2011 / 20:00:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'autoboxing support'!

javaWrap: boolean

    ^boolean ifTrue:[1] ifFalse:[0].

    "Created: / 18-03-2012 / 22:03:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'autoboxing support'!

javaWrapRequired

    ^true

    "Created: / 29-11-2012 / 23:02:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Boolean class methodsFor:'accessing'!

javaWrapperClass

    ^(JavaVM classForName: 'java.lang.Boolean')

    "Created: / 24-02-2012 / 19:43:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 07-05-2013 / 11:21:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray methodsFor:'vm support'!

_ARRAYLENGTH: cls

    ^self basicSize

    "Created: / 14-05-2013 / 10:10:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray methodsFor:'vm support'!

_CHECKCAST: cls

    ^cls == ByteArray ifTrue:[self] ifFalse:[JavaVM throwClassCastException]

    "Created: / 14-05-2013 / 10:09:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray methodsFor:'vm support'!

_INSTANCEOF: cls

    ^ByteArray == cls ifTrue:[1] ifFalse:[0]

    "Created: / 14-05-2013 / 10:09:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray class methodsFor:'testing'!

isInterface

    ^false

! !

!ByteArray class methodsFor:'queries'!

isJavaArrayClass

    ^true

    "Created: / 05-02-2011 / 22:45:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray class methodsFor:'queries'!

isJavaReferenceType

    "Java arrays are reference types"

    ^true

    "Created: / 20-12-2010 / 22:30:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray class methodsFor:'accessing-java'!

javaArrayClass

    ^JavaArray javaArrayClassFor: self

    "Created: / 11-06-2011 / 23:42:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray class methodsFor:'accessing-java'!

javaComponentClass

    ^JavaByte

    "Created: / 20-12-2010 / 22:05:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray class methodsFor:'accessing'!

javaName

    ^'[B'.

    "Modified: / 25-02-2011 / 19:02:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'queries'!

isJavaPrimitiveType

    ^true

    "Created: / 20-12-2010 / 22:18:35 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'accessing'!

javaArrayClass

    ^ String

    "Created: / 11-02-2011 / 10:44:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'autoboxing support'!

javaBox: anObject

    | wrapper |

    wrapper := (JavaVM classForName: 'java.lang.Character') new.

    wrapper perform: #'<init>(C)V' with: anObject codePoint.

    ^ wrapper

    "Created: / 16-08-2011 / 09:58:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'accessing'!

javaName

    ^'char'.

    "Modified: / 25-02-2011 / 18:58:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'autoboxing support'!

javaUnbox: object onError: errorBlock

    | value |

    (object class binaryName = 'java/lang/Character') ifFalse:[

	errorBlock value.

    ].

    value := object instVarNamed: #value.

    (value between: 0 and: 255) ifFalse:[

	errorBlock value.

    ].

    ^value

    "Created: / 22-11-2011 / 11:52:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 08-10-2013 / 22:41:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Character class methodsFor:'accessing'!

javaWrapperClass

    ^(JavaVM classForName: 'java.lang.Character')

    "Created: / 24-02-2012 / 19:42:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 07-05-2013 / 11:21:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'vm support'!

_ARRAYLENGTH: cls

    ^self basicSize

    "Created: / 14-05-2013 / 10:10:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'vm support'!

_CHECKCAST: cls

    cls == Unicode16String ifTrue:[^self].

    cls == String          ifTrue:[^self].

    ^JavaVM throwClassCastException.

    "Created: / 14-05-2013 / 10:09:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 14-05-2013 / 11:10:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'vm support'!

_INSTANCEOF: cls

    cls == Unicode16String ifTrue:[^1].

    cls == String          ifTrue:[^1].

    ^0

    "Created: / 14-05-2013 / 10:09:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 14-05-2013 / 11:10:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'java conversions'!

asDottedJavaClassName

 "

    examples:

    java.lang.String

    [[[Ljava/lang/Object; => java.lang.Object

    "

    | nm |

    nm := self asJavaComponentClassName.

    (nm first == $L) ifTrue: [

	nm := nm copyFrom: 2 to: nm size - 1.

	(nm includes: $/) ifTrue: [

	    "/ No need to do another copt here!!

	    nm replaceAll: $/ with: $.

	].

    ] ifFalse:[

	(nm includes: $/) ifTrue: [

	    nm := nm copyReplaceAll: $/ with: $.

	].

    ].

    ^ nm.

    "Created: / 21-10-2011 / 12:31:51 / Marcel Hlopko <hlopkmar@fel.cvut.cz>"

    "Created: / 30-10-2011 / 17:41:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-05-2014 / 12:29:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'java conversions'!

asJavaComponentClassName

    | componentClassName |

    componentClassName := self "utf8Encoded".

    (componentClassName first == $[) ifTrue: [

	componentClassName := componentClassName copyFrom: (componentClassName lastIndexOf: $[) + 1

    ].

    ^ componentClassName.

    "Modified: / 27-05-2014 / 12:25:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'java conversions'!

asNiceJavaClassName

    | niceName |

    niceName := self asJavaComponentClassName asSTXInternalJavaClassName.

    (self occurrencesOf: $[) timesRepeat: [ niceName := niceName , '[]' ].

    niceName := niceName asString copyReplaceAll: $/ with: $..

    ^ niceName.

! !

!CharacterArray methodsFor:'java conversions'!

asSTXInternalJavaClassName

    | internalName |

    internalName := self asJavaComponentClassName.

    (internalName startsWith: $L) ifTrue: [

	internalName := internalName copyFrom: 2 to: internalName size - 1

    ].

    (internalName includes: $.) ifTrue: [

	internalName := internalName asString copyReplaceAll: $. with: $/

    ].

    ^internalName.

! !

!CharacterArray methodsFor:'java conversions'!

asSlashedJavaClassName

    "removes square brackets and adds slashes"

    | internalName |

    internalName := self asJavaComponentClassName.

    (internalName first == $L) ifTrue: [

	internalName := internalName copyFrom: 2 to: internalName size - 1.

	"/ No need to do another copy here

	(internalName includes: $.) ifTrue: [

	    internalName replaceAll: $. with: $/

	].

    ] ifFalse:[

	(internalName includes: $.) ifTrue: [

	    internalName := internalName copyReplaceAll: $. with: $/

	].

    ].

    ^ internalName.

    "Created: / 21-10-2011 / 12:31:51 / Marcel Hlopko <hlopkmar@fel.cvut.cz>"

    "Created: / 30-10-2011 / 17:40:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-05-2014 / 12:30:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!CharacterArray methodsFor:'java queries'!

isJavaArrayDescriptor

^ self startsWith:$[.

! !

!CharacterArray methodsFor:'java queries'!

isJavaPrimitiveTypeDescriptor

    ^ (self size = 1 and: [ JavaDescriptor baseTypes includesKey: self first ]).

! !

!CharacterArray class methodsFor:'encoding & decoding'!

decodeFromJavaUTF8: string8

    "Decodes a string from modified UTF8 encoding

     as used in Java .class files. see

     'The class file format specification', section 4.5.7"

    | string16 |

%{

    if (__isStringLike(string8) ) {

        unsigned char *ptr;

        unsigned short c;

        unsigned short* dst;

        int len;

        ptr = __stringVal(string8);

        len = 0;

        while (*ptr) {

            len++;

            if ( ( *ptr & 0x80) == 0 ) {

                ptr++;

            } else {

                len--;

                goto non7bitString;

            }

        }

        RETURN ( string8 );

    non7bitString:

        while (*ptr) {

            len++;

            ptr += (*ptr & 0x80) ? ((*ptr & 0x20) ? 3 : 2) : 1;

        }

        string16 = __MKEMPTYUSTRING(len);

        ptr = __stringVal(string8);

        dst = __unicode16StringVal(string16);

        while (*ptr) {

            int x = *ptr++;

            if ( x & 0x80 ) {

                int y = *ptr++;

                if ( x & 0x20 ) {

                    int z = *ptr++;

                    *dst++ = ( (x & 0xf ) << 12 ) + ( ( y & 0x3f ) << 6 ) + ( z & 0x3f);

                } else {

                    *dst++ = ( ( x & 0x1f ) << 6 ) + ( y & 0x3f );

                }

            } else {

                *dst++ = x;

            }

        }

        RETURN ( string16 );

    }

%}.

    self primitiveFailed.

    "Created: / 22-12-2010 / 23:45:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 09-02-2011 / 01:12:25 / Marcel Hlopko <hlopik@gmail.com>"

    "Modified: / 13-03-2011 / 15:52:36 / Marcel Hlopko <hlopkmar@fel.cvut.cz>"

    "Modified: / 04-08-2014 / 14:45:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 22-03-2019 / 03:00:17 / Claus Gittinger"

! !

!CharacterArray class methodsFor:'instance creation'!

fromJavaUTF8Bytes:aByteCollection

    <resource: #obsolete>

    "return a new string which represents the characters as decoded

     from the modified utf8 encoded bytes as specified in

     The class file format specification, section 4.5.7"

    ^ self decodeFromJavaUTF8:aByteCollection asString.

    "

     CharacterArray fromUTF8Bytes:#[ 16r41 16r42 ]

     CharacterArray fromUTF8Bytes:#[ 16rC1 16r02 ]

     CharacterArray fromUTF8Bytes:#[ 16rE0 16r81 16r02 ]

     CharacterArray fromUTF8Bytes:#[ 16rEF 16rBF 16rBF ]

   rfc2279 examples:

     CharacterArray fromUTF8Bytes:#[ 16r41 16rE2 16r89 16rA2 16rCE 16r91 16r2E ]

     CharacterArray fromUTF8Bytes:#[ 16rED 16r95 16r9C 16rEA 16rB5 16rAD 16rEC 16r96 16rB4 ]

     CharacterArray fromUTF8Bytes:#[ 16rE6 16r97 16rA5 16rE6 16r9C 16rAC 16rE8 16rAA 16r9E ]

   invalid:

     CharacterArray fromUTF8Bytes:#[ 16rC0 16r80 ]

     CharacterArray fromUTF8Bytes:#[ 16rE0 16r80 16r80 ]

    "

    "Created: / 23-12-2010 / 09:01:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 04-08-2014 / 14:48:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !