"

 COPYRIGHT (c) 1996-2015 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2015 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

"{ Package: 'stx:libjava' }"

"{ NameSpace: Smalltalk }"

CompiledCode variableSubclass:#JavaMethod

	instanceVariableNames:'accessFlags selector javaClass descriptor signature lookupObject

		lineNumberTable localVariableTable source annotations'

	classVariableNames:'AbstractMethodInvokationSignal SignatureTypeCodes

		ForceByteCodeDisplay ShowFullSource UnresolvedClassSignal

		A_PUBLIC A_PRIVATE A_PROTECTED A_STATIC A_FINAL A_SYNCHRONIZED

		A_ABSTRACT A_NATIVE A_BREAKPOINT A_HASHANDLER A_BRIDGE A_VARARGS

		A_STRICT A_SYNTHETIC A_RESOLVED A_HASFINALLY'

	poolDictionaries:'JavaConstants'

	category:'Languages-Java-Classes'

!

!JavaMethod class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996-2015 by Claus Gittinger

 New code and modifications done at SWING Research Group [1]:

 COPYRIGHT (c) 2010-2015 by Jan Vrany, Jan Kurs and Marcel Hlopko

                            SWING Research Group, Czech Technical University in Prague

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

 [1] Code written at SWING Research Group contains a signature

     of one of the above copright owners. For exact set of such code,

     see the differences between this version and version stx:libjava

     as of 1.9.2010

"

! !

!JavaMethod class methodsFor:'initialization'!

initialize

    AbstractMethodInvokationSignal isNil ifTrue:[

        AbstractMethodInvokationSignal := ExecutionError newSignalMayProceed:true.

        AbstractMethodInvokationSignal nameClass:self message:#abstractMethodInvokationSignal.

        AbstractMethodInvokationSignal notifierString:'attempt to execute abstract method'.

        UnresolvedClassSignal := ExecutionError newSignalMayProceed:true.

        UnresolvedClassSignal nameClass:self message:#unresolvedClassSignal.

        UnresolvedClassSignal notifierString:'unresolved class'.

    ].

    ShowFullSource := true.

    ForceByteCodeDisplay := false.

    A_PUBLIC       := 16r0001.

    A_PRIVATE      := 16r0002.

    A_PROTECTED    := 16r0004.

    A_STATIC       := 16r0008.

    A_FINAL        := 16r0010.

    A_SYNCHRONIZED := 16r0020.

    A_BRIDGE       := 16r0040.

    A_VARARGS      := 16r0080.

    A_NATIVE       := 16r0100.

    A_ABSTRACT     := 16r0400.

    A_STRICT       := 16r0800.

    A_SYNTHETIC    := 16r1000.

    A_BREAKPOINT   := 16r10000000.

    A_HASHANDLER   := 16r20000000.

    A_HASFINALLY   := 16r00004000.

    A_RESOLVED     := 16r00000200.

    self flags:(self flags bitOr:Behavior flagJavaMethod).

    SignatureTypeCodes := IdentityDictionary new.

    SignatureTypeCodes at:$B put:#byte.

    SignatureTypeCodes at:$C put:#char.

    SignatureTypeCodes at:$D put:#double.

    SignatureTypeCodes at:$F put:#float.

    SignatureTypeCodes at:$I put:#int.

    SignatureTypeCodes at:$J put:#long.

    SignatureTypeCodes at:$S put:#'unsigned short'.

    SignatureTypeCodes at:$Z put:#boolean.

    SignatureTypeCodes at:$L put:#object.

    SignatureTypeCodes at:$[ put:#array.

    SignatureTypeCodes at:$T put:#typevar.

    ForceByteCodeDisplay := false.

    "

     JavaMethod initialize.

     JavaMethodWithHandler initialize.

     ForceByteCodeDisplay := true.

     ForceByteCodeDisplay := false.

    "

    "Modified: / 16-10-1998 / 01:29:48 / cg"

    "Modified: / 31-01-2014 / 03:35:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

reinitialize

    self flags:(self flags bitOr:Behavior flagJavaMethod).

    "Created: / 14-12-2010 / 20:58:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaMethod class methodsFor:'instance creation'!

fromMethod:aJavaMethod

    "create a new javaMethod, copying values from another javaMethod"

    ^ self new fromMethod:aJavaMethod

    "Created: / 16.10.1998 / 01:25:12 / cg"

!

new

    "create a new javaMethod.

     Redefined, since constants are NOT stored in a literalArray,

     but my classes constantTable instead."

    ^ self basicNew:0.

    "Created: / 16.10.1998 / 01:13:02 / cg"

! !

!JavaMethod class methodsFor:'Signal constants'!

abstractMethodInvokationSignal

    "return the signal raised when an abstract method is invoked"

    ^ AbstractMethodInvokationSignal

    "Created: / 27.1.1998 / 21:50:05 / cg"

!

unresolvedClassSignal

    "return the signal raised when an unresolved class is referenced"

    ^ UnresolvedClassSignal

    "Created: / 27.1.1998 / 21:50:05 / cg"

! !

!JavaMethod class methodsFor:'accessing'!

showFullSource

    ^ ShowFullSource

    "Created: / 14-09-2013 / 11:56:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaMethod class methodsFor:'misc'!

forceByteCodeDisplay

    ^ ForceByteCodeDisplay

    "Created: 7.4.1997 / 20:11:39 / cg"

!

forceByteCodeDisplay:aBoolean

    ForceByteCodeDisplay := aBoolean

    "

     self forceByteCodeDisplay:true

     self forceByteCodeDisplay:false

    "

    "Created: / 4.2.1998 / 00:22:54 / cg"

!

makeJavaMethod

    self flags:((self flags

                 bitOr:Behavior flagJavaMethod)

                 bitClear:Behavior flagMetaMethod)

    "

        JavaMethod makeJavaMethod

        JavaMethod makeMetaMethod

    "

    "Created: / 23-02-2011 / 12:56:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

makeMetaMethod

    self flags:((self flags

                 bitOr:Behavior flagMetaMethod)

                 bitClear:Behavior flagJavaMethod)

     "

        JavaMethod makeJavaMethod

        JavaMethod makeMetaMethod

    "

    "Created: / 23-02-2011 / 12:56:24 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!JavaMethod class methodsFor:'others'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !

!JavaMethod class methodsFor:'signature parsing'!

argSigArrayFromSignature:aSignature

    "given a signature, return a specArray for the arguments"

    |s|

    s := aSignature readStream.

    s next ~~ $( ifTrue:[self halt].

    ^ self argSigArrayFromStream:s.

    "

     JavaMethod argSigArrayFromSignature:'(LObject;)V'

     JavaMethod argSigArrayFromSignature:'(BB)S'

     JavaMethod argSigArrayFromSignature:'(LObject;LObject;II)V'

    "

!

argSigArrayFromStream:s

    "parse an argSpec, return an array of specs - see java doc"

    |argSpec spec|

    spec := #().

    [s atEnd or:[s peek == $)]] whileFalse:[

"/        s peek == Character space ifTrue:[

"/            s next

"/        ] ifFalse:[

            argSpec := self fieldTypeFromStream:s in:nil.

            spec := spec copyWith:argSpec.

"/        ]

    ].

    ^ spec

    "Modified: / 8.1.1998 / 19:10:20 / cg"

!

argSignatureFromArgTypeArray:arr

    | sig |

    sig := ''.

    arr do:

            [:el |

            | jCLass |

            jCLass := el.

            jCLass isJavaClass

                ifFalse:[ jCLass := JavaVM reflection classForJavaClassObject:el ].

            jCLass isJavaClass

                ifTrue:

                    [ sig := sig , jCLass typeName.

                    ]

                ifFalse:[ self halt. ] ].

    ^ sig

    "

     self argSignatureFromArgTypeArray:

 (Array

     with:(JavaVM javaClassObjectForClass:(Java at:'com.sun.java.swing.JComponent')))"

    "Modified: / 13-02-1998 / 14:57:58 / cg"

    "Modified: / 02-03-2011 / 22:49:24 / Marcel Hlopko <hlopik@gmail.com>"

!

argSpecFromSignature:aSignature withName:name

    "given a signature, return a spec"

    |s argSpec|

    s := aSignature readStream.

    s next ~~ $( ifTrue:[self halt. ^ name].

    argSpec := self argSpecFromStream:s in:nil.

    s next ~~ $) ifTrue:[self halt. ^ name].

    ^ name , ' (' , argSpec , ')'

    "

     JavaMethod argSpecFromSignature:'(LObject;)V' withName:'foo'

     JavaMethod argSpecFromSignature:'(BB)S'       withName:'foo'

    "

    "Modified: / 8.1.1998 / 19:05:36 / cg"

!

argSpecFromStream:s in:aPackage

    "parse an argSpec - see java doc"

    |argSpec spec|

    spec := ''.

    [s atEnd or:[s peek == $)]] whileFalse:[

"/        s peek == Character space ifTrue:[

"/            s next

"/        ] ifFalse:[

            argSpec := self fieldTypeFromStream:s in:aPackage.

            spec size ~~ 0 ifTrue:[

                spec := spec , ', '

            ].

            spec := spec , argSpec.

"/        ]

    ].

    ^ spec

    "Created: / 18-03-1997 / 11:06:44 / cg"

    "Modified: / 04-10-2013 / 12:45:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

argSpecWithArgsFromStream:s in:aPackage

    "parse an argSpec - see java doc"

    ^ self argSpecWithArgsFromStream:s in:aPackage argNames:nil

    "Modified: / 8.1.1998 / 19:21:00 / cg"

!

argSpecWithArgsFromStream:s in:aPackage argNames:argNames

    "parse an argSpec - see java doc"

    |argSpec spec argNr nm|

    argNr := 1.

    spec := ''.

    [s atEnd or:[s peek == $)]] whileFalse:[

        argSpec := self fieldTypeFromStream:s in:aPackage.

        (argNames notNil

        and:[argNames size >= argNr

        and:[(nm := argNames at:argNr) notNil]]) ifFalse:[

            nm := 'arg' , argNr printString.

        ].

        argSpec := argSpec , ' ' , nm.

        spec size ~~ 0 ifTrue:[

            spec := spec , ', '

        ].

        spec := spec , argSpec.

        argNr := argNr + 1.

    ].

    ^ spec

    "Created: / 8.1.1998 / 19:20:36 / cg"

    "Modified: / 8.1.1998 / 21:14:33 / cg"

!

fieldTypeFromStream:s in:aPackage

    "parse a fieldTypeSpec - see java doc"

    |typeChar typeSym elType size className nm out nangles |

    typeChar := s next.

    typeSym := SignatureTypeCodes at:typeChar ifAbsent:#unknown.

    typeSym == #unknown ifTrue:[

        ^ typeSym

    ].

    (typeSym == #object or: [typeSym == #typevar]) ifTrue:[

        "Take care about type variables"

        out := String new writeStream.

        [ s peek ~~ $; and:[ s peek ~~ $< ] ] whileTrue:[

            out nextPut: s next.

        ].

        className := out contents.

        "Eat possible type variables"

        (s peek == $<) ifTrue:[

            nangles := 1. s next.

            [  nangles ~~ 0 ] whileTrue:[

                s peek == $< ifTrue:[nangles := nangles + 1].

                s peek == $> ifTrue:[nangles := nangles - 1].

                s next.

            ]

        ].

        s peek ~~ $; ifTrue:[self error: 'Signature corrupted?'].

        s next. "/eat ;

        typeSym == #typevar ifTrue:[^className].

        "/ strip off default

        nm := className.

"/        aPackage notNil ifTrue:[

"/            (nm startsWith:aPackage) ifTrue:[

"/                nm := nm copyFrom:(aPackage size + 2).

"/            ].

"/        ].

        "/ Show only local name, otherwise names are way too long...

        nm := nm copyFrom: (nm lastIndexOf: $/) + 1.

"/        nm := nm copyReplaceAll:$/ with:$..

        ^ nm

    ].

    typeSym == #array ifTrue:[

        s peek isDigit ifTrue:[

            size := Integer readFrom:s.

            elType := self fieldTypeFromStream:s in:aPackage.

            ^ elType , '[' , size printString , ']'

        ].

        elType := self fieldTypeFromStream:s in:aPackage.

        ^ elType , '[]'

    ].

    ^ typeSym

    "Created: / 18-03-1997 / 11:07:56 / cg"

    "Modified: / 18-07-1998 / 22:57:06 / cg"

    "Modified: / 04-10-2013 / 12:42:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

numArgsFromDescriptor:descriptor 

    "Given a method descriptor, return the number physical of args (number of arg slots)"

    | i c numArgs |

    "/ The following code is king of ugly, but it is optimized for speed as

    "/ profiling shown that some 10% time was spent in descriptor parsing.

    "/ Fillowing code is written upon assumption we get a proper method

    "/ descriptor (i.e., descriptor, not signature with type parameters).

    numArgs := 0.

    i := descriptor indexOf: $(.

    i ~~ 0 ifTrue:[ 

        i := i + 1.

        [ (c := descriptor at: i) ~~ $) ] whileTrue:[

            c == $D ifTrue:[ 

                numArgs := numArgs + 2.

            ] ifFalse:[ 

                c == $J ifTrue:[ 

                    numArgs := numArgs + 2.

                ] ifFalse:[ 

                    numArgs := numArgs + 1.

                    c == $[ ifTrue:[ 

                        i := i + 1.

                        [ (c := descriptor at: i) == $[ ] whileTrue:[ i := i + 1 ].

                    ].

                    c == $L ifTrue:[ 

                        i := descriptor indexOf: $; startingAt: i + 1.

                        i == 0 ifTrue:[ 

                            self error: 'Invalid descriptor'

                        ].

                    ].

                ].

            ].

            i := i + 1.

        ].

        ^ numArgs

    ].

    self error: 'Invalid descriptor'

    "

     JavaMethod numArgsFromDescriptor:'(LObject;)V'

     JavaMethod numArgsFromDescriptor:'(BB)S'