"

 COPYRIGHT (c) 2005 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libjavascript' }"

"{ NameSpace: Smalltalk }"

JavaScriptParser subclass:#JavaScriptCompiler

	instanceVariableNames:'codeBytes codeIndex litArray stackDelta extra lineno extraLiteral

		maxStackDepth relocList methodTempVars numTemp maxNumTemp

		methodClass loopStack currentLineNumber'

	classVariableNames:'JumpToAbsJump'

	poolDictionaries:''

	category:'Languages-JavaScript-Compiling & Parsing'

!

Object subclass:#LoopDescription

	instanceVariableNames:'breakLabel continueLabel backPatchListForBreak

		backPatchListForContinue'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaScriptCompiler

!

Object subclass:#LoopDescriptionForBlock

	instanceVariableNames:'deltaScope'

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaScriptCompiler

!

JavaScriptCompiler::LoopDescription subclass:#SwitchDescription

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:JavaScriptCompiler

!

!JavaScriptCompiler class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2005 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    JavaScriptCompiler has a lot of stuff copied from ByteCodeCompiler.

    This is a very BAD SMELL!!

"

!

examples

"

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'max(a, b) {

		    if (a > b) return a;

		    return b;

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(10 20).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'max(a, b) {

		    if (a > b) ;

		    else return b;

		    return a;

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(10 20).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'max(a, b) {

		    if (a > b) return a;

		    else return b;

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(20 10).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:('test(arg) {

		    var n;

		    n = arg;

		    while (n > 0) {

			n--;

			Transcript.showCR(#hello#);

		    }

		 }' replaceAll:$# with:Character doubleQuote)

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(5).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:('test(arg) {

		    var n;

		    n = 1;

		    while (n <= arg) {

			n++;

			Transcript.showCR(#hello#);

		    }

		 }' replaceAll:$# with:Character doubleQuote)

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(5).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'test(arg) {

		    var n;

		    n = 1;

		    while (n <= arg) {

			Transcript.showCR(n++);

		    }

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(5).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'test(arg) {

		    var n;

		    n = 1;

		    while (n++ <= arg) {

			Transcript.showCR(n);

		    }

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#(5).

				    [exEnd]

				    [exBegin]

    |f|

    f := JavaScriptCompiler

	compile:'foo() {

		    Transcript.showCR(''start'');

		    try {

			Error.raise();

		    } catch(Error) {

			Transcript.showCR(''caught error'');

		    };

		    Transcript.showCR(''end'');

		 }'

	forClass:nil

	inCategory:nil

	notifying:nil.

    f valueWithReceiver:nil arguments:#().

				    [exEnd]

"

! !

!JavaScriptCompiler class methodsFor:'instance creation'!

new

    "/ Pretty ugly hack. A caller to compiler may provide a set of breakpoints

    "/ that has to be injected to the code. However, since breakpoint injection

    "/ is actually done by a subclass or me, so we have to return this subclass here.

    "/ This subclass-to-transform API is bit unfortunate.

    | breakpoints |

    self == JavaScriptCompiler ifTrue:[

        breakpoints := BreakpointQuery query.

        breakpoints notEmptyOrNil ifTrue:[

            ^ JavaScriptCompilerWithBreakpointSupport new

                breakpoints: breakpoints;

                yourself.

        ].

    ].

    ^ super new.

    "Created: / 08-05-2014 / 11:01:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 08-05-2014 / 13:56:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 27-06-2019 / 10:05:48 / Claus Gittinger"

! !

!JavaScriptCompiler class methodsFor:'compiling methods'!

compile:aString forClass:aClass inCategory:cat

    ^ self

	compile:aString

	forClass:aClass

	inCategory:cat

	notifying:nil

	install:true

	skipIfSame:false

	silent:false

	foldConstants:true

    "Created: / 30-01-2011 / 16:59:00 / cg"

!

compile:aString forClass:aClass inCategory:cat notifying:requestor

    "compile a source-string for a method in classToCompileFor.

     errors are forwarded to requestor.

     The method will get cat as category.

     Returns the new method, #Error or nil."

    ^ self

	compile:aString

	forClass:aClass

	inCategory:cat

	notifying:requestor

	install:true

	skipIfSame:false

	silent:false

	foldConstants:true

!

compile:aString forClass:aClass inCategory:cat notifying:requestor install:install

    ^ self

	compile:aString

	forClass:aClass

	inCategory:cat

	notifying:requestor

	install:install

	skipIfSame:false

	silent:false

!

compile:aString forClass:aClass inCategory:cat notifying:requestor

		 install:install skipIfSame:skipIfSame silent:silent

    "compile a source-string for a method in aClass.

     errors are forwarded to requestor.

     The method will get cat as category.

     if install is true, the method is installed in the class.

     if skipIfSame, the method is not installed if there is no change

     (used when filing in).

     if silent is true, no warnings are output.

     Returns the new method, #Error or nil."

    ^ self

	compile:aString

	forClass:aClass

	inCategory:cat

	notifying:requestor

	install:install

	skipIfSame:skipIfSame

	silent:silent

	foldConstants:true

!

compile:aString forClass:aClass inCategory:cat notifying:requestor

		 install:install skipIfSame:skipIfSame silent:silent foldConstants:fold

    |compiler |

    compiler := self new.

    "/ not needed...

    "/ compiler := self for:(ReadStream on:aString).

    "/ compiler setClassToCompileFor:aClass.

    "/ compiler nextToken.

    ^ compiler

	compile:aString

	forClass:aClass

	inCategory:cat

	notifying:requestor

	install:install

	skipIfSame:skipIfSame

	silent:silent

	foldConstants:fold

    "Modified: / 30-09-2011 / 12:49:29 / cg"

!

compile:aString in:aClass notifying:requestor ifFail:failBlock

    |newMethod|

    newMethod := self

	compile:aString

	forClass:aClass

	inCategory:'no category'

	notifying:requestor

	install:true

	skipIfSame:false

	silent:false

	foldConstants:true.

    newMethod == #Error ifTrue:[

	^ failBlock value

    ].

    ^ newMethod

!

evaluate:aString notifying:requestor compile:doCompile

    "used to install new classes"

    |tree|

    tree := self parseClassDefinition:aString.

    ^ tree evaluate.

!

newCodeSet

    ^ true

! !

!JavaScriptCompiler class methodsFor:'private'!

selectorFor:functionName numArgs:nargs

    (nargs == 1) ifTrue:[

        ^ (functionName , ':') asSymbol.

    ].

    (nargs == 2) ifTrue:[

        ^ (functionName , ':_:') asSymbol.

    ].

    (nargs == 3) ifTrue:[

        ^ (functionName , ':_:_:') asSymbol.

    ].

    ^ (functionName , (':_:_:_:_:_:_:_:_:_:_:_:_:_:_:_:_:_:' copyTo:nargs*2-1)) asSymbol.

! !

!JavaScriptCompiler methodsFor:'accessing'!

methodClass:something

    methodClass := something.

! !

!JavaScriptCompiler methodsFor:'code generation'!

absJumpFromJump:code

    "given a jump-symbolic code, return corresponding absolute jump"

    JumpToAbsJump isNil ifTrue:[

	JumpToAbsJump := IdentityDictionary new.

	JumpToAbsJump at:#jump put:#jumpabs.

	JumpToAbsJump at:#trueJump put:#trueJumpabs.

	JumpToAbsJump at:#falseJump put:#falseJumpabs.

	JumpToAbsJump at:#nilJump put:#nilJumpabs.

	JumpToAbsJump at:#notNilJump put:#notNilJumpabs.

	JumpToAbsJump at:#eqJump put:#eqJumpabs.

	JumpToAbsJump at:#notEqJump put:#notEqJumpabs.

	JumpToAbsJump at:#zeroJump put:#zeroJumpabs.

	JumpToAbsJump at:#notZeroJump put:#notZeroJumpabs.

	JumpToAbsJump at:#makeBlock put:#makeBlockabs.

    ].

    ^ JumpToAbsJump at:code

!

addLiteral:anObject

    "add a literal to the literalArray - watch for and eliminate

     duplicates. return the index of the literal in the Array"

    |index "{ Class: SmallInteger }" oldLit class|

    litArray isNil ifTrue:[

	litArray := Array with:anObject.

	^ 1

    ].

    index := litArray identityIndexOf:anObject.

    (index == 0) ifTrue:[

	"

	 reuse constants if same value and same class

	"

	class := anObject class.

	((class == Float)

	or:[class == Fraction

	or:[class == LargeInteger

	"or:[class == String] --only if literalString option has been added---" ]]) ifTrue:[

	    index := litArray indexOf:anObject.

	    index ~~ 0 ifTrue:[

		oldLit := litArray at:index.

		oldLit class == class ifFalse:[

		    index := 0.

		] ifTrue:[

		    "/ dont mess up negative with positive zeros

		    anObject = 0.0 ifTrue:[

			anObject isNegativeZero ~~ oldLit isNegativeZero ifTrue:[

			    index := 0

			]

		    ]

		].

	    ].

	].

	(index == 0) ifTrue:[

	    litArray := litArray copyWith:anObject.

	    ^ litArray size

	].

    ].

    ^ index

    "Modified: / 12.11.1997 / 18:49:43 / cg"

!

addReloc:symIndex

    "remember to relocate offset at symIndex later ..."

    relocList isNil ifTrue:[

	relocList := OrderedCollection new.

    ].

    relocList add:symIndex

!

appendByte:aByte

    "append a byte to the code-Array, checking for byte-range (debug-only)"

    |idx "{Class: SmallInteger }"|

    idx := codeIndex.

    (aByte between:0 and:255) ifTrue:[

	codeBytes at:idx put:aByte.

	codeIndex := idx + 1

    ] ifFalse:[

	self error:'byte range error'.

	errorFlag := #Error

    ]

!

appendByteCodeFor:codeSymbol

    "append the byteCode for an instructionSymbol to the code-Array"

    |idx "{Class: SmallInteger }"|

    idx := codeIndex.

    codeBytes at:idx put:(self byteCodeFor:codeSymbol).

    codeIndex := idx + 1

!

appendEmptyByte

    "append an empty byte to the code-Array"

    |idx "{Class: SmallInteger }"|