"

 COPYRIGHT (c) 2012-2013 by Jan Vrany

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libscm/mercurial' }"

TestResource subclass:#HGRepositoriesResource

	instanceVariableNames:'repositoryDirectory'

	classVariableNames:'HGRepositoriesArchiveDir'

	poolDictionaries:''

	category:'SCM-Mercurial-Tests'

!

!HGRepositoriesResource class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2012-2013 by Jan Vrany

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!HGRepositoriesResource class methodsFor:'class initialization'!

initialize

    HGRepositoriesArchiveDir := (Smalltalk packageDirectoryForPackageId:self package)

                    / 'tests' / 'repositories'

    "Created: / 09-12-2010 / 23:07:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 27-12-2011 / 18:07:34 / dundee"

    "Modified: / 17-10-2012 / 13:02:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGRepositoriesResource methodsFor:'accessing'!

directoryForRepositories

    ^repositoryDirectory

    "Created: / 22-11-2012 / 11:34:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

directoryForRepositoryNamed: nm

    ^self directoryForRepositoryNamed: nm unpack: true

    "Created: / 19-09-2012 / 18:57:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 14-01-2013 / 13:13:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

directoryForRepositoryNamed: nm init: init

    "Returns path to repository named nm.

     If `init` is true, then the repository is created and initialized

     (with no content at all). If 'init' is false, then only directory

     name is returned (without creating it)."

    ^self directoryForRepositoryNamed: nm unpack: false init: init

    "Created: / 01-02-2013 / 13:38:49 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

directoryForRepositoryNamed: nm unpack: unpack

    "Returns path to repository named nm.

     If `unpack` is true, then the repository is frechly created and thus

     empty. If 'unpack' is true, then initial content of repository will 

     be loaded from zip archive located in

        <package path>/stx/libsvn/tests/repositories/<name>.git.zip

     If the files does not exists, an error is raised"

    ^self directoryForRepositoryNamed: nm unpack: unpack init: true

    "Created: / 14-01-2013 / 13:13:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 01-02-2013 / 13:39:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

directoryForRepositoryNamed: nm unpack: unpack init: init

    "Returns path to repository named nm.

     If `unpack` is true, then the repository is frechly created and thus

     empty, unless 'init' is false (in that case, only a name of directory

     that does not exists yet ir returned.

     If 'unpack' is true, then initial content of repository will 

     be loaded from zip archive located in

        <package path>/stx/libsvn/tests/repositories/<name>.git.zip

     If the files does not exists, an error is raised"

    | archiveNm archive repo dir  ok |

    unpack ifTrue:[

        self assert: init description: 'Cannot unpack non-initialized repo!!'

    ].

    archiveNm := nm copy 

                    replaceAll:$/ with:$_; 

                    yourself.

    archive := HGRepositoriesArchiveDir / (archiveNm , '.hg.zip').

    unpack ifTrue:[

        self assert:archive exists description:'dump file does not exist'.

    ].

    self assert:repositoryDirectory exists description:'repository directory does not exist'.

    dir := "/Filename newTemporaryDirectoryIn: 

                repositoryDirectory.

    init ifFalse:[

        ^ (dir asAbsoluteFilename / nm) pathName.

    ].

    unpack ifTrue:[

        ok := true.

        OperatingSystem 

            executeCommand:('unzip %1' bindWith: (archive asAbsoluteFilename pathName))

            inDirectory:dir 

            onError:[:status | ok := false].

        ok ifFalse:[

            OperatingSystem 

                executeCommand:('unzip %1' bindWith: (archive asAbsoluteFilename pathName))

                inDirectory:dir 

                onError:[:status | self assert:false description:'unzip failed'].

        ].

    ] ifFalse:[

        | repodir |

        repodir := (dir asAbsoluteFilename / nm).

        repodir directory recursiveMakeDirectory.

        OperatingSystem 

                executeCommand:('hg init %1' bindWith: (repodir baseName))

                inDirectory:repodir directory pathName 

                onError:[:status | self assert:false description:'hg init failed'].

    ].

    repo := (dir asAbsoluteFilename / nm).

    self assert: repo exists.

    self assert: (repo / '.hg') exists.

    ^repo pathName

    "Created: / 01-02-2013 / 13:35:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGRepositoriesResource methodsFor:'running'!

setUp

    repositoryDirectory := Filename newTemporaryDirectory.

    Smalltalk packagePath: (Smalltalk packagePath asOrderedCollection

                                addFirst: repositoryDirectory pathName;

                                yourself)

    "Created: / 09-12-2010 / 23:53:48 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 27-12-2011 / 18:07:04 / dundee"

    "Modified: / 16-11-2012 / 20:16:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

tearDown

    Smalltalk packagePath: (Smalltalk packagePath 

                                remove: repositoryDirectory pathName;

                                yourself).

    [

        repositoryDirectory recursiveRemove

    ] on: Error do:[

        "Stupid windows!!"

    ]

    "Created: / 09-12-2010 / 23:54:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified: / 30-09-2012 / 05:26:04 / jv"

    "Modified: / 16-11-2012 / 20:16:32 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGRepositoriesResource methodsFor:'testing'!

isAvailable

    ^HGRepositoriesArchiveDir exists and:[OperatingSystem canExecuteCommand:'unzip']

    "Created: / 09-12-2010 / 23:06:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (format): / 27-12-2011 / 18:05:57 / dundee"

    "Modified: / 17-10-2012 / 13:02:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!HGRepositoriesResource class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

!

version_SVN

    ^ '§Id::                                                                                                                        §'

! !

HGRepositoriesResource initialize!