"

COPYRIGHT (c) 2020 LabWare

stx:libscm - a new source code management library for Smalltalk/X

This library is free software; you can redistribute it and/or

modify it under the terms of the GNU Lesser General Public

License as published by the Free Software Foundation; either

version 2.1 of the License. 

This library is distributed in the hope that it will be useful,

but WITHOUT ANY WARRANTY; without even the implied warranty of

MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public

License along with this library; if not, write to the Free Software

Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

"

"{ Package: 'stx:libscm/common' }"

"{ NameSpace: Smalltalk }"

StandaloneStartup subclass:#SCMMergeToolStartup

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'SCM-Common-StX-Tools'

!

!SCMMergeToolStartup class methodsFor:'documentation'!

copyright

"

COPYRIGHT (c) 2020 LabWare

stx:libscm - a new source code management library for Smalltalk/X

This library is free software; you can redistribute it and/or

modify it under the terms of the GNU Lesser General Public

License as published by the Free Software Foundation; either

version 2.1 of the License. 

This library is distributed in the hope that it will be useful,

but WITHOUT ANY WARRANTY; without even the implied warranty of

MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU

Lesser General Public License for more details.

You should have received a copy of the GNU Lesser General Public

License along with this library; if not, write to the Free Software

Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

"

!

documentation

"

    documentation to be added.

    [author:]

        Jan Vrany <jan.vrany@labware.com>

    [instance variables:]

    [class variables:]

    [see also:]

"

! !

!SCMMergeToolStartup class methodsFor:'startup'!

main: argv

    "Application entry point. `argv` is the array of command arguments (as Array of Strings)"

    | optparser positional base local other output |

    optparser := CmdLineParser new.

    optparser

          on: #('-o' '--output') do:[ :o | output := o asFilename ];

          on: #('-h' '--help') do:[ self usage. Smalltalk exitIfStandalone:0 ].

    [

        positional := optparser parse:argv.

    ] on: CmdLineOptionError do:[:ex |

        Stderr nextPutLine: 'ERROR: '; nextPutLine: ex description.

        Smalltalk exitIfStandalone:0.        

    ].

    positional size ~~ 3 ifTrue: [

        Stderr nextPutLine: 'ERROR: Invalid invocation (see --help)'.

        Smalltalk exitIfStandalone:1.        

    ].

    positional := positional collect: [:each | each asFilename ].

    positional do: [:each | 

        each isRegularFile ifFalse: [

            Stderr nextPutLine: 'ERROR: No such file: ', each pathName.

            Smalltalk exitIfStandalone:2.        

        ].

        each isReadable ifFalse: [

            Stderr nextPutLine: 'ERROR: File not readable: ', each pathName.

            Smalltalk exitIfStandalone:2.        

        ].

    ].

    base := positional first.

    local := positional second.

    other := positional third.

    output notNil ifTrue: [

        (output exists and:[output isWritable not]) ifTrue: [

            Stderr nextPutLine: 'ERROR: File not writable: ', output pathName.

            Smalltalk exitIfStandalone:2.        

        ] ifFalse: [

            output directory isWritable ifFalse: [

                Stderr nextPutLine: 'ERROR: Directory not writable: ', output directory pathName.

                Smalltalk exitIfStandalone:2.        

            ].

        ].

    ].

    [

        (SCMMergeTool new base: base local: local other: other output: output)

            ifTrue:[ Smalltalk exitIfStandalone:0 ]

            ifFalse:[ Smalltalk exitIfStandalone:3 ].

    ] on: Error do: [:ex |

        Stderr nextPutLine: 'ERROR: '; nextPutLine: ex description.

        Smalltalk exitIfStandalone:4.        

    ].

    "

    SCMMergeToolStartup main: #('file.txt.base' 'file.txt' 'file.txt.other')

    SCMMergeToolStartup main: #('file.txt.base' 'file.txt')

    SCMMergeToolStartup main: #(

    '-o' '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/LargeFloat.st'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/LargeFloat.st.base'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/LargeFloat.st.local'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/LargeFloat.st.other')

    SCMMergeToolStartup main: #(

    '-o' '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/Smalltalk.st'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/Smalltalk.st.base'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/Smalltalk.st.local'

         '/home/jv/Projects/SmalltalkX/sources/merge-with-exept/build/stx/libbasic/Smalltalk.st.other')

    "

    "Modified: / 27-08-2020 / 09:59:00 / Jan Vrany <jan.vrany@labware.com>"

!

usage

    "output some command-line usage infos on stderr"

    Stderr nextPutLine:'usage: ',self applicationName,' [-o OUTPUT] BASE LOCAL OTHER'.

    Stderr nextPutLine:'  -h | --help .......... output this message'.

    Stderr nextPutLine:'  -o | --output OUTPUT . save merge to OUTPUT'.

    "Modified: / 27-08-2020 / 09:41:34 / Jan Vrany <jan.vrany@labware.com>"

! !

!SCMMergeToolStartup class methodsFor:'documentation'!

version_HG

    ^ '$Changeset: <not expanded> $'

! !