"{ Package: 'stx:libsvn' }"!

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

canSubversionMerge

    "Return true, if file is in conflict an can be merged"

    | files |    

    files := self currentSelectedFiles.

    files size ~~ 1 ifTrue:[ ^ false ].

    self svnMergeFilesFor: files anElement do:[:base :wc :merge :output| ^ true ].

    ^false

    "Modified: / 20-03-2012 / 15:50:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

canSubversionMergeAuto

    "Return true, if file is in conflict an can be merged"

    | files |    

    files := self currentSelectedFiles copy.

    files isEmptyOrNil ifTrue:[

        files := self currentDirectory directoryContentsAsFilenames select:[:e|e isRegularFile].

    ].

    files do:[:file|

        self svnMergeFilesFor: file inDirectoryContaining: files do:[:base :wc :merge :output| ^true ].

        files remove: file ifAbsent:[nil].

    ].

    ^false

    "Created: / 21-03-2012 / 00:07:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

canSubversionMergeWithExternalDiff3

    | cmd |

    cmd := UserPreferences current svnDiff3Command.

    ^cmd notEmptyOrNil 

        and:[(OperatingSystem canExecuteCommand: cmd)

            and:[self canSubversionMerge]].

    "Modified: / 20-03-2012 / 15:51:29 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

canSubversionResolve

    "Return true, if file can be marked as resolved"

    ^false

    "Modified: / 20-03-2012 / 15:50:54 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Created: / 27-03-2012 / 17:33:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

hasSubversionWorkingCopySelected

    ^((self currentDirectory  / '.svn') exists) and:

        [(self currentDirectory  / '.svn' / 'entries') exists].

    "Created: / 24-06-2010 / 20:13:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu-queries-svn'!

hasSubversionWorkingCopySelectedAndDiff3CmdDefined

    | cmd |

    cmd := UserPreferences current svnDiff3Command.

    ^cmd notEmptyOrNil 

        and:[(OperatingSystem canExecuteCommand: cmd) 

            and:[self hasSubversionWorkingCopySelected]].

    "Modified: / 17-02-2012 / 10:18:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnAdd

    self svnExecuteCommand: 'add'

    "Modified: / 08-02-2012 / 09:28:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnCommit

    | wc task |

    wc := self svnWorkingCopy.

    task := SVN::CommitTask new workingCopy: wc.

    SVN::CommitDialog2 new

        task: task;

        open

    "Modified: / 30-03-2012 / 10:35:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnCompare

    Dialog warn: 'Not (yet) implemented'

    "Modified: / 30-03-2012 / 10:11:55 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnCompare: rev

    | wc wcfile revfile |

    wc := self svnWorkingCopy.

    wcfile := self currentSelectedFiles anyOne.

    revfile := wc cat: wcfile asString revision: rev.

    "/Argh...backward compatibility..."

        (Tools::TextDiff2Tool ? Tools::TextDiffTool) new

            labelA: 'Working copy';

            labelB: ('r %1' bindWith: rev printString);

            textA: wcfile contents asString; 

            textB: revfile asString;

            title:('%1: Diffbetween working copy and rev. %2 ' bindWith: wcfile asFilename baseName with: rev printString);

            open

    "Created: / 14-02-2012 / 19:13:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnCompareWithBASE

    self svnCompare: SVN::Revision base

    "Modified: / 14-02-2012 / 19:13:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnCompareWithHEAD

    self svnCompare: SVN::Revision head

    "Modified: / 14-02-2012 / 19:13:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnDebugOpenWorkingCopyBrowser

    | wcPath wc |

    wcPath := self currentDirectory asFilename.

    wcPath isDirectory ifFalse:[wcPath := wcPath directory].

    wc := SVN::WorkingCopy path: wcPath.

    (SVN::WorkingCopyBrowser on: wc) open

    "Modified: / 07-02-2012 / 22:51:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnDiff

    self svnExecuteCommand: 'diff'

    "Created: / 04-02-2012 / 19:26:02 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnExecuteCommand: command

    "Executes svn command on currently selected objects"

    self svnExecuteCommand: command objects: self currentSelectedObjects.

    "Created: / 04-02-2012 / 19:22:41 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnExecuteCommand: command objects: givenObjects

    "Executes svn command on given objects (files/dirs)"

    | objects workdir objectsAsString executionBlock |

    objects := givenObjects.

    (self isKindOf: FileBrowserV2) ifTrue:[

        workdir := self fileEntryFieldHolder value asFilename.

        workdir isDirectory ifFalse:[

            workdir := workdir directory

        ].

    ] ifFalse:[

        (objects size == 1 and:[objects anElement isDirectory]) ifTrue:[

            workdir := objects anElement

        ] ifFalse:[

            workdir := Filename currentDirectory.

        ]

    ].

    objectsAsString := String streamContents:[:s|

        objects size == 1 ifTrue:[

            workdir asString = objects anElement asString ifTrue:[

                s nextPut:$.

            ] ifFalse:[

                s nextPutAll: objects anElement asString.

            ]

        ] ifFalse:[

            objects do:[:each|s nextPut:$"; nextPutAll:each asString; nextPut:$"]

                separatedBy:[s space]

        ]

    ].

    executionBlock := [:stream |

        | cmd |

        cmd := '%1 --non-interactive %2 %3' 

                bindWith: SVN::Command executable

                    with: command

                    with: objectsAsString.

        stream nextPutAll: cmd; cr; cr.

        (self getExecutionBlockForCommand:cmd inDirectory: workdir) value:stream.

    ].

    self makeExecutionResultProcessFor:executionBlock withName:'SubVersion> svn ', command.

    "Created: / 21-03-2012 / 10:08:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnInfo

    self svnExecuteCommand: 'info'

    "Modified: / 08-02-2012 / 09:33:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnLog: limit

    self svnExecuteCommand: 'log --verbose' , (limit notNil ifTrue:[' --limit ' , limit printString] ifFalse:[''])

    "Created: / 11-04-2012 / 18:11:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMerge

    "Return true, if file is in conflict an can be merged"

    | files |    

    files := self currentSelectedFiles.

    files size ~~ 1 ifTrue:[ ^ self ].

    self svnMergeFilesFor: files anElement do:[:base :wc :merge :output|

        output suffix = 'st' ifTrue:[

            | info |

            Tools::ChangeSetDiffInfo isNil ifTrue:[

                Dialog warn: 'ChangeSet merge tool not available, JV''s libtool required'.

                ^self.

            ].

            info := Tools::ChangeSetDiffInfo

                        specA: (Tools::ChangeSetSpec file: wc pathName)

                        specB: (Tools::ChangeSetSpec file: merge pathName)

                        specBase: (Tools::ChangeSetSpec file: base pathName)

                        specMerge: (Tools::ChangeSetSpec file: output pathName).        

            Tools::ChangeSetDiffTool new

                        open;

                        fileMenuOpenOnDiffInfo: info.

        ] ifFalse:[

            Dialog warn: 'Merging non .st files not yet supported\Use ''Merge (with external diff3)'' instead' withCRs.                        

        ]

    ]

    "Modified: / 21-03-2012 / 00:06:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMergeAuto

    "Return true, if file is in conflict an can be merged"

    | files unmerged |    

    files := self currentSelectedFiles copy.

    files isEmptyOrNil ifTrue:[

        files := self currentDirectory directoryContentsAsFilenames select:[:e|e isRegularFile].

    ].

    unmerged := OrderedCollection new.

    self makeExecutionResultProcessFor:[:stream|

        [ files isEmpty ] whileFalse:[

            | file |    

            file := files first.

            self svnMergeFilesFor: file inDirectoryContaining: files do:[:base :wc :merge :output|

                | nm |    

                files remove: base ifAbsent:[nil].

                files remove: wc ifAbsent:[nil].

                files remove: merge ifAbsent:[nil].

                files remove: output ifAbsent:[nil].

                nm := output baseName.

                stream nextPutAll: nm; space; next: (40 - nm size) put: $.; space.

                output suffix = 'st' ifTrue:[

                    | info tool  |

                    Tools::ChangeSetDiffInfo isNil ifTrue:[

                        Dialog warn: 'ChangeSet merge tool not available, JV''s libtool required'.

                        ^self.

                    ].

                    info := Tools::ChangeSetDiffInfo

                                specA: (Tools::ChangeSetSpec file: wc pathName)

                                specB: (Tools::ChangeSetSpec file: merge pathName)

                                specBase: (Tools::ChangeSetSpec file: base pathName)

                                specMerge: (Tools::ChangeSetSpec file: output pathName).        

                    [

                        tool := Tools::ChangeSetDiffTool new.

                        tool fileMenuOpenOnDiffInfo: info.

                        Delay waitForSeconds: 2.

                        tool canSave ifTrue:[

                            tool fileMenuSave.

                            stream nextPutLine: 'MERGED (auto)'

                        ] ifFalse:[

                            unmerged add: output.

                            stream nextPutLine: 'FAILED (conflicts)'

                        ]

                    ] on: Error do:[:ex|

                        unmerged add: output.

                        stream nextPutLine: 'FAILED (ERROR: ',ex description, ')'.

                        ex pass

                    ]

                ] ifFalse:[

                    unmerged add: output.

                    stream nextPutLine: 'FAILED (no text merge not, use ''Merge (with external diff3)'' instead'

                ].

            ].

            files remove: file ifAbsent:[nil].

        ].

        stream cr;cr.

        unmerged notEmpty ifTrue:[

            stream nextPutLine:'=== SUMMARY ==='.

            stream nextPutLine:'List of __UNMERGED__ files'.

            unmerged do:[:each|

                stream  nextPutAll: '  '; 

                        nextPutAll: each baseName asString;

                        cr.

            ]

        ].

    ] withName:'SVN merge (auto)'.

    "Created: / 21-03-2012 / 00:04:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMergeBranch

    | branch | 

    branch := Dialog request: 'Enter URL of SVN branch to merge:' initialAnswer:'^/trunk'.

    branch notEmptyOrNil ifTrue:[

        self svnExecuteCommand: 'merge ',branch objects: #()

    ].

    "Modified: / 13-04-2012 / 13:41:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMergeFilesFor: file do: aBlock

    self 

        svnMergeFilesFor: file 

        inDirectoryContaining: file directory directoryContentsAsFilenames 

        do: aBlock

    "Created: / 20-03-2012 / 15:50:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMergeFilesFor: file inDirectoryContaining: files do: aBlock

    | nm i base wc merge output |

    "Find out base name..."

    nm := file pathName.

    ((i := nm indexOfSubCollection: '.working') ~~ 0) ifTrue:[

        nm := nm copyTo: i - 1

    ] ifFalse:[((i := nm indexOfSubCollection: '.merge-left.') ~~ 0) ifTrue:[

        nm := nm copyTo: i - 1

    ] ifFalse:[((i := nm indexOfSubCollection: '.merge-right.') ~~ 0) ifTrue:[

        nm := nm copyTo: i - 1

    ]]].

    output := nm asFilename.

    output exists ifFalse:[ ^ self ].

    wc := (nm , '.working') asFilename.

    wc exists ifFalse:[ ^ self ].

    "Now, search for base and version to merge..."

    files do:[:each|

        (each pathName startsWith:nm , '.merge-left.') ifTrue:[

            base := each

        ].

        (each pathName startsWith:nm , '.merge-right.') ifTrue:[

            merge := each

        ].

    ].

    (base isNil or:[merge isNil]) ifTrue:[ ^ self ].

    aBlock value: base value:wc value:merge value:output.

    "Created: / 21-03-2012 / 10:19:47 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnMergeWithExternalDiff3

    | files |    

    files := self currentSelectedFiles.

    files size ~~ 1 ifTrue:[ ^ self ].

    self svnMergeFilesFor: files anElement do:[:base :wc :merge :output|

        OperatingSystem executeCommand:

            ('%1 %2 %3 %4 -o %5'

                bindWith: UserPreferences current svnDiff3Command

                    with: base pathName

                    with: wc pathName

                    with: merge pathName

                    with: output pathName)

    ]

    "Modified: / 20-03-2012 / 23:21:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnRemove

    self svnExecuteCommand: 'remove'

    "Created: / 08-02-2012 / 09:28:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnRevert

    self svnExecuteCommand: 'revert'

    "Modified: / 21-03-2012 / 01:53:01 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnStatus

    self svnExecuteCommand: 'status'

    "Modified: / 04-02-2012 / 19:22:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractFileBrowser methodsFor:'menu actions-scm-svn'!

svnStatusShowUpdates

    self svnExecuteCommand: 'status --show-updates --verbose'

    "Modified: / 04-02-2012 / 19:22:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Created: / 07-02-2012 / 19:25:53 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !