"{ Package: 'stx:libtool' }"!

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatExpression:aString in:aClass elementsInto: elements

    ^self formatExpression:aString in:aClass

    "Created: / 25-07-2010 / 08:57:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AbstractSyntaxHighlighter class methodsFor:'api highlighting'!

formatMethod:aString in:aClass using:preferencesOrNil elementsInto: elements

    ^self formatMethod:aString in:aClass using:preferencesOrNil

    "Created: / 25-07-2010 / 08:58:00 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AddClassChange methodsFor:'testing'!

isClassDefinitionChange

    ^true

    "Created: / 29-10-2010 / 13:35:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!AddMethodChange methodsFor:'testing'!

isMethodCodeChange

    ^true

! !

!AddMethodChange methodsFor:'accessing'!

source

    ^ source

! !

!AddMethodChange methodsFor:'initialization & release'!

source: aString 

    source := aString.

! !

!Breakpoint methodsFor:'accessing'!

icon

    state == #enabled ifTrue:[^ToolbarIconLibrary brkp_obj].

    state == #disabled ifTrue:[^ToolbarIconLibrary brkpd_obj].

    ^nil

    "Created: / 28-06-2011 / 08:29:12 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ByteArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

        declareAllNewFrom:(super inspectorExtraAttributes ? #());

        add:'-hexstring' -> [ self hexPrintString "WithSeparator:Character space" ];

        add:'-hexadecimal' ->

            [

                String

                    streamContents:[:s |

                        self class isWords ifTrue:[

                            self asWordArray printOn:s base:16 showRadix:true

                        ] ifFalse:[

                            self class isLongs ifTrue:[

                                self asLongIntegerArray printOn:s base:16 showRadix:true

                            ] ifFalse:[

                                self asByteArray printOn:s base:16 showRadix:true

                            ]

                        ]

                    ]

            ];

        yourself

    "Created: / 18-09-2006 / 21:29:59 / cg"

    "Modified: / 06-10-2006 / 13:57:20 / cg"

! !

!Change methodsFor:'private'!

flattenOnto: aCollection 

	aCollection add: self

! !

!Change methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!Change methodsFor:'accessing'!

removed

    ^(self objectAttributeAt: #removed) ? false

    "Created: / 24-10-2009 / 21:10:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!Change methodsFor:'accessing'!

removed: aBoolean

    ^self objectAttributeAt: #removed put: aBoolean

    "Created: / 24-10-2009 / 21:11:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!ChangeSet methodsFor:'utilities'!

condenseChangesForRemoved

    "remove all changes which has been removed (marked for removal

     by aChange removed: true)"

    |changesToRemove|

    changesToRemove := self select:[:aChange | 

        aChange isCompositeChange ifTrue:

            [aChange condenseChangesForRemoved].        

        aChange removed

    ].

    self condenseChanges:changesToRemove

    "Created: / 05-11-2001 / 14:21:17 / cg"

    "Modified: / 12-10-2006 / 16:51:27 / cg"

! !

!ChangeSet methodsFor:'private'!

flattenOnto: aCollection 

    self do:[:change|change flattenOnto: aCollection]

! !

!ChangeSet methodsFor:'private'!

flattenedChanges

	| changes |

	changes := OrderedCollection new.

	self flattenOnto: changes.

	^changes

! !

!ChangeSet methodsFor:'debugging support'!

inspector2TabBrowser

    ^self newInspector2Tab

        label: 'Changes';    

        priority: 75;

        application: (Tools::ChangeSetBrowser on: self)

! !

!Character methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-hexValue' -> [ self codePoint radixPrintStringRadix:16 ];

	add:'-string' -> [ self stringSpecies with:self ];

	add:'-utf8String' -> [ self utf8Encoded ];

	add:'-utf8' -> [ self utf8Encoded asByteArray hexPrintStringWithSeparator:Character space ];

	yourself

    "

     $a inspect

    "

    "Created: / 22-10-2006 / 03:52:20 / cg"

! !

!CharacterArray methodsFor:'debugging support'!

inspector2TabText

    ^self newInspector2Tab

        label: 'String';

        priority: 75;

        view: ((ScrollableView for:TextView) contents: self; yourself)

    "Created: / 17-02-2008 / 10:10:50 / janfrog"

! !

!CharacterArray methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    |d|

    d := Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-utf8String' -> [ self utf8Encoded ];

	add:'-utf8' -> [ self utf8Encoded asByteArray hexPrintStringWithSeparator:Character space ];

	yourself.

    HTMLUtilities notNil ifTrue:[

	d add:'-html' -> [ HTMLUtilities escapeCharacterEntities:self ].

    ].

    ^ d

    "

     'aou' inspect

    "

    "Created: / 22-10-2006 / 03:52:20 / cg"

! !

!ClassDescription methodsFor:'misc'!

iconInBrowserForVariableNamed: varName

    "variables for which an entry is found in the xml-spec (if any) are marked

     with an <xml>-icon. For now, this is expecco-specific, but should be somehow

     lifted to the base system"

    (Expecco::ExpeccoXMLDecoder notNil and:

        [self canUnderstand: #xmlSpecFor:]) ifTrue:

            [

            (Expecco::ExpeccoXMLDecoder xmlSpecForObject:self basicNew)

                collect:[:spec|spec getter = varName ifTrue:

                    [^SystemBrowser instVarOverlayXmlSpec]].

            ].

    ^nil

    "Created: / 12-04-2011 / 16:04:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"

    "Modified (comment): / 03-07-2011 / 15:46:07 / cg"

! !

!Collection methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:('-size' -> [ self size ]);

	yourself

    "

     'hello' inspect

    "

    "Created: / 06-10-2006 / 13:56:52 / cg"

    "Modified: / 06-10-2006 / 17:43:45 / cg"

! !

!Color methodsFor:'inspecting'!

inspectorClass

    "return the class of an appropriate inspector.

     ST/X has a specialized ColorInspectorView for that"

    ^ ColorInspectorView

    "Modified: 23.4.1996 / 13:39:50 / cg"

! !

!Color methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

	declareAllNewFrom:(super inspectorExtraAttributes ? #());

	add:'-rgb' -> [ self rgbValue hexPrintString ];

	add:'-html' -> [ self htmlPrintString ];

	yourself

    "

     Color red inspect

    "

! !

!CompositeChange methodsFor:'utilities'!

condenseChangesForRemoved

    self changes condenseChangesForRemoved

! !

!CompositeChange methodsFor:'private'!

flattenOnto: aCollection

    changes do:[:change|change flattenOnto: aCollection]

! !

!CompositeChange methodsFor:'accessing'!

removed

    ^changes allSatisfy: [:e|e removed]

! !

!CompositeChange methodsFor:'accessing'!

removed: aBoolean

    changes do:[:e|e removed: aBoolean]

! !

!CompositeRefactoryChange methodsFor:'utilities'!

condenseChangesForRemoved

    changes := 

        changes reject:

            [:chg|

            chg isCompositeChange ifTrue:[chg condenseChangesForRemoved].

            chg removed]

! !

!CompositeRefactoryChange methodsFor:'user interface'!

inspect

    ^super inspect

    "

        CompositeRefactoryChangeInspector openOn: self

    "

! !

!CompositeRefactoryChange methodsFor:'testing'!

isComplexRefactoryChange

    ^changes size > 1

    "Created: / 26-11-2008 / 11:56:18 / Jan Vrany <vranyj1@fel.cvut.cz>"

! !

!CompositeRefactoryChange methodsFor:'testing'!

isCompositeChange

    ^true

    "Created: / 26-11-2008 / 11:34:56 / Jan Vrany <vranyj1@fel.cvut.cz>"

! !

!CompositeRefactoryChange methodsFor:'testing'!

isCompositeRefactoryChange

    ^true

    "Created: / 26-11-2008 / 11:34:56 / Jan Vrany <vranyj1@fel.cvut.cz>"

! !

!CompositeRefactoryChange methodsFor:'accessing'!

removed

    ^changes allSatisfy: [:e|e removed]

! !

!CompositeRefactoryChange methodsFor:'accessing'!

removed: aBoolean

    changes do:[:e|e removed: aBoolean]

! !

!Date methodsFor:'inspecting'!

inspectorExtraAttributes

    "extra (pseudo instvar) entries to be shown in an inspector."

    ^ Dictionary new

        declareAllNewFrom:(super inspectorExtraAttributes ? #());

        add:'-dayInWeek' -> [ self dayInWeek printString , ' "', self dayOfWeekName , '"' ];

        add:'-dayInYear' -> [ self dayInYear ];

        add:'-daysInMonth' -> [ self daysInMonth ];

        add:'-monthName' -> [ self monthName ];

        add:'-leapYear' -> [ self isLeapYear ];

        yourself

    "

     Date today inspect

    "

    "Created: / 20-01-2011 / 12:19:05 / cg"

! !

!Dictionary methodsFor:'inspecting'!

inspectorClass

    "redefined to use DictionaryInspector

     (instead of the default Inspector)."

    ^ DictionaryInspectorView

! !

!DoWhatIMeanSupport class methodsFor:'code completion-helpers'!

askUserForCompletion:what for:codeView at:position from:allTheBest 

    |list choice lastChoice|

    allTheBest isEmpty ifTrue:[

        ^ nil

    ].

    allTheBest size == 1 ifTrue:[

        ^ allTheBest first

    ].

    list := allTheBest.

    LastChoices notNil ifTrue:[

        lastChoice := LastChoices at:what ifAbsent:nil.

        lastChoice notNil ifTrue:[

            list := 

                    { lastChoice.

                    nil } , (list copyWithout:lastChoice).

        ].

    ].

    choice := Tools::CodeCompletionMenu 

                openFor:codeView

                at:position

                with:allTheBest.

    LastChoices isNil ifTrue:[

        LastChoices := Dictionary new.

    ].

    LastChoices at:what put:choice.

    ^ choice

    "Created: / 16-02-2010 / 10:09:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!DoWhatIMeanSupport class methodsFor:'code completion-helpers'!

codeCompletionForLiteralSymbol:node inClass:classOrNil codeView:codeView

    |sym possibleCompletions best start stop oldLen newLen oldVar|

    sym := node value.

    possibleCompletions := OrderedCollection new.

    Symbol allInstancesDo:[:existingSym |

        (existingSym startsWith:sym) ifTrue:[

            (existingSym = sym) ifFalse:[

                possibleCompletions add:existingSym

            ].

        ].

    ].

    possibleCompletions sort.

    best := possibleCompletions longestCommonPrefix.

    (best = sym or:[(possibleCompletions includes:best) not]) ifTrue:[

        best := self askUserForCompletion:'symbol literal' for:codeView at: node start from:possibleCompletions.

        best isNil ifTrue:[^ self].

    ].

"/ self showInfo:best.

    start := node start.

    stop := node stop.

    (codeView characterAtCharacterPosition:start) == $# ifTrue:[

        start := start + 1.

    ].

    (codeView characterAtCharacterPosition:start) == $' ifTrue:[

        start := start + 1.

        stop := stop - 1.

    ].

    oldVar := (codeView textFromCharacterPosition:start to:stop) asString string withoutSeparators.

    codeView

        undoableDo:[ codeView replaceFromCharacterPosition:start to:stop with:best ]

        info:'Completion'.

    (best startsWith:oldVar) ifTrue:[

        oldLen := stop - start + 1.

        newLen := best size.