"

 COPYRIGHT (c) 2000 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

"{ NameSpace: Tools }"

DialogBox subclass:#SearchDialog

	instanceVariableNames:'openHow classes methods selectedClasses selectedCategories

		selectedMethods selectedPackages currentClass currentNamespace

		currentClassCategory currentPackage browser whereRadioGroup

		currentPanel searchAreas caseHolder matchHolder isMethodHolder

		codeField selectorHolder defaultOpenHow withTextEntry allowFind

		allowBuffer allowBrowser searchWhat searchClassProtocolHolder

		searchInstanceProtocolHolder selectorOrCode selectionList

		listHolder matchProcess inputField showMetaFilter

		metaclassesOnlyHolder classesOnlyHolder initialText

		withSearchStringInLiterals searchStringInLiteralsHolder

		searchFreeStandingWordsOnlyHolder withSearchFreeStandingWordsOnly

		ignoreDocumentationMethodsHolder resourceMethodsOnlyHolder'

	classVariableNames:'LastCodeSearched LastCodeSearchWasMethod LastGlobalSearched

		LastStringSearched LastSearchWasMatch LastSearchWasCaseSensitive

		LastStringSearchArea LastCodeSearchArea AREA_LISTOFMETHODS

		LastResourceSearched'

	poolDictionaries:''

	category:'Interface-Browsers-New'

!

!SearchDialog class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2000 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

! !

!SearchDialog class methodsFor:'initialization'!

initialize

    AREA_LISTOFMETHODS := #listOfMethods

    "Created: / 19-11-2010 / 12:00:18 / cg"

! !

!SearchDialog class methodsFor:'constants'!

constantForListOfMethodsArea

    ^ AREA_LISTOFMETHODS

    "Created: / 19-11-2010 / 12:11:50 / cg"

! !

!SearchDialog class methodsFor:'help specs'!

helpSpec

    ^ Dictionary new addPairsFrom:#(

#listOfChangedClasses

'Search only in changed classes'

#listOfChangedMethods

'Search only in changed methods'

#currentClassesNameSpace

'Search in the namespace(s) of the selected class(es)'

#currentClassesPackage

'Search in the package(s) of the selected class(es)'

#currentNameSpace

'Search in the current selected or selected classes namespace'

#currentPackage

'Search in the current selected or selected classes package'

#currentClassesPackage

'Search in the current selected classes package'

#currentPackageAndSubPackages

'Search in the current (selected) package and subpackages.\(disabled if there are no subpackages)'

#everywhere

'Search everywhere (all loaded classes)'

#listOfMethods

'Search only in the list of (shown) methods'

#ownersWithPrivateClasses

'Search in class and the owning and private classes.\(disabled if there are none)'

#ownersHierarchiesWithPrivateClasses

'Search in class, owners, private classes and all subclasses.\(disabled if there are none)'

#classes

'Search in selected class(es) only'

#classesWithPrivateClasses

'Search in selected class(es) and any private classes.\(disabled if there are no private classes)'

#classHierarchies

'Search in selected class(es) and down all subclasses.\(disabled if there are no subclasses)'

#classHierarchiesWithPrivateClasses

'Search in selected class(es), down all subclasses and all of their private classes.\(disabled if there are none)'

#classesAndSuperclasses

'Search in selected class(es) and up all super classes.\(disabled if there are none)'

#classCategories

'Search in selected class category(s)'

#listOfSelectedMethodClasses

'Search in class(es) of selected method(s)'

#listOfSelectedMethodPackages

'Search in package(es) of selected method(s)'

#listOfSelectedMethods

'Search in selected method(s)'

#selectedPackages

'Search in selected package(s)'

#searchPatternField

'The searched string or name. Does completion on TAB-key'

#codeEntryField

'Code fragment to match against in the search.\Press "pattern-help" to learn more about code searches'

#nonMetaClassesOnly

'Search only in instance methods (non-meta classes)'

#metaClassesOnly

'Search only in class methods (meta classes)'

#searchStringInLiterals

'Search string in literal constants; not in source code'

#searchFreeStandingWordsOnly

'Search for free-standing words only (i.e. not substrings)'

#match

'Perform a pattern match search, as opposed to an exact string search.\Pattern is a simple GLOB pattern (as in filenames)'

#caseSensitive

'Perform a case sensitive search (default is to ignore case differences)'

)

! !

!SearchDialog class methodsFor:'queries'!

lastCodeSearchArea

    ^ LastCodeSearchArea

!

lastStringSearchArea

    ^ LastStringSearchArea

!

lastStringSearchArea:aSymbol

    LastStringSearchArea := aSymbol

! !

!SearchDialog methodsFor:'accessing'!

currentClass:aClass

    currentClass := aClass   

!

currentPackage

    ^ currentPackage

!

currentPackage:aPackage

    currentPackage := aPackage   

!

initialText:aString

    initialText := aString.

!

showMetaFilter:aBoolean

    "enable another checkbox, to allow searching in meta/non-meta"

    showMetaFilter := aBoolean.

!

withSearchFreeStandingWordsOnly:aBoolean

    "enable another checkbox, to allow searching for full words only"

    withSearchFreeStandingWordsOnly := aBoolean.

!

withSearchStringInLiterals:aBoolean

    "enable another checkbox, to allow searching for a string

     in the literals only (and in resource methods only)"

    withSearchStringInLiterals := aBoolean.

! !

!SearchDialog methodsFor:'accessing-entered values'!

classesOnly

    "the value of the corresponding check toggle;

     if on, only search in non-metaclasses"

    ^ (classesOnlyHolder ? false) value

    "Created: / 20-08-2012 / 13:25:26 / cg"

!

classesToSearch

    ^ classes.

!

codeToSearch

    ^ selectorOrCode.

!

ignoreDocumentationMethods

    "the value of the corresponding check toggle;

     if on, only search in metaclasses"

    ^ (ignoreDocumentationMethodsHolder ? false) value

!

matchMethods

    ^ isMethodHolder value ? false.

!

metaclassesOnly

    "the value of the corresponding check toggle;

     if on, only search in metaclasses"

    ^ (metaclassesOnlyHolder ? false) value

    "Created: / 20-08-2012 / 13:17:12 / cg"

!

methodsToSearch

    ^ methods.

!

openHow

    "the value of the corresponding button pressed to close the dialog;

     a symbol describing what to do (newBrowser/newBuffer/find)"

    ^ openHow.

!

resourceMethodsOnly

    "the value of the corresponding check toggle;

     if on, only resource methods are consulted;

     otherwise, all methods are visited"

    ^ resourceMethodsOnlyHolder value ? false.

!

searchAreaSelected

    "the value of the corresponding radio button;

     a symbol describing where to search"

    ^ whereRadioGroup value.

!

searchFreeStandingWordsOnly

    "the value of the corresponding check toggle;

     if on, only free standing words match - i.e. the searched word

     may not be part of a longer word"

    ^ searchFreeStandingWordsOnlyHolder value ? false.

!

searchIgnoringCase

    ^ self searchIsCaseSensitive not

!

searchIsCaseSensitive

    "the value of the corresponding check toggle;

     if on, search is case sensitive; otherwise ignore case"

    ^ (caseHolder value ? false)

!

searchStringInLiterals

    "the value of the corresponding check toggle;

     if on, only literal strings should be searched;

     otherwise, the sourcecode is searched"

    ^ searchStringInLiteralsHolder value ? false.

!

searchWithMatch

    "the value of the corresponding check toggle;

     if on, do a GLOB match; otherwise an exact search"

    ^ matchHolder value ? false.

!

selectorToSearch

    ^ selectorOrCode.

! !

!SearchDialog methodsFor:'help'!

helpTextFor:aComponent

    |symbolicHelpKey text|

    (symbolicHelpKey := aComponent helpKey) notNil ifTrue:[

        text := self class helpSpec at:symbolicHelpKey ifAbsent:[ nil ].

        text notNil ifTrue:[

            ^ NewSystemBrowser classResources stringWithCRs:text.

        ].    

    ].

    ^ nil

! !

!SearchDialog methodsFor:'obsolete'!

addCheckBoxForClassMethodSearch

    |b|

    b := CheckBox label:(resources string:'Class Protocol').

    b model:(self searchClassProtocolHolder).

    currentPanel add:b.

    ^ b.

!

addCheckBoxForInstanceMethodSearch

    |b|

    b := CheckBox label:(resources string:'Instance Protocol').

    b model:(self searchInstanceProtocolHolder).

    currentPanel add:b.

    ^ b.

! !

!SearchDialog methodsFor:'private'!

searchClassProtocolHolder

    searchClassProtocolHolder isNil ifTrue:[

        searchClassProtocolHolder := true asValue

    ].

    ^ searchClassProtocolHolder

!

searchInstanceProtocolHolder

    searchInstanceProtocolHolder isNil ifTrue:[

        searchInstanceProtocolHolder := true asValue

    ].

    ^ searchInstanceProtocolHolder

!

showHelpOnCodePatterns

    HTMLDocumentView openFullOnHelpFile:'Browser/RBSearchPatterns.html'

!

updateListOfMatchingSelectorsFor:aPartialName

    |p|

    (p := matchProcess) notNil ifTrue:[

        p terminate.

    ].

    listHolder isNil ifTrue:[^ self].

    matchProcess := 

        [

            |what matching whatWithGLOB matchingWithGLOB|

            [

                searchWhat == #globalName ifFalse:[ 

                    what := DoWhatIMeanSupport selectorCompletion:aPartialName inEnvironment:Smalltalk match:(matchHolder value) ignoreCase:(caseHolder value not)

                ] ifTrue:[ 

                    what := DoWhatIMeanSupport globalNameCompletion:aPartialName inEnvironment:Smalltalk match:(matchHolder value).

                ].

                "/ best := what first.

                matching := what second.

                self sensor pushAction:[ listHolder contents:matching ].

"/              "/ disabled; not a good idea:

"/

"/                "/ if nothing found AND a corresponding match-searhc would find something,

"/                "/ then ADD a '*' at the end and auto-enable match-search

"/                (matching isEmptyOrNil 

"/                  and:[ aPartialName includesMatchCharacters not

"/                  and:[ matchHolder value not ]]

"/                ) ifTrue:[

"/                    searchWhat == #globalName ifFalse:[ 

"/                        whatWithGLOB := DoWhatIMeanSupport selectorCompletion:'*',aPartialName,'*' inEnvironment:Smalltalk match:true ignoreCase:(caseHolder value not)

"/                    ] ifTrue:[ 

"/                        whatWithGLOB := DoWhatIMeanSupport globalNameCompletion:'*',aPartialName,'*' inEnvironment:Smalltalk match:true.

"/                    ].

"/                    matchingWithGLOB := whatWithGLOB second.

"/                    matchingWithGLOB notEmptyOrNil ifTrue:[

"/                        self sensor pushAction:[ 

"/                            inputField contents:('*',aPartialName,'*').

"/                            selectorHolder value:('*',aPartialName,'*').

"/                            matchHolder value:true.

"/                            listHolder contents:matchingWithGLOB 

"/                        ].

"/                    ].

"/                ].

            ] ensure:[

                matchProcess := nil.

            ].

        ] fork.

    "Modified: / 26-10-2010 / 20:33:05 / cg"

! !

!SearchDialog methodsFor:'public'!

addTextEntryWithCaseIgnore:withCaseIgnore withMatch:withMatch

    |initialMatch initialCaseSensitive|

    matchHolder := caseHolder := nil.

    searchWhat == #code ifTrue:[

        self addTextEntryFieldForCode.

        ^ self.

    ].

    self addInputFieldForSelectorOrNameOrString.

    withCaseIgnore ifTrue:[

        initialCaseSensitive := false.

        (searchWhat ~~ #resource) ifTrue:[ 

            initialCaseSensitive := (LastSearchWasCaseSensitive ? false) 

        ].  

        (self 

            addCheckBox:(resources string:'Case Sensitive')

            on:(caseHolder := initialCaseSensitive asValue))

            helpKey:#caseSensitive.

    ].

    withMatch ifTrue:[

        initialMatch := true.

        (searchWhat ~~ #resource) ifTrue:[ 

            initialMatch := (LastSearchWasMatch ? true) 

        ].

        (self 

            addCheckBox:(resources string:'Match')

            on:(matchHolder := initialMatch asValue))

            helpKey:#match.

"/                (isSelector and:[ sel notNil. ]) ifTrue:[ 

"/                    sel includesMatchCharacters ifTrue:[ 

"/                        matchHolder value:false.

"/                    ].

"/                ].

    ]

    "Modified (format): / 06-07-2011 / 11:56:31 / cg"

!

askThenDo:aBlock 

    |where code sel matchHolderValue caseHolderValue|

    self beScreenDialog.                "raise it above all windows"

    self open.

    self accepted ifFalse:[ 

        ^ self.

    ].

    openHow isNil ifTrue:[ 

        openHow := defaultOpenHow.

    ].

    where := whereRadioGroup value.

    withTextEntry ifTrue:[ 

        searchWhat == #code ifTrue:[

            code := codeField contentsAsString.

            LastCodeSearched := code.

            LastCodeSearchArea := where.

        ] ifFalse:[

            (selectionList notNil and:[selectionList hasSelection]) ifTrue:[

                sel := selectionList selectionValue.

            ] ifFalse:[

                sel := selectorHolder value.

                searchWhat ~~ #string ifTrue:[

                    sel := sel withoutSeparators.

                ].

            ].

            sel isEmptyOrNil ifTrue:[ 

                browser warn:((searchWhat == #selector) 

                            ifTrue:[ 'No selector entered for search'. ]

                            ifFalse:[ 'Nothing entered for search'. ]).

                ^ self.

            ].

            sel := sel string.

            (browser ? SystemBrowser) rememberSearchPattern:sel.

            searchWhat == #globalName ifTrue:[ 

                LastGlobalSearched := sel.

            ] ifFalse:[