"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libtool' }"

"{ NameSpace: Smalltalk }"

SimpleView subclass:#InspectorView

	instanceVariableNames:'listView labelView workspace inspectedObject selectedLine nShown

		hasMore monitorProcess hideReceiver integerDisplayRadix

		inspectHistory allowFollow isStandaloneInspector selectionIndex

		object inspectedObjectHolder displayStringMessage

		suppressPseudoSlots dereferenceValueHolders suppressHeadline

		headLineLabel sortOrder hideMessages hideHashes

		holderChangeInterest sortOrderHolder maxValueDisplayStringLength'

	classVariableNames:'DefaultIcon DefaultIntegerDisplayRadix ExpandArraysInAllLists

		IdDictionary LastExtent NextSequentialID SortOrderAlphabetical

		SortOrderInstvarOrder DefaultHideMessages DefaultHideHashes

		NoLongerPresentDummyObject DefaultMaxValueDisplayStringLength'

	poolDictionaries:''

	category:'Interface-Inspector'

!

!InspectorView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class implements a graphical inspector.

    Inspecting can be done on an object -

    (where its instvarnames/values are inspected)

    or a list of objects (where a nameArray/valuesArray is inspected).

    The later is used by the debugger to inspect method variables/args.

    The system calls the inspector through the global variable 'Inspector'

    which is bound to this class (but could be redefined - it actually is

    set to MiniInspector in a smalltalk without graphical user interface,

    or to NewInspector if that is wanted).

    Also notice, that there are two methods to inspect an object:

    sending #basicInspect to any object, will open this kind of inspector on 

    it (showing instance variables which are physically present).

    Sending it #inspect, will - depending on the object - sometimes invoke a

    specialized inspector. 

    (see OrderedCollectionInspectorView, ImageInspectorView, 

     ColorInspectorView etc. as examples).

    You can also open a monitoring inspector, which displays some instance

    variable in regular intervals. See #openOn:monitor:.

    examples:

            #(1 2 3 4) asOrderedCollection inspect

            #(1 2 3 4) asOrderedCollection basicInspect

            (Array new:10000) inspect

            (Image fromFile:'bitmaps/claus.gif') inspect

            (Image fromFile:'bitmaps/claus.gif') basicInspect

            (Image fromFile:'bitmaps/SBrowser.xbm') inspect

            (Image fromFile:'bitmaps/SBrowser.xbm') basicInspect

            InspectorView openOn:Display

            InspectorView openOn:Display monitor:'shiftDown'

            InspectorView openOn:(Image fromScreen)

            InspectorView openOn:(Image fromFile:'banner8.xpm')

    The InspectorView can also be used as a subComponent within another view.

    In this case, the isStandAlone flag should be cleared, to prevent the

    inspector from changing the topViews window label.

    Notice:

        the instvars 'inspectedObject' and 'selectedLine' have been 

        renamed to 'object' and 'selectionIndex' for squeak compatibility;

        however, the old vars are kept (in sync) for a while, to allow for

        smooth migration.

  Controlling the contents from the inspected object.

    By redefining inspectorExtraAttributes or inspectorExtraNamedFields, the inspected

    object can add items to the list of fields as ashown in the left list-view of the inspector.

    These methods are meant to return a sequencable Collection of Associations, which represent

    of pseudo slot-name, slot-value pairs.

    In the list, extra attributes are shown with a dash (-), extra named fields are marked with a tick (`).

    These are added (read only) to the list.

    [author:]

        Claus Gittinger

"

! !

!InspectorView class methodsFor:'initialization'!

initialize

    SortOrderAlphabetical := #alphabetical.

    SortOrderInstvarOrder := #instvarOrder.

    NoLongerPresentDummyObject := Object new.

! !

!InspectorView class methodsFor:'instance creation'!

for:anObject

    "create and launch a new inspector for anObject.

     This protocol is a historic leftover - this method will vanish."

    ^ self openOn:anObject

!

inspect:anObject

    "create and launch a new inspector for anObject.

     This protocol is a historic leftover - this method will vanish."

    ^ self openOn:anObject

!

openOn:anObject

    "create and launch a new inspector for anObject"

    ^ self openOn:anObject monitor:nil

    "

     InspectorView openOn:(5 @ 7)

     InspectorView openOn:(Array new:400)

     DictionaryInspectorView openOn:(IdentityDictionary new)

    "

    "Modified: 1.3.1996 / 19:31:03 / cg"

!

openOn:anObject monitor:anInstVarNameOrNil

    "create and launch a new inspector for anObject.

     If anInstVarNameOrNil is nonNil, let the inspector monitor it

     (use an integer-printString as name, for indexed instVars)."

    |topView inspectorView|

    topView := StandardSystemView new.

    topView

        icon:self defaultIcon;

        label:'Inspector';

        iconLabel:'Inspector';  

        extent:self defaultTopViewExtent;

        objectAttributeAt:#rememberExtent put:true.

    inspectorView := self origin:(0.0 @ 0.0)

                          corner:(1.0 @ 1.0)

                             in:topView.

    "kludge: must realize first, to be able to set menu again"

    topView openAndWait.

    topView windowGroup 

        focusSequence:(Array 

                            with:inspectorView listView

                            with:inspectorView workspace).

    inspectorView 

        allowFollow:true;

        isStandaloneInspector:true;

        inspect:anObject.

    anInstVarNameOrNil notNil ifTrue:[

        inspectorView monitor:anInstVarNameOrNil

    ].

    ^ inspectorView

    "

     |m|

     m := 1 asValue.

     InspectorView openOn:m monitor:'value'.

     2 to:10 do:[:i |

         Delay waitForSeconds:1.

         m value:i

     ]

    "

    "

     |o|

     o := Array with:1 with:2 with:3.

     InspectorView openOn:o monitor:'2'.

     Delay waitForSeconds:1.

     o at:2 put:20

    "

    "Created: / 01-03-1996 / 19:30:50 / cg"

    "Modified: / 23-10-2007 / 19:08:21 / cg"

!

openOn:anObject title:aString

    "create and launch a new inspector for anObject"

    (self openOn:anObject monitor:nil) topView label:aString

    "

     InspectorView openOn:(5 @ 7) title:'my point'

    "

!

openOn:anObject withEvalPane:withEvalPane

    ^ self openOn:anObject

!

openOn:anObject withEvalPane:withEvalPane withLabel:aLabel

    ^ self openOn:anObject

! !

!InspectorView class methodsFor:'common label support'!

commonLabelFor:anObject

    "return the windowLabel to use in my topView, when inspecting anObject.

     Identical objects are labelled with the same id, which makes it easy to

     see if two objects are identical (and is very useful, indeed).

     WARNING: used by both Inspector and Inspector2 !!!!!!"

    |lbl id|

    (anObject isProtoObject not and:[anObject isImmediate or:[anObject isBoolean]]) ifTrue:[

        ^ self labelNameFor:anObject.

    ].

    lbl := '<%1> %2'.

    IdDictionary isNil ifTrue:[

        IdDictionary := WeakIdentityDictionary new.

    ].

    "/ get or assign a new id

    [    

        id := IdDictionary 

                    at:anObject 

                    ifAbsentPut:[ 

                        |nextID|

                        nextID := NextSequentialID ? 0.

                        NextSequentialID := nextID + 1.

                        nextID

                    ].

    ] valueUninterruptably.

    ^ self classResources 

        string:lbl 

        with:id

        with:(self labelNameFor:anObject)

    "Created: / 15-07-2011 / 16:21:44 / cg"

!

labelNameFor:anObject

    "return the iconLabel to use in my topView, when inspecting anObject.

     Simply returns the className or name of anObjects class"

    |s|

    anObject isProtoObject ifTrue:[

        ^ anObject class nameWithArticle.

    ].

    anObject isClass ifTrue:[

        s := anObject displayString

    ] ifFalse:[

        (anObject isImmediate

         or:[anObject isBoolean]) ifTrue:[

            s := anObject printString , ', ' , anObject classNameWithArticle

        ] ifFalse:[

            s := anObject classNameWithArticle

        ].

    ].

    s isNil ifTrue:[

        anObject isBehavior ifTrue:[

            ^ 'someBehavior'

        ].

        ^ 'something'

    ].

    ^ s

    "Created: / 15-07-2011 / 16:20:06 / cg"

    "Modified: / 29-11-2017 / 10:22:15 / stefan"

! !

!InspectorView class methodsFor:'defaults'!

defaultExtent

    "return the default extent of my instances.

     The value returned here is usually ignored, and

     the value from preferredExtent taken instead."

     |display|

    display := Screen current.

    ^ (display monitorBoundsAt:display pointerPosition) extent // 3.

    "Created: / 7.9.1998 / 13:47:45 / cg"

    "Modified: / 7.9.1998 / 14:15:38 / cg"

!

defaultHideHashes

    ^ DefaultHideHashes? true

!

defaultHideHashes:aBoolean

    DefaultHideHashes := aBoolean

!

defaultHideMessages

    ^ DefaultHideMessages ? true

!

defaultHideMessages:aBoolean

    DefaultHideMessages := aBoolean

!

defaultIcon

    "return the browsers default window icon"

    <resource: #programImage>

    <resource: #style (#INSPECTOR_ICON #INSPECTOR_ICON_FILE)>

    |nm i resources|

    (i := DefaultIcon) isNil ifTrue:[

        resources := self classResources.

        i := resources at:#INSPECTOR_ICON default:nil.

        i isNil ifTrue:[

            nm := resources at:#INSPECTOR_ICON_FILE default:'Inspector.xbm'.

            i := Smalltalk imageFromFileNamed:nm forClass:self.

            i isNil ifTrue:[

                i := StandardSystemView defaultIcon

            ]

        ].

        i notNil ifTrue:[

            DefaultIcon := i := i onDevice:Display

        ]

    ].

    ^ i

    "

       DefaultIcon := nil

    "

    "Modified: / 17-09-2007 / 11:36:17 / cg"

!

defaultIntegerDisplayRadix

    ^ DefaultIntegerDisplayRadix ? 10

    "Created: / 10-02-2012 / 19:51:38 / cg"

!

defaultMaxValueDisplayStringLength

    "cut off and show '...' if longer"

    ^ DefaultMaxValueDisplayStringLength ? 100000

!

defaultMaxValueDisplayStringLength:anIntegerOrNilForDefault

    "cut off and show '...' if longer"

    DefaultMaxValueDisplayStringLength := anIntegerOrNilForDefault

!

defaultSortOrder

    ^ SortOrderInstvarOrder

!

defaultTopViewExtent

    |def|

    def := LastExtent ? self defaultExtent.

    ^ def min:(Screen current usableExtent)

    "Created: / 23-10-2007 / 19:04:13 / cg"

!

expandArraysInAllLists

    "in the 'all instvars' list, expand arrays"

    ^ ExpandArraysInAllLists ? false

    "Created: / 30-01-2012 / 16:52:57 / cg"

!

expandArraysInAllLists:aBoolean

    "in the 'all instvars' list, expand arrays"

    ExpandArraysInAllLists := aBoolean

    "Created: / 30-01-2012 / 16:53:01 / cg"

!

rememberLastExtent:anExtent

    LastExtent := anExtent

    "Created: / 23-10-2007 / 19:10:02 / cg"

!

sortOrderAlphabetical

    ^ SortOrderAlphabetical

!

sortOrderInstvarOrder

    ^ SortOrderInstvarOrder

! !

!InspectorView class methodsFor:'image specs'!

imageFor_arrays

    "This resource specification was automatically generated

     by the ImageEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the ImageEditor may not be able to read the specification."

    "

     self imageFor_arrays inspect

     ImageEditor openOnClass:self andSelector:#imageFor_arrays

     Icon flushCachedIcons

    "

    <resource: #image>

    ^Icon

        constantNamed:'InspectorView class imageFor_arrays'

        ifAbsentPut:[(Depth4Image width:16 height:16) bits:(ByteArray fromPackedString:'

H"H"H"H"H"H"H"H"H"H"H"H"H"H"H"H"H"H&*H)"H"H"H!! 3@0D"H"H!! C@8PAH"H"(@@@!!@\"H"JC@0!!DARH"H(@@@D\EH"H")@PD]P\"H"HTQ@U[BRH"H"

EUTKBRH"H"H!!]U^RH"H"H"H"H"H"H"H"H"H"H"H"H"H"H"H"H"Hb')

            colorMapFromArray:#[255 255 255 218 112 214 226 226 226 255 0 255 199 21 133 115 16 49 198 123 148 140 49 74 208 32 144 156 74 99 186 85 211 90 0 33]

            mask:((ImageMask width:16 height:16) bits:(ByteArray fromPackedString:'@@@@@@@@A>@O<A?8G? _>A?8G? _>@?0A>@@@@@@@@@b'); yourself); yourself]

!

imageFor_characters

    <resource: #image>

    "This resource specification was automatically generated

     by the ImageEditor of ST/X."

    "Do not manually edit this!! If it is corrupted,

     the ImageEditor may not be able to read the specification."

    "

     self imageFor_characters inspect

     ImageEditor openOnClass:self andSelector:#imageFor_characters

     Icon flushCachedIcons"

    ^ Icon constantNamed:'InspectorView class imageFor_characters'

        ifAbsentPut:[

            (Depth8Image new)

                width:16;

                height:16;

                photometric:(#palette);

                bitsPerSample:(#[ 8 ]);

                samplesPerPixel:(1);

                bits:(ByteArray 

                            fromPackedString:'

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@6LD5MLCX@@@@@@@@@@@ADRTDIOC-FQ@@@@@@@@@A@MP$IBP$I

Q$U@@@@@@@@@L@%SOP%HRP$>M@@@@@@@@D4<BP$IS#MEP4H@@@@@@@AMNUP9BP$IP3)B@@@@@@@@L@$3R0%EP0%GLP@@@@@@@D@>BP$IBP%RQ2<@@@@@@@@@

K$1LBT]GQ3<@@@@@@@@@@@A@LTIBLR<@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@a');

                colorMapFromArray:#[ 226 226 226 176 176 176 155 155 155 169 169 169 152 152 152 164 164 164 149 149 149 192 192 192 240 240 240 255 255 255 202 202 202 201 201 201 151 151 151 162 162 162 148 148 148 158 158 158 173 173 173 154 154 154 167 167 167 150 150 150 160 160 160 180 180 180 156 156 156 170 170 170 153 153 153 165 165 165 183 183 183 0 0 0 227 231 0 132 132 0 151 156 0 142 131 128 255 252 49 175 181 0 255 234 140 218 222 0 251 255 33 74 74 0 94 99 0 107 107 0 143 148 0 189 189 0 87 90 0 251 255 8 247 255 16 167 173 0 206 99 132 156 74 99 206 66 107 115 16 49 255 16 90 189 0 57 132 16 49 206 0 57 198 123 140 255 49 123 255 33 99 222 0 66 99 0 24 239 0 66 255 0 74 255 140 214 148 0 41 140 49 74 198 123 148 255 0 82 90 0 24 132 0 41 206 99 123 156 0 41 198 0 57 74 0 24 255 16 82 214 0 66 90 0 33 189 0 49 107 0 33 206 16 74 214 8 66 173 0 49 115 0 33 181 0 49 74 0 16 255 8 82 231 0 66 ];

                mask:((ImageMask new)

                            width:16;

                            height:16;

                            bits:(ByteArray 

                                        fromPackedString:'@@@@@@@@A>@O<A?8G? _>A?8G? _>@?0A>@@@@@@@@@b');

                            yourself);

                yourself

        ]

!

imageFor_classes