"
 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague
              All Rights Reserved

Permission is hereby granted, free of charge, to any person
obtaining a copy of this software and associated documentation
files (the 'Software'), to deal in the Software without
restriction, including without limitation the rights to use,
copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the
Software is furnished to do so, subject to the following
conditions:

The above copyright notice and this permission notice shall be
included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
OTHER DEALINGS IN THE SOFTWARE.
"
"{ Package: 'stx:libtool' }"

"{ NameSpace: Tools }"

CodeViewService subclass:#CodeNavigationService
	instanceVariableNames:'selectorEmphasis variableEmphasis currentEmphasis
		currentEmphasisForAssign linesToRedraw menuShown
		assignmentEmphasis'
	classVariableNames:'DefaultVariableEmphasis DefaultSelectorEmphasis
		DefaultAssignmentEmphasis'
	poolDictionaries:''
	category:'Interface-CodeView'
!

!CodeNavigationService class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 2010 by Jan Vrany, SWING Research Group. CTU in Prague
              All Rights Reserved

Permission is hereby granted, free of charge, to any person
obtaining a copy of this software and associated documentation
files (the 'Software'), to deal in the Software without
restriction, including without limitation the rights to use,
copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the
Software is furnished to do so, subject to the following
conditions:

The above copyright notice and this permission notice shall be
included in all copies or substantial portions of the Software.

THE SOFTWARE IS PROVIDED 'AS IS', WITHOUT WARRANTY OF ANY KIND,
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
OTHER DEALINGS IN THE SOFTWARE.
"
! !

!CodeNavigationService class methodsFor:'accessing'!

label
    "Answers a short label - for UI"

    ^'Semi-modal Code Navigation'

    "Created: / 07-03-2010 / 14:00:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

requiredServices

    ^#(#'Tools::CodeHighlightingService')

    "Created: / 27-07-2011 / 11:40:56 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!CodeNavigationService class methodsFor:'accessing - defaults'!

defaultAssignmentEmphasis
    "must only define a background - otherwise, syntax highlight fg is lost"

    DefaultAssignmentEmphasis isNil ifTrue:[
        ^ Array with:(#backgroundColor -> (UserPreferences current assignmentBackgroundColorForNavigationService))
    ].
    ^ DefaultAssignmentEmphasis
!

defaultSelectorEmphasis
    "must only define a background - otherwise, syntax highlight fg is lost"

    DefaultSelectorEmphasis isNil ifTrue:[
        ^ Array with:(#backgroundColor -> (UserPreferences current selectorBackgroundColorForNavigationService))
    ].
    ^ DefaultSelectorEmphasis

    "Modified: / 21-08-2011 / 09:58:18 / cg"
!

defaultVariableEmphasis
    "must only define a background - otherwise, syntax highlight fg is lost"

    DefaultVariableEmphasis isNil ifTrue:[
        ^ Array with:(#backgroundColor -> (UserPreferences current variableBackgroundColorForNavigationService))
    ].
    ^ DefaultVariableEmphasis

    "Created: / 25-06-2010 / 13:56:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 11:04:20 / cg"
! !

!CodeNavigationService methodsFor:'change & update'!

update: aspect with: param from: sender
    sender == textView modifiedChannel ifTrue:[
        codeView reallyModified ifTrue:[
            "/ no longer highlight - the info is wrong anyway !!
            self highlightClear.
        ].
    ].

    "JV: I changed 'halt' to 'breakPoint: #cg'"

    "Created: / 22-08-2011 / 16:22:19 / cg"
    "Modified: / 25-08-2011 / 15:10:28 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 05-09-2011 / 05:15:42 / cg"
! !

!CodeNavigationService methodsFor:'code services'!

browseClass:class 
    self browser isNil ifTrue:[ ^ NewSystemBrowser browseClass:class ].
    (UserPreferences current alwaysOpenNewTabWhenCtrlClick 
        or:[ self browser navigationState modified ]) 
            ifTrue:[
                self browser 
                    spawnFullBrowserInClass:class
                    selector:nil
                    in:#newBuffer
            ]
            ifFalse:[ self browser switchToClass:class ]

    "Created: / 15-02-2010 / 09:36:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 25-07-2010 / 11:00:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 10:07:30 / cg"
!

browser

    ^codeView browserHolder value

    "Created: / 06-03-2010 / 21:14:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!CodeNavigationService methodsFor:'event handling'!

button1Press
    |element|

    (element := codeView syntaxElementSelection) notNil ifTrue:[
        element type == #selector ifTrue:[self button1PressForSelector: element value. ^true].
        element type == #class    ifTrue:[self browseClass:element value. ^true].
    ].
    ^ false

    "Created: / 14-02-2010 / 18:43:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 06-03-2010 / 21:11:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 18-11-2011 / 14:58:02 / cg"
!

button1PressForSelector: selector
    | impls |

    impls := codeView implementorsOf: selector.
    "/ impls size = 1 ifTrue:[^codeView browseMethod: impls anyOne].
    [
        menuShown := codeView implementorsMenu: impls selector: selector.
        self highlightClear.
        menuShown showAtPointer.
    ] ensure:[
        menuShown := nil
    ].

    "Created: / 14-02-2010 / 18:50:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 30-06-2011 / 19:34:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 07-07-2011 / 17:16:23 / jv"
    "Modified: / 21-08-2011 / 11:06:08 / cg"
!

button2Press
    | element |

    (element := codeView syntaxElementSelection) notNil ifTrue:[
        element type == #selector ifTrue:[self button2PressForSelector: element value. ^ true].
    ].
    ^ false

    "Created: / 14-02-2010 / 18:43:04 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 17-06-2011 / 08:58:34 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

button2PressForSelector: selector
    | senders |

    senders := codeView sendersOf: selector.
    "/ senders size = 1 ifTrue:[ codeView browseMethod: senders anyOne. ^ self].
    [
        menuShown := codeView sendersMenu: senders selector: selector.
        self highlightClear.
        menuShown showAtPointer.
    ] ensure:[
        menuShown := nil.
    ].

    "Created: / 14-02-2010 / 18:50:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 30-06-2011 / 19:34:43 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 11:34:49 / cg"
!

buttonMotion:button x:x y:y in:view 
    "Handles an event in given view (a subview of codeView).
     If the method returns true, the event will not be processed
     by the view."
    
    (view == textView and:[ textView sensor metaDown ]) ifTrue:[
        self highlightElementAtX:x y:y.
        ^ true
    ].
    ^ false

    "Created: / 06-03-2010 / 20:40:37 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified (format): / 21-08-2011 / 10:07:15 / cg"
!

buttonPress: button x:x y:y in: view

    "Handles an event in given view (a subview of codeView).
     If the method returns true, the event will not be processed
     by the view."

    (view == textView) ifTrue:[
        textView isQuickMenuModifierPressed ifTrue:[
            button == 1      ifTrue: [^self button1Press].
            button == #paste ifTrue: [^self button2Press].   
            button == 2      ifTrue: [^self button2Press]
        ] ifFalse:[
            button == 1 ifTrue:[
                self highlightVariableAtX:x y:y.
            ]
        ]
    ].
    ^false

    "Created: / 06-03-2010 / 21:12:26 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 25-06-2010 / 14:53:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified (format): / 21-08-2011 / 10:06:54 / cg"
!

buttonRelease: button x:x y:y in: view
    "Handles an event in given view (a subview of codeView).
     If the method returns true, the event will not be processed
     by the view."

    "/ if I show a quick senders/implementors menu, eat this event
    ^ menuShown notNil
!

isQuickMenuModifierPressed
    |sensor|

    sensor := textView sensor.
    UserPreferences current codeView2QuickSendersAndImplementorsOnControl ifTrue:[
        ^ sensor ctrlDown
    ].
    ^ sensor metaDown
!

isQuickMenuModifierReleased
    |sensor|

    sensor := textView sensor.
    UserPreferences current codeView2QuickSendersAndImplementorsOnControl ifTrue:[
        ^ sensor ctrlDown not
    ].
    ^ sensor metaDown not
!

keyPress:key x:x y:y in:view 
    "Handles an event in given view (a subview of codeView).
     If the method returns true, it has eaten the event and it will not be processed
     by the view."

    <resource: #keyboard (#Control_L #Ctrl 
                          #CursorRight #CursorDown #CursorLeft #CursorUp)>

    |ev p|

    (view == textView) ifTrue:[
        "/ ("ctrlDown" "key == #'Control_L' or:[ key == #Ctrl ]") ifTrue:[
        (textView isQuickMenuModifierPressed) ifTrue:[
            "/ because it is delegated, the position is not correct
            ev := WindowGroup lastEventQuerySignal query.
            p := view device translatePoint:(ev x @ ev y) fromView:ev view toView:view.
            view sensor 
                pushUserEvent:#highlightElementAtX:y: 
                for: self 
                withArguments:{p x. p y.}.
            ^ false "/ true. -- no, dont eat the key
        ].

"/        codeView reallyModified "textView modified" ifTrue:[
"/            self highlightClear. 
"/            codeView syntaxElements: nil.
"/            ^ false
"/        ].

        view sensor metaDown ifTrue:[
            (key == #CursorRight or:[key == #CursorDown]) ifTrue:[
                view sensor pushUserEvent:#findNextVariableFromCursor for:self.
            ] ifFalse:[(key == #CursorLeft or:[key == #CursorUp]) ifTrue:[
                view sensor pushUserEvent:#findPreviousVariableFromCursor for:self.
            ]].
        ] ifFalse:[
            (key == #CursorRight
              or:[key == #CursorDown
              or:[key == #CursorLeft
              or:[key == #CursorUp]]]
            ) ifTrue:[
                view sensor pushUserEvent:#highlightVariableAtCursor for:self .
            ] ifFalse:[
                view sensor pushUserEvent:#highlightClear for:self .
            ]
        ]
    ].
    ^ false

    "Created: / 06-03-2010 / 20:50:45 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 05-09-2011 / 05:17:30 / cg"
    "Modified: / 27-09-2011 / 19:24:13 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

keyRelease: key x:x y:y in: view
    "Handles an event in given view (a subview of codeView).
     If the method returns true, it has eaten the event and it will not be processed
     by the view."

    |ev p|

    (view == textView and:[textView isQuickMenuModifierReleased]) ifTrue:[
        "/    (view == textView and:[key == #'Control_L' or:[key == #Ctrl]]) ifTrue:[
        "/ because it is delegated, the position is not correct
        ev := WindowGroup lastEventQuerySignal query.
        p := view device translatePoint:(ev x @ ev y) fromView:ev view toView:view.
 "/       self highlightClear. 
"/        view sensor pushUserEvent:#highlightClear for:self. 
        ^ false "/ true -- do not eat the event
    ].
    ^ false

    "Created: / 06-03-2010 / 21:03:59 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 11:32:40 / cg"
!

linesDeletedFrom: start to: end

    self highlightClear

    "Created: / 06-07-2011 / 17:14:36 / jv"
    "Created: / 16-09-2011 / 15:39:33 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

linesInsertedFrom: start to: end

    self highlightClear

    "Created: / 06-07-2011 / 17:14:36 / jv"
    "Created: / 16-09-2011 / 15:39:30 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

linesModifiedFrom: start to: end

    self highlightClear

    "Created: / 06-07-2011 / 17:14:36 / jv"
    "Created: / 16-09-2011 / 15:19:52 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!CodeNavigationService methodsFor:'initialization'!

initialize

    super initialize.

    "the following must only define a background - otherwise, syntax highlight fg is lost"
    selectorEmphasis := self class defaultSelectorEmphasis.
    variableEmphasis := self class defaultVariableEmphasis.
    assignmentEmphasis := self class defaultAssignmentEmphasis.
    linesToRedraw := OrderedCollection new.

    "Created: / 25-06-2010 / 14:05:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!CodeNavigationService methodsFor:'misc'!

highlightInstanceVariable:name
    |element|

    element := (codeView syntaxElements ? #()) 
                    detect:[:e |     
                        e isVariable
                        and:[ e isInstanceVariable
                        and:[ e name = name ]]
                    ] ifNone:nil.

    self highlightClear.
    codeView syntaxElementSelection:nil.
    self highlightVariable:element.
! !

!CodeNavigationService methodsFor:'private'!

elementAtCursor
    ^self elementAtLine: textView cursorLine col: textView cursorCol - 1

    "Created: / 25-06-2010 / 14:39:14 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

elementAtLine:line col:colArg 
    |characterPosition syntaxElements index element col|

    "/ if beyond end of line, do not advance into next line
    col := colArg min:(textView listAt:line) size.

    characterPosition := textView characterPositionOfLine:line col:col.
    syntaxElements := codeView syntaxElements.
    syntaxElements isEmptyOrNil ifTrue:[
        ^ nil.
    ].
    0"1" to:0 by:-1 do:[:d |
        index := (syntaxElements indexForInserting:characterPosition) - d.
        index > syntaxElements size ifTrue:[^nil].
        element := syntaxElements at:index ifAbsent:nil.
        element notNil ifTrue:[
            (characterPosition between: element start - 1 and: element stop) ifTrue:[^element].
        ].
    ].
    ^nil

    "Created: / 25-06-2010 / 14:40:03 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 11:03:29 / cg"
    "Modified: / 16-09-2011 / 17:04:06 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

elementAtX:x y:y 
    |visibleLine line col|

    codeView syntaxElements isNil ifTrue:[^nil].

    visibleLine := textView visibleLineOfY:y.
    col := textView colOfX:x inVisibleLine:visibleLine.
    line := textView visibleLineToAbsoluteLine:visibleLine.
    ^self elementAtLine:line col:col

    "Created: / 25-06-2010 / 14:52:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 01-08-2010 / 08:50:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 10:26:08 / cg"
!

foo
|characterPosition index element |

characterPosition := 1

    "Created: / 21-08-2011 / 10:48:05 / cg"
!

highlighEmphasisFor: element

    element isNil ifTrue:[^nil].

    element isSelector ifTrue:[^selectorEmphasis].
    element isVariable ifTrue:[^variableEmphasis].
    element isSelf     ifTrue:[^variableEmphasis].

    ^nil

    "Created: / 25-06-2010 / 13:54:42 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 18-11-2011 / 14:58:05 / cg"
!

highlightClear

    ^self highlightClear: true.

    "Modified: / 26-12-2007 / 12:28:05 / janfrog"
    "Created: / 25-06-2010 / 14:15:58 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 08-07-2011 / 08:50:45 / cg"
    "Modified: / 20-07-2011 / 18:52:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

highlightClear: redraw

    codeView syntaxElementSelection == nil ifTrue:[ ^ self ].

    textView list isNil ifTrue:[ ^ self ].
    textView list withIndexDo:[:line :lineNo | 
        line isText ifTrue:[ 
            (line hasEmphasis: currentEmphasis) ifTrue:[
                line emphasisAllRemove:currentEmphasis.
                linesToRedraw add: lineNo.
            ] ifFalse:[
                (currentEmphasisForAssign notNil and:[line hasEmphasis: currentEmphasisForAssign]) ifTrue:[
                    line emphasisAllRemove:currentEmphasisForAssign.
                    linesToRedraw add: lineNo.
                ]
            ]
        ] 
    ].
    codeView syntaxElementSelection:nil.

    redraw ifTrue:[self redrawLines].

    "Modified: / 26-12-2007 / 12:28:05 / janfrog"
    "Created: / 20-07-2011 / 18:52:19 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 18-11-2011 / 14:58:08 / cg"
!

highlightElement:element 
    |e savedEmphasis currentSelection|

    (currentSelection := codeView syntaxElementSelection) == element ifTrue:[ ^ self ]. "/ no change
    currentSelection notNil ifTrue:[
        self highlightClear: false.
    ].

    currentEmphasis := savedEmphasis := self highlighEmphasisFor:element.
    currentEmphasisForAssign := nil.

    element notNil ifTrue:[ 
        codeView syntaxElementSelection:element.
        e := element firstElementInChain.
        [ e notNil ] whileTrue:[ 
            e assigned ifTrue:[
                [
                    currentEmphasis := currentEmphasisForAssign := assignmentEmphasis.
                    self highlightWithoutClearFrom:e start to:e stop.
                ] ensure:[
                    currentEmphasis := savedEmphasis.
                ].
            ] ifFalse:[
                self highlightWithoutClearFrom:e start to:e stop.
            ].
            e := e nextElement 
        ].
    ].
    self redrawLines.

    "Created: / 14-02-2010 / 16:18:36 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 20-07-2011 / 18:52:46 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 10:22:58 / cg"
!

highlightElementAtCursor
    self highlightElementAtLine: textView cursorLine col: textView cursorCol

    "Created: / 14-02-2010 / 16:17:40 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 06-03-2010 / 19:59:18 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

highlightElementAtLine:line col:col 
    |characterPosition syntaxElements index element|

    characterPosition := textView characterPositionOfLine:line col:col.
    syntaxElements := codeView syntaxElements.
    syntaxElements isEmptyOrNil ifTrue:[self highlightElement:nil. ^ self].
    index := syntaxElements indexForInserting:characterPosition.
    index > syntaxElements size ifTrue:[self highlightElement:nil. ^ self].
    element := syntaxElements at:index.
    (characterPosition between: element start and: element stop) ifFalse:[element := nil].
    self highlightElement:element

    "Created: / 14-02-2010 / 16:17:22 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 01-08-2010 / 08:50:11 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

highlightElementAtX:x y:y 
    |visibleLine line col|

    codeView syntaxElements isNil ifTrue:[^self].
    visibleLine := textView visibleLineOfY:y.
    col := textView colOfX:x inVisibleLine:visibleLine.
    line := textView visibleLineToAbsoluteLine:visibleLine.
    self highlightElementAtLine:line col:col

    "Created: / 14-02-2010 / 16:12:50 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 06-03-2010 / 20:06:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 10:22:10 / cg"
!

highlightElementOrNil:e
    e notNil ifTrue:[
        "/ cg: only if selected !!
        "/ self halt.
        self highlightElement:e.
    ] ifFalse:[
        self highlightClear
    ].

    "Created: / 25-06-2010 / 14:52:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Created: / 21-08-2011 / 09:56:39 / cg"
!

highlightLine:lineNo fromLine:startLine col:endLine toLine:startCol col:endCol
    |line start end|

    (lineNo between:startLine and:endLine) ifFalse:[ ^ self ].

    line := textView listAt:lineNo.
    line isEmpty ifTrue:[^self].
    start := (lineNo = startLine) 
                ifTrue:[ startCol  ] 
                ifFalse:[ line indexOfNonSeparator ].
    end := (lineNo = endLine) 
                ifTrue:[ endCol ] 
                ifFalse:[ line size ].
    line    
        emphasisFrom:(start max: 1)
        to:(end min: line size)
        add: currentEmphasis.

    linesToRedraw add: lineNo.

    "Created: / 25-06-2010 / 14:15:39 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 08-07-2011 / 13:02:51 / cg"
    "Modified: / 20-07-2011 / 18:43:57 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

highlightVariable:element 
    (element notNil and:[ element isVariableOrSelf ]) ifTrue:[
        self highlightElement:element.
    ] ifFalse:[
        self highlightClear.
    ].

    "Modified: / 20-07-2011 / 18:54:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 09:39:42 / cg"
!

highlightVariableAtCursor
    self highlightElementOrNil:(self elementAtCursor)

    "Modified: / 25-06-2010 / 14:53:17 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 09:56:56 / cg"
!

highlightVariableAtX:x y:y 
    self highlightElementOrNil:(self elementAtX:x y:y).

    "Created: / 25-06-2010 / 14:52:09 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified: / 21-08-2011 / 10:24:50 / cg"
!

highlightWithoutClearFrom: start to: end
    "Remove underlined emphasis"

    |startLine startCol endLine endCol|

    startLine := textView lineOfCharacterPosition:start.
    startCol := start - (textView characterPositionOfLine:startLine col:1) + 1.
    endLine := textView lineOfCharacterPosition:end.
    endCol := end - (textView characterPositionOfLine:endLine col:1) + 1.
    self highlightWithoutClearFromLine: startLine col: startCol toLine: endLine col: endCol

    "Created: / 25-06-2010 / 14:15:21 / Jan Vrany <jan.vrany@fit.cvut.cz>"
!

highlightWithoutClearFromLine: startLine col: startCol toLine: endLine col: endCol 

    textView list keysAndValuesDo: [:lineNo :line|
        line isText ifTrue: [
            self highlightLine: lineNo fromLine: startLine col: endLine toLine: startCol col: endCol
        ]
    ].

    "Created: / 25-06-2010 / 14:15:08 / Jan Vrany <jan.vrany@fit.cvut.cz>"
! !

!CodeNavigationService methodsFor:'redrawing'!

redrawLines
    linesToRedraw do:[:lineNo|
        textView invalidateLine: lineNo.
    ].
    linesToRedraw := OrderedCollection new

    "Created: / 20-07-2011 / 18:45:38 / Jan Vrany <jan.vrany@fit.cvut.cz>"
    "Modified (format): / 18-08-2011 / 16:01:34 / cg"
! !

!CodeNavigationService class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libtool/Tools__CodeNavigationService.st,v 1.30 2013-07-04 19:28:51 cg Exp $'
!

version_CVS
    ^ '$Header: /cvs/stx/stx/libtool/Tools__CodeNavigationService.st,v 1.30 2013-07-04 19:28:51 cg Exp $'
!

version_SVN
    ^ '$Id: Tools__CodeNavigationService.st,v 1.30 2013-07-04 19:28:51 cg Exp $'
! !