"
 COPYRIGHT (c) 1993 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

InspectorView subclass:#DictionaryInspectorView
	 instanceVariableNames:'keys'
	 classVariableNames:''
	 poolDictionaries:''
	 category:'Interface-Inspector'
!

DictionaryInspectorView comment:'
COPYRIGHT (c) 1993 by Claus Gittinger
	      All Rights Reserved

$Header: /cvs/stx/stx/libtool/Attic/DictInspV.st,v 1.14 1995-08-10 13:14:00 claus Exp $
'!

!DictionaryInspectorView class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1993 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

version
"
$Header: /cvs/stx/stx/libtool/Attic/DictInspV.st,v 1.14 1995-08-10 13:14:00 claus Exp $
$Revision: 1.14 $
"
!

documentation
"
    a modified Inspector for Dictionaries
"
! !

!DictionaryInspectorView methodsFor:'user interaction'!

doAccept:theText
    "accept value for selected item"

    |value|

    value := Compiler evaluate:theText receiver:inspectedObject notifying:workspace.

    selectedLine notNil ifTrue:[
	selectedLine == 1 ifFalse:[
	    inspectedObject at:(keys at:selectedLine - 1) put:value.
	    inspectedObject changed
	].
    ]
!

valueAtLine:lineNr
    "helper - return the value of the selected entry"

    |key|

    lineNr == 1 ifTrue:[
	^ inspectedObject
    ].
    key := (keys at:lineNr - 1).
    ^ inspectedObject at:key.
!

doInspectKey
    "inspect selected items key"

    selectedLine notNil ifTrue:[
	selectedLine ~~ 1 ifTrue:[
	    (keys at:selectedLine - 1) inspect
	].
    ]
!

doAddKey
    "add a key"

    |keyName key|

    keyName := Dialog request:'key to add:' initialAnswer:''.
    keyName notEmpty ifTrue:[
	key := keyName asSymbol.
	(inspectedObject includesKey:key) ifFalse:[
	    inspectedObject at:key put:nil.
	    selectedLine := nil.
	    inspectedObject changed.
	    self inspect:inspectedObject. "force list update"
	]
    ]
!

doRemoveKey
    "remove selected item from keys"

    |key|

    selectedLine == 1 ifFalse:[
	key := (keys at:selectedLine - 1).
	(inspectedObject includesKey:key) ifTrue:[
	    listView cursor:(Cursor wait).
	    inspectedObject removeKey:key.
	    keys := nil.
	    selectedLine := nil.
	    inspectedObject changed.
	    listView cursor:(Cursor hand).
	    self inspect:inspectedObject. "force list update"
	].
    ]
!

doReferences
    "show users of selected key (i.e. global)"

    |k|

    selectedLine notNil ifTrue:[
	selectedLine == 1 ifFalse:[
	    k := (keys at:selectedLine - 1).
	    SystemBrowser browseReferendsOf:k asSymbol
	].
    ]
! !

!DictionaryInspectorView methodsFor:'private'!

fieldList 
    "return a list of names for the selectionlist. Leave hasMore as
     true, if a '...' entry should be added."

    |aList|

    keys := inspectedObject keys asSortedCollection:[:a :b | a printString < b printString].
    aList := keys collect:[:k | k isSymbol ifTrue:[
						k printString
					       ] ifFalse:[
						k displayString
					       ]
					 ].
    aList := keys asOrderedCollection.
    aList addFirst:'self'.
    ^ aList
!

release 
    "release inspected object"

    keys := nil.
    super release
! !

!DictionaryInspectorView methodsFor:'initialization'!

fieldMenu
    |labels selectors|

    inspectedObject == Smalltalk ifTrue:[
	labels := #(
		       'inspect'
		       'inspect key'
		       'basicInspect'
		       'references'
		       '-'
		       'add key'
		       'remove key'
		   ).
	selectors := #(
		       doInspect 
		       doInspectKey 
		       doBasicInspect 
		       doReferences 
		       nil 
		       doAddKey 
		       doRemoveKey
		      ).
    ] ifFalse:[
	labels := #(
		       'inspect'
		       'inspect key'
		       'basicInspect'
		       '-'
		       'add key'
		       'remove key'
		   ).
	selectors := #(
		       doInspect 
		       doInspectKey 
		       doBasicInspect 
		       nil 
		       doAddKey 
		       doRemoveKey
		      ).
    ].

    ^ PopUpMenu
	 labels:(resources array:labels)
	 selectors:selectors
! !