"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview' }"

"{ NameSpace: Smalltalk }"

Image subclass:#Depth24Image

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Images'

!

!Depth24Image class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class represents true-color (24 bit / pixel) images.

    It mainly consists of methods already implemented in Image,

    reimplemented here for more performance.

    Only the #rgb format is supported here.

    with #rgb, pixels are internally stored byte-wise in rgb order

    (i.e. r at low byte, b at high byte).

    When reading pixel values, these are returned as rrggbb,

    both on LSB and on MSB machines.

    (red in high bits of the returned 24bit integer)

    Thus, pixelValues and rgbValues are identical, simulating MSB on all

    architectures (this should be transparent, if you use the rgbValueAt

    accessors; however, some old code uses pixelValueAt:, assuming that the

    returned pixel value is rrggbb (which it would not be without this hack).

    [author:]

        Claus Gittinger

    [see also:]

        Depth1Image Depth2Image Depth4Image Depth8Image Depth16Image

        ImageReader

"

! !

!Depth24Image class methodsFor:'queries'!

defaultPhotometric

    "return the default photometric pixel interpretation"

    ^ #rgb

    "Created: 10.6.1996 / 18:08:25 / cg"

!

imageDepth

    "return the depth of images represented by instances of

     this class - here we return 24"

    ^ 24

    "Modified: 20.4.1996 / 23:39:50 / cg"

! !

!Depth24Image methodsFor:'accessing-pixels'!

colorAtX:x y:y

    "retrieve a pixel at x/y; return a color.

     Pixels start at x=0 , y=0 for upper left pixel,

     end at x = width-1, y=height-1 for lower right pixel"

    |rgbVal|

    rgbVal := self rgbValueAtX:x y:y.

    ^ Color rgbValue:rgbVal.

!

colorAtX:x y:y put:aColor

    "set the pixel at x/y to aColor.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel."

    self rgbValueAtX:x y:y put:(aColor rgbValue).

    "Created: / 24-04-1997 / 17:32:59 / cg"

    "Modified (format): / 31-08-2017 / 12:01:01 / cg"

!

pixelAtX:x y:y

    "retrieve a pixel at x/y; 

     return a pixel value (0..16rFFFFFF) which is 24 bits RGB.

     In theory, the interpretation of the pixel value depends on the photometric,

     however as the only one supported here is #rgb, the returned value

     is always rrggbb (with r in high bits, b in low 8 bits).

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel."

    |index "{ Class: SmallInteger }"

     rVal  "{ Class: SmallInteger }"

     gVal  "{ Class: SmallInteger }"

     bVal  "{ Class: SmallInteger }"|

%{  /* NOCONTEXT */

    OBJ b = __INST(bytes);

    OBJ w = __INST(width);

    if (__isByteArrayLike(b)

     && __bothSmallInteger(x, y)

     && __isSmallInteger(w)

     && (__INST(pixelFunction)==nil) ) {

        int _idx;

        _idx = ((__intVal(w) * __intVal(y)) + __intVal(x))*3;

        if (((unsigned)(_idx+2)) < __byteArraySize(b)) {

            unsigned char *pPix = &(__ByteArrayInstPtr(b)->ba_element[_idx]);

            unsigned int _pix;

            _pix = (pPix[0]<<16) + (pPix[1] << 8) + pPix[2];

            RETURN( __MKSMALLINT(_pix) );

        }

    }

%}.

    pixelFunction notNil ifTrue:[^ pixelFunction value:x value:y].

    index := 1 + (((width * y) + x) * 3).

    rVal := bytes at:(index).

    gVal := bytes at:(index + 1).

    bVal := bytes at:(index + 2).

    ^ (((rVal bitShift:8) bitOr:gVal) bitShift:8) bitOr:bVal

    "Created: 24.4.1997 / 16:06:34 / cg"

!

pixelAtX:x y:y put:aPixelValue

    "set a pixel at x/y to aPixelValue, (0..16rFFFFFF) which is 24 bits RGB.

     In theory, the interpretation of the pixel value depends on the photometric,

     however as the only one supported here is #rgb, the expected value

     is always rrggbb (with r in high bits, b in low 8 bits).

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |index "{ Class: SmallInteger }"

     val   "{ Class: SmallInteger }"|

%{  /* NOCONTEXT */

    OBJ b = __INST(bytes);

    OBJ w = __INST(width);

    if (__isByteArrayLike(b)

     && __bothSmallInteger(x, y)

     && __bothSmallInteger(w, aPixelValue)

     && (__INST(pixelFunction)==nil) ) {

        int _idx;

        _idx = ((__intVal(w) * __intVal(y)) + __intVal(x))*3;

        if (((unsigned)(_idx+2)) < __byteArraySize(b)) {

            unsigned char *pPix = &(__ByteArrayInstPtr(b)->ba_element[_idx]);

            unsigned int _pix = __intVal(aPixelValue);

            pPix[0] = (_pix>>16) & 0xFF;    // r

            pPix[1] = (_pix>>8) & 0xFF;     // g 

            pPix[2] = (_pix) & 0xFF;        // b 

            RETURN( self );

        }

    }

%}.

    bytes isNil ifTrue:[ self createPixelStore ].

    index := 1 + (((width * y) + x) * 3).

    val := aPixelValue.

    bytes at:(index + 2) put:(val bitAnd:16rFF).

    val := val bitShift:-8.

    bytes at:(index + 1) put:(val bitAnd:16rFF).

    val := val bitShift:-8.

    bytes at:(index) put:val.

!

rgbValueAtX:x y:y

    "retrieve a pixel's rgb value at x/y; 

     return a 24bit rgbValue (rrggbb, red is MSB).

     Pixels start at 0@0 for the upper left pixel, 

     and end at (width-1)@(height-1) for the lower right pixel."

    photometric == #rgb ifTrue:[

        ^ self pixelAtX:x y:y

    ].

    ^ super rgbValueAtX:x y:y

    "Modified: / 10-09-2017 / 16:21:25 / cg"

!

rgbValueAtX:x y:y put:rgbValue

    "store a pixel's rgb value at x/y; 

     return a 24bit rgbValue (rrggbb, red is MSB).

     Pixels start at 0@0 for the upper left pixel, 

     and end at (width-1)@(height-1) for the lower right pixel."

    photometric == #rgb ifTrue:[

        self pixelAtX:x y:y put:rgbValue

    ] ifFalse:[

        super rgbValueAtX:x y:y put:rgbValue

    ].

    "Created: / 10-09-2017 / 16:21:50 / cg"

!

rowAt:y putAll:pixelArray startingAt:startIndex

    "store a single row's bits from bits in the pixelArray argument;

     The interpretation of the pixel values depends on the photometric.

     Return the pixelArray.

     Notice: row coordinate starts at 0."

    |bytes dstIdx pixel|

    photometric == #rgb ifTrue:[

        bytes := self bits.

        dstIdx := (y * self bytesPerRow) + 1.

        0 to:width-1 do:[:col |

            pixel := pixelArray at:(startIndex + col).

            "/ msbFirst

            bytes at:dstIdx put:((pixel bitShift:-16) bitAnd:16rFF).

            bytes at:dstIdx+1 put:((pixel bitShift:-8) bitAnd:16rFF).

            bytes at:dstIdx+2 put:(pixel bitAnd:16rFF).

            dstIdx := dstIdx + 3.

        ].

        ^ self

    ].

    super rowAt:y putAll:pixelArray startingAt:startIndex.

    "Created: / 24-04-1997 / 15:50:27 / cg"

    "Modified (comment): / 10-09-2017 / 16:22:39 / cg"

! !

!Depth24Image methodsFor:'converting rgb images'!

asGrayFormOn:aDevice

    "return a grey form from the receiver.

     Redefined to use special code when converting to 8-bit

     greyScale displays."

    (aDevice visualType == #StaticGray) ifTrue:[

        aDevice depth == 8 ifTrue:[

            ^ self 

                makeDeviceGrayPixmapOn:aDevice depth:aDevice depth 

                fromArray:(self threshold8BitGrayBits)

        ].

    ].

    ^ super asGrayFormOn:aDevice

    "Created: / 10-06-1996 / 19:00:45 / cg"

    "Modified: / 10-06-1996 / 20:10:19 / cg"

    "Modified (format): / 24-08-2017 / 15:18:31 / cg"

!

asThresholdGrayImageDepth:depth

    "return an 8-bit grey image from the rgb picture.

     Pixel values are reduced to a 0..255 grey level."

    depth == 8 ifTrue:[

        photometric == #rgb ifTrue:[

            ^ (Depth8Image

                width:width height:height fromArray:(self threshold8BitGrayBits))

                photometric:#blackIs0    

        ]

    ].

    ^ super asThresholdGrayImageDepth:depth

    "

     |i|

     i := Image fromFile:'bitmaps/granite.tiff'.

     (i asThresholdGrayImageDepth:8) inspect.

     (i asThresholdGrayImageDepth:4) inspect.

     (i asThresholdGrayImageDepth:2) inspect.

     (i asThresholdGrayImageDepth:1) inspect.

    "

    "

     |i|

     i := Image fromFile:'bitmaps/granite.tiff'.

     ((i asThresholdGrayImageDepth:8) asOrderedDitheredGrayImageDepth:2) inspect

    "

    "

     |i|

     i := Image fromFile:'bitmaps/granite.tiff'.

     ((i asThresholdGrayImageDepth:8) asOrderedDitheredGrayImageDepth:4) inspect

    "

    "

     |i|

     i := Image fromFile:'bitmaps/granite.tiff'.

     (i asThresholdGrayImageDepth:8) asOrderedDitheredMonochromeImage inspect

    "

    "Created: / 08-06-1996 / 13:58:46 / cg"

    "Modified: / 29-08-2017 / 22:28:55 / cg"

!

rgbImageAsDitheredPseudoFormOn:aDevice

    "return a dithered pseudocolor form from the rgb-picture.

     This method depends on fixColors being allocated (see Color>>getColors*)"

    |ditherColors|

    (ditherColors := aDevice fixColors) notNil ifTrue:[

	^ self

		rgbImageAsDitheredPseudoFormOn:aDevice

		colors:ditherColors

		nRed:aDevice numFixRed

		nGreen:aDevice numFixGreen

		nBlue:aDevice numFixBlue

    ].

    ditherColors := Set new.

    ditherColors addAll:(aDevice ditherColors).

    ditherColors addAll:(aDevice deviceColors).

    ditherColors := ditherColors asArray.

    ^ self

	rgbImageAsDitheredPseudoFormOn:aDevice

	colors:ditherColors.

    "Modified: 22.4.1997 / 11:59:44 / cg"

!

rgbImageAsDitheredPseudoFormOn:aDevice colors:fixColors

    "return a dithered 8-bit pseudocolor form from the rgb-picture, using

     arbitrary fix colors in fixColors."

    |pseudoBits f

     h        "{ Class: SmallInteger }"

     w        "{ Class: SmallInteger }"

     numFix   "{Class: SmallInteger }" deviceDepth

     fixIds fixRed fixGreen fixBlue failed cache idsUsed usedColors

     fixColorArray|

    numFix := fixColors size.

    numFix == 256 ifTrue:[

        "/ algorithm below only handles 255 colors.

        numFix := 255.

    ].

    fixColorArray := fixColors asArray.

    fixIds := (fixColorArray collect:[:clr | clr colorId]) asByteArray.

    fixRed := (fixColorArray collect:[:clr | clr redByte]) asByteArray.

    fixGreen := (fixColorArray collect:[:clr | clr greenByte]) asByteArray.

    fixBlue := (fixColorArray collect:[:clr | clr blueByte]) asByteArray.

    cache := ByteArray new:(1 bitShift:14).

    cache atAllPut:16rFF.

    deviceDepth := aDevice depth.

    deviceDepth == 8 ifFalse:[

        (aDevice supportedImageFormatForDepth:8) isNil ifTrue:[

            ^ nil

        ]

    ].

    idsUsed := ByteArray new:(fixIds size).

    'Depth24Image [info]: dithering ...' infoPrintCR.

    pseudoBits := ByteArray uninitializedNew:(width * height).

    h := height.

    w := width.

%{

    int __x, __y, __numFix;

    int __eR, __eG, __eB;

    unsigned char *srcP, *dstP;

    int pix;

    unsigned char *idP, *usedIdP, *redP, *greenP, *blueP, *cacheP;

    int __w = __intVal(w);

    if (__isByteArrayLike(__INST(bytes))

     && __isSmallInteger(numFix)

     && __isByteArrayLike(pseudoBits)

     && __isByteArrayLike(cache)

     && __isByteArrayLike(fixIds)

     && __isByteArrayLike(idsUsed)

     && __isByteArrayLike(fixRed)

     && __isByteArrayLike(fixGreen)

     && __isByteArrayLike(fixBlue) ) {

        failed = false;

        srcP = __ByteArrayInstPtr(__INST(bytes))->ba_element;

        dstP = __ByteArrayInstPtr(pseudoBits)->ba_element;

        idP = __ByteArrayInstPtr(fixIds)->ba_element;

        usedIdP = __ByteArrayInstPtr(idsUsed)->ba_element;

        redP = __ByteArrayInstPtr(fixRed)->ba_element;

        greenP = __ByteArrayInstPtr(fixGreen)->ba_element;

        blueP = __ByteArrayInstPtr(fixBlue)->ba_element;

        cacheP = __ByteArrayInstPtr(cache)->ba_element;

        __numFix = __intVal(numFix);

        for (__y=__intVal(h); __y>0; __y--) {

            __eR = __eG = __eB = 0;

            for (__x=__w; __x>0; __x--) {

                int cacheIdx, clrIdx;

                int __wantR, __wantG, __wantB;

                __wantR = srcP[0] + __eR;

                if (__wantR > 255) __wantR = 255;

                else if (__wantR < 0) __wantR = 0;

                __wantG = srcP[1] + __eG;

                if (__wantG > 255) __wantG = 255;

                else if (__wantG < 0) __wantG = 0;

                __wantB = srcP[2] + __eB;

                if (__wantB > 255) __wantB = 255;

                else if (__wantB < 0) __wantB = 0;

                /*

                 * compute cache index

                 */

                cacheIdx = ((__wantR & 0xF8) >> 3);

                cacheIdx = (cacheIdx << 5) | ((__wantG & 0xF8) >> 3);

                cacheIdx = (cacheIdx << 4) | ((__wantB & 0xF0) >> 4);

                clrIdx = cacheP[cacheIdx];

                if (clrIdx == 0xFF) {   /* invalid slot */

                    unsigned minErr, minIdx;

                    int i;

                    /*

                     * must search ...

                     */

                    minErr = 0x7FFFFFF; minIdx = 0;

                    for (i=0; i<__numFix; i++) {

                        unsigned cR, cG, cB, e;

                        int eR, eG, eB;

                        cR = redP[i]; cG = greenP[i]; cB = blueP[i];

                        eR = cR - __wantR;

                        if (eR < 0) eR = -eR;

                        eG = cG - __wantG;

                        if (eG < 0) eG = -eG;

                        eB = cB - __wantB;

                        if (eB < 0) eB = -eB;

                        e = eR + eG + eB;

                        if (e < minErr) {

                            minErr = e;

                            minIdx = i;

                            if (e < 7) {

                                break;

                            }

                        }

                    }

                    /*

                     * minIdx is now index into fixColors

                     */

                    cacheP[cacheIdx] = clrIdx = minIdx;

/*

console_fprintf(stderr, "want %d/%d/%d best: %d [%d/%d/%d]\n", __wantR, __wantG, __wantB, clrIdx, redP[clrIdx], greenP[clrIdx], blueP[clrIdx]);

*/

                }