"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Image subclass:#Depth24Image

	 instanceVariableNames:''

	 classVariableNames:''

	 poolDictionaries:''

	 category:'Graphics-Images'

!

!Depth24Image class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

!

documentation

"

    this class represents true-color (24 bit / pixel) images.

    It mainly consists of methods already implemented in Image,

    reimplemented here for more performance.

"

! !

!Depth24Image class methodsFor:'queries'!

imageDepth

    ^ 24

! !

!Depth24Image methodsFor:'queries'!

bitsPerPixel

    "return the number of bits per pixel"

    ^ 24

!

bitsPerRow

    "return the number of bits in one scanline of the image"

    ^  width * 24

!

bitsPerSample

    "return the number of bits per sample.

     The return value is an array of bits-per-plane."

    ^ #(8 8 8)

!

bytesPerRow

    "return the number of bytes in one scanline of the image"

    ^ width * 3

!

samplesPerPixel

    "return the number of samples per pixel in the image."

    ^ 3

! !

!Depth24Image methodsFor:'accessing'!

atX:x y:y

    "retrieve a pixel at x/y; return a color.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |index "{ Class: SmallInteger }"

     rVal gVal bVal|

    index := 1 + (((width * y) + x) * 3).

    rVal := bytes at:(index).

    gVal := bytes at:(index + 1).

    bVal := bytes at:(index + 2).

    photometric ~~ #rgb ifTrue:[

	self error:'format not supported'.

	^ nil

    ].

    ^ Color red:rVal * 100 / 255

	  green:gVal * 100 / 255

	   blue:bVal * 100 / 255

!

atX:x y:y put:aColor

    "set the pixel at x/y to aColor.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel."

    |index "{ Class: SmallInteger }"

     val   "{ Class: SmallInteger }" |

    index := 1 + (((width * y) + x) * 3).

    val := (aColor red / 100 * 255) rounded.

    bytes at:(index) put:val.

    val := (aColor green / 100 * 255) rounded.

    bytes at:(index + 1) put:val.

    val := (aColor blue / 100 * 255) rounded.

    bytes at:(index + 2) put:val.

!

valueAtX:x y:y

    "retrieve a pixel at x/y; return a color.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |index "{ Class: SmallInteger }"

     rVal  "{ Class: SmallInteger }"

     gVal  "{ Class: SmallInteger }"

     bVal  "{ Class: SmallInteger }"|

    index := 1 + (((width * y) + x) * 3).

    rVal := bytes at:(index).

    gVal := bytes at:(index + 1).

    bVal := bytes at:(index + 2).

    ^ (((rVal bitShift:8) bitOr:gVal) bitShift:8) bitOr:bVal

!

atX:x y:y putValue:aPixelValue

    "set a pixel at x/y to aPixelValue, which is 24 bits RGB.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |index "{ Class: SmallInteger }"

     val   "{ Class: SmallInteger }" |

    index := 1 + (((width * y) + x) * 3).

    val := aPixelValue.

    bytes at:(index + 2) put:(val bitAnd:16rFF).

    val := val bitShift:-8.

    bytes at:(index + 1) put:(val bitAnd:16rFF).

    val := val bitShift:-8.

    bytes at:(index) put:val.

! !

!Depth24Image methodsFor:'enumerating'!

valueAtY:y from:xLow to:xHigh do:aBlock

    "perform aBlock for each pixelValue from x1 to x2 in row y.

     The block is passed the pixelValue at each pixel.

     This method allows slighly faster processing of an

     image than using valueAtX:y:, since some processing can be

     avoided when going from pixel to pixel. However, for

     real image processing, specialized methods should be written.

     Notice that the pixelValue is the r/g/b value packed into an integer

     (r bitShift:16) bitOr:(g bitSHift:8) bitOr:b"

    |srcIndex "{ Class: SmallInteger }"

     x1       "{ Class: SmallInteger }"

     x2       "{ Class: SmallInteger }"

     r        "{ Class: SmallInteger }"

     g        "{ Class: SmallInteger }"

     b        "{ Class: SmallInteger }"|

    x1 := xLow.

    x2 := xHigh.

    srcIndex := 1 + (((width * y) + x1) * 3).

    x1 to:x2 do:[:x |

	r := bytes at:(srcIndex).

	g := bytes at:(srcIndex + 1).

	b := bytes at:(srcIndex + 2).

	srcIndex := srcIndex + 3.

	aBlock value:x value:(((r bitShift:16) bitOr:(g bitShift:8)) bitOr:b)

    ]

!

atY:y from:xLow to:xHigh do:aBlock

    "perform aBlock for each pixel from x1 to x2 in row y.

     The block is passed the color at each pixel.

     This method allows slighly faster processing of an

     image than using atX:y:, since some processing can be

     avoided when going from pixel to pixel. However, for

     real image processing, specialized methods should be written."

    |srcIndex "{ Class: SmallInteger }"

     x1       "{ Class: SmallInteger }"

     x2       "{ Class: SmallInteger }"

     rVal     "{ Class: SmallInteger }"

     gVal     "{ Class: SmallInteger }"

     bVal     "{ Class: SmallInteger }"

     lastR lastG lastB lastColor|

    photometric ~~ #rgb ifTrue:[

	self error:'format not supported'.

	^ nil

    ].

    x1 := xLow.

    x2 := xHigh.

    srcIndex := 1 + (((width * y) + x1) * 3).

    x1 to:x2 do:[:x |

	rVal := bytes at:(srcIndex).

	gVal := bytes at:(srcIndex + 1).

	bVal := bytes at:(srcIndex + 2).

	srcIndex := srcIndex + 3.

	(rVal == lastR and:[gVal == lastG and:[bVal == lastB]]) ifFalse:[

	    lastColor := Color red:rVal * 100 / 255

			     green:gVal * 100 / 255

			      blue:bVal * 100 / 255.

	    lastR := rVal.

	    lastG := gVal.

	    lastB := bVal.

	].

	aBlock value:x value:lastColor

    ]

! !

!Depth24Image methodsFor:'converting rgb images'!

rgbImageAsGreyFormOn:aDevice

    "convert an rgb image to a grey image for greyscale displays"

    |deviceDepth|

    deviceDepth := aDevice depth.

    "I have specially tuned methods for monochrome"

    (deviceDepth == 1) ifTrue:[

	DitherAlgorithm == #error ifTrue:[

	    ^ self rgbImageAsErrorDitheredGreyFormOn:aDevice

	].

	DitherAlgorithm == #pattern ifTrue:[

	    ^ self rgbImageAsPatternDitheredGreyFormOn:aDevice

	].

	^ self rgbImageAsMonoFormOn:aDevice

    ].

    "and for 2plane greyscale (i.e. NeXTs)"

    (deviceDepth == 2) ifTrue:[

	DitherAlgorithm == #error  ifTrue:[

	    ^ self rgbImageAsErrorDitheredGreyFormOn:aDevice

	].

	DitherAlgorithm == #pattern  ifTrue:[

	    ^ self rgbImageAsPatternDitheredGreyFormOn:aDevice

	].

	^ self rgbImageAs2PlaneFormOn:aDevice

    ].

    (deviceDepth == 8) ifTrue:[

	^ self rgbImageAs8BitGreyFormOn:aDevice

    ].

    "mhmh need another converter ...

     till then we do:"

    DitherAlgorithm == #error  ifTrue:[

	^ self rgbImageAsErrorDitheredGreyFormOn:aDevice

    ].

    DitherAlgorithm == #pattern  ifTrue:[

	^ self rgbImageAsPatternDitheredGreyFormOn:aDevice

    ].

    ^ self rgbImageAsMonoFormOn:aDevice

!

rgbImageAsMonoFormOn:aDevice

    "return a 1-bit monochrome form for aDevice from the rgb picture,

     using a threshold algorithm. 

     (i.e. grey value < 0.5 -> black, grey value >= 0.5 -> white)."

    |monoBits f

     w        "{ Class: SmallInteger }"

     h        "{ Class: SmallInteger }"

     r        "{ Class: SmallInteger }"

     g        "{ Class: SmallInteger }"

     b        "{ Class: SmallInteger }"

     v        "{ Class: SmallInteger }"

     map rMap gMap bMap

     srcIndex "{ Class: SmallInteger }"

     dstIndex "{ Class: SmallInteger }"

     bits     "{ Class: SmallInteger }"

     bitCount "{ Class: SmallInteger }"

     failed |

    w := width.

    h := height.

    monoBits := ByteArray uninitializedNew:(((w + 7) // 8) * h).

    failed := true.

%{

    register unsigned char *srcPtr, *dstPtr;

    register _v, _bits, _bitCount;

    register j;

    register i;

    extern OBJ ByteArray;

    if (__isByteArray(_INST(bytes))

     && __isByteArray(monoBits)) {

	failed = false;

	srcPtr = _ByteArrayInstPtr(_INST(bytes))->ba_element;

	dstPtr = _ByteArrayInstPtr(monoBits)->ba_element;

	for (i=_intVal(h); i>0; i--) {

	    _bitCount = 0;

	    _bits = 0;

	    for (j=_intVal(w); j>0; j--) {

		_bits <<= 1; 

		_v = (*srcPtr++ * 3);   /* 0.3*r + 0.6*g + b */

		_v += (*srcPtr++ * 6);

		_v += *srcPtr++;

		_v /= 10;

		if (_v & 0x80)

		    _bits |= 1;

		_bitCount++;

		if (_bitCount == 8) {

		    *dstPtr++ = _bits;

		    _bits = 0;

		    _bitCount = 0;

		}

	    }

	    if (_bitCount != 0) {

		while (_bitCount++ != 8) _bits <<= 1;

		*dstPtr++ = _bits;

	    }

	}

    }

%}.

    failed ifTrue:[

"/ the above is equivalent to:

"/

"/        srcIndex := 1.

"/        dstIndex := 1.

"/        1 to:h do:[:row |

"/            bitCount := 0.

"/            bits := 0.

"/            1 to:w do:[:col |

"/                bits := bits bitShift:1.

"/

"/                r := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                g := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                b := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                v := ((3 * r) + (6 * g) + (1 * b)) // 10.

"/                ((v bitAnd:16r80) == 0) ifFalse:[

"/                    bits := bits bitOr:1

"/                ].

"/                bitCount := bitCount + 1.

"/                (bitCount == 8) ifTrue:[

"/                    monoBits at:dstIndex put:bits.

"/                    dstIndex := dstIndex + 1.

"/                    bits := 0.

"/                    bitCount := 0

"/                ]

"/            ].

"/            (bitCount ~~ 0) ifTrue:[

"/                [bitCount == 8] whileFalse:[

"/                    bitCount := bitCount + 1.

"/                    bits := bits bitShift:1.

"/                ].

"/                monoBits at:dstIndex put:bits.

"/                dstIndex := dstIndex + 1

"/            ]

"/        ]

	self primitiveFailed.

	^ nil

    ].

    f := Form width:w height:h depth:1 on:aDevice.

    f isNil ifTrue:[^ nil].

    f initGC.

    (aDevice blackpixel == 0) ifFalse:[

	"have to invert bits"

	f function:#copyInverted

    ].

    aDevice drawBits:monoBits depth:1 width:w height:h

		   x:0 y:0

		into:(f id) x:0 y:0 width:w height:h with:(f gcId).

    ^ f

!

rgbImageAs2PlaneFormOn:aDevice

    "return a 2-bit device form for aDevice from the rgb picture,

     using a threshold algorithm. 

     (i.e. grey value < 0.25 -> black // 0.25..0.5 -> darkgrey //

      0.5 .. 0.75 -> lightgrey // > 0.75 -> white)."

    |twoPlaneBits f

     map rMap gMap bMap 

     failed

     r        "{ Class: SmallInteger }"

     g        "{ Class: SmallInteger }"

     b        "{ Class: SmallInteger }"

     v        "{ Class: SmallInteger }"

     w        "{ Class: SmallInteger }"

     h        "{ Class: SmallInteger }"

     srcIndex "{ Class: SmallInteger }"

     dstIndex "{ Class: SmallInteger }"

     bits     "{ Class: SmallInteger }"

     bitCount "{ Class: SmallInteger }" |

    w := width.

    h := height.

    twoPlaneBits := ByteArray uninitializedNew:(((w * 2 + 7) // 8) * h).

    failed := true.

%{

    register unsigned char *srcPtr, *dstPtr;

    register _v, _bits, _bitCount;

    register j;

    register i;

    extern OBJ ByteArray;

    if ((__Class(_INST(bytes)) == ByteArray)

     && (__Class(twoPlaneBits) == ByteArray)) {

	failed = false;

	srcPtr = _ByteArrayInstPtr(_INST(bytes))->ba_element;

	dstPtr = _ByteArrayInstPtr(twoPlaneBits)->ba_element;

	for (i=_intVal(h); i>0; i--) {

	    _bitCount = 0;

	    _bits = 0;

	    for (j=_intVal(w); j>0; j--) {

		_v = (*srcPtr++ * 3);   /* 0.3*r + 0.6*g + b */

		_v += (*srcPtr++ * 6);

		_v += *srcPtr++;

		_v /= 10;

		_bits <<= 2; 

		_bits |= (_v >> 6); /* take top 2 bits */

		_bitCount++;

		if (_bitCount == 4) {

		    *dstPtr++ = _bits;

		    _bits = 0;

		    _bitCount = 0;

		}

	    }

	    if (_bitCount != 0) {

		while (_bitCount++ != 4) _bits <<= 2;

		*dstPtr++ = _bits;

	    }

	}

    }

%}.

    failed ifTrue:[

"/ the above is equivalent to:

"/

"/        srcIndex := 1.

"/        dstIndex := 1.

"/        1 to:h do:[:row |

"/            bitCount := 0.

"/            bits := 0.

"/            1 to:w do:[:col |

"/                r := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                g := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                b := bytes at:srcIndex.

"/                srcIndex := srcIndex + 1.

"/                v := ((3 * r) + (6 * g) + (1 * b)) // 10.

"/                v := v bitShift:-6. "take 2 hi bits"

"/                bits := (bits bitShift:2) bitOr:v.

"/                bitCount := bitCount + 1.

"/                (bitCount == 4) ifTrue:[

"/                    twoPlaneBits at:dstIndex put:bits.

"/                    dstIndex := dstIndex + 1.

"/                    bits := 0.

"/                    bitCount := 0

"/                ]

"/            ].

"/            (bitCount ~~ 0) ifTrue:[

"/                [bitCount == 4] whileFalse:[

"/                    bitCount := bitCount + 1.

"/                    bits := bits bitShift:2.

"/                ].

"/                twoPlaneBits at:dstIndex put:bits.

"/                dstIndex := dstIndex + 1

"/            ]

"/        ]

	self primitiveFailed.

	^ nil

    ].

    f := Form width:width height:height depth:2 on:aDevice.

    f isNil ifTrue:[^ nil].

    f initGC.

    (aDevice blackpixel == 0) ifFalse:[