"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview' }"

"{ NameSpace: Smalltalk }"

Image subclass:#Depth32Image

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Images'

!

!Depth32Image class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class represents 32 bit (eg. rgb+alpha) images.

    Only the minimum protocol is implemented here; much more is

    needed for higher performance operations on depth32 images.

    with #rgb, #rgba, #rgbx, photometrics 

    pixels are internally stored byte-wise in rgba order.

    (i.e. r at low-address byte, a at high-address byte). 

    For rgb, a zero is always retrieved as alpha; 255 for rgbx.

    When reading pixel values, photometric argb is returned as aarrggbb,

    photometric rgb is returned as 00rrggbb,

    photometric rgba is returned as rrggbb00,

    both on LSB and on MSB machines.

    (i.e. blue in lower bits of the returned 32bit integer, alpha in the high bits for argb,

     and in the low bits for rgba)

    Thus, pixelValues and rgbValues are identical, simulating MSB on all

    architectures.

    (this should be transparent, if you use the rgbValueAt

     accessors; however, some old code uses pixelValueAt:, assuming that the

    returned pixel value is rrggbb - which it would not be without this hack).

    This also makes depth24Image's rgbValues compatible with depth32Image's rgbValues.

    For argb and xrgb formats, alpha (or dummy alpha) is in the first byte 

    (which are the high bits, as we present pixel values always MSB).

    [author:]

        Claus Gittinger

    [see also:]

        Depth1Image Depth2Image Depth4Image Depth8Image Depth16Image Depth24Image

        ImageReader

"

! !

!Depth32Image class methodsFor:'queries'!

defaultPhotometric

    "return the default photometric pixel interpretation"

    "/ here we return #rgb - thus ignoring any alpha channel.

    "/ the reason is that many displays and graphics formats do use

    "/ 32bit per pixel, but provide an alpha value of 0, instead of 255.

    "/ Thus returning rgba here would make many images invisible (totally transparent)

    ^ #rgb

    "Created: / 27-05-2007 / 14:03:59 / cg"

    "Modified: / 16-02-2017 / 17:41:09 / cg"

    "Modified (comment): / 16-02-2017 / 19:00:25 / cg"

!

imageDepth

    "return the depth of images represented by instances of

     this class - here we return 32"

    ^ 32

    "Modified: 20.4.1996 / 23:40:01 / cg"

    "Created: 24.4.1997 / 19:00:28 / cg"

! !

!Depth32Image methodsFor:'accessing-pixels'!

colorAtX:x y:y

    "retrieve a pixel at x/y; return a color.

     Pixels start at x=0 , y=0 for upper left pixel, 

     end at x = width-1, y=height-1 for lower right pixel"

    |index "{ Class: SmallInteger }"

     rVal gVal bVal aVal|

    index := 1 + (((width * y) + x) * 4).

    ((photometric == #rgb) or:[photometric == #rgbx]) ifTrue:[

        "/ byteorder is: r,g,b,<ignoredAlpha>

        rVal := bytes at:index.

        gVal := bytes at:(index + 1).

        bVal := bytes at:(index + 2).

        ^ Color redByte:rVal greenByte:gVal blueByte:bVal

    ].

    (photometric == #rgba) ifTrue:[

        "/ byteorder is: r,g,b,<ignoredAlpha>

        rVal := bytes at:(index).

        gVal := bytes at:(index + 1).

        bVal := bytes at:(index + 2).

        aVal := bytes at:(index + 3).

        ^ Color redByte:rVal greenByte:gVal blueByte:bVal alphaByte:aVal

    ].

    photometric == #argb ifTrue:[

        "/ byteorder is: a,r,g,b

        aVal := bytes at:(index).

        rVal := bytes at:(index + 1).

        gVal := bytes at:(index + 2).

        bVal := bytes at:(index + 3).

        ^ Color redByte:rVal greenByte:gVal blueByte:bVal alphaByte:aVal

    ].

    photometric == #xrgb ifTrue:[

        "/ byteorder is: ignored-alpha,r,g,b

        rVal := bytes at:(index + 1).

        gVal := bytes at:(index + 2).

        bVal := bytes at:(index + 3).

        ^ Color redByte:rVal greenByte:gVal blueByte:bVal

    ].

    "/ the inherited method should handle all cases.

    ^ super colorAtX:x y:y.

    "Modified: / 22-08-2017 / 18:17:38 / cg"

    "Modified: / 12-07-2019 / 14:39:41 / Stefan Reise"

!

colorAtX:x y:y put:aColor

    "set the pixel at x/y to aColor.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel."

    |index "{ Class: SmallInteger }"

     r g b|

    index := 1 + (((width * y) + x) * 4).

    r := aColor redByte.

    g := aColor greenByte.

    b := aColor blueByte.

    ((photometric == #rgb) or:[(photometric == #xrgb)]) ifTrue:[

        "/ byteorder is: ignored-alpha,r,g,b

        bytes at:(index + 1) put:r.

        bytes at:(index + 2) put:g.

        bytes at:(index + 3) put:b.

        ^ self

    ].

    (photometric == #rgba) ifTrue:[

        "/ byteorder is: r,g,b,a

        bytes at:(index + 0) put:r.

        bytes at:(index + 1) put:g.

        bytes at:(index + 2) put:b.

        bytes at:(index + 3) put:(aColor alphaByte). "alpha channel in last byte"

        ^ self

    ].

    (photometric == #argb) ifTrue:[

        "/ byteorder is: a,r,g,b

        bytes at:(index + 0) put:(aColor alphaByte).     "alpha channel in first byte"

        bytes at:(index + 1) put:r.

        bytes at:(index + 2) put:g.

        bytes at:(index + 3) put:b.             

        ^ self

    ].

    (photometric == #rgbx) ifTrue:[

        "/ byteorder is: <ignoredAlpha>,r,g,b

        bytes at:(index + 0) put:r.

        bytes at:(index + 1) put:g.

        bytes at:(index + 2) put:b.

        ^ self

    ].

    super colorAtX:x y:y put:aColor.

    "Modified: / 22-08-2017 / 18:17:14 / cg"

!

pixelAtX:x y:y

    "retrieve a pixel at x/y; return a pixelValue.

     The interpretation of the returned value depends on the photometric

     and the colormap. See also Image>>atX:y:)

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel.

     With rgba photometric, the pixel value contains r/g/b/a in lsb order 

     (i.e. r at low, a at high bits);

     with argb, alpha is in the low byte"

    |pixelIndex "{ Class: SmallInteger }"|

%{  /* NOCONTEXT */

    OBJ b = __INST(bytes);

    OBJ w = __INST(width);

    if (__isByteArrayLike(b)

     && __bothSmallInteger(x, y)

     && __isSmallInteger(w)

     && (__INST(pixelFunction)==nil) ) {

        int _idx;

        _idx = ((__intVal(w) * __intVal(y)) + __intVal(x))*4;

        if (((unsigned)(_idx+3)) < __byteArraySize(b)) {

            unsigned char *pPix = &(__ByteArrayInstPtr(b)->ba_element[_idx]);

            unsigned int _pix;

#ifdef __MSBFIRST__

            _pix = ((int *)pPix)[0];

#else

            _pix = pPix[0] << 24;

            _pix |= pPix[1] << 16;

            _pix |= pPix[2] << 8;

            _pix |= pPix[3];

#endif

#if __POINTER_SIZE__ == 8

            RETURN( __MKSMALLINT(_pix) );

#else

            RETURN( __MKUINT(_pix) );

#endif

        }

    }

%}.

    pixelFunction notNil ifTrue:[^ pixelFunction value:x value:y].

    pixelIndex := 1 + (((width * y) + x) * 4).

    ^ bytes unsignedInt32At:pixelIndex MSB:true.

    "Created: / 24-04-1997 / 19:00:28 / cg"

    "Modified: / 21-02-2017 / 17:21:44 / cg"

    "Modified (comment): / 22-08-2017 / 18:24:22 / cg"

!

pixelAtX:x y:y put:aPixelValue

    "set the pixel at x/y to aPixelValue.

     The interpretation of the pixelValue depends on the photometric.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel.

     With rgba photometric, the pixel value contains r/g/b/a in lsb order 

     (i.e. r at low, a at high bits);

     with argb, alpha is in the low byte"

    |pixelIndex "{ Class: SmallInteger }"|

%{  /* NOCONTEXT */

    OBJ b = __INST(bytes);

    OBJ w = __INST(width);

    if ((b != nil)

     && __isByteArrayLike(b)

     && __bothSmallInteger(x, y)

     && __isSmallInteger(aPixelValue)

     && (__INST(pixelFunction)==nil) ) {

        int _idx;

        _idx = ((__intVal(w) * __intVal(y)) + __intVal(x))*4;

        if (((unsigned)(_idx+3)) < __byteArraySize(b)) {

            unsigned char *pPix = &(__ByteArrayInstPtr(b)->ba_element[_idx]);

            unsigned int _pix = __intVal(aPixelValue);

#ifdef __MSBFIRST__

            ((int *)pPix)[0] = _pix;

#else

            pPix[0] = (_pix >> 24) & 0xFF;

            pPix[1] = (_pix >> 16) & 0xFF;

            pPix[2] = (_pix >> 8) & 0xFF;

            pPix[3] = _pix & 0xFF;

#endif

            RETURN(self);

        }

    }

%}.

    bytes isNil ifTrue:[ self createPixelStore ].

    pixelIndex := 1 + (((width * y) + x) * 4).

    bytes unsignedInt32At:pixelIndex put:aPixelValue MSB:true.

    "Created: / 24-04-1997 / 19:00:28 / cg"

    "Modified: / 22-08-2017 / 18:21:47 / cg"

!

rowAt:y putAll:pixelArray startingAt:startIndex

    "store a single rows bits from bits in the pixelArray argument;

     The interpretation of the pixel values depends on the photometric.

     Notice: row coordinate starts at 0."

    |bytes pixel

     dstIdx "{ Class: SmallInteger }" 

     w "{ Class: SmallInteger }"|

    bytes := self bits.

    dstIdx := (y * self bytesPerRow) + 1.

    w := width - 1.

    0 to:w do:[:col |

        pixel := pixelArray at:(startIndex + col).

        "/ msbFirst

        bytes unsignedInt32At:dstIdx put:pixel MSB:true.

        dstIdx := dstIdx + 4.

    ].

    "Modified (comment): / 21-02-2017 / 15:03:24 / cg"

! !

!Depth32Image methodsFor:'converting rgb images'!

computeAlphaValuesFromMask:aMaskImage

    "convert a mask into alpha values;

     masked pixels get an alpha value of 0, unmasked of 255"

    |alphaMask|

    alphaMask := (self alphaMaskForPixelValue bitShift:self alphaShiftForPixelValue).

    self 

        valuesFromX:0 y:0 toX:(width-1) y:(height-1)

        do:[:x :y :pixelValue |

            (aMaskImage pixelAtX:x y:y) ~~ 0 ifTrue:[

                self pixelAtX:x y:y put:(pixelValue bitOr:alphaMask).

            ] ifFalse:[

                self pixelAtX:x y:y put:(pixelValue bitClear:alphaMask).

            ].

        ].

    photometric := #rgba

    "Modified: / 21-02-2017 / 16:41:02 / cg"

!

rgbImageAsTrueColorFormOn:aDevice

    "return a truecolor form from the rgba or argb-picture."

    |bytes bestFormat usedDeviceDepth usedDeviceBitsPerPixel usedDevicePadding

     myDepth form imageBits padd

     rightShiftR rightShiftG rightShiftB

     shiftRed shiftGreen shiftBlue

     redOffs greenOffs blueOffs alphaOffs|

    bytes := self bits.

    bestFormat := self bestSupportedImageFormatFor:aDevice.

    usedDeviceDepth := bestFormat at:#depth.

    usedDeviceBitsPerPixel := bestFormat at:#bitsPerPixel.

    usedDevicePadding := bestFormat at:#padding.

    rightShiftR := (8 - aDevice bitsRed).

    rightShiftG := (8 - aDevice bitsGreen).

    rightShiftB := (8 - aDevice bitsBlue).

    shiftRed := aDevice shiftRed.

    shiftGreen := aDevice shiftGreen.

    shiftBlue := aDevice shiftBlue.

    redOffs := 0.

    greenOffs := 1.  

    blueOffs := 2.

    alphaOffs := 3.

    ((photometric == #argb) or:[ photometric == #rgb ]) ifTrue:[

        redOffs := 1. greenOffs := 2. blueOffs := 3. alphaOffs := 0.

    ] ifFalse:[

        (photometric == #rgba) ifFalse:[

            ^ self anyImageAsTrueColorFormOn:aDevice

        ].    

    ].    

    "/

    "/ for now, only a few formats are supported

    "/

    myDepth := self bitsPerPixel.

    usedDeviceBitsPerPixel == 24 ifTrue:[

        "/

        "/ 24 bit/pixel

        "/

        imageBits := ByteArray uninitializedNew:(width * height * 3).

        usedDevicePadding := 8.

        "/ now, walk over the image and compose 24bit values from the r/g/b/a triples

%{

        unsigned char *srcPtr = 0;

        unsigned char *dstPtr = 0;

        int _redOffs = __intVal(redOffs);

        int _greenOffs = __intVal(greenOffs);  

        int _blueOffs = __intVal(blueOffs);

        // int _alphaOffs = __intVal(alphaOffs);

        if (__isByteArrayLike(bytes)) {

            srcPtr = __ByteArrayInstPtr(bytes)->ba_element;

        } else {

            if (__isExternalBytesLike(bytes)) {

                srcPtr = __externalBytesAddress(bytes);

            }

        }

        if (__isByteArray(imageBits)) {

            dstPtr = __ByteArrayInstPtr(imageBits)->ba_element;

        } else {

            if (__isExternalBytesLike(imageBits)) {

                dstPtr = __externalBytesAddress(imageBits);

            }

        }

        if (__bothSmallInteger(__INST(height), __INST(width))

         && __bothSmallInteger(rightShiftR, shiftRed)

         && __bothSmallInteger(rightShiftG, shiftGreen)

         && __bothSmallInteger(rightShiftB, shiftBlue)

         && srcPtr

         && dstPtr) {

            int rShRed = __intVal(rightShiftR),

                rShGreen = __intVal(rightShiftG),

                rShBlue = __intVal(rightShiftB),

                lShRed = __intVal(shiftRed),

                lShGreen = __intVal(shiftGreen),

                lShBlue = __intVal(shiftBlue);

            int x, y, w;

            w = __intVal(__INST(width));

            if ((rShRed == 0) && (rShGreen == 0) && (rShBlue == 0)) {

                if ((lShRed == 0) && (lShGreen == 8) && (lShBlue == 16)) {

                    for (y=__intVal(__INST(height)); y > 0; y--) {

                        for (x=w; x > 0; x--) {                        

# ifdef __MSBFIRST

                            dstPtr[0] = srcPtr[_redOffs];

                            dstPtr[1] = srcPtr[_greenOffs];

                            dstPtr[2] = srcPtr[_blueOffs];

# else /* not MSB */

                            dstPtr[0] = srcPtr[_blueOffs];

                            dstPtr[1] = srcPtr[_greenOffs];

                            dstPtr[2] = srcPtr[_redOffs];

# endif /* not MSB */

                            dstPtr += 3;

                            srcPtr += 4;

                        }

                    }

                } else {

                    for (y=__intVal(__INST(height)); y > 0; y--) {

                        for (x=w; x > 0; x--) {

                            unsigned v;

                            v = srcPtr[_redOffs] << lShRed;

                            v |= (srcPtr[_greenOffs] << lShGreen);

                            v |= (srcPtr[_blueOffs] << lShBlue);

# ifdef __MSBFIRST

                            dstPtr[0] = (v) & 0xFF;

                            dstPtr[1] = (v>>8) & 0xFF;

                            dstPtr[2] = (v>>16) & 0xFF;

# else /* not MSB */

                            dstPtr[0] = (v>>16) & 0xFF;

                            dstPtr[1] = (v>>8) & 0xFF;

                            dstPtr[2] = (v) & 0xFF;

# endif /* not MSB */

                            dstPtr += 3;

                            srcPtr += 4;

                        }

                    }

                }

            } else {

                for (y=__intVal(__INST(height)); y > 0; y--) {

                    for (x=w; x > 0; x--) {

                        unsigned r, g, b, v;

                        r = srcPtr[_redOffs] >> rShRed;

                        g = srcPtr[_greenOffs] >> rShGreen;

                        b = srcPtr[_blueOffs] >> rShBlue;

                        v = r << lShRed;

                        v |= (g << lShGreen);

                        v |= (b << lShBlue);

# ifdef __MSBFIRST

                        dstPtr[0] = (v) & 0xFF;