"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

Object subclass:#WindowEvent

	 instanceVariableNames:'view type arguments'

	 classVariableNames:''

	 poolDictionaries:''

	 category:'Interface-Support'

!

WindowEvent comment:'

COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

'!

!WindowEvent class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

version

"

"

!

documentation

"

    Instances of WindowEvent are created for every event coming from

    the graphics device, to be handled by a windowGroup. 

    Usually, they are queued by a sensor, and processed in some event loop

    in the window group.

"

! !

!WindowEvent class methodsFor:'instance creation'!

for:aView type:aSymbol arguments:argArray

    "create and return a new windowEvent for sending

     aSymbol-message with arguments to aView"

    ^ (self new) for:aView type:aSymbol arguments:argArray

!

for:aView type:aSymbol

    "create and return a new windowEvent for sending

     aSymbol-message with no arguments to aView"

    ^ (self new) for:aView type:aSymbol arguments:#()

!

damageFor:aView rectangle:aRectangle

    "create and return a new damage Event for aRectangle

     in aView"

    ^ (self new) for:aView type:#damage arguments:aRectangle

! !

!WindowEvent methodsFor:'queries'!

isKeyEvent

    "return true, if this event is a keyboard event"

    ^ (type == #keyPress:x:y) or:[type == #keyRelease:x:y]

!

isDamage

    "return true, if this is a damage event"

    ^ type == #damage

! !

!WindowEvent methodsFor:'accessing'!

view

    "return the view, for which the event is for"

    ^ view

!

view:aView

    "set the view, for which the event is for"

    view := aView

!

type

    "return the type of the event"

    ^ type

!

arguments

    "return the arguments of the event"

    ^ arguments

!

arguments:anArray

    "set the arguments"

    arguments := anArray

!

rectangle

    "return the damage rectangle"

    ^ arguments "consider this a kludge"

! !

!WindowEvent methodsFor:'sending'!

sendEvent

    "forward the event represented by the receiver to the delegate,

     the controller or the view.

     Delegated messages get the original view as an extra argument."

    |delegate selector eventReceiver controller|

    selector := type.

    delegate := view delegate.

    delegate notNil ifTrue:[

	"

	 what a kludge - sending to delegate needs another

	 selector and an additional argument.

	 have to edit the selector ...

	"

	(selector endsWith:':') ifTrue:[

	    selector := (selector , 'view:') asSymbol.

	] ifFalse:[

	    selector := (selector , 'View:') asSymbol.

	].

	arguments isNil ifTrue:[

	    delegate perform:selector with:view

	] ifFalse:[

	    delegate perform:selector withArguments:(arguments copyWith:view)

	]

    ] ifFalse:[

	"

	 another one:

	 if the view has a transformation, edit the selector

	 This allows the view to handle the event either in device or

	 in PseudoView translates and resends).

	 (event sending is no high frequency operation), but that just adds 

	 another context to any debuggers walkback, making things less clear.

	"

	eventReceiver := view.

	(controller := view controller) notNil ifTrue:[  

	    (#(

	      #'buttonPress:x:y:'

	      #'buttonRelease:x:y:'

	      #'buttonShiftPress:x:y:'

	      #'buttonMultiPress:x:y:'

	      #'buttonMotion:x:y:'

	      #'keyPress:x:y:'

	      #'keyRelease:x:y:'

	      #'exposeX:y:width:height:'

	      #'graphicExposeX:y:width:height:'

	      #'pointerEnter:x:y:'

	    ) includes:selector) ifTrue:[

		eventReceiver := controller.

	    ]

	].

	view transformation notNil ifTrue:[

	    (#(

	      #'buttonPress:x:y:'

	      #'buttonRelease:x:y:'

	      #'buttonShiftPress:x:y:'

	      #'buttonMultiPress:x:y:'

	      #'buttonMotion:x:y:'

	      #'keyPress:x:y:'

	      #'keyRelease:x:y:'

	      #'exposeX:y:width:height:'

	      #'graphicExposeX:y:width:height:'

	      #'pointerEnter:x:y:'

	    )includes:selector) ifTrue:[

		selector := selector asString.

		selector at:1 put:(selector at:1) asUppercase.

	    ]        

	].

	eventReceiver perform:selector withArguments:arguments

    ]

! !

!WindowEvent methodsFor:'private accessing'!

for:aView type:aSymbol arguments:argArray

    "set the instances of the window event"

    view := aView.

    type := aSymbol.

    arguments := argArray

! !