"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview' }"

Image subclass:#Depth4Image

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Images'

!

!Depth4Image class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class represents 16-color (4 bit / pixel) images.

    Most images coming from the windows world are represented as Depth4Images.

    It mainly consists of methods already implemented in Image,

    reimplemented here for more performance.

    [author:]

        Claus Gittinger

    [see also:]

        Depth1Image Depth2Image Depth8Image Depth16Image Depth24Image

        ImageReader

"

! !

!Depth4Image class methodsFor:'queries'!

imageDepth

    "return the depth of images represented by instances of

     this class - here we return 4"

    ^ 4

    "Modified: 20.4.1996 / 23:40:18 / cg"

! !

!Depth4Image methodsFor:'accessing-pixels'!

colorAtX:x y:y

    "retrieve a pixel at x/y; return a color.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |lineIndex "{ Class: SmallInteger }"

     byte      "{ Class: SmallInteger }"

     value     "{ Class: SmallInteger }" |

    lineIndex := (self bytesPerRow * y) + 1.

    "left pixel in high bits"

    byte := bytes at:(lineIndex + (x // 2)).

    x even ifTrue:[

        value := (byte bitShift:-4) bitAnd:16rF.

    ] ifFalse:[

        value := byte bitAnd:16rF.

    ].

    photometric == #whiteIs0 ifTrue:[

        ^ Color gray:100 - (100 / 15 * value)

    ].

    photometric == #blackIs0 ifTrue:[

        ^ Color gray:(100 / 15 * value)

    ].

    photometric ~~ #palette ifTrue:[

        ^ self colorFromValue:value

    ].

    ^ colorMap at:(value + 1)

    "Modified: 8.6.1996 / 10:52:43 / cg"

    "Created: 24.4.1997 / 17:33:51 / cg"

!

pixelAtX:x y:y

    "retrieve a pixel at x/y; return a pixelValue.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |lineIndex "{ Class: SmallInteger }"

     byte      "{ Class: SmallInteger }" |

    lineIndex := (self bytesPerRow * y) + 1.

    "left pixel in high bits"

    byte := bytes at:(lineIndex + (x // 2)).

    x even ifTrue:[

        ^ (byte bitShift:-4) bitAnd:16rF.

    ].

    ^ byte bitAnd:16rF.

    "Created: 24.4.1997 / 16:06:43 / cg"

!

pixelAtX:x y:y put:aPixelValue

    "set the pixel at x/y to aPixelValue.

     Pixels start at x=0 , y=0 for upper left pixel, end at

     x = width-1, y=height-1 for lower right pixel"

    |lineIndex "{ Class: SmallInteger }"

     index     "{ Class: SmallInteger }"

     byte      "{ Class: SmallInteger }" |

    lineIndex := (self bytesPerRow * y) + 1.

    "left pixel is in high bits"

    index := lineIndex + (x // 2).

    byte := bytes at:index.

    x even ifTrue:[

        byte := (byte bitAnd:16rF) bitOr:(aPixelValue bitShift:4)

    ] ifFalse:[

        byte := (byte bitAnd:16rF0) bitOr:aPixelValue

    ].

    bytes at:index put:byte

    "Created: 24.4.1997 / 17:06:39 / cg"

!

rowAt:rowIndex into:aPixelBuffer

    "fill aBuffer with pixel values retrieved from a single row.

     Notice: rowIndex is 0-based."

    |lineIndex "{ Class: SmallInteger }"

     byte      "{ Class: SmallInteger }" 

     w         "{ Class: SmallInteger }" 

     pixel dstIdx|

    dstIdx := 1.

    w := width - 1.

    lineIndex := (self bytesPerRow * rowIndex).

    0 to:w do:[:x |

        x even ifTrue:[

            lineIndex := lineIndex + 1.

            byte := bytes at:lineIndex.

            pixel := (byte bitShift:-4) bitAnd:16rF.

        ] ifFalse:[

            pixel := byte bitAnd:16rF.

        ].

        aPixelBuffer at:dstIdx put:pixel.

        dstIdx := dstIdx + 1

    ].

    "Created: 21.7.1997 / 18:04:00 / cg"

    "Modified: 21.7.1997 / 18:05:47 / cg"

! !

!Depth4Image methodsFor:'converting images'!

anyImageAsTrueColorFormOn:aDevice

    "return a true-color device-form for receiver.

     Supports true color devices with depths: 8, 16, 24 and 32"

    |depth 

     colorValues 

     form imageBits bestFormat usedDeviceDepth usedDeviceBitsPerPixel 

     usedDevicePadding usedDeviceBytesPerRow padd n|

    depth := aDevice depth.

    "/ gather r/g/b values for all colors in the map ...

    colorValues := self rgbColormapFor:aDevice.

    bestFormat := self bestSupportedImageFormatFor:aDevice.

    usedDeviceDepth := bestFormat at:#depth.

    usedDeviceDepth == 1 ifTrue:[

        ^ self asMonochromeFormOn:aDevice

    ].

    usedDeviceBitsPerPixel := bestFormat at:#bitsPerPixel.

    usedDevicePadding := bestFormat at:#padding.

    usedDeviceBytesPerRow := self class bytesPerRowForWidth:width depth:usedDeviceBitsPerPixel padding:usedDevicePadding.

    padd := usedDeviceBytesPerRow -( self class bytesPerRowForWidth:width depth:usedDeviceBitsPerPixel padding:8).

    imageBits := ByteArray uninitializedNew:(usedDeviceBytesPerRow * height).

    "/ for now, only support some depths

    usedDeviceBitsPerPixel == 16 ifTrue:[

        "/ 16 bits/pixel

        "/ now, walk over the image and replace

        "/ colorMap indices by color values in the bits array

%{  

        if (__bothSmallInteger(_INST(height), _INST(width))

         && __isArray(colorValues)

         && __isByteArray(_INST(bytes))

         && __isByteArray(imageBits)) {

            int r,p;

            int x, y, w, h, nPix;

            int byte;

            unsigned char *srcPtr = __ByteArrayInstPtr(_INST(bytes))->ba_element;

            unsigned char *dstPtr = __ByteArrayInstPtr(imageBits)->ba_element;

            OBJ *ap = __ArrayInstPtr(colorValues)->a_element;

            w = __intVal(_INST(width));

            h = __intVal(_INST(height));

            r = 0;

            p = __intVal(padd);

            nPix = w * h;

            while (nPix-- > 0) {

                unsigned idx, v;

                OBJ clr;

                if (r & 1) {

                    idx = byte & 0xF;

                } else {

                    byte = *srcPtr++;

                    idx = (byte>>4) & 0xF;

                }

                clr = ap[idx];

                v = __intVal(clr);

#ifdef __MSBFIRST

                ((short *)dstPtr)[0] = v;

#else

# ifdef xxSWAP_BYTES

                SWAP_BYTES(v);

                ((short *)dstPtr)[0] = v;

# else

                dstPtr[0] = (v>>8) & 0xFF;

                dstPtr[1] = (v) & 0xFF;

# endif

#endif

                dstPtr += 2;

                if (++r == w) {

                    dstPtr += p;

                    r = 0;

                }

            }

        }

%}.

    ] ifFalse:[

        usedDeviceBitsPerPixel == 32 ifTrue:[

            "/ 32 bits/pixel

            "/ now, walk over the image and replace

            "/ colorMap indices by color values in the bits array

%{       

            if (__bothSmallInteger(_INST(height), _INST(width))

             && __isArray(colorValues)

             && __isByteArray(_INST(bytes))

             && __isByteArray(imageBits)) {

                int x, y, w, h, nPix;

                int r,p;

                int byte;

                unsigned char *srcPtr = __ByteArrayInstPtr(_INST(bytes))->ba_element;

                unsigned char *dstPtr = __ByteArrayInstPtr(imageBits)->ba_element;

                OBJ *ap = __ArrayInstPtr(colorValues)->a_element;

                w = __intVal(_INST(width));

                h = __intVal(_INST(height));

                r = 0;

                p = __intVal(padd);

                nPix = w * h;

                while (nPix > 0) {

                    unsigned idx, v;

                    OBJ clr;

                    if (r & 1) {

                        idx = byte & 0xF;

                    } else {

                        byte = *srcPtr++;

                        idx = (byte>>4) & 0xF;

                    }

                    clr = ap[idx];

                    v = __intVal(clr);

#ifdef __MSBFIRST

                    ((long *)dstPtr)[0] = v;

#else

                    dstPtr[0] = (v>>24) & 0xFF;

                    dstPtr[1] = (v>>16) & 0xFF;

                    dstPtr[2] = (v>>8) & 0xFF;

                    dstPtr[3] = (v) & 0xFF;

#endif

                    dstPtr += 4;

                    nPix--;

                    if (++r == w) {

                        dstPtr += p;

                        r = 0;

                    }

                }

            }

%}.

        ] ifFalse:[

            usedDeviceBitsPerPixel == 8 ifTrue:[

                "/ 8 bits/pixel

                "/ now, walk over the image and replace

                "/ colorMap indices by color values in the bits array

%{       

                if (__bothSmallInteger(_INST(height), _INST(width))

                 && __isArray(colorValues)

                 && __isByteArray(_INST(bytes))

                 && __isByteArray(imageBits)) {

                    int x, y, w, h, nPix;

                    int r,p, byte;

                    unsigned char *srcPtr = __ByteArrayInstPtr(_INST(bytes))->ba_element;

                    unsigned char *dstPtr = __ByteArrayInstPtr(imageBits)->ba_element;

                    OBJ *ap = __ArrayInstPtr(colorValues)->a_element;

                    w = __intVal(_INST(width));

                    h = __intVal(_INST(height));

                    r = 0;

                    p = __intVal(padd);

                    nPix = w * h;

                    while (nPix > 0) {

                        unsigned idx, v;

                        OBJ clr;

                        if (r & 1) {

                            idx = byte & 0xF;

                        } else {

                            byte = *srcPtr++;

                            idx = (byte>>4) & 0xF;

                        }

                        clr = ap[idx];

                        v = __intVal(clr);

                        dstPtr[0] = v;

                        dstPtr += 1;

                        nPix--;

                        if (++r == w) {

                            dstPtr += p;

                            r = 0;

                        }

                    }

                }

%}.

            ] ifFalse:[

                usedDeviceBitsPerPixel == 24 ifTrue:[

                    "/ 24 bits/pixel

                    "/ now, walk over the image and replace

                    "/ colorMap indices by color values in the bits array

%{       

                    if (__bothSmallInteger(_INST(height), _INST(width))

                     && __isArray(colorValues)

                     && __isByteArray(_INST(bytes))

                     && __isByteArray(imageBits)) {

                        int x, y, w, h, nPix;

                        int r, p, byte;

                        unsigned char *srcPtr = __ByteArrayInstPtr(_INST(bytes))->ba_element;

                        unsigned char *dstPtr = __ByteArrayInstPtr(imageBits)->ba_element;

                        OBJ *ap = __ArrayInstPtr(colorValues)->a_element;

                        w = __intVal(_INST(width));

                        h = __intVal(_INST(height));

                        r = 0;

                        p = __intVal(padd);

                        nPix = w * h;

                        while (nPix > 0) {

                            unsigned idx, v;

                            OBJ clr;

                            if (r & 1) {

                                idx = byte & 0xF;

                            } else {

                                byte = *srcPtr++;

                                idx = (byte>>4) & 0xF;

                            }

                            clr = ap[idx];

                            v = __intVal(clr);

                            dstPtr[0] = (v>>16) & 0xFF;

                            dstPtr[1] = (v>>8) & 0xFF;

                            dstPtr[2] = (v) & 0xFF;

                            dstPtr += 3;

                            nPix--;

                            if (++r == w) {

                                dstPtr += p;

                                r = 0;

                            }

                        }

                    }

%}.

                ] ifFalse:[

                    'Image [warning]: unimplemented trueColor depth in anyImageAsTrueColorFormOn: ' errorPrint. usedDeviceBitsPerPixel errorPrintCR.

                    ^ nil

                ]

            ]

        ]

    ].

    imageBits isNil ifTrue:[            

        ^ nil

    ].

    form := Form width:width height:height depth:usedDeviceDepth on:aDevice.

    form isNil ifTrue:[^ nil].

    form initGC.

    form

        copyBitsFrom:imageBits

        bitsPerPixel:usedDeviceBitsPerPixel

        depth:usedDeviceDepth

        padding:usedDevicePadding

        width:width height:height 

        x:0 y:0

        toX:0 y:0. 

    ^ form

    "Created: 20.10.1995 / 22:05:10 / cg"

    "Modified: 21.10.1995 / 19:30:26 / cg"

!

greyImageAsTrueColorFormOn:aDevice

    "return a true-color device-form for the grey-image receiver.

     Supports true color devices with depths: 8, 16, 24 and 32"

    |f|

    f := self anyImageAsTrueColorFormOn:aDevice.

    f notNil ifTrue:[^ f].

    ^ super greyImageAsTrueColorFormOn:aDevice

    "Created: / 24.7.1998 / 01:21:28 / cg"

!

paletteImageAsTrueColorFormOn:aDevice

    "return a true-color device-form for the palette-image receiver.

     Supports true color devices with depths: 8, 16, 24 and 32"

    |f|

    f := self anyImageAsTrueColorFormOn:aDevice.

    f notNil ifTrue:[^ f].

    ^ super paletteImageAsTrueColorFormOn:aDevice

    "Created: / 24.7.1998 / 01:20:46 / cg"

!

rgbImageAsTrueColorFormOn:aDevice

    "return a true-color device-form for the rgb-image receiver.

     Supports true color devices with depths: 8, 16, 24 and 32"

    |f|

    f := self anyImageAsTrueColorFormOn:aDevice.

    f notNil ifTrue:[^ f].

    ^ super rgbImageAsTrueColorFormOn:aDevice

    "Created: / 24.7.1998 / 01:21:57 / cg"

! !

!Depth4Image methodsFor:'dither helpers'!

orderedDitheredGrayBitsWithDitherMatrix:ditherMatrix ditherWidth:dW depth:depth

    "return the bitmap for a dithered depth-bitmap from the image;

     with a constant ditherMatrix, this can be used for thresholding.

     Redefined to make use of knowing that pixels are 4-bit values."