"

 COPYRIGHT (c) 1991 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ImageReader subclass:#TIFFReader

         instanceVariableNames:'planarConfiguration

                                subFileType stripOffsets rowsPerStrip

                                fillOrder compression group3options predictor

                                stripByteCounts

                                currentOffset 

                                stripOffsetsPos stripByteCountsPos bitsPerSamplePos

                                colorMapPos'

         classVariableNames:''

         poolDictionaries:''

         category:'Graphics-Support'

!

TIFFReader comment:'

COPYRIGHT (c) 1991 by Claus Gittinger

              All Rights Reserved

$Header: /cvs/stx/stx/libview2/Attic/TIFFRdr.st,v 1.6 1994-01-08 17:10:32 claus Exp $

written Summer 91 by claus

'!

!TIFFReader class methodsFor:'documentation'!

documentation

"

This class knows how to read TIFF files and how to

write uncompressed TIFF files.

Only single image files are supported.

Currently, not all formats are implemented, and of those that are not 

all are tested.

It should work with most rgb, mono and 2-plane greyscale

images, since this is what I have as test material on

the NeXT.

It supports reading of uncompressed, LZW and G3 compressed 

images; JPEG and packbits are currently not implemented.

Only writing of uncompressed images is currently implemented.

More formats will come ...

"

! !

!TIFFReader class methodsFor:'testing'!

isValidImageFile:aFileName

    "return true, if aFileName contains a GIF image"

    |inStream char1 char2 version|

    inStream := self streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ false].

    char1 := inStream next.

    char2 := inStream next.

    ((char1 ~~ char2) or:[(char1 ~~ $I) and:[char1 ~~ $M]]) ifTrue:[

        inStream close.

        ^ false

    ].

    inStream binary.

    version := inStream nextShortMSB:(char1 == $M).

    inStream close.

    (version ~~ 42) ifTrue:[^ false].

    ^ true

! !

!TIFFReader methodsFor:'reading from file'!

fromFile:aFileName

    "read an image from aFileName"

    |char1 char2 version 

     numberOfTags "{ Class: SmallInteger }"

     tagType      "{ Class: SmallInteger }"

     numberType   "{ Class: SmallInteger }"

     length       "{ Class: SmallInteger }"

     result offset ok|

    inStream := self class streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ nil].

    char1 := inStream next.

    char2 := inStream next.

    (char1 ~~ char2) ifTrue:[

        'not a tiff file' printNewline.

        inStream close.

        ^ nil

    ].

    (char1 == $I) ifTrue:[

        byteOrder := #lsb

    ] ifFalse:[

        (char1 == $M) ifTrue:[

            byteOrder := #msb

        ] ifFalse:[

            'not a tiff file' printNewline.

            inStream close.

            ^ nil

        ]

    ].

    inStream binary.

    version := self readShort.

    (version ~~ 42) ifTrue:[

        'version of tiff-file not supported' printNewline.

        inStream close.

        ^ nil

    ].

    "setup default values"

    compression := 1. "none"

    fillOrder := #msb.

    planarConfiguration := 1.

    photometric := nil.

    bitsPerSample := 1.

    samplesPerPixel := 1.

    width := nil.

    height := nil.

    stripOffsets := nil.

    rowsPerStrip := nil.

    "resolutionUnit := 2."

    predictor := 1.

    offset := self readLong + 1.

    inStream position:offset.

    numberOfTags := self readShort.

    1 to:numberOfTags do:[:index |

        tagType := self readShort.

        numberType := self readShort.

        length := self readLong.

        self decodeTiffTag:tagType numberType:numberType length:length

    ].

    offset := self readLong.

    (offset ~~ 0) ifTrue:[

        'more tags ignored' printNewline

    ].

    "check for required tags"

    ok := true.

    width isNil ifTrue:[

        'missing width tag' printNewline.

        ok := false

    ].

    height isNil ifTrue:[

        'missing length tag' printNewline.

        ok := false

    ].

    photometric isNil ifTrue:[

        'missing photometric tag' printNewline.

        ok := false

    ].

    stripOffsets isNil ifTrue:[

        'missing stripOffsets tag' printNewline.

        ok := false

    ].

    ok ifFalse:[

        inStream close.

        ^ nil

    ].

    "given all the information, read the bits"

    rowsPerStrip isNil ifTrue:[

        rowsPerStrip := height

    ].

    (compression == 1) ifTrue:[

      result := self readUncompressedTiffImageData

    ] ifFalse:[

      (compression == 5) ifTrue:[

        result := self readLZWTiffImageData

      ] ifFalse:[

        (compression == 2) ifTrue:[

          "result := self readCCITT3ModHuffmanTiffImageData"

          'ccitt mod Huffman compression not implemented' printNewline

        ] ifFalse:[ 

          (compression == 3) ifTrue:[

            result := self readCCITTGroup3TiffImageData

          ] ifFalse:[ 

            (compression == 4) ifTrue:[

              "result := self readCCITTGroup4TiffImageData"

              'ccitt group4 fax compression not implemented' printNewline

            ] ifFalse:[ 

              (compression == 32773) ifTrue:[

                result := self readPackbitsTiffImageData

              ] ifFalse:[

                  (compression == 32865) ifTrue:[

                    result := self readJPEGTiffImageData

                  ] ifFalse:[

                    'compression type ' , compression printString , ' not known' printNewline

                  ] 

              ] 

            ] 

          ] 

        ] 

      ] 

    ].

    inStream close.

    ^ result

! !

!TIFFReader methodsFor:'writing to file'!

save:image onFile:aFileName

    "save image as (uncompressed) TIFF file on aFileName"

    |pos1 pos|

    outStream := FileStream newFileNamed:aFileName.

    outStream isNil ifTrue:[

        'create error' printNewline. 

        ^ nil

    ].

    "save as msb"

    byteOrder := #msb.

"

    byteOrder := #lsb.

"

    fillOrder := #msb.

    width := image width.

    height := image height.

    photometric := image photometric.

    samplesPerPixel := image samplesPerPixel.

    bitsPerSample := image bitsPerSample.

    colorMap := image colorMap.

    planarConfiguration := 1.

    compression := 1.   "none"

    data := image bits.

    currentOffset := 0.

    (byteOrder == #msb) ifTrue:[

        outStream nextPut:$M.

        outStream nextPut:$M.

    ] ifFalse:[

        outStream nextPut:$I.

        outStream nextPut:$I.

    ].

    currentOffset := currentOffset + 2.

    outStream binary.

    self writeShort:42.

    currentOffset := currentOffset + 2.

    pos1 := outStream position.

    self writeLong:0.           "start of tags - filled in later"

    currentOffset := currentOffset + 4.

    "output strips"

    self writeUncompressedBits. "this outputs bits as strips, sets stripOffsets and stripByteCounts"

    self writeStripOffsets.     "this outputs strip offsets, sets stripOffsetsPos"

    self writeStripByteCounts.  "this outputs strip bytecounts, sets stripByteCountPos"

    self writeBitsPerSample.    "this outputs bitsPerSample, sets bitsPerSamplePos"

    photometric == #palette ifTrue:[

        self writeColorMap      "this outputs colorMap, sets colorMapPos"

    ].

    pos := outStream position.                  "backpatch tag offset"

    outStream position:pos1.

    self writeLong:(pos - 1).                   "fill in tag offset"

    outStream position:pos.

"

('patch tag offset at: ', (pos1 printStringRadix:16) , ' to ',

                         (pos printStringRadix:16)) printNewline.

"

    "output tag data"

    photometric == #palette ifTrue:[

        self writeShort:10.  "10 tags"

    ] ifFalse:[

        self writeShort:9.   "9 tags"

    ].

    self writeTag:256.               "image width"

    self writeTag:257.               "image height"

    self writeTag:258.               "bits per sample"

    self writeTag:259.               "compression"

    self writeTag:262.               "photometric"

    self writeTag:273.               "strip offsets"

    self writeTag:279.               "strip byte counts"

    self writeTag:284.               "planarconfig"

    self writeTag:278.               "rowsPerStrip"

    photometric == #palette ifTrue:[

        self writeTag:320            "colorMap"

    ].

    self writeLong:0.                "end of tags mark"

    outStream close

! !

!TIFFReader methodsFor:'private'!

readLongs:n

    |oldPos offset values|

    values := Array new:n.

    (n == 1) ifTrue:[

        values at:1 put:self readLong.

    ] ifFalse:[

        offset := self readLong.

        oldPos := inStream position.

        inStream position:(offset + 1).

        1 to:n do:[:index |

            values at:index put:self readLong

        ].

        inStream position:oldPos

    ].

    ^ values

!

writeLongs:longs

    1 to:longs size do:[:l |

        self writeLong:l

    ]

!

readShorts:n

    |oldPos offset values|

    values := Array new:n.

    (n <= 2) ifTrue:[

        values at:1 put:self readShort.

        (n == 2) ifTrue:[

            values at:2 put:self readShort

        ] ifFalse:[

            self readShort

        ]

    ] ifFalse:[

        offset := self readLong.

        oldPos := inStream position.

        inStream position:(offset + 1).

        1 to:n do:[:index |

            values at:index put:self readShort

        ].

        inStream position:oldPos

    ].

    ^ values

!

readChars:n

    |oldPos offset string|

    string := String new:(n - 1).

    (n <= 4) ifTrue:[

        inStream nextBytes:(n - 1) into:string

    ] ifFalse:[

        offset := self readLong.

        oldPos := inStream position.

        inStream position:(offset + 1).

        inStream nextBytes:(n - 1) into:string.

        inStream position:oldPos

    ].

    ^ string

!

readFracts:cnt

    |oldPos offset values n d|

    values := Array new:cnt.

    offset := self readLong.

    oldPos := inStream position.

    inStream position:(offset + 1).

    1 to:cnt do:[:index |

        n := self readLong.

        d := self readLong.

        values at:index put:(Fraction numerator:n denominator:d)

    ].

    inStream position:oldPos.

    ^ values

!

decodeTiffTag:tagType numberType:numberType length:length

    |offset value valueArray 

     val

     n "{ Class: SmallInteger }" |

    (numberType == 3) ifTrue:[

        "short"

        valueArray := self readShorts:length.

        value := valueArray at:1

    ] ifFalse:[

        (numberType == 4) ifTrue:[

            "integer"

            valueArray := self readLongs:length.

            value := valueArray at:1

        ] ifFalse:[

            (numberType == 2) ifTrue:[

                "character"

                value := self readChars:length

            ] ifFalse:[

                (numberType == 5) ifTrue:[

                    "fraction"

                    valueArray := self readFracts:length.

                    value := valueArray at:1

                ] ifFalse:[

                    offset := self readLong

                ]

            ]

        ]

    ].

    (tagType == 254) ifTrue:[

        "NewSubfileType"

        "newSubFileType := value."

"

        'newSubfiletype ' print. value printNewline.

"

        ^ self

    ].

    (tagType == 255) ifTrue:[

        "SubfileType"

        subFileType := value.

"

        'subfiletype ' print. value printNewline.

"

        ^ self

    ].

    (tagType == 256) ifTrue:[

        "ImageWidth"

        width := value.

        'width ' print. width printNewline.

"

        ^ self

"

    ].

    (tagType == 257) ifTrue:[

        "ImageHeight"

        height := value.

"

        'height ' print. height  printNewline.

"

        ^ self

    ].

    (tagType == 258) ifTrue:[

        "bitspersample"

         bitsPerSample := valueArray.

"

        'bitspersample ' print. bitsPerSample printNewline.

"

        ^ self

    ].

    (tagType == 259) ifTrue:[

        "compression"

        compression := value.

"

        'compression ' print. compression printNewline.

"

        ^ self

    ].

    (tagType == 262) ifTrue:[

        "photometric"

        (value == 0) ifTrue:[

          photometric := #whiteIs0

        ] ifFalse:[

          (value == 1) ifTrue:[

            photometric := #blackIs0

          ] ifFalse:[

            (value == 2) ifTrue:[

              photometric := #rgb

            ] ifFalse:[

              (value == 3) ifTrue:[

                photometric := #palette

              ] ifFalse:[

                (value == 4) ifTrue:[

                  photometric := #transparency

                ] ifFalse:[

                  photometric := nil

                ]

              ]

            ]

          ]

        ].

"

        'photometric ' print. photometric printNewline.

"

        ^ self

    ].

    (tagType == 263) ifTrue:[

        "Treshholding"

        "threshholding := value."

"

        'treshholding ' print. value printNewline.

"

        ^ self

    ].

    (tagType == 264) ifTrue:[

        "CellWidth"

        "cellWidth:= value."

"