"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

"{ NameSpace: Smalltalk }"

ImageReader subclass:#PNGReader

        instanceVariableNames:'colorType bitsPerChannel depth compressionMethod filterMethod

                interlaceMode bytesPerScanline globalDataChunk thisScanline

                prevScanline processTextChunks'

        classVariableNames:'Verbose'

        poolDictionaries:''

        category:'Graphics-Images-Readers'

!

!PNGReader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1996 by Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class will provide methods for loading and saving PNG pictures.

    It is currenty unfinished (some interlaced image formats are unsupported, for example: grayscale+alpha)

    In the meantime, use a pngtoXXX converter for interlaced images, and read XXX.

    [caveats:]

        writer ignores any mask (for now).

        writer only generates unfiltered non-interlaced data

    [See also:]

        Image Form Icon

        BlitImageReader FaceReader GIFReader JPEGReader PBMReader PCXReader 

        ST80FormReader SunRasterReader TargaReader TIFFReader WindowsIconReader 

        XBMReader XPMReader XWDReader 

    [author:]

        Claus Gittinger

"

!

examples

"

    PNGReader fromFile:'/home/cg/AudioExplorer_51_files/use_small.png'

    PNGReader fromFile:'\\Exeptn\tmp\images\expeccoScreenshot4020_5526507.png'

    PNGReader fromFile:'C:\Users\cg\Desktop\croquet\cobalt-base-current-build-20090210\cobalt-base-current-build-20090210\content\models\textures\checkerboard.png'

    PNGReader fromFile:'C:\Dokumente und Einstellungen\cg\Desktop\misc\PNGs\Delete.png'

    PNGReader fromFile:'\\exeptn\unsaved\pd_stuff\PNGs\Delete.png'

    PNGReader fromFile:'\\exeptn\unsaved\pd_stuff\PNGs\Down.png'

    |img img2 outStream png|

    img := ToolbarIconLibrary error32x32Icon.

    outStream := WriteStream on:(ByteArray new:100).

    PNGReader save:img onStream:outStream.

    png := outStream contents.

    img2 := PNGReader fromStream:(png readStream).

    self assert:(img bits = img2 bits).

    img inspect.

    img2 inspect.

"

! !

!PNGReader class methodsFor:'initialization'!

initialize

    "install myself in the Image classes fileFormat table for the `.png' extension."

    MIMETypes defineImageType:'image/png'  suffix:'png' reader:self.

    "/ backward compatibility from times when png was not yet so common...

    MIMETypes defineImageType:'image/x-png' suffix:nil reader:self.

! !

!PNGReader class methodsFor:'queries'!

canRepresent:anImage

    "return true, if anImage can be represented in my file format.

     Any image is supported."

    ^ true

! !

!PNGReader class methodsFor:'testing'!

isValidImageFile:aFileName

    "return true, if aFileName contains a PNG image"

    |inStream magic|

    inStream := self streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ false].

    inStream binary.

    magic := ByteArray new:8.

    inStream nextBytes:8 into:magic.

    inStream close.

    ^ (magic = #[137 80 78 71 13 10 26 10])

    "

     self isValidImageFile:'/home/cg/AudioExplorer_51_files/use_small.png'

     self isValidImageFile:'C:\Users\cg\Desktop\croquet\cobalt-base-current-build-20090210\cobalt-base-current-build-20090210\content\models\textures\checkerboard.png'

     self isValidImageFile:'C:\Dokumente und Einstellungen\cg\Desktop\misc\PNGs\Delete.png'

    "

    "Modified: 21.6.1996 / 20:38:46 / cg"

! !

!PNGReader methodsFor:'private-chunks'!

doPass: pass

    "Certain interlace passes are skipped with certain small image dimensions"

    pass = 1 ifTrue: [ ^ true ].

    ((width = 1) and: [height = 1]) ifTrue: [ ^ false ].

    pass = 2 ifTrue: [ ^ width >= 5 ].

    pass = 3 ifTrue: [ ^ height >= 5 ].

    pass = 4 ifTrue: [ ^ (width >=3 ) or: [height >= 5] ].

    pass = 5 ifTrue: [ ^ height >=3 ].

    pass = 6 ifTrue: [ ^ width >=2 ].

    pass = 7 ifTrue: [ ^ height >=2 ].

    self error:'invalid argument'.

    ^ true

!

processBKGDChunkLen:len

    inStream skip:len.

    ^ true

    "Created: 21.6.1996 / 21:15:49 / cg"

!

processCHRMChunkLen:len

    "cHRM Primary chromaticities chunk - currently unhandled"

    |whitePointX whitePointY redX redY greenX greenY blueX blueY|

    whitePointX := (inStream nextInt32MSB:true) / 100000.0.

    whitePointY := (inStream nextInt32MSB:true) / 100000.0.

    redX := (inStream nextInt32MSB:true) / 100000.0.

    redY := (inStream nextInt32MSB:true) / 100000.0.

    greenX := (inStream nextInt32MSB:true) / 100000.0.

    greenY := (inStream nextInt32MSB:true) / 100000.0.

    blueX := (inStream nextInt32MSB:true) / 100000.0.

    blueY := (inStream nextInt32MSB:true) / 100000.0.

    Verbose == true ifTrue:[

        'PNGReader: CHRM chunk ignored:' infoPrintCR.

        'PNGReader:   whitePointX:' infoPrint. whitePointX infoPrintCR.

        'PNGReader:   whitePointY:' infoPrint. whitePointX infoPrintCR.

        'PNGReader:   redX:' infoPrint. redX infoPrintCR.

        'PNGReader:   redY:' infoPrint. redY infoPrintCR.

        'PNGReader:   greenX:' infoPrint. greenX infoPrintCR.

        'PNGReader:   greenY:' infoPrint. greenY infoPrintCR.

        'PNGReader:   blueX:' infoPrint. blueX infoPrintCR.

        'PNGReader:   blueY:' infoPrint. blueY infoPrintCR.

    ].

    ^ true

!

processChunk:type len:len

    |chunk|

    type = 'IDAT' ifTrue:[

        "---since the compressed data can span multiple

        chunks, stitch them all together first. later,

        if memory is an issue, we need to figure out how

        to do this on the fly---"

        chunk := inStream next:len.

        globalDataChunk isNil ifTrue:[

            globalDataChunk := ReadWriteStream on:(ByteArray new:(height * self bytesPerRow)).

        ].

        globalDataChunk nextPutAll:chunk.

        ^ true

    ].

    type = 'gAMA' ifTrue:[^ self processGAMAChunkLen:len].

    type = 'sBIT' ifTrue:[^ self processSBITChunkLen:len].

    type = 'tEXt' ifTrue:[^ self processTEXTChunkLen:len].

    type = 'tIME' ifTrue:[^ self processTIMEChunkLen:len].

    type = 'bKGD' ifTrue:[^ self processBKGDChunkLen:len].

    type = 'zTXt' ifTrue:[^ self processZTXTChunkLen:len].

    type = 'PLTE' ifTrue:[^ self processPLTEChunkLen:len].

    type = 'pHYs' ifTrue:[^ self processPHYSChunkLen:len].

    type = 'cHRM' ifTrue:[^ self processCHRMChunkLen:len].

    type = 'tRNS' ifTrue:[^ self processTRNSChunkLen:len].

    type = 'IHDR' ifTrue:[^ self processIHDRChunkLen:len].

    type = 'iTXt' ifTrue:[^ self processITXTChunkLen:len].

    type = 'iCCP' ifTrue:[^ self processICCPChunkLen:len].

    ('PNGReader: unrecognized chunk: ' , type , ' ignored.') infoPrintCR.

    inStream skip:len.

    ^ true.

    "Created: 21.6.1996 / 21:10:37 / cg"

    "Modified: 21.6.1996 / 21:22:37 / cg"

!

processGAMAChunkLen:len

    inStream skip:len.

    ^ true

    "Created: 21.6.1996 / 21:10:52 / cg"

!

processGlobalIDATChunk

    interlaceMode == 0 ifTrue: [

        ^ self processNonInterlacedGlobalDATA

    ]. 

    ^ self processInterlacedGlobalDATA

!

processICCPChunkLen:len

    "/ ignored

    "/ inStream nextBytes:len.

    inStream skip:len.

    ^ true

    "Created: 21.6.1996 / 21:15:58 / cg"

!

processIDATChunkLen:len

    interlaceMode == 0 ifTrue: [

        ^ self processNonInterlacedDATA:len

    ]. 

    ^ self processInterlacedDATA:len

!

processIHDRChunkLen:len

    "/ ignored

    inStream skip:len.

    ^ true

    "Created: 21.6.1996 / 21:15:58 / cg"

!

processITXTChunkLen:len

    "/ international (i.e.utf8) textual data.

    "/ currently ignored - not needed to display png images

    "/

    "/   Keyword:             1-79 bytes (character string)

    "/   Null separator:      1 byte

    "/   Compression flag:    1 byte

    "/   Compression method:  1 byte

    "/   Language tag:        0 or more bytes (character string)

    "/   Null separator:      1 byte

    "/   Translated keyword:  0 or more bytes

    "/   Null separator:      1 byte

    "/   Text:                0 or more bytes

    "/ if needed, set processTextChunks to true somewhere...

    processTextChunks == true ifTrue:[

        |chunkData keyword text i1 i2 i3 

         compressionFlag compressionMethod languageTag

         xlatedKeyword textBytes|

        chunkData := inStream nextBytes:len.

        i1 := chunkData indexOf:0.

        keyword := (chunkData copyTo:i1-1) asString.

        compressionFlag := chunkData at:i1+1.

        compressionMethod := chunkData at:i1+2.

        i2 := chunkData indexOf:0 startingAt:i1+3.

        languageTag := (chunkData copyFrom:i1+3 to:i2-1) asString.

        i3 := chunkData indexOf:0 startingAt:i2+1.

        xlatedKeyword := (chunkData copyFrom:i2+1 to:i3-1) asString.

        textBytes := chunkData copyFrom:i3+1.

        compressionFlag == 0 ifTrue:[

            text := textBytes

        ] ifFalse:[

            compressionFlag == 1 ifTrue:[

                "/ for now, only zlib compression is supported...

                'zlib compression currently unsupported' infoPrintCR.

            ] ifFalse:[

                'unsupported compression method' infoPrintCR.

            ].    

        ].    

        text := text utf8Decoded.

        self handleText:text keyword:keyword.

    ] ifFalse:[    

        inStream skip:len.

    ].

    ^ true

    "Created: 21.6.1996 / 21:15:58 / cg"

!

processInterlacedDATA:len

    inStream skip:len.

    ^ true

!

processInterlacedGlobalDATA

    "adam7 interlace method"

    | zlibReader filter 

      bytesPerPass startingCol colIncrement rowIncrement 

      startingRow 

      temp "filtersSeen"  

      cx       "{ Class: SmallInteger }"

      sc       "{ Class: SmallInteger }"

      cy       "{ Class: SmallInteger }"

      startRow "{ Class: SmallInteger }"

      w        "{ Class: SmallInteger }"

      h        "{ Class: SmallInteger }"

    |

    interlaceMode == 1 ifFalse: [

        self error:'unsupported interlaced mode'.

        ^ self

    ].

    "/ filtersSeen := Set new.

    startingCol := #(0 4 0 2 0 1 0 ).

    startingRow := #(0 0 4 0 2 0 1 ).

    colIncrement := #(8 8 4 4 2 2 1 ).

    rowIncrement := #(8 8 8 4 4 2 2 ).

    globalDataChunk reset.

    zlibReader := ZipStream readOpenAsZipStreamOn:globalDataChunk suppressHeaderAndChecksum:false.

    zlibReader binary.

    h := height.

    w := width.

    1 to: 7 do: [:pass |

        (self doPass: pass) ifTrue:[

            cx := colIncrement at: pass.

            sc := startingCol at: pass.

            cy := rowIncrement at: pass.

            bytesPerPass := (((w - sc + cx - 1) // cx * depth) + 7) // 8.

            prevScanline := ByteArray new: bytesPerPass.

            thisScanline := ByteArray new: bytesPerScanline.

            startRow := startingRow at: pass.

            startRow to: h-1 by: cy do: [:y |

                filter := zlibReader nextByte.

                "/ filtersSeen add: filter.

                (filter isNil or: [(filter between: 0 and: 4) not])

                    ifTrue: [^ self].

                zlibReader next: bytesPerPass into: thisScanline startingAt: 1.

                filter ~~ 0 ifTrue:[ self filterScanline: filter count: bytesPerPass ].

                self copyPixels:y at:sc by:cx.

                temp := prevScanline.

                prevScanline := thisScanline.

                thisScanline := temp.

            ]

        ]

    ].

    zlibReader atEnd ifFalse:[self error:'Unexpected data'].

    "Modified: / 03-05-2011 / 12:03:33 / cg"

!

processNonInterlacedDATA:len

    self halt:'not used'

"/

"/    | zlibReader filter temp prevScanline thisScanline bytesPerScanline filtersSeen|

"/

"/    zlibReader := ZipStream readOpenAsZipStreamOn:inStream suppressHeaderAndChecksum:false. 

"/    "/ zlibReader := ZLibReadStream on:inStream from: 1 to:len.

"/

"/    prevScanline := ByteArray new: self bytesPerRow.

"/    thisScanline := ByteArray new: self bytesPerRow.

"/    0 to: height - 1 do:[:index | 

"/            filter := (zlibReader next: 1) first.

"/            filtersSeen add: filter.

"/            (filter isNil or: [(filter between: 0 and: 4) not]) ifTrue: [^self].

"/            thisScanline := zlibReader next: bytesPerScanline into: thisScanline startingAt: 1.

"/            self filterScanline: filter count: bytesPerScanline.

"/            self copyPixels: index.

"/            temp := prevScanline.

"/            prevScanline := thisScanline.

"/            thisScanline := temp

"/    ]

!

processNonInterlacedGlobalDATA

    | "data n" zlibReader filter temp "filtersSeen" i|

    "/ filtersSeen := Set new.

"/    data := ByteArray new:(self bytesPerRow * height)+1000.

"/    n := ZipStream uncompress: globalDataChunk into: data.

"/    self halt.

    globalDataChunk reset.

    zlibReader := ZipStream readOpenAsZipStreamOn:globalDataChunk suppressHeaderAndChecksum:false.

    zlibReader binary.

    prevScanline := ByteArray new: bytesPerScanline.

    thisScanline := ByteArray new: bytesPerScanline.

    0 to: height - 1 do:[:y | 

        filter := zlibReader nextByte.

        "/ filtersSeen add: filter.

        (filter notNil and: [filter between: 0 and: 4]) ifFalse: [

            'PNGReader: unsupported filter: ' infoPrint. filter infoPrintCR.

            ^ self

        ].

        zlibReader next: bytesPerScanline into: thisScanline startingAt: 1.

        filter ~~ 0 ifTrue:[ self filterScanline: filter count: bytesPerScanline ].

        i := y * bytesPerScanline.

        data replaceFrom:i+1 to:(i+bytesPerScanline) with:thisScanline startingAt:1.

        temp := prevScanline.

        prevScanline := thisScanline.

        thisScanline := temp

    ].

    "/ Fill in mask if image contains alpha channel

    photometric == #rgba ifTrue:[ 

        | maskBits |

        mask := AlphaMask width: width height: height.

        maskBits := ByteArray new: width * height.

        0 to: height - 1 do:[:y | 

            0 to: width - 1 do:[:x |  

                | alpha |

                alpha := data at: (y * bytesPerScanline) + (x * 4) + 1.

                maskBits at: (y*width) + x + 1 put: alpha

            ]

        ].

        mask bits: maskBits

    ].

    "Modified: / 11-04-2016 / 08:39:44 / Jan Vrany <jan.vrany@fit.cvut.cz>"

!

processPHYSChunkLen:len

    "physical pixel chunk - currently unhandled"

    |pixelPerUnitX pixelPerUnitY unit|

    pixelPerUnitX := inStream nextInt32MSB:true.  

    pixelPerUnitY := inStream nextInt32MSB:true.

    unit := inStream nextByte.

    Verbose == true ifTrue:[

        'PNGReader: PHYS chunk ignored:' infoPrintCR.

        'PNGReader:   ppuX:' infoPrint. pixelPerUnitX infoPrintCR.

        'PNGReader:   ppuY:' infoPrint. pixelPerUnitY infoPrintCR.

        'PNGReader:   unit:' infoPrint. unit infoPrintCR.

    ].

    ^ true

!

processPLTEChunkLen:len

    "read a color palette"

    |n "{ Class: SmallInteger }"

     redBytes greenBytes blueBytes|

    (len \\ 3) ~~ 0 ifTrue:[

        'PNGReader: invalid size of PLTE chunk' infoPrintCR.

        ^ false

    ].

    n := len // 3.

    redBytes := ByteArray new:n.

    greenBytes := ByteArray new:n.

    blueBytes := ByteArray new:n.

    1 to:n do:[:i |