"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

"{ NameSpace: Smalltalk }"

ImageReader subclass:#TIFFReader

	instanceVariableNames:'planarConfiguration subFileType stripOffsets rowsPerStrip

		fillOrder compression group3options predictor stripByteCounts

		currentOffset stripOffsetsPos stripByteCountsPos bitsPerSamplePos

		colorMapPos orientation isBigTiff'

	classVariableNames:'Verbose'

	poolDictionaries:''

	category:'Graphics-Images-Readers'

!

Dictionary subclass:#TIFFMetaData

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	privateIn:TIFFReader

!

!TIFFReader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class knows how to read TIFF files and how to write uncompressed TIFF files.

    Implemented & Missing Features:

      - Only single image files are supported.

      - Not all formats are implemented, and of those that are, not all are tested.

        It should read with most rgb, palette, mono and greyscale images, 

        although the alpha channel is currently not supported and ignored.

        It supports reading of uncompressed, LZW, packbits and CCITT-G3 compressed images

        JPEG and many other formats are currently not implemented.

      - Only writing of uncompressed images is currently implemented.

        It should write (at least) mono, 8-bit palette and 24 bit rgb formats.

      - bigTiff is supported

      - some dng tags are supported

    More formats will come... (will they ever be needed?)

    TODO (?): 

        since I don't want to spend all of my life adding more formats here and

        reinventing the wheel, this code should be changed to use the tiff library.

        That would give us most formats and also writing capabilities for free.

        Late note: 

            I hate C and interfacing to C libraries: it almost always leads to trouble

            w.r.t. memory leaks, non-reentrancy, non-interruptability etc.

            (we recently fixed a malloc-non-reentrant bug for some architecture...)

            So its probably better to do it all in a real programming language ;-)

    [author:]

        Claus Gittinger

    [See also:]

        Image Form Icon

        BlitImageReader FaceReader GIFReader JPEGReader PBMReader PCXReader 

        ST80FormReader SunRasterReader TargaReader WindowsIconReader 

        XBMReader XPMReader XWDReader 

"

! !

!TIFFReader class methodsFor:'initialization'!

initialize

    "install myself in the Image classes fileFormat table

     for the `.tiff' and `.tif' extensions."

    MIMETypes defineImageType:'image/tiff' suffix:'tif'  reader:self.

    MIMETypes defineImageType:nil          suffix:'tiff' reader:self.

    "

     self initialize

    "

    "Modified: 1.2.1997 / 15:00:01 / cg"

! !

!TIFFReader class methodsFor:'testing'!

canRepresent:anImage

    "return true, if anImage can be represented in my file format.

     Any image is supported."

    ^ true

!

isValidImageFile:aFileName

    "return true, if aFileName contains a GIF image"

    |inStream char1 char2 version|

    inStream := self streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ false].

    char1 := inStream next.

    char2 := inStream next.

    ((char1 ~~ char2) or:[(char1 ~~ $I) and:[char1 ~~ $M]]) ifTrue:[

        inStream close.

        ^ false

    ].

    inStream binary.

    version := inStream nextInt16MSB:(char1 == $M).

    inStream close.

    "/ 43 is bigTiff

    ^ (version == 42) or:[ (version == 43) ]

    "Modified: / 25-08-2017 / 08:39:20 / cg"

! !

!TIFFReader methodsFor:'private-data reading'!

readCCITT3RLETiffImageData

    ^ self fileFormatError:'ccitt G3 mod Huffman (rle) compression not implemented'

    "Modified: / 3.2.1998 / 18:03:14 / cg"

!

readCCITT3RLEWTiffImageData

    ^ self fileFormatError:'ccitt G3 mod Huffman (rlew) compression not implemented'.

    "Modified: / 3.2.1998 / 18:03:30 / cg"

!

readCCITTGroup3TiffImageData

    "not really tested - all I got is a single fax from NeXT step"

    |bytesPerRow bitsPerRow compressedStrip nPlanes 

     stripNr       "{ Class: SmallInteger }"

     offset        "{ Class: SmallInteger }"

     row           "{ Class: SmallInteger }"

     bytesPerStrip "{ Class: SmallInteger }" |

    nPlanes := samplesPerPixel.

    (nPlanes ~~ 1) ifTrue:[

        (nPlanes == 2) ifTrue:[

            (planarConfiguration ~~ 2) ifTrue:[

                ^ self fileFormatError:'only separate planes are supported'.

            ].

            'TIFFReader [info]: ignoring alpha plane' infoPrintCR.

            nPlanes := 1

        ] ifFalse:[

            ^ self fileFormatError:'only monochrome/greyscale ccitt3supported'.

        ].   

    ].

"/    (rowsPerStrip ~~ 1) ifTrue:[

"/        ^ self fileFormatError:'currently require rowsPerStrip to be 1'.

"/    ].

    "/ 'TIFFReader: decompressing CCITT-3 ...' infoPrintNL.

    bitsPerRow := width * (bitsPerSample at:1).

    bytesPerRow := bitsPerRow // 8.

    ((bitsPerRow \\ 8) ~~ 0) ifTrue:[

        bytesPerRow := bytesPerRow + 1

    ].

    data := ByteArray new:(bytesPerRow * height).

    "/ if the number of rows per strip is unknown (-1),

    "/ make it one big strip and decompress that

    rowsPerStrip = 16rFFFFFFFF ifTrue:[

        compressedStrip := ByteArray uninitializedNew:(stripByteCounts sum).

        self positionToStrip:1.

        inStream nextBytes:(compressedStrip size) into:compressedStrip.

        self class 

            decompressCCITT3From:compressedStrip

            into:data

            startingAt:1

            count:compressedStrip size.

        ^ self 

    ].

    compressedStrip := ByteArray uninitializedNew:bytesPerRow.

    offset := 1.

    stripNr := 0.

    row := 1.

    bytesPerStrip := bytesPerRow * rowsPerStrip.

    [row <= height] whileTrue:[

        stripNr := stripNr + 1.

        self positionToStrip:stripNr.

        inStream nextBytes:(stripByteCounts at:stripNr) into:compressedStrip.

        self class 

            decompressCCITT3From:compressedStrip

            into:data

            startingAt:offset

            count:width.

        offset := offset + bytesPerStrip.

        row := row + rowsPerStrip

    ]

    "Modified: / 25-08-2017 / 11:09:02 / cg"

!

readCCITTGroup4TiffImageData

    ^ self fileFormatError:'ccitt group4 fax compression not implemented'.

    "Modified: / 3.2.1998 / 18:04:34 / cg"

!

readCCITTRLEWTiffImageData

    ^ self fileFormatError:'ccitt mod Huffman (rlew) compression not implemented'

!

readDCSTiffImageData

    ^ self fileFormatError:'dcs compression not implemented'.

    "Modified: / 3.2.1998 / 18:04:44 / cg"

!

readDeflateTiffImageData

    ^ self fileFormatError:'deflate compression not implemented'.

    "Modified: / 3.2.1998 / 18:04:54 / cg"

!

readJBIGTiffImageData

    ^ self fileFormatError:'jbig compression not implemented'.

    "Modified: / 3.2.1998 / 18:05:04 / cg"

!

readJPEGTiffImageData

    ^ self fileFormatError:'jpeg compression not implemented'.

    "Modified: / 3.2.1998 / 18:05:12 / cg"

!

readLZWTiffImageData

    "read LZW compressed tiff data; 

     this method only handles 8+8+8 and 8+8+8+8 rgb 

     and 2bit or 2+2bit greyscale images.

     For 2+2bit greyscale images, the alpha plane is ignored.

     (maybe other formats work also - but simply not tested)"

    |bytesPerRow compressedStrip nPlanes overAllBytes

     bytesPerStrip "{ Class: SmallInteger }"

     nBytes        "{ Class: SmallInteger }"

     prevSize      "{ Class: SmallInteger }"

     stripNr       "{ Class: SmallInteger }"

     offset        "{ Class: SmallInteger }"

     row           "{ Class: SmallInteger }" |

    nPlanes := samplesPerPixel.

    (nPlanes >= 3) ifTrue:[

        (bitsPerSample conform:[:each | each == 8]) ifFalse:[

            ^ self fileFormatError:'only 8/8/8(/8) bits/sample are supported'.

        ].

        bytesPerRow := width * samplesPerPixel.

    ] ifFalse:[

        (nPlanes == 2) ifTrue:[

            (planarConfiguration ~~ 2) ifTrue:[

                ^ self fileFormatError:'only separate planes are supported'.

            ].

            'TIFFReader [info]: ignoring alpha plane' infoPrintCR.

            nPlanes := 1

        ].

        (nPlanes == 1) ifFalse:[

            ^ self fileFormatError:'unsupported nPlanes: ' , nPlanes printString, '; only 3-sample rgb / monochrome supported'.

        ].

        bytesPerRow := (width * (bitsPerSample at:1) + 7) // 8.

    ].

    "/ 'TIFFReader: decompressing LZW ...' infoPrintNL.

    overAllBytes := bytesPerRow * height.

    bytesPerRow == width ifTrue:[

        data := ByteArray uninitializedNew:overAllBytes.

    ] ifFalse:[

        data := ByteArray new:overAllBytes.

    ].

    offset := 1.

    stripNr := 0.

    row := 1.

    bytesPerStrip := bytesPerRow * rowsPerStrip.

    prevSize := 0.

    [row <= height] whileTrue:[

        stripNr := stripNr + 1.

        self positionToStrip:stripNr.

        nBytes := stripByteCounts at:stripNr.

        (nBytes > prevSize) ifTrue:[

            compressedStrip := ByteArray uninitializedNew:nBytes.

            prevSize := nBytes

        ].

        inStream nextBytes:nBytes into:compressedStrip.

        self class 

            decompressLZWFrom:compressedStrip count:nBytes

            into:data startingAt:offset.

        offset := offset + bytesPerStrip.

        row := row + rowsPerStrip

    ].

    (predictor == 2) ifTrue:[

        self class decodeDelta:nPlanes in:data width:width height:height

    ]

    "Modified: / 25-08-2017 / 10:09:03 / cg"

!

readNeXTJPEGTiffImageData

    ^ self fileFormatError:'next jpeg compression not implemented'.

    "Modified: / 3.2.1998 / 18:10:45 / cg"

!

readNeXTRLE2TiffImageData

    ^ self fileFormatError:'next 2bit rle compression not implemented'.

    "Modified: / 3.2.1998 / 18:10:54 / cg"

!

readNewJPEGTiffImageData

    ^ self fileFormatError:'new jpeg compression not implemented'.

!

readPackbitsTiffImageData

    "this has only been tested with monochrome images"

    |bytesPerRow bitsPerRow nPlanes 

     stripNr       "{ Class: SmallInteger }"

     offset        "{ Class: SmallInteger }"

     row           "{ Class: SmallInteger }" 

     nBytes        "{ Class: SmallInteger }"

     nDecompressedBytes  "{ Class: SmallInteger }"

     bitsPerPixel overAllBytes buffer|

    nPlanes := samplesPerPixel.

    "only support 1-sample/pixel,

     with alpha - if separate planes,

     or rgb - if non separate planes and no alpha"

    (nPlanes == 2) ifTrue:[

        (planarConfiguration ~~ 2) ifTrue:[

            ^ self fileFormatError:'with alpha, only separate planes supported'.

        ].

        'TIFFReader [info]: ignoring alpha plane' infoPrintCR.

        nPlanes := 1.

        bitsPerPixel := bitsPerSample at:1.

        bitsPerSample := Array with:bitsPerPixel.

        samplesPerPixel := 1.

    ] ifFalse:[

        (nPlanes == 3) ifTrue:[

            (planarConfiguration ~~ 1) ifTrue:[

                ^ self fileFormatError:'only non separate planes supported'.

            ].

            bitsPerSample ~= #(8 8 8) ifTrue:[

                ^ self fileFormatError:'only 8/8/8 rgb images supported'.

            ].

            bitsPerPixel := 24

        ] ifFalse:[

            (nPlanes ~~ 1) ifTrue:[

                ^ self fileFormatError:'format not supported'.

            ].

            bitsPerPixel := bitsPerSample at:1.

        ]

    ].

    bitsPerRow := width * bitsPerPixel.

    bytesPerRow := bitsPerRow // 8.

    ((bitsPerRow \\ 8) ~~ 0) ifTrue:[

        bytesPerRow := bytesPerRow + 1

    ].

    overAllBytes := bytesPerRow * height.

    bytesPerRow == width ifTrue:[

        data := ByteArray uninitializedNew:overAllBytes.

    ] ifFalse:[

        data := ByteArray new:overAllBytes.

    ].

    offset := 1.

    stripNr := 0.

    buffer := nil.

    row := 1.

    [row <= height] whileTrue:[

        stripNr := stripNr + 1.

        nBytes := stripByteCounts at:stripNr.

        self positionToStrip:stripNr.

        nBytes > buffer size ifTrue:[

            "/ realloc

            buffer := ByteArray uninitializedNew:nBytes.

        ].

        inStream nextBytes:nBytes into:buffer.

        nDecompressedBytes := self class decompressPackBitsFrom:buffer at:1 to:data at:offset count:nBytes.

        "/ nDecompressedBytes := self class decompressPackBits:nBytes from:buffer to:data startingAt:offset.

        offset := offset + nDecompressedBytes.

        row := row + rowsPerStrip

    ]

    "Modified: / 25-08-2017 / 02:02:20 / cg"

!

readPixarFilmTiffImageData

    ^ self fileFormatError:'pixar film compression not implemented'.

    "Modified: / 3.2.1998 / 18:11:45 / cg"

!

readPixarLogTiffImageData

    ^ self fileFormatError:'pixar log compression not implemented'.

    "Modified: / 3.2.1998 / 18:11:53 / cg"

!

readSGI24TiffImageData

    ^ self fileFormatError:'SGI 24-bit Log Luminance encoding not implemented' .

    "Created: / 25-08-2017 / 11:17:25 / cg"

!

readSGI32TiffImageData

    ^ self fileFormatError:'SGI 32-bit Log Luminance encoding not implemented' .

    "Created: / 25-08-2017 / 11:17:21 / cg"

!

readThunderScanTiffImageData

    |bytesPerRow compressedStrip nPlanes overAllBytes

     bytesPerStrip "{ Class: SmallInteger }"

     nBytes        "{ Class: SmallInteger }"

     prevSize      "{ Class: SmallInteger }"

     stripNr       "{ Class: SmallInteger }"

     offset        "{ Class: SmallInteger }"

     row           "{ Class: SmallInteger }"

     pixelIndex

     i even gen highNibble lastPixel d1 d2 d3|

    nPlanes := samplesPerPixel.

    (nPlanes == 2) ifTrue:[

        (planarConfiguration ~~ 2) ifTrue:[

            ^ self fileFormatError:'only separate planes are supported'.

        ].

        'TIFFReader [info]: ignoring alpha plane' infoPrintCR.

        nPlanes := 1

    ].

    (nPlanes == 1) ifFalse:[

        ^ self fileFormatError:'unsupported nPlanes: ' , nPlanes printString.

    ].

    (bitsPerSample at:1) == 4 ifFalse:[

        ^ self fileFormatError:('unsupported bitsPerSample: %1 (only 4 supported)' bindWith:(bitsPerSample at:1)).

    ].