"

 COPYRIGHT (c) 2006 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

PrinterContext subclass:#WinPrinterContext

	instanceVariableNames:'deviceFonts hatch supportsColor'

	classVariableNames:'PostScriptBlackWhite'

	poolDictionaries:''

	category:'Interface-Printing'

!

WinPrinterContext subclass:#WinPrinterGraphicContext

	instanceVariableNames:'fontScale printPageNumbers pageNumberFormat pageCounter

		needsEndOfPage titleFont'

	classVariableNames:''

	poolDictionaries:''

	privateIn:WinPrinterContext

!

!WinPrinterContext primitiveDefinitions!

%{

#undef INT

#define INT WIN_INT

#undef Array

#define Array WIN_Array

#undef Number

#define Number WIN_Number

#undef Method

#define Method WIN_Method

#undef Point

#define Point WIN_Point

#undef Rectangle

/* #define Rectangle WIN_Rectangle */

#undef True

#define True WIN_True

#undef False

#define False WIN_False

#undef Block

#define Block WIN_Block

#undef Context

#define Context WIN_Context

#undef Date

#define Date WIN_Date

#undef Time

#define Time WIN_Time

#undef Delay

#define Delay WIN_Delay

#undef Signal

#define Signal WIN_Signal

#undef Set

#define Set WIN_Set

#undef Process

#define Process WIN_Process

#undef Processor

#define Processor WIN_Processor

#undef Message

#define Message WIN_Message

#undef String

#define String WIN_String

#undef Character

#define Character WIN_Character

#include <stdio.h>

#include <errno.h>

#ifdef __BORLANDC__

# define NOATOM

# define NOGDICAPMASKS

# define NOMETAFILE

# define NOMINMAX

# define NOOPENFILE

# define NOSOUND

# define NOWH

# define NOCOMM

# define NOKANJI

# define NOCRYPT

# define NOMCX

# define WIN32_LEAN_AND_MEAN

# include <windows.h>

# include <shellapi.h>

# include <sys\timeb.h>

# include <dir.h>

#else

# define _USERENTRY /**/

# define NOATOM

# define NOGDICAPMASKS

# define NOMETAFILE

# define NOMINMAX

# define NOOPENFILE

# define NOSOUND

# define NOWH

# define NOCOMM

# define NOKANJI

# define NOCRYPT

# define NOMCX

# define WIN32_LEAN_AND_MEAN

# include <windows.h>

# include <sys\timeb.h>

#endif

#include <process.h>

#ifdef __DEF_Array

# undef Array

# define Array __DEF_Array

#endif

#ifdef __DEF_Number

# undef Number

# define Number __DEF_Number

#endif

#ifdef __DEF_Method

# undef Method

# define Method __DEF_Method

#endif

#ifdef __DEF_Point

# undef Point

# define Point __DEF_Point

#endif

#ifdef __DEF_Rectangle

# undef Rectangle

# define Rectangle __DEF_Rectangle

#else

# undef Rectangle

#endif

#ifdef __DEF_Block

# undef Block

# define Block __DEF_Block

#endif

#ifdef __DEF_Context

# undef Context

# define Context __DEF_Context

#endif

#ifdef __DEF_Date

# undef Date

# define Date __DEF_Date

#endif

#ifdef __DEF_Time

# undef Time

# define Time __DEF_Time

#endif

# ifdef __DEF_Set

#  undef Set

#  define Set __DEF_Set

# endif

# ifdef __DEF_Signal

#  undef Signal

#  define Signal __DEF_Signal

# endif

# ifdef __DEF_Delay

#  undef Delay

#  define Delay __DEF_Delay

# endif

# ifdef __DEF_Process

#  undef Process

#  define Process __DEF_Process

# endif

# ifdef __DEF_Processor

#  undef Processor

#  define Processor __DEF_Processor

# endif

# ifdef __DEF_Message

#  undef Message

#  define Message __DEF_Message

# endif

# ifdef __DEF_String

#  undef String

#  define String __DEF_String

# endif

# ifdef __DEF_Character

#  undef Character

#  define Character __DEF_Character

# endif

#undef INT

#define INT STX_INT

#undef UINT

#define UINT STX_UINT

/*

 * some defines - tired of typing ...

 */

#define _HANDLEVal(o)        (HANDLE)(__MKCP(o))

#define _HBITMAPVAL(o)       (HBITMAP)(__MKCP(o))

#define _HWNDVal(o)          (HWND)(__MKCP(o))

#define _HPALETTEVal(o)      (HPALETTE)(__MKCP(o))

#define _HCURSORVal(o)       (HCURSOR)(__MKCP(o))

#define _HGDIOBJVal(o)       (HGDIOBJ)(__MKCP(o))

#define _LOGPALETTEVal(o)    (LOGPALETTE *)(__MKCP(o))

#define _COLORREFVal(o)      (COLORREF)(__MKCP(o))

#define WIDECHAR unsigned short

#define WIN32PADDING 32

#ifdef DEBUG

# define DPRINTF(x)              /* printf  x */

# define DFPRINTF(x)             /* fprintf x */

#else

# define DPRINTF(x)              /* */

# define DFPRINTF(x)             /* */

#endif

typedef int (*intf)(int);

typedef INT (*INTF)(INT);

%}

! !

!WinPrinterContext class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 2006 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    I am the mediator between the smalltalk printing protocol

    (which is the same as the graphics drawing protocol) and the

    windows printer.

    When you open a printer, you will typically talk to me.

    [author:]

	Felix Madrid (fm@exept.de)

"

! !

!WinPrinterContext class methodsFor:'instance creation'!

fromPrinterInfo: aPrinterInfo

    | printerContext printerDevice hDC|

    hDC := aPrinterInfo createDC.

    hDC = 0 ifTrue: [ ^self error: 'Error while opening printer.' ].

    printerContext := self new.

    printerDevice := printerContext.

"/    printerDevice := WinPrinter on: aPrinterInfo.

"/    printerDevice printerDC:hDC.

    printerContext printerInfo: aPrinterInfo.

    printerContext setDevice:printerDevice id:nil gcId:hDC.

    printerContext initExtent.

    ^printerContext

    "Created: / 03-08-2006 / 12:53:52 / fm"

    "Modified: / 04-08-2006 / 12:55:01 / fm"

    "Modified: / 16-04-2007 / 12:36:26 / cg"

!

newPrinter

    | printer printerInfo|

    printerInfo := PrintingDialog getPrinterInfo.

    printerInfo isNil ifTrue:[^self].

    printer := WinPrinterContext fromPrinterInfo: printerInfo.

    ^ printer

!

openGraphicContext

    ^ self openGraphicContextWithoutDialog:false

!

openGraphicContextWithoutDialog:withoutDialog

    |printerInfo gc|

    printerInfo := PrintingDialog getPrinterInfoWithoutDialog:withoutDialog.

    printerInfo isNil ifTrue:[^ nil].

    gc := WinPrinterGraphicContext fromPrinterInfo:printerInfo.

    gc notNil ifTrue:[

	gc startPrintJob

    ].

    ^ gc

! !

!WinPrinterContext class methodsFor:'accessing'!

getPrinterInformation:printerNameString

    " Answer the printer information for the printer named printerNameString.  If no name is specified,

      answer the information for the default printer."

    |h|

    h := OperatingSystem openPrinter:printerNameString.

    ^ OperatingSystem

	getDocumentProperties:nil

	hPrinter:h

	pDeviceName:printerNameString.

    "Created: / 27-07-2006 / 10:22:32 / fm"

    "Modified: / 01-08-2006 / 16:01:44 / fm"

    "Modified: / 10-10-2006 / 18:57:45 / cg"

!

getPrinterInformationString: printerNameString

	" Answer the printer information string from the WIN.INI file

	for the printer named printerNameString.  If no name is specified,

	answer the information for the default printer. "

    | printerInfo result |

    printerInfo := ( String new: 80 ).

    result := OperatingSystem primGetProfileString: 'windows'

	keyName:  'device'

	default: ( printerNameString isNil ifTrue: [ '' ] ifFalse: [ printerNameString ] )

	returnedString: printerInfo

	size: printerInfo size.

    ^result > 0

	ifTrue: [printerInfo copyFrom: 1 to: result]

	ifFalse: ['']

!

named: aName

    "Answer a new instance of Printer which represents

     the printer named aName as specified in the host

     Control Panel."

    aName isNil ifTrue: [ ^self default ].

    ^self new printerInfoWithName: aName

    "Created: / 27-07-2006 / 17:51:27 / fm"

    "Modified: / 02-08-2006 / 17:26:29 / fm"

    "Modified: / 10-10-2006 / 17:33:29 / cg"

!

postScriptBlackWhite

    "Returns true if the postscript is b&w or returns false if the postscript is color"

    ^ PostScriptBlackWhite ? false

!

postScriptBlackWhite: aBoolean

    PostScriptBlackWhite := aBoolean

! !

!WinPrinterContext class methodsFor:'not supported yet'!

printAdvancedLines: pairOfPointsArray

    "Opens a print dialog and prints the given lines"

    | printerInfo printer |

    printerInfo := PrintingDialog getPrinterInfo.

    printerInfo isNil ifTrue:[^self].

    printer := self fromPrinterInfo: printerInfo.

    [

	printer startPrintJob: 'Advanced Lines'.

	printer foreground:Color red background:Color white.

	pairOfPointsArray

	    do:[:pairOfPointsAndContext |

		 |pairOfPoints|

		 pairOfPoints := pairOfPointsAndContext at:1.

		 printer

		    lineWidth: (pairOfPointsAndContext at:2);

		    lineStyle: (pairOfPointsAndContext at:3);

		    capStyle: (pairOfPointsAndContext at:4);

		    joinStyle: (pairOfPointsAndContext at:5);

		    foreground: (pairOfPointsAndContext at:6);

		    displayAdvanceLineFrom: (pairOfPoints at:1)  to: (pairOfPoints at:2).

	    ].

	printer endPrintJob.

    ] forkAt: 3

    "

     WinPrinterContext printAdvancedLines:

	(Array with: (Array with: (Array with:10@10 with:1000@5000) with: 3 with:#dashed with: #butt with: #miter with: Color green)

	       with: (Array with: (Array with:10@10 with:3500@2000) with: 2 with:#solid  with: #butt with: #miter with: Color yellow)

	       with: (Array with: (Array with:1000@800 with:6000@5000) with: 8 with:#dashed  with: #butt with: #miter with: Color black)

	       with: (Array with: (Array with:2000@2800 with:2000@5000) with: 1 with:#dashed  with: #butt with: #miter with: Color red)

	)

    "

    "Created: / 07-08-2006 / 12:09:48 / fm"

    "Modified: / 07-08-2006 / 14:11:17 / fm"

    "Modified: / 16-04-2007 / 15:37:41 / cg"

! !

!WinPrinterContext class methodsFor:'testing'!

computeScaleForPrinter:aPrinter

    ^ Point x:(aPrinter pixelsPerInchOfScreenWidth / Screen current horizontalPixelPerInch)

	    y:(aPrinter pixelsPerInchOfScreenHeight / Screen current verticalPixelPerInch)

!

testPrintingDo:anOneArgBlock

    "Opens a print dialog and invokes the action with the printer"

    | printerInfo printer |

    printerInfo := PrintingDialog getPrinterInfo.

    printerInfo isNil ifTrue:[^self].

    printer := self fromPrinterInfo: printerInfo.

    printer startPrintJob: 'Testing'.

    anOneArgBlock value:printer.

    printer endPrintJob.

"

self testPrintingDo:[:aPrinter| |icon|

    aPrinter scale:(self computeScaleForPrinter:aPrinter).

    aPrinter displayLineFrom:10@10   to:100@10.

    aPrinter displayLineFrom:100@10  to:100@100.

    aPrinter displayLineFrom:100@100 to:10@100.

    aPrinter displayLineFrom:10@100  to:10@10.

    icon := XPToolbarIconLibrary eraseXP28x28Icon.

    icon displayOn:aPrinter x:10 y:10.

].

self testPrintingDo:[:aPrinter| |scale|

    scale := self computeScaleForPrinter:aPrinter.

    aPrinter scale:(1 * scale).

    aPrinter  font:(Font family:'Arial' face:'medium' size:8).

    aPrinter displayLineFrom:8@16 to:100@16.

    aPrinter displayLineFrom:8@16 to:8@128.

    'hallo' displayOn:aPrinter x:8 y:16.

    aPrinter scale:(2 * scale).

    'hallo' displayOn:aPrinter x:4 y:32.

    aPrinter scale:(4 * scale).

    'hallo' displayOn:aPrinter x:2 y:32.

].

"

! !

!WinPrinterContext class methodsFor:'testing & examples'!

fillCircles: arrayOfPointsAndRadiusWithContextArray

    "Opens a print dialog and prints the given circles"

    | printerInfo printer |

    printerInfo := PrintingDialog getPrinterInfo.

    printerInfo isNil ifTrue:[^self].

    printer := self fromPrinterInfo: printerInfo.

    [

	printer startPrintJob: 'Fill Circles'.

	arrayOfPointsAndRadiusWithContextArray

	    do:[:pointsAndRadiusWithContextArray |

		printer foreground:(pointsAndRadiusWithContextArray at:3).

		printer fillCircle:(pointsAndRadiusWithContextArray at:1)

			radius:(pointsAndRadiusWithContextArray at:2).

	    ].

	printer endPrintJob.

    ] forkAt: 3

    "

     WinPrinterContext fillCircles:

	(Array with: (Array with: 800@800 with: 600 with:Color red)

	       with: (Array with: 1500@1500 with: 1000 with:Color blue)

	       with: (Array with: 4000@2500 with: 2000 with:Color gray))

    "

    "Created: / 07-08-2006 / 11:46:52 / fm"

    "Modified: / 16-04-2007 / 15:37:34 / cg"

!

fillHatchCircles: arrayOfPointsAndRadiusWithContextArray

    "Opens a print dialog and prints the given circles"

    | printerInfo printer |

    printerInfo := PrintingDialog getPrinterInfo.

    printerInfo isNil ifTrue:[^self].

    printer := self fromPrinterInfo: printerInfo.