"{ Encoding: utf8 }"

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

"{ NameSpace: Smalltalk }"

LayoutOrigin subclass:#LayoutFrame

	instanceVariableNames:'rightFraction bottomFraction rightOffset bottomOffset'

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Geometry'

!

!LayoutFrame class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1995 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class is provided to make porting of existing ST-80/Squeak applications

    easier. Instances can be used to control the geometry of a subview, within

    its superview. Like a layoutOrigin, it controls the origin of a component

    by given fraction and offset dimensions; in addition, the bottom-right

    corner is also controlled by corresponding values. 

    Therefore, the component's preferredExtent is ignored.

    Notice: 

        this class was implemented using protocol information

        from alpha testers - it may not be complete or compatible to

        the corresponding ST-80 class. 

        If you encounter any incompatibilities, please forward a note 

        describing the incompatibility verbal (i.e. no code) to the ST/X team.

    [author:]

        Claus Gittinger

    [see also:]

        View

        LayoutOrigin AlignmentOrigin Layout 

        Rectangle Point

"

!

examples

"

    Although the examples below use a button as component,

    they work of course with any type of subview ....

    arrange for the button to be in 0.25 @ 0.25 -> 0.75 @ 0.75.

    This is the same as with relative origin/corner.

                                                                        [exBegin]

        |top button|

        top := StandardSystemView new.

        top extent:300@300.

        button := Button label:'component'.

        top add:button in:(LayoutFrame new

                                leftFraction:0.25;

                                topFraction:0.25;

                                rightFraction:0.75;

                                bottomFraction:0.75).

        top open

                                                                        [exEnd]

    like above, but adds additional offset to the origin:

    This is the same as with relative origin/corner

    and setting left & right insets.

                                                                        [exBegin]

        |top button|

        top := StandardSystemView new.

        top extent:300@300.

        button := Button label:'component'.

        top add:button in:(LayoutFrame new

                                leftFraction:0.25; leftOffset:10;

                                topFraction:0.25;  topOffset:-20;

                                rightFraction:0.75;

                                bottomFraction:0.75).

        top open

                                                                        [exEnd]

    like above, with offsets on all edges, 

    actually simulating a constant inset on all four edges:

                                                                        [exBegin]

        |top button|

        top := StandardSystemView new.

        top extent:300@300.

        button := Button label:'component'.

        top add:button in:(LayoutFrame new

                                leftFraction:0.0; leftOffset:10;

                                topFraction:0.0;  topOffset:10;

                                rightFraction:1.0; rightOffset:-10;

                                bottomFraction:1.0; bottomOffset:-10).

        top open

                                                                        [exEnd]

"

! !

!LayoutFrame class methodsFor:'instance creation'!

bottomFrame:pixels

    "create a new layoutFrame which makes the child take a fixed frame at the bottom"

    ^ self

        leftFraction:0 offset:0

        rightFraction:1 offset:0

        topFraction:1 offset:pixels negated 

        bottomFraction:1 offset:0

!

bottomInset:pixels

    "create a new layoutFrame which insets the child at the bottom by some pixels"

    ^ self

        leftFraction:0 offset:0

        rightFraction:1 offset:0

        topFraction:0 offset:0 

        bottomFraction:1 offset:pixels negated

    "Created: / 26-04-2010 / 15:07:50 / cg"

!

fractions:fractionRectangle offsets:offsetRectangle

    "create a new layoutFrame given a rectangle of fractions and a rectangle of offsets"

    ^ self new

        fractions:fractionRectangle offsets:offsetRectangle

    "

     LayoutFrame 

        fractions:(0 @ 0 corner:1.0 @ 1.0) 

        offsets:(0 @ 0 corner:0 @ 0)

    "

!

inset:pixels

    "create a new layoutFrame which insets the child by some pixels"

    ^ self

        leftFraction:0 offset:pixels

        rightFraction:1 offset:pixels negated

        topFraction:0 offset:pixels 

        bottomFraction:1 offset:pixels negated 

!

leftFraction:lF offset:lO rightFraction:rF offset:rO topFraction:tF offset:tO bottomFraction:bF offset:bO

    "create a new layoutFrame"

    ^ self new

        leftFraction:lF offset:lO 

        rightFraction:rF offset:rO 

        topFraction:tF offset:tO 

        bottomFraction:bF offset:bO

!

leftFraction:lF rightFraction:rF topFraction:tF bottomFraction:bF

    "create a new layoutFrame"

    ^ self new 

        leftFraction:lF rightFraction:rF topFraction:tF bottomFraction:bF

    "Modified (format): / 17-07-2019 / 10:09:10 / Claus Gittinger"

!

leftFrame:pixels

    "create a new layoutFrame which makes the child take a fixed frame at the left"

    ^ self

        leftFraction:0 offset:0

        rightFraction:0 offset:pixels

        topFraction:0 offset:0 

        bottomFraction:1 offset:0

!

leftOffset:lO rightOffset:rO topOffset:tO bottomOffset:bO

    "create a new layoutFrame"

    ^ self new

        leftOffset:lO 

        rightOffset:rO 

        topOffset:tO 

        bottomOffset:bO

    "Created: 18.4.1997 / 20:14:44 / cg"

!

leftOffset:lO topOffset:tO rightOffset:rO bottomOffset:bO

    "create a new layoutFrame"

    ^ self leftOffset:lO rightOffset:rO topOffset:tO bottomOffset:bO

    "Modified: 18.4.1997 / 20:15:23 / cg"

!

origin:origin corner:corner

    "create a new layoutFrame from an oldStyle origin-corner rectangle.

     Added to make migration from Rectangles to LayoutFrames easier."

    |leftFraction leftOffset rightFraction rightOffset

     topFraction topOffset bottomFraction bottomOffset

     orgX orgY cornerX cornerY|

    orgX := origin x.

    orgY := origin y.

    cornerX := corner x.

    cornerY := corner y.

    leftFraction := leftOffset := 0.

    orgX isInteger ifTrue:[

        leftOffset := orgX

    ] ifFalse:[

        leftFraction := orgX.

    ].

    orgY isInteger ifTrue:[

        topOffset := orgY

    ] ifFalse:[

        topFraction := orgY.

    ].

    cornerX isInteger ifTrue:[

        rightOffset := cornerX

    ] ifFalse:[

        rightFraction := cornerX.

    ].

    cornerY isInteger ifTrue:[

        bottomOffset := cornerY

    ] ifFalse:[

        bottomFraction := cornerY.

    ].

    ^ self

        leftFraction:leftFraction offset:leftOffset

        rightFraction:rightFraction offset:rightOffset

        topFraction:topFraction offset:rightOffset 

        bottomFraction:bottomFraction offset:bottomOffset 

!

rightFrame:pixels

    "create a new layoutFrame which makes the child take a fixed frame at the right"

    ^ self

        leftFraction:1 offset:pixels negated

        rightFraction:1 offset:0

        topFraction:0 offset:0 

        bottomFraction:1 offset:0

!

topFrame:pixels

    "create a new layoutFrame which makes the child take a fixed frame at the top"

    ^ self

        leftFraction:0 offset:0

        rightFraction:1 offset:0

        topFraction:0 offset:0 

        bottomFraction:0 offset:pixels

!

topInset:pixels

    "create a new layoutFrame which insets the child at the top by some pixels"

    ^ self

        leftFraction:0 offset:0

        rightFraction:1 offset:0

        topFraction:0 offset:pixels 

        bottomFraction:1 offset:0

! !

!LayoutFrame methodsFor:'accessing'!

bottomFraction

    "Return the y-coordinate of the bottom of the relative rectangle as a percentage of the height of the reference rectangle."

    ^ bottomFraction

!

bottomFraction:aFraction

    "Set the y-coordinate of the bottom of the relative rectangle to be a fraction of the height of the reference rectangle."

    bottomFraction := aFraction.

!

bottomFraction:aFraction offset:o

    "set both bottomFraction (0..1) and offset"

    bottomFraction := aFraction.

    bottomOffset := o

!

bottomInset:pixels

    "set bottomOffset for an inset at the bottom"

    bottomOffset := pixels negated.

    "Created: 26.5.1996 / 17:38:30 / cg"

!

bottomOffset

    "return bottomOffset"

    ^ bottomOffset

!

bottomOffset:something

    "set bottomOffset"

    bottomOffset := something.

!

fractions:fractionRectangle offsets:offsetRectangle

    "LayoutFrame fractions:(0 @ 0 corner:1.0 @ 1.0) offsets:(0 @ 0 corner:0 @ 0)"

    self

        leftFraction:(fractionRectangle left) offset:(offsetRectangle left)

        rightFraction:(fractionRectangle right) offset:(offsetRectangle right)

        topFraction:(fractionRectangle top) offset:(offsetRectangle top)

        bottomFraction:(fractionRectangle bottom) offset:(offsetRectangle bottom)

!

horizontalInset:aNumber

    "setup the offsets for insetting horizontally the frame aNumber pixels at all sides"

    leftOffset := aNumber.

    rightOffset := aNumber negated.

    "Created: 26.5.1996 / 17:39:35 / cg"

!

inset:aNumber

    "setup the offsets for insetting the frame aNumber pixels at all sides"

    topOffset := leftOffset := aNumber.

    rightOffset := bottomOffset := aNumber negated.

    "Created: 26.5.1996 / 17:36:49 / cg"

!

leftFraction:lF offset:lO rightFraction:rF offset:rO topFraction:tF offset:tO bottomFraction:bF offset:bO

    "set all fields"

    leftFraction := lF.

    rightFraction := rF.

    topFraction := tF.

    bottomFraction := bF.

    leftOffset := lO.

    rightOffset := rO.

    topOffset := tO.

    bottomOffset := bO.

!

leftFraction:lF rightFraction:rF

    leftFraction := lF.

    rightFraction := rF.

    "Created: / 17-07-2019 / 10:05:53 / Claus Gittinger"

!

leftFraction:lF rightFraction:rF topFraction:tF bottomFraction:bF

    leftFraction := lF.

    rightFraction := rF.

    topFraction := tF.

    bottomFraction := bF.

    "Created: / 17-07-2019 / 10:07:46 / Claus Gittinger"

!

leftOffset:lO rightOffset:rO

    "set the horizontal offset fields"

    leftOffset := lO.

    rightOffset := rO.

!

leftOffset:lO rightOffset:rO topOffset:tO bottomOffset:bO

    "set all offset fields"

    leftOffset := lO.

    rightOffset := rO.

    topOffset := tO.

    bottomOffset := bO.

    "Created: 18.4.1997 / 20:16:08 / cg"

!

rightFraction

    "return rightFraction"

    ^ rightFraction

!

rightFraction:aFraction

    "set rightFraction (0..1)"

    rightFraction := aFraction.

!

rightFraction:rF bottomFraction:bF

    rightFraction := rF.

    bottomFraction := bF.

    "Created: / 17-07-2019 / 10:26:24 / Claus Gittinger"

!

rightFraction:aFraction offset:o

    "set rightFraction (0..1) and offset"

    rightFraction := aFraction.

    rightOffset := o

!

rightInset:pixels

    "set rightOffset for an inset at the right"

    rightOffset := pixels negated.

    "Created: 26.5.1996 / 17:38:38 / cg"

!

rightOffset

    "return rightOffset"

    ^ rightOffset

!

rightOffset:something

    "set rightOffset"

    rightOffset := something.

!

topFraction:tF bottomFraction:bF

    topFraction := tF.

    bottomFraction := bF.

    "Created: / 17-07-2019 / 10:07:15 / Claus Gittinger"

!

topOffset:newTopOffset bottomOffset:newBottomOffset

    topOffset := newTopOffset.

    bottomOffset := newBottomOffset.

!

verticalInset:aNumber

    "setup the offsets for insetting vertically the frame aNumber pixels

     at all sides"

    topOffset := aNumber.

    bottomOffset := aNumber negated.

    "Created: 26.5.1996 / 17:39:50 / cg"

! !

!LayoutFrame methodsFor:'comparing'!

= anObject

    ^ super = anObject

        and:[ anObject rightFraction = rightFraction