"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libview2' }"

"{ NameSpace: Smalltalk }"

ImageReader subclass:#TIFFReader

	instanceVariableNames:'planarConfiguration subFileType stripOffsets rowsPerStrip

		fillOrder compression group3options predictor stripByteCounts

		currentOffset stripOffsetsPos stripByteCountsPos bitsPerSamplePos

		colorMapPos orientation'

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Images-Readers'

!

!TIFFReader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    This class knows how to read TIFF files and how to

    write uncompressed TIFF files.

    Implemented & Missing Features:

      - Only single image files are supported.

      - Not all formats are implemented, and of those that are, not all are tested.

        It should read with most rgb, palette, mono and greyscale images, 

        although the alpha channel is currently not supported and ignored.

        It supports reading of uncompressed, LZW, packbits and CCITT-G3 compressed images

        JPEG and many other formats are currently not implemented.

      - Only writing of uncompressed images is currently implemented.

        It should write (at least) mono, 8-bit palette and 24 bit rgb formats.

    More formats will come... (will they ever be needed ?)

    TODO (?): since I dont want to spend all of my life adding more formats here and

    reinventing the wheel, this code should be changed to use the tiff library.

    That would give us most formats and also writing capabilities for free.

    Late note: 

        I hate C and interfacing to C libraries: it almost always leads to trouble

        w.r.t. memory leaks, non-reentrancy, non-interruptability etc.

        (we recently fixed a malloc-non-reentrant bug for some architecture...)

        So its robably better to do it all in a real programming language ;-)

    [author:]

        Claus Gittinger

    [See also:]

        Image Form Icon

        BlitImageReader FaceReader GIFReader JPEGReader PBMReader PCXReader 

        ST80FormReader SunRasterReader TargaReader WindowsIconReader 

        XBMReader XPMReader XWDReader 

"

! !

!TIFFReader class methodsFor:'initialization'!

initialize

    "install myself in the Image classes fileFormat table

     for the `.tiff' and `.tif' extensions."

    MIMETypes defineImageType:'image/tiff' suffix:'tif'  reader:self.

    MIMETypes defineImageType:nil          suffix:'tiff' reader:self.

    "

     self initialize

    "

    "Modified: 1.2.1997 / 15:00:01 / cg"

! !

!TIFFReader class methodsFor:'testing'!

canRepresent:anImage

    "return true, if anImage can be represented in my file format.

     Any image is supported."

    ^ true

!

isValidImageFile:aFileName

    "return true, if aFileName contains a GIF image"

    |inStream char1 char2 version|

    inStream := self streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ false].

    char1 := inStream next.

    char2 := inStream next.

    ((char1 ~~ char2) or:[(char1 ~~ $I) and:[char1 ~~ $M]]) ifTrue:[

        inStream close.

        ^ false

    ].

    inStream binary.

    version := inStream nextInt16MSB:(char1 == $M).

    inStream close.

    (version ~~ 42) ifTrue:[^ false].

    ^ true

! !

!TIFFReader methodsFor:'private'!

decodeTiffTag:tagType numberType:numberType length:length

    |offset value valueArray 

     val scaleFactor rV gV bV

     n  "{ Class: SmallInteger }"

     i2 "{ Class: SmallInteger }"

     i3 "{ Class: SmallInteger }" |

"/ 'tiffTag: ' print. tagType printCR.

    (numberType == 3 "TIFF_SHORT") ifTrue:[

        "16 bit ushort"

        valueArray := self readShorts:length signed:false.

        value := valueArray at:1

    ] ifFalse:[(numberType == 4 "TIFF_LONG") ifTrue:[

        "32 bit uinteger"

        valueArray := self readLongs:length signed:false.

        value := valueArray at:1

    ] ifFalse:[(numberType == 2 "TIFF_ASCII") ifTrue:[

        "ascii characters"

        value := self readChars:length

    ] ifFalse:[(numberType == 5 "TIFF_RATIONAL") ifTrue:[

        "64 (32+32) bit ufraction"

        valueArray := self readFracts:length signed:false.

        value := valueArray at:1

    ] ifFalse:[(numberType == 1 "TIFF_BYTE") ifTrue:[

        "8bit uinteger"

        value := self readBytes:length signed:false

    ] ifFalse:[(numberType == 6 "TIFF_SBYTE") ifTrue:[

        "TIFF6: 8bit signed integer"

        value := self readBytes:length  signed:true

    ] ifFalse:[(numberType == 8 "TIFF_SSHORT") ifTrue:[

        "TIFF6: 16bit signed integer"

        value := self readShorts:length signed:true

    ] ifFalse:[(numberType == 9 "TIFF_SLONG") ifTrue:[

        "TIFF6: 32bit signed integer"

        value := self readLongs:length signed:true

    ] ifFalse:[(numberType == 10 "TIFF_SRATIONAL") ifTrue:[

        "TIFF6: 64 (32+32) bit signed fraction"

        value := self readFracts:length signed:true

    ] ifFalse:[(numberType == 11 "TIFF_FLOAT") ifTrue:[

        "TIFF6: 32 bit IEEE float"

        value := self readFloats:length

    ] ifFalse:[(numberType == 12 "TIFF_DOUBLE") ifTrue:[

        "TIFF6: 64 bit IEEE double"

        value := self readDoubles:length

    ] ifFalse:[

        offset := (inStream nextInt32MSB:(byteOrder ~~ #lsb))

    ]]]]]]]]]]].

    (tagType < 300) ifTrue:[

        (tagType == 254) ifTrue:[

            "/ New SubfileType

            "/      REDUCEDIMAGE    -> 1

            "/      PAGE            -> 2

            "/      MASK            -> 4

            "newSubFileType := value."

    "/        'newSubfiletype ' print. value printNewline.

            ^ self

        ].

        (tagType == 255) ifTrue:[

            "/ Old SubfileType

            "/      IMAGE           -> 1

            "/      REDUCEDIMAGE    -> 2

            "/      PAGE            -> 3

            subFileType := value.

    "/        'subfiletype ' print. value printNewline.

            ^ self

        ].

        (tagType == 256) ifTrue:[

            "ImageWidth"

            width := value.

    "/        'width ' print. width printNewline.

            ^ self

        ].

        (tagType == 257) ifTrue:[

            "ImageHeight"

            height := value.

    "/        'height ' print. height  printNewline.

            ^ self

        ].

        (tagType == 258) ifTrue:[

            "bitspersample"  

             bitsPerSample := valueArray.

    "/        'bitspersample ' print. bitsPerSample printNewline.

            ^ self

        ].

        (tagType == 259) ifTrue:[

            "/ compression

            "/      NONE            -> 1

            "/      CCITTRLE        -> 2

            "/      CCITTFAX3       -> 3

            "/      CCITTFAX4       -> 4

            "/      LZW             -> 5

            "/      OJPEG           -> 6

            "/      JPEG            -> 7

            "/      NEXT            -> 32766

            "/      CCITTRLEW       -> 32771

            "/      PACKBITS        -> 32773

            "/      THUNDERSCAN     -> 32809

            "/      PIXARFILM       -> 32908

            "/      PIXARLOG        -> 32909

            "/      DEFLATE         -> 32946

            "/      DCS             -> 32947

            "/      JBIG            -> 34661

            compression := value.

    "/        'compression ' print. compression printNewline.

            ^ self

        ].

        (tagType == 262) ifTrue:[

            "photometric"

            (value == 0) ifTrue:[

              photometric := #whiteIs0

            ] ifFalse:[

              (value == 1) ifTrue:[

                photometric := #blackIs0

              ] ifFalse:[

                (value == 2) ifTrue:[

                  photometric := #rgb

                ] ifFalse:[

                  (value == 3) ifTrue:[

                    photometric := #palette

                  ] ifFalse:[

                    (value == 4) ifTrue:[

                      photometric := #transparencyMask

                    ] ifFalse:[

                      (value == 5) ifTrue:[

                        photometric := #cmyk  "/ color separations

                      ] ifFalse:[

                        (value == 6) ifTrue:[

                          photometric := #ycbcr    "/ CCIR 601

                        ] ifFalse:[

                          (value == 8) ifTrue:[

                            photometric := #cielab  "/ 1976 CIE L*a*b*

                          ] ifFalse:[

                            photometric := nil

                          ]

                        ]

                      ]

                    ]

                  ]

                ]

              ]

            ].

    "/        'photometric ' print. photometric printNewline.

            ^ self

        ].

        (tagType == 263) ifTrue:[

            "/ Treshholding

            "/      BILEVEL         -> 1

            "/      HALFTONE        -> 2

            "/      ERRORDIFFUSE    -> 3

            "threshholding := value."

    "/        'treshholding ' print. value printNewline.

            ^ self

        ].

        (tagType == 264) ifTrue:[

            "CellWidth"

            "cellWidth:= value."

    "/        'cellWidth ' print. value printNewline.

            ^ self

        ].

        (tagType == 265) ifTrue:[

            "CellLength"

            "cellLength:= value."

    "/        'cellLength ' print. value printNewline.

            ^ self

        ].

        (tagType == 266) ifTrue:[

            "fillOrder"

            (value == 1) ifTrue:[

              fillOrder := #msb

            ] ifFalse:[

              (value == 2) ifTrue:[

                fillOrder := #lsb

              ] ifFalse:[

                fillOrder := nil

              ]

            ].

    "/        'fillorder ' print. fillOrder printNewline.

            ^ self

        ].

        (tagType == 269) ifTrue:[

            "documentName - info only"

    "/        'documentName ' print. value printNewline.

            ^ self

        ].

        (tagType == 270) ifTrue:[

            "imageDescription - info only"

    "/        'imageDescription ' print. value printNewline.

            ^ self

        ].

        (tagType == 271) ifTrue:[

            "make - info only"

    "/        'make ' print. value printNewline.

            ^ self

        ].

        (tagType == 272) ifTrue:[

            "model - info only"

    "/        'model ' print. value printNewline.

            ^ self

        ].

        (tagType == 273) ifTrue:[

            "stripoffsets"

            stripOffsets := valueArray.

    "/        'stripOffsets Array(' print. stripOffsets size print. ')' printNewline.

            ^ self

        ].

        (tagType == 274) ifTrue:[

            "Orientation"

            orientation :=

                            #( nil          "/ 1 normal (topLeft)

                               unsupported  "/ 2 horizontal flip

                               unsupported  "/ 3 horizontal & vertical flip

                               vFlip        "/ 4 vertical flip

                               unsupported  "/ 5 rot 90' counter clock-wise

                               unsupported  "/ 6 rot 90' clock-wise

                               unsupported  "/ 7 rot 90' & flip

                               unsupported  "/ 8 rot 90' ccw & flip

                             ) at:value ifAbsent:#unsupported.

    "/        'orientation ' print. value printNewline.

            ^ self

        ].

        (tagType == 277) ifTrue:[

            "samplesPerPixel"

            samplesPerPixel := value.

    "/        'samplesperpixel ' print. samplesPerPixel printNewline.

            ^ self

        ].

        (tagType == 278) ifTrue:[

            "rowsperstrip"

            rowsPerStrip := value.

    "/        'rowsperstrip ' print. rowsPerStrip printNewline.

            ^ self

        ].

        (tagType == 279) ifTrue:[

            "stripbytecount"

            stripByteCounts := valueArray.

    "/        'stripByteCounts Array(' print. 

    "/        stripByteCounts size print.

    "/        ')' printNewline.

            ^ self

        ].

        (tagType == 280) ifTrue:[

            "MinSampleValue"

            "minSampleValue:= value."

    "/        'minSampleValue ' print. value printNewline.

            ^ self

        ].

        (tagType == 281) ifTrue:[

            "MaxSampleValue"

            "maxSampleValue:= value."

    "/        'maxSampleValue ' print. value printNewline.

            ^ self

        ].

        (tagType == 282) ifTrue:[

            "xResolution"

    "/        'xres ' print. value printNewline.

            ^ self

        ].

        (tagType == 283) ifTrue:[

            "yResolution"

    "/        'yres ' print. value printNewline.

            ^ self

        ].

        (tagType == 284) ifTrue:[

            "planarconfig"

            (value == 1) ifTrue:[

              planarConfiguration := 1

            ] ifFalse:[

              (value == 2) ifTrue:[

                planarConfiguration := 2

              ] ifFalse:[

                planarConfiguration := nil

              ]

            ].

    "/        'planarconfig ' print. planarConfiguration printNewline.

            ^ self

        ].

        (tagType == 285) ifTrue:[

            "pageName"

    "/        'pageName ' print. value printNewline.

            ^ self

        ].

        (tagType == 286) ifTrue:[

            "xPosition"

    "/        'xPos ' print. value printNewline.

            ^ self

        ].

        (tagType == 287) ifTrue:[

            "yPosition"

    "/        'yPos ' print. value printNewline.

            ^ self

        ].

        (tagType == 288) ifTrue:[

            "freeOffsets"

    "/        'freeOffsets ' print. value printNewline.