"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ImageReader subclass:#ST80FormReader

	instanceVariableNames:''

	classVariableNames:''

	poolDictionaries:''

	category:'Graphics-Images-Support'

!

!ST80FormReader class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1993 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class provides methods for loading and saving st80-bitmap-file images.

    I am not sure, if this format is still supported/used by newer ST-80

    versions; it used to be in 2.x versions 

    (from what can be deduced by some bitmaps found in the manchester goodies).

    No writing is supported by this class.

    [See also:]

        Image Form Icon

        BlitImageReader FaceReader JPEGReader GIFReader PBMReader PCXReader 

        SunRasterReader TargaReader TIFFReader WindowsIconReader 

        XBMReader XPMReader XWDReader 

"

! !

!ST80FormReader class methodsFor:'testing'!

canRepresent:anImage

    "return true, if anImage can be represented in my file format.

     Only B&Wimages are supported."

    |photometric|

    anImage depth ~~ 1 ifTrue:[^ false].

    (((photometric := anImage photometric) ~~ #blackIs0) and:[photometric ~~ #whiteIs0]) ifTrue:[^ false.].

    ^ true

!

isValidImageFile:aFileName

    "return true, if aFileName contains an st80-bitmap-file image"

    |code inStream ok|

    inStream := self streamReadingFile:aFileName.

    inStream isNil ifTrue:[^ false].

    inStream binary.

    code := inStream nextWord.

    ok := (code == 1).

    inStream close.

    ^ ok

! !

!ST80FormReader methodsFor:'reading from file'!

fromStream:aStream

    "read an image in my format from aStream"

    |nBytes code offsetX offsetY|

    inStream := aStream.

    inStream binary.

    code := inStream nextWord.

    code isNil ifTrue:[

        ^ nil

    ].

    width := aStream nextWord.

    height := aStream nextWord.

    offsetX := aStream nextWord.

    offsetY := aStream nextWord.

    nBytes := width + 15 // 16 * 2 * height.

    data := ByteArray new:nBytes.

    aStream nextBytes:nBytes into:data.

    photometric := #whiteIs0.

    samplesPerPixel := 1.

    bitsPerSample := #(1)

    "ST80FormReader fromFile:''" 

! !

!ST80FormReader methodsFor:'writing to file'!

save:image onFile:aFileName

    "save image as XBM file on aFileName.

     This is obsolete - use the XBMReader directly."

    (self class canRepresent:image) ifFalse:[

        self error:'can only save Depth1Images'.

        ^ nil.

    ].

    outStream := FileStream newFileNamed:aFileName.

    outStream isNil ifTrue:[

        'create error' printNewline. 

        ^ nil

    ].

    width := image width.

    height := image height.

    photometric := image photometric.

    samplesPerPixel := image samplesPerPixel.

    bitsPerSample := image bitsPerSample.

    colorMap := image colorMap.

    outStream binary.

    outStream nextPutWord:1.

    outStream nextPutWord:width.

    outStream nextPutWord:height.

    outStream nextPutWord:0.

    outStream nextPutWord:0.

    outStream nextPutBytes:(data size) from:data.

    outStream close

    "ST80FormReader save:(Image fromFile:'bitmaps/SBrowser.xbm') onFile:'test.form'"

! !

!ST80FormReader class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libview2/ST80FormReader.st,v 1.15 1996-05-10 16:45:03 cg Exp $'

! !