"
 COPYRIGHT (c) 1992 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

ImageReader subclass:#PBMReader
	 instanceVariableNames:''
	 classVariableNames:''
	 poolDictionaries:''
	 category:'Graphics-Images support'
!

!PBMReader class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1992 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
! 

version
"
$Header: /cvs/stx/stx/libview2/PBMReader.st,v 1.13 1995-08-30 17:54:07 claus Exp $
"
!

documentation
"
    this class provides methods for loading and saving Portable BitMap-file 
    images (Jef Poskanzers portable bitmap package).
    Reading is supported for 1bit (pbm), greyscale (pgm) and 24bit (ppm) formats.
    Currently, only writing of 1-bit images (Pbm) is supported.

    Q: should we bring this one to perfection and base all others on
       pipe-readers to the various pbmplus converters ?
"
! !

!PBMReader class methodsFor:'initialization'!

initialize
    Image fileFormats at:'.pbm'  put:self.
    Image fileFormats at:'.pgm'  put:self.
    Image fileFormats at:'.pnm'  put:self.
! !

!PBMReader methodsFor:'private'!

skipPBMJunkOn:aStream 
    "This method removes any superfluous characters from the input stream."

    | char foundNL|

    [
	char := aStream peek.
	char == $# ifTrue:[
	    "Start of a comment. Skip to end-of-line."
"/            foundNL := (aStream skipUpTo: Character cr) notNil.
	    foundNL := (aStream skipThrough: Character cr) notNil.
	    foundNL ifFalse: [
		"Must be EOF"
		^self
	    ].
	    char := aStream peek].
	    aStream atEnd not and: [char isSeparator]
    ] whileTrue: [aStream next]
!

skipXPMJunkOn:aStream
    "This method removes any superfluous characters from the input stream."

    | char |

    [       
	char := aStream peek. 
	aStream atEnd not and: [char isSeparator not]
    ] whileTrue: [aStream next].

    [aStream atEnd not and: [char isSeparator]] whileTrue: [
	aStream next. char := aStream peek
    ].
    aStream atEnd ifTrue: [^char].
    (char isDigit) ifTrue: [ ^char ].
    (char == $") ifTrue: [ 
	aStream next. 
	char := aStream peek. 
	(char isLetterOrDigit 
	 or: [(char == $#) 
	 or: [char == Character space]]) ifFalse:[
	    ^ self skipXPMJunkOn: aStream 
	] ifTrue: [^char]
    ].

    ^self skipXPMJunkOn: aStream.
! !

!PBMReader methodsFor:'testing '!

canRepresent:anImage
    "return true, if anImage can be represented in my file format.
     Currently only B&W and Depth8 images are supported."

    |depth|

    anImage photometric == #rgb ifTrue:[
	^ false  "/ not yet implemented
    ].
    (depth := anImage depth) == 1 ifTrue:[^ true].
    depth == 8 ifTrue:[^ true].
    ^ false
! !

!PBMReader methodsFor:'writing to file'!

save:image onFile:aFileName
    "save image as PBM/PGM/PNM file on aFileName"

    outStream := FileStream newFileNamed:aFileName.
    outStream isNil ifTrue:[
	'PBMREADER: create error' errorPrintNL. 
	^ nil
    ].

    width := image width.
    height := image height.
    photometric := image photometric.
    samplesPerPixel := image samplesPerPixel.
    bitsPerSample := image bitsPerSample.
    colorMap := image colorMap.
    data := image bits.

    photometric == #rgb ifTrue:[
	^ self writePNMFileOn:outStream
    ].
    samplesPerPixel == 1 ifTrue:[
	((bitsPerSample at:1) == 1) ifTrue:[
	    ^ self writePBMFileOn:outStream
	].
	((bitsPerSample at:1) == 8) ifTrue:[
	    ^ self writePGMFileOn:outStream
	].
    ].
    self error:'format not supported'.

    "
     |img|

     img := Image fromFile:'bitmaps/SBrowser.xbm'.
     img inspect.
     PBMReader save:img onFile:'test.pbm'.
     img := Image fromFile:'test.pbm'.
     img inspect.


     |img mono|

     img := Image fromFile:'bitmaps/garfield.gif'.
     img inspect.
     mono := img asMonochromeFormOn:Display.
     img := mono asImage.
     img inspect.
     PBMReader save:img onFile:'test.pbm'.
     img := Image fromFile:'test.pbm'.
     img inspect.
    "
!

writePNMFileOn:outStream
    self error:'not yet implemented'
!

writePBMFileOn:aStream
    "Saves the receivers image on the file fileName in Portable Bitmap format.
     See the class method pbmSyntax for details of the format."

    aStream nextPutAll:'P4'; cr.
    aStream nextPutAll:'#  Converted from Smalltalk Form on '.
    aStream nextPutAll:Date today printString.
    aStream nextPutAll:' at ', Time now printString.
    aStream cr.
    aStream nextPutAll:width printString.
    aStream space.
    aStream nextPutAll:height printString.
    aStream cr.

    aStream binary.
    photometric == #blackIs0 ifTrue:[
	aStream nextPutAll:data.
    ] ifFalse:[
	data invert.
	aStream nextPutAll:data.
	data invert.
    ].
    aStream close.
!

writePGMFileOn:outStream
    self error:'not yet implemented'
! !

!PBMReader methodsFor:'reading from file'!

fromStream:aStream
    "read a Portable bitmap file format as of Jef Poskanzers Portable Bitmap Package.
     supported are PBM, PGB and PNM files." 

    | pnmType |

    inStream := aStream.
    inStream text.

    inStream next == $P ifFalse:[
	'PBMREADER: PNM format' errorPrintNL.
	^nil
    ].
    pnmType := inStream next.
    pnmType == $4 ifTrue: [
	^ self readDepth1PBMStream:aStream
    ].
    pnmType == $5 ifTrue: [
	^ self readDepth8PGMStream:aStream
    ].
    pnmType == $6 ifTrue: [
	^ self readDepth24PPMStream:aStream
    ].
    'PBMREADER: No recognized PNM file format' errorPrintNL.
    ^ nil

    "
     PBMReader fromFile:'bitmaps/testimg.ppm'
     PBMReader fromFile:'../../fileIn/bitmaps/keyboard.pbm'
    "
!

readDepth1PBMStream:aStream 
    "import portable bitmap (PBM); P4 is already read"

    self skipPBMJunkOn:aStream.
    width := Integer readFrom:aStream.
    width > 0 ifFalse: [
	'PBMREADER: Invalid width' errorPrintNL.
	^ nil
    ].

    self skipPBMJunkOn:aStream.
    height := Integer readFrom:aStream.
    height > 0 ifFalse: [
	'PBMREADER: Invalid height' errorPrintNL.
	^ nil
    ].

    aStream nextLine "skipThrough: Character cr".
    aStream binary.
    data := aStream contents.

    photometric := #blackIs0.
    samplesPerPixel := 1.
    bitsPerSample := #(1).
!

readDepth8PGMStream:aStream 
    "import portable gray map (PGM); P5 is already read"

    |maxval|

    self skipPBMJunkOn:aStream.
    width := Integer readFrom:aStream.
    width > 0 ifFalse:[ 
	'PBMREADER: Invalid width' errorPrintNL.
	^ nil
    ].
    self skipPBMJunkOn:aStream.
    height := Integer readFrom:aStream.
    height > 0 ifFalse:[ 
	'PBMREADER: Invalid height' errorPrintNL.
	^ nil
    ].
    self skipPBMJunkOn:aStream.
    maxval := Integer readFrom:aStream.
    maxval >= 256 ifTrue:[
	'PBMREADER: Invalid format' errorPrintNL.
	^ nil
    ].
    aStream skipThrough: Character cr.
    aStream binary.
    data := aStream contents.

    photometric := #blackIs0.
    samplesPerPixel := 1.
    bitsPerSample := #(8).
!

readDepth24PPMStream:aStream
    "import portable pixmap (PPM); P6 is already read"

    | maxval |

    self skipPBMJunkOn:aStream.
    width := Integer readFrom:aStream.
    width > 0 ifFalse: [
	'PBMREADER: Invalid width' errorPrintNL.
	^ nil
    ].

    self skipPBMJunkOn:aStream.
    height := Integer readFrom:aStream.
    height > 0 ifFalse: [
	'PBMREADER: Invalid height' errorPrintNL.
	^ nil
    ].

    self skipPBMJunkOn:aStream.
    maxval := Integer readFrom:aStream.
    maxval >= 256 ifTrue: [
	'PBMREADER: format error' errorPrintNL.
	^ nil
    ].

    aStream skipThrough: Character cr.
    aStream binary.

    data := aStream contents.
    photometric := #rgb.
    samplesPerPixel := 3.
    bitsPerSample := #(8 8 8).
! !