"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

ListSelectionBox subclass:#FileSelectionBox

	 instanceVariableNames:'patternField'

	 classVariableNames:''

	 poolDictionaries:''

	 category:'Views-DialogBoxes'

!

!FileSelectionBox class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1990 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this class implements file selection boxes. Instances show a list of

    files, and perform an action block with the selected pathname as

    argument when ok is clicked.

    There is an optional PatternField, which shows itself when a pattern

    is defined (i.e. if there is no pattern, it is hidden). 

    If there is a pattern, only files matching the pattern will be shown in 

    the list (and directories).

    In addition, there is an optional matchBlock (actually this is defined 

    in the FileSelectionList). Only filenames for which this matchblock

    returns true will be presented.

"

!

examples 

"

    Example1:

	FileSelectionBox open

    Example2:

	FileSelectionBox new open

    Example3:

	|box|

	box := FileSelectionBox new.

	box title:'Which file ?'.

	box open

    Example4:

	|box|

	box := FileSelectionBox new.

	box title:'Which file ?'.

	box pattern:'*.doc'.

	box open

    Example5:

	|box|

	box := FileSelectionBox new.

	box title:'Which file ?'.

	box pattern:'*'.

	box matchBlock:[:name | name first isLowercase].

	box open

    Example6:

	|box|

	box := FileSelectionBox new.

	box title:'Which directory ?'.

	box pattern:'l*'.

	box matchBlock:[:name | OperatingSystem isDirectory:name].

	box open

"

!

version

    ^ '$Header: /cvs/stx/stx/libwidg/Attic/FSelBox.st,v 1.23 1995-11-23 02:25:26 cg Exp $'

! !

!FileSelectionBox class methodsFor:'defaults'!

requestFilename

    ^ self requestFilename:'filename:'

    "

     FileSelectionBox requestFilename

    "

!

requestFilename:title

    |fileBox|

    fileBox := self

		    title:title

		    okText:'ok'

		    abortText:'cancel'

		    action:[:fileName | ^ fileName].

    fileBox showAtPointer.

    ^ nil

    "

     FileSelectionBox requestFilename:'which file ?'

    "

! !

!FileSelectionBox class methodsFor:'requests'!

listViewType

    "return the type of listView - using a FileSelectionList here"

    ^ FileSelectionList

! !

!FileSelectionBox methodsFor:'accessing'!

contents

    "return the current entered value (i.e. the enterFields string).

     redefined to return the full pathname."

    |string sep|

    string := super contents.

    string isNil ifTrue:[

	^ selectionList directory pathName

    ].

    sep := Filename separator.

    (string startsWith:sep) ifTrue:[

	^ string

    ].

    ^ (selectionList directory pathName asFilename construct:string) asString

!

directory:directoryName

    "change the directory shown in the list."

    selectionList directory:directoryName

!

matchBlock:aBlock

    "set the matchBlock (in the selectionList). Only files

     for which the block returns true are shown.

     The matching is actually done in the fileSelectionList."

    selectionList matchBlock:aBlock 

!

openOn:aPath

    "open the box showing files in aPath.

     This is only a shortcut message - no new functionality."

    self directory:aPath.

    self showAtPointer

!

pattern:aPattern

    "set the pattern - this also enables the PatternField

     (if the pattern is non-nil) or hides it (if nil)."

    |hidePatternField focusSequence|

    patternField initialText:aPattern.

    selectionList pattern:aPattern.

    aPattern isNil ifTrue:[

	hidePatternField := true.

	realized ifTrue:[

	    patternField hide.

	].

	focusSequence := (Array 

			     with:enterField 

			     with:selectionList 

			     with:okButton 

			     with:abortButton)

    ] ifFalse:[

	hidePatternField := false.

	realized ifTrue:[

	    patternField realize.

	].

	focusSequence := (Array 

			     with:patternField 

			     with:enterField 

			     with:selectionList 

			     with:okButton 

			     with:abortButton)

    ].

    patternField hiddenOnRealize:hidePatternField.

    windowGroup notNil ifTrue:[

	windowGroup focusSequence:focusSequence

    ].

! !

!FileSelectionBox methodsFor:'change & update'!

update:something with:argument from:changedObject

    |commonName index s|

    something == #directory ifTrue:[

	"

	 sent by fileNameEnterField, if a filename

	 completion was not possible due to multiple

	 matches.

	"

	selectionList directory:argument.

	s := enterField contents.

	s notNil ifTrue:[

	    commonName := s asFilename baseName.

	    commonName size > 0 ifTrue:[

		index := selectionList list findFirst:[:entry | entry startsWith:commonName].

		index ~~ 0 ifTrue:[

		    selectionList makeLineVisible:index

		]

	    ]

	]

    ]

! !

!FileSelectionBox methodsFor:'initialization'!

createEnterField

    "if the (optional) class FilenameEditField is present, use

     it, since it provides filename completion. Otherwise, we have

     to live with the dump (default) field ...

    "

    FilenameEditField notNil ifTrue:[

	^ FilenameEditField new.

    ].

    ^ super createEnterField

!

focusSequence

    patternField shown ifTrue:[

	^ Array 

	    with:patternField 

	    with:enterField 

	    with:selectionList 

	    with:abortButton

	    with:okButton 

    ].

    ^ super focusSequence

!

initialize

    |corner|

    super initialize.

    label := resources string:'File dialog'.

    labelField extent:(0.7 @ labelField height).

    labelField label:(resources string:'select a file:').

    labelField adjust:#left.

    patternField := EditField in:self.

    self is3D ifTrue:[

	corner := (1.0 @ (labelField origin y+patternField heightIncludingBorder)).

    ] ifFalse:[

	corner := [(width - ViewSpacing - (patternField borderWidth * 2)) @ (labelField origin y+patternField height"IncludingBorder")].

    ].

    patternField origin:(0.7 @ labelField origin y) corner:corner.

    patternField rightInset:ViewSpacing.

    patternField initialText:'*'.

    patternField leaveAction:[:reason | 

	selectionList pattern:patternField contents. 

	self updateList

    ].

    patternField hiddenOnRealize:true. "delay showing, until a pattern is defined"

    enterField addDependent:self.

    "

     FileSelectionBox open

     FileSelectionBox new show

    "

!

realize

    "if some default is present in the enterField,

     scroll to make this one visible"

    |contents|

    super realize.

    (contents := enterField contents) notNil ifTrue:[

	contents notEmpty ifTrue:[

	    selectionList makeVisible:contents

	]

    ]

! !

!FileSelectionBox methodsFor:'private'!

updateList

    selectionList updateList

! !

!FileSelectionBox methodsFor:'queries'!

preferredExtent

    "return my preferred extent - thats the minimum size 

     to make everything visible"

    |wWanted hWanted|

    wWanted := ViewSpacing + 

	       labelField preferredExtent x + 

	       (ViewSpacing * 2) + 

	       patternField preferredExtent x + 

	       ViewSpacing.

    (wWanted < width) ifTrue:[

	wWanted := width

    ].

    hWanted := ViewSpacing + labelField height +

	       ViewSpacing + enterField height +

	       ViewSpacing + selectionList height +

	       ViewSpacing + buttonPanel preferredExtent y +

	       ViewSpacing.

    (hWanted < height) ifTrue:[

	hWanted := height

    ].

    ^ (wWanted @ hWanted)

! !

!FileSelectionBox methodsFor:'user actions'!

doubleClick

    |entry|

    entry := selectionList selectionValue.

    entry notNil ifTrue:[

	((selectionList directory typeOf:entry) == #directory) ifFalse:[

	    enterField contents:entry.

	    self okPressed

	]

    ].

!

okPressed

    "called for both on ok-press and on return-key"

    |dir string fname|

    string := enterField contents.

    string notNil ifTrue:[

	string := string withoutSeparators.

	string asFilename isAbsolute ifTrue:[

	    fname := string asFilename

	] ifFalse:[

	    dir := selectionList directory pathName asFilename.

	    fname := dir construct:string

	].

	fname isDirectory ifTrue:[

	    selectionList directory:fname asString.

	    self updateList.

	    ^ self

	]

    ].

    super okPressed

!

selectionChanged

    |entry|

    entry := selectionList selectionValue.

    enterField contents:entry

! !