"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

OrderedCollection subclass:#RadioButtonGroup

!

!RadioButtonGroup class methodsFor:'documentation '!

copyright

"

 COPYRIGHT (c) 1991 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    RadioButtonGroups control the interaction between RadioButtons

    turning off other button(s) when one of the group is pressed.

    To group some buttons (and have one-on behavior) use:

    A radioButtonGroup installs itself as the model of its toggles or

    radioButtons. Therefore, you can no longer operate the individual

    elements on models.

    Instead, the group now provides a valueHolder which takes as value 

    the index of the selected toggle. You can set/get this valueHolder

    via the valueChannel:/valueChannel messages.

    See the last example for how this is done.

    The groupID instance variable is not required for normal operation;

    the interface builder uses it to give a button-group some descriptive 

    (unique) name.

"

!

examples 

"

    example (using Toggles for 'at most one-on behavior'):

	|top panel toggle b group|

	top := StandardSystemView new.

	panel := HorizontalPanelView origin:0.0@0.0 corner:1.0@1.0 in:top.

	group := RadioButtonGroup new.

	b := Toggle label:'one' in:panel.

	group add:b.

	b := Toggle label:'two' in:panel.

	group add:b.

	b := Toggle label:'three' in:panel.

	group add:b.

	top extent:(panel preferredExtent).

	top open.

    example (using RadioButtons for 'one-on behavior'):

	|top panel toggle b group|

	top := StandardSystemView new.

	panel := HorizontalPanelView origin:0.0@0.0 corner:1.0@1.0 in:top.

	group := RadioButtonGroup new.

	b := RadioButton label:'one' in:panel.

	group add:b.

	b := RadioButton label:'two' in:panel.

	group add:b.

	b := RadioButton label:'three' in:panel.

	group add:b.

	top extent:(panel preferredExtent).

	top open.

    example (using Buttons for 'none-on behavior'; but the groups value remembers the last button):

	|top panel toggle b group|

	top := StandardSystemView new.

	panel := HorizontalPanelView origin:0.0@0.0 corner:1.0@1.0 in:top.

	group := RadioButtonGroup new.

	b := Button label:'one' in:panel.

	group add:b.

	b := Button label:'two' in:panel.

	group add:b.

	b := Button label:'three' in:panel.

	group add:b.

	top extent:(panel preferredExtent).

	top open.

	group valueChannel inspect

    example (same, with button 'two' initially on):

	|top panel toggle b group|

	top := StandardSystemView new.

	panel := HorizontalPanelView origin:0.0@0.0 corner:1.0@1.0 in:top.

	group := RadioButtonGroup new.

	b := RadioButton label:'one' in:panel.

	group add:b.

	b := RadioButton label:'two' in:panel.

	group add:b.

	group value:2.

	b := RadioButton label:'three' in:panel.

	group add:b.

	top extent:(panel preferredExtent).

	top open.

    using checkBoxes (these have a label included):

	|top panel toggle b group|

	top := StandardSystemView new.

	panel := VerticalPanelView origin:0.0@0.0 corner:1.0@1.0 in:top.

	panel horizontalLayout:#left.

	group := RadioButtonGroup new.

	b := CheckBox label:'one' in:panel.

	group add:b.

	b := CheckBox label:'two' in:panel.

	group add:b.

	b := CheckBox label:'three' in:panel.

	group add:b.

	top extent:(panel preferredExtent).

	top open.

    example (operating on a model)

	|selected dialog group|

	selected := 2 asValue.

	dialog := Dialog new.

	group := RadioButtonGroup new.

	group add:(dialog addCheckBox:'one' on:nil) toggleView.

	group add:(dialog addCheckBox:'two' on:nil) toggleView.

	group add:(dialog addCheckBox:'three' on:nil) toggleView.

	group valueChannel:selected.

	dialog addAbortButton; addOkButton.

	dialog open.

	dialog accepted ifTrue:[

	    Transcript showCr:'you selected: ' , selected value printString

	] ifFalse:[

	    Transcript showCr:'aborted'

	]

"

    "Created: 15.11.1995 / 17:14:53 / cg"

!

version

! !

!RadioButtonGroup methodsFor:'accessing'!

groupID

    ^ groupID

    "Modified: 5.9.1995 / 16:04:33 / claus"

!

groupID:aSymbol 

    groupID := aSymbol

    "Modified: 5.9.1995 / 16:04:28 / claus"

! !

!RadioButtonGroup methodsFor:'accessing-mvc'!

value

    ^ valueChannel value

!

value:anIndex

    valueChannel value:anIndex

!

valueChannel

    ^ valueChannel

!

valueChannel:aValueHolder

    |oldValue newValue|

    valueChannel notNil ifTrue:[oldValue := valueChannel value].

    valueChannel := aValueHolder.

    (newValue := valueChannel value) ~~ oldValue ifTrue:[

	(self at:newValue) turnOnWithAction

    ]

! !

!RadioButtonGroup methodsFor:'adding / removing'!

add:aRadioButton

    super add:aRadioButton.

    "

     this would work, if dependencies were not weak ...

    "

"/    aRadioButton addDependent:self.

    "

     therefore, we have to install ourself as model of the buttons/toggles

     creating a valueChannel, if there is none yet.

    "

    valueChannel isNil ifTrue:[

	valueChannel := 0 asValue

    ].

    aRadioButton isOn ifTrue:[valueChannel value:self size].

    aRadioButton model:self; aspectMessage:#queryFrom:; changeMessage:#elementChanged:from:.

! !

!RadioButtonGroup methodsFor:'update'!

elementChanged:aToggle

    "historic compatibility leftover - will vanish"

    ^ self elementChanged:true from:aToggle

!

elementChanged:value from:aToggle

    "some element changed its value - find it, turn the others off

     and update my value"

    |newValue|

    self keysAndValuesDo:[:index :aComponent |

       ((aToggle == aComponent) or:[aToggle isSubViewOf:aComponent]) ifTrue:[

	    value ifTrue:[newValue := index]   

	] ifFalse:[

"/            aComponent isOn ifTrue:[

"/               aComponent turnOff

"/            ]

	]

    ].

"/    aToggle turnOn.

    valueChannel value:newValue.

    self changed:#queryFrom:

    "Modified: 21.9.1995 / 13:42:06 / claus"

!

queryFrom:aToggle

    "a query from a toggle, if its the selected one"

    self keysAndValuesDo:[:index :aComponent |

       ((aToggle == aComponent) or:[aToggle isSubViewOf:aComponent]) ifTrue:[

	    ^ valueChannel value == index

       ]

    ].

    ^ false

    "Modified: 14.11.1995 / 21:21:27 / cg"

!

update:something with:someArgument from:changedButton

    "

     a RadioButton in this group has changed - notify the others

    "

    self elementChanged:(changedButton isOn) from:changedButton

! !