"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

SimpleView subclass:#PanelView

	instanceVariableNames:'hLayout vLayout verticalSpace horizontalSpace mustRearrange

		elementsChangeSize'

	classVariableNames:''

	poolDictionaries:''

	category:'Views-Layout'

!

!PanelView  class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    this is a view for holding subviews. (layout-widget ?)

    Instances of PanelView try to get all their subviews into them,

    arranging subviews left-to-right, top-to-bottom.

    If you dont like its layout, define a new subclass or use one of

    the existing subclasses: HorizontalPanelView and VerticalPanelView.

    The panel assumes, that the elements do not resize themselfes, after it

    became visible. This is not true for all widgets (buttons or labels may

    like to change). If you have changing elements, tell this to the panel

    with 'aPanel elementsChangeSize:true'. In that case, the panel will react

    to size changes, and reorganize things.

    PanelViews normally delay the actual positioning/sizing of their elements,

    until actually displayed. This is useful, if more elements are to

    be added, to avoid repeated configuration of the elements.

    If you want to query for the relative position of an element BEFORE

    the view is visible, you have to send #setChildPositionsIfChanged before

    doing so (otherwise, you may get invalid origins from the subviews). As

    an example, the modalBoxes do so before showing themselfes to ask for the

    position of the ok-button relative to the top-left box-origin, in order to

    position the ok-button under the mouse-pointer.

    [Instance variables:]

        hLayout         <Symbol>        controls horizontal layout; ignored in this

                                        class, but used in Horizontal- and

                                        VerticalPanelViews. See more info there.

        vLayout         <Symbol>        controls vertical layout; ignored in this

                                        class, but used in Horizontal- and

                                        VerticalPanelViews. See more info there.

        horizontalSpace <Integer>       number of pixels to use as space between elements

                                        defaults to ViewSpacing, which is 1mm

        verticalSpace   <Integer>       number of pixels to use as space between elements

                                        defaults to ViewSpacing, which is 1mm

        mustRearrange   <Boolean>       internal flag, if rearrangement is needed

        elementsChangeSize   

                        <Boolean>       if true, the panel takes care of this situation.

                                        By default, this is false.

    [author:]

        Claus Gittinger

"

! !

!PanelView methodsFor:'accessing'!

elementsChangeSize:aBoolean

    "tell the panel if elements are to change their size by themselfes

     (for example, Lables or Buttons may do so if their contents changes).

     Setting this flag will make the panel reorganize the elements whenever

     any element changes its size."

    elementsChangeSize := aBoolean.

    aBoolean ifTrue:[

	subViews notNil ifTrue:[

	    subViews do:[:aView |

		aView addDependent:self

	    ]

	]

    ]

!

horizontalSpace:numberOfPixels

    "set the horizontal space between elements on pixels (default is 1mm)"

    horizontalSpace ~= numberOfPixels ifTrue:[

	horizontalSpace := numberOfPixels.

	self layoutChanged

    ]

!

space:numberOfPixels

    "set the space between elements in pixels (default is 1mm) for both directions"

    (verticalSpace ~= numberOfPixels 

    or:[horizontalSpace ~= numberOfPixels]) ifTrue:[

	horizontalSpace := numberOfPixels.

	verticalSpace := numberOfPixels.

	self layoutChanged

    ]

!

verticalSpace:numberOfPixels

    "set the vertical space between elements (in pixels).

     The default is computed for 1mm spacing."

    verticalSpace ~= numberOfPixels ifTrue:[

	verticalSpace := numberOfPixels.

	self layoutChanged

    ]

! !

!PanelView methodsFor:'adding & removing subviews'!

addSubView:aView

    "redefined to recompute layout when a subview is added"

    super addSubView:aView.

    self addedView:aView

!

addSubView:newView after:aView

    "redefined to recompute layout when a subview is added"

    super addSubView:newView after:aView.

    self addedView:newView

    "Modified: 15.7.1996 / 10:15:04 / cg"

!

addSubView:newView before:aView

    "redefined to recompute layout when a subview is added"

    super addSubView:newView before:aView.

    self addedView:newView

    "Modified: 15.7.1996 / 10:14:39 / cg"

!

removeSubView:aView

    "redefined to recompute layout when a subview is removed"

    super removeSubView:aView.

    aView removeDependent:self.

    self layoutChanged

! !

!PanelView methodsFor:'event processing'!

sizeChanged:how

    "my size has changed - must rearrange elements"

    super sizeChanged:how.

    self layoutChanged

!

update:something with:aParameter from:changedObject

    something == #sizeOfView ifTrue:[

	"

	 an element changed its size

	"

	(subViews includes:changedObject) ifTrue:[

	    self layoutChanged

	].

	^ self

    ].

    ^ super update:something with:aParameter from:changedObject

! !

!PanelView methodsFor:'initialization'!

initialize

    super initialize.

    hLayout := vLayout := #center.  "/ notice, this is ignored in this class

				    "/ used by subclasses only

    verticalSpace := ViewSpacing.

    horizontalSpace := ViewSpacing.

    mustRearrange := elementsChangeSize := false

!

realize

    mustRearrange ifTrue:[

	self setChildPositions

    ].

    super realize

!

setChildPositionsIfChanged

    "set all of my child positions - this is usually delayed,

     until the panel is actually shown (since we dont know, if more

     elements are to be added) thus avoiding repositioning the elements

     over and over. However, sometimes it is nescessary, to force positioning

     the elements, for example, before querying the relative position of

     an element (modalBoxes do so, to position the ok-button under the mouse

     pointer)."

    mustRearrange ifTrue:[

	self setChildPositions

    ].

! !

!PanelView methodsFor:'private'!

addedView:aView

    "added a new element"

    elementsChangeSize ifTrue:[

        aView addDependent:self

    ].

    aView resize.

"/    explicitExtent ~~ true ifTrue:[

"/        self resize

"/    ].

    self layoutChanged

    "Modified: 15.7.1996 / 12:52:07 / cg"

!

layoutChanged

    "called whenever repositioning is required. If the panel view is

     already visible, reposition elements right now. Otherwise, remember

     that a repositioning is needed to do so when the view eventually becomes

     visible."

    shown ifTrue:[

	self setChildPositions

    ] ifFalse:[

	mustRearrange := true

    ]

!

setChildPositions

    "(re)compute position of every child.

     This method is redefined for different layout characteristics - you may

     even create subclasses with completely different geometry management."

    |first xpos ypos maxHeightInRow thisRow|

    subViews notNil ifTrue:[

	xpos := horizontalSpace.

	ypos := verticalSpace.

	maxHeightInRow := 0.

	first := true.

	thisRow := OrderedCollection new.

	subViews do:[:child |

	    "go to next row, if this subview won't fit"

	    first ifFalse: [

		(xpos + child widthIncludingBorder + horizontalSpace) > width

		ifTrue: [

		    thisRow notEmpty ifTrue:[

			thisRow do:[:rowElement |

			    rowElement heightIncludingBorder < maxHeightInRow ifTrue:[

				rowElement top:(rowElement top + (maxHeightInRow - rowElement heightIncludingBorder))

			    ]

			]

		    ].

		    ypos := ypos + verticalSpace + maxHeightInRow.

		    xpos := horizontalSpace.

		    maxHeightInRow := 0.

		    thisRow := OrderedCollection new.

		]

	    ].

	    thisRow add:child.

	    child origin:(xpos@ypos).

	    xpos := xpos + (child widthIncludingBorder) + horizontalSpace.

	    (maxHeightInRow < (child heightIncludingBorder)) ifTrue:[

		maxHeightInRow := child heightIncludingBorder

	    ].

	    first := false

	].

	thisRow notEmpty ifTrue:[

	    thisRow do:[:rowElement |

		rowElement heightIncludingBorder < maxHeightInRow ifTrue:[

		    rowElement top:(rowElement top + (maxHeightInRow - rowElement heightIncludingBorder))

		]

	    ]

	].

    ].

    mustRearrange := false

! !

!PanelView  class methodsFor:'documentation'!

version

    ^ '$Header: /cvs/stx/stx/libwidg/PanelView.st,v 1.18 1996-07-15 14:40:45 cg Exp $'

! !