"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg' }"

"{ NameSpace: Smalltalk }"

EditTextView subclass:#TextCollector

	instanceVariableNames:'entryStream lineLimit destroyAction outstandingLines

		outstandingLine flushBlock flushPending inFlush collecting

		timeDelay access currentEmphasis alwaysAppendAtEnd collectSize

		autoRaise'

	classVariableNames:'TranscriptQuerySignal DebugSendersOfMessagePattern

		TraceSendersOfMessagePattern TimestampMessages DefaultLineLimit

		DefaultTimeDelay DefaultCollectSize'

	poolDictionaries:''

	category:'Views-Text'

!

!TextCollector class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1989 by Claus Gittinger

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    a view for editable text, which also understands some stream messages.

    Instances of this view can take the place of a stream and display the 

    received text.

    Its main use in the system is the Transcript, but it can also be used for

    things like trace-windows, errorLogs etc.

    It is also inherited by TerminalView, which especially uses the buffering and

    delayed output features for high performance output (compare to a windows console).

    If collecting is turned on, a textcollector will not immediately display 

    entered text, but wait for some short time (timeDelay) and collect incoming 

    data - finally updating the whole chunk in one piece. 

    This helps slow display devices, which would otherwise scroll a lot. 

    (on fast displays this is less of a problem).

    The total number of lines kept is controlled by lineLimit, if more lines 

    than this limit are added at the bottom, the textcollector will forget lines 

    at the top. You can set linelimit to nil (i.e. no limit), but you may need a lot 

    of memory then ...

    [StyleSheet paramters (transcript only):]

        transcriptForegroundColor       defaults to textForegroundColor

        transcriptBackgroundColor'      defaults to textBackgroundColor.

        transcriptCursorForegroundColor

        transcriptCursorBackgroundColor

    [author:]

        Claus Gittinger

    [see also:]

        CodeView EditTextView

        ActorStream

"

! !

!TextCollector class methodsFor:'instance creation'!

initialize

    TranscriptQuerySignal isNil ifTrue:[

        TranscriptQuerySignal := QuerySignal new.

    ]

!

newTranscript

    "create and open a new transcript.

     This is a leftOver method from times were the Launcher & Transcript

     were two different views. It is no longer recommended."

    ^ self newTranscript:#Transcript

    "

     TextCollector newTranscript.

     Transcript lineLimit:3000.

    "

    "Modified: 17.2.1997 / 18:20:27 / cg"

!

newTranscript:nameSymbol

    "create and open a new transcript, unless one already exists by that name.

     The transcript is remembered in a global by that name.

     This is a leftOver method from times were the Launcher & Transcript

     were two different views. It is no longer recommended."

    |topView transcript defSz f v lines cols|

    transcript := Smalltalk at:nameSymbol.

    (transcript isTextView and:[transcript isOpen and:[transcript device == Screen current]]) ifTrue:[

        "if there is already an open Transcript on the same device, 

         do not open an additional one.

         expecco StandardLibrary <= 2.0.0.3 checked for Transcript>>#isStream and

         tries to opens a new Transcript window for each new Transcribe with expecco >=2.4"

        ^ transcript.

    ].

    topView := StandardSystemView label:nameSymbol "minExtent:(100 @ 100)".

    v := HVScrollableView for:self miniScrollerH:true miniScrollerV:false in:topView.

    v origin:(0.0 @ 0.0) corner:(1.0 @ 1.0).

    transcript := v scrolledView.

    "transcript partialLines:false."

    f := transcript font.

    "

     should add the height of the frame & scrollbars to be exact ...

    "

    defSz := self defaultTranscriptSize.

    cols := defSz x.

    lines := defSz y.

    topView extent:(((f widthOf:'x') * cols) @ (f height * lines)).

    transcript beTranscript:nameSymbol.

    "

     run it at a slightly higher prio, to allow for

     delayed buffered updates to be performed

    "

    topView openWithPriority:(Processor userSchedulingPriority + 1).

    ^ transcript

    "

     TextCollector newTranscript:#T2.

     T2 showCR:'Hello world'.

     Smalltalk removeKey:#T2

    "

    "Modified: 17.2.1997 / 18:20:27 / cg"

! !

!TextCollector class methodsFor:'Signal constants'!

transcriptQuerySignal

    ^ TranscriptQuerySignal

! !

!TextCollector class methodsFor:'debugging'!

debugSendersOfMessagePattern

    ^ DebugSendersOfMessagePattern

    "Created: / 02-02-2012 / 12:05:27 / cg"

!

debugSendersOfMessagePattern:aGLOBMatchPattern

    "ever want to know, who sends a particular text-message to the transcript ?

     Call this with a match string and get a halt, when a matching text is sent to the transcript"

    DebugSendersOfMessagePattern := aGLOBMatchPattern asNilIfEmpty

    "

     self debugSendersOfMessagePattern:'no such*'

     self debugSendersOfMessagePattern:'remove*'

     self debugSendersOfMessagePattern:nil.

     self debugSendersOfMessagePattern:'*'.

    "

    "Modified: / 02-02-2012 / 12:07:11 / cg"

!

timestampMessages

    ^ TimestampMessages

!

timestampMessages:aBoolean

    "if true, all messages are shown with a timestamp in front"

    TimestampMessages := aBoolean 

    "

     self timestampMessages:true

     self timestampMessages:false.

    "

!

traceSendersOfMessagePattern

    ^ TraceSendersOfMessagePattern

    "Created: / 02-02-2012 / 12:05:32 / cg"

!

traceSendersOfMessagePattern:aGLOBMatchPattern

    "ever want to know, who sends a particular text-message to the transcript ?

     Call this with a match string and get a trace, when a matching text is sent to the transcript"

    TraceSendersOfMessagePattern := aGLOBMatchPattern asNilIfEmpty

    "

     self traceSendersOfMessagePattern:'removed unreached*'

     self traceSendersOfMessagePattern:nil.

     self traceSendersOfMessagePattern:'*'.

    "

    "Created: / 02-02-2012 / 11:59:22 / cg"

! !

!TextCollector class methodsFor:'defaults'!

defaultCollectSize

    "the number of lines buffered for delayed update.

     At most this number of lines to be shown are buffered (without redrawing),

     before a redraw is done. Thus, if a lot of output is generated fast,

     the redrawing is performed in chunks. 

     This has a significant effect on the performane, 

     as the view does not have to scroll and redraw for each

     individual line, but does junp-scrolling instead.

     See also defaultTimeDelay"

    ^ DefaultCollectSize ? 1000

    "Modified: / 27.7.1998 / 16:14:51 / cg"

!

defaultCollectSize:numberOfLines

    "the number of lines buffered for delayed update.

     At most this number of lines to be shown are buffered (without redrawing),

     before a redraw is done. Thus, if a lot of output is generated fast,

     the redrawing is performed in chunks. 

     This has a significant effect on the performane, 

     as the view does not have to scroll and redraw for each

     individual line, but does junp-scrolling instead.

     See also defaultTimeDelay"

    DefaultCollectSize := numberOfLines

    "Modified: / 27.7.1998 / 16:14:51 / cg"

!

defaultLineLimit

    "the number of lines remembered by default.

     Only the last n lines are remembered and can be seen by scrolling.

     Older lines are forgotten.

     This limit can be changed by the userPreferences dialog"

    ^ DefaultLineLimit ? 1000

!

defaultLineLimit:numberOfLines

    "the number of lines remembered by default.

     Only the last n lines are remembered and can be seen by scrolling.

     Older lines are forgotten.

     This limit can be changed by the userPreferences dialog"

    DefaultLineLimit := numberOfLines

!

defaultTimeDelay

    "the time in seconds to wait & collect by default.

     At most this number of seconds incoming text is buffered (without redrawing),

     before a redraw is done. Thus, if a lot of output is generated fast,

     the redrawing is performed in chunks. 

     This has a significant effect on the performane, 

     as the view does not have to scroll and redraw for each

     individual line, but does junp-scrolling instead.

     The value may be a float (eg. 0.5)

     See also defaultCollectSize"

    ^ DefaultTimeDelay ? 0.5 

!

defaultTimeDelay:seconds

    "the time in seconds to wait & collect by default.

     At most this number of seconds incoming text is buffered (without redrawing),

     before a redraw is done. Thus, if a lot of output is generated fast,

     the redrawing is performed in chunks. 

     This has a significant effect on the performane, 

     as the view does not have to scroll and redraw for each

     individual line, but does junp-scrolling instead.

     The argument may be a float (eg. 0.5)

     See also defaultCollectSize"

    DefaultTimeDelay := seconds 

!

defaultTranscriptSize

    "the number of cols/lines by which the Transcript should come up"

    ^ 70@11

! !

!TextCollector methodsFor:'Compatibility-ST80'!

deselect

    self unselect

!

flush

    self endEntry.

    super flush

! !

!TextCollector methodsFor:'accessing'!

autoRaise

    ^ autoRaise ? false

!

autoRaise:something

    autoRaise := something.

!

collect:aBoolean

    "turn on/off collecting - if on, do not output immediately

     but collect text and output en-bloque after some time delta"

    collecting := aBoolean

!

collectSize:numberOfLines

    "set the collect buffer size. If collect is enabled,

     the receiver will force update of the view, 

     whenever that many lines have been collected

     (or the updateTimeDelay interval has passed).

     With collect turned off, an immediate update is performed."

    collectSize := numberOfLines

    "Modified: / 27.7.1998 / 16:16:00 / cg"

!

destroyAction:aBlock

    "define the action to be performed when I get destroyed.

     This is a special feature, to allow resetting Transcript to Stderr

     when closed. (see TextCollectorclass>>newTranscript)"

    destroyAction := aBlock

!

entryStream

    ^ entryStream

!

lineLimit

    "return the number of text-lines I am supposed to hold when collecting.

     Nil means: unlimited"

    ^ lineLimit

    "

     Transcript lineLimit:5000

     Transcript lineLimit

    "

    "Modified: / 16.5.1998 / 01:33:52 / cg"

!

lineLimit:aNumber

    "define the number of text-lines I am supposed to hold"

    lineLimit := aNumber

    "

     Transcript lineLimit:5000

    "

    "Modified: / 16.5.1998 / 01:33:52 / cg"

!

updateTimeDelay:seconds

    "if collect is enabled, the receiver will update its view, 

     after that time delay (i.e. it collects output during that period),

     or when collectSize lines have been collected without update.

     With collect turned off, an immediate update is performed."

    timeDelay := seconds

    "Modified: / 27.7.1998 / 16:16:41 / cg"

! !

!TextCollector methodsFor:'event handling'!

exposeX:x y:y width:w height:h

    "flush buffered text when exposed"

    super exposeX:x y:y width:w height:h.

    "/ self endEntry

! !

!TextCollector methodsFor:'initialization & release'!

destroy

    "destroy this view"

    destroyAction value.

    super destroy

    "Modified: / 9.11.1998 / 21:18:17 / cg"

!

initialize

    super initialize.

    scrollWhenUpdating := #endOfText.

    outstandingLines := nil.

    alwaysAppendAtEnd := true.

    collectSize := self class defaultCollectSize.

    flushPending := inFlush := false.

    collecting := true.

    timeDelay := self class defaultTimeDelay.

    access := RecursionLock new name:'TextCollector access lock'.

    lineLimit := self class defaultLineLimit.

    entryStream := ActorStream new.

    entryStream nextPutBlock:[:something | self nextPut:something].

    entryStream nextPutAllBlock:[:something | self nextPutAll:something]

    "Modified: / 14.12.1999 / 21:13:54 / cg"

!

mapped

    "view became visible - show collected lines (if any)"

    super mapped.

    self endEntry

!

reinitialize

    "reinit after a snapIn.

     recreate access-semaphore; image could have been save (theoretically)

     with the semaphore locked - in this case, we had a deadlock"

    flushPending := inFlush := false.

    access := RecursionLock new. "/ Semaphore forMutualExclusion.

    super reinitialize.

    "Modified: / 5.3.1998 / 10:09:14 / stefan"

!

release

    flushBlock notNil ifTrue:[

        Processor removeTimedBlock:flushBlock.

        flushBlock := nil.

    ].

    outstandingLines := nil.

    outstandingLine := ''.

    super release

    "Modified: / 9.11.1998 / 21:18:17 / cg"

! !

!TextCollector methodsFor:'menu'!

editMenu

    "return my popUpMenu; that's the superClasses menu,

     plus a 'Line Limit' item."

    <resource: #programMenu>

    |m sub sensor|

    m := super editMenu.

    self showLineLimitInMenu ifTrue:[

        ((sensor := self sensor) notNil and:[sensor ctrlDown and:[sensor shiftDown not]]) ifTrue:[

            sub := m.

        ] ifFalse:[

            sub := m subMenuAt:#others.

        ].