"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

Workspace subclass:#CodeView
	instanceVariableNames:'explainAction formatAction pointerOverWordAction'
	classVariableNames:''
	poolDictionaries:''
	category:'Interface-Workspace'
!

!CodeView class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1989 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    a view for text which is known to be smalltalk code. 
    It adds 'explain' to the menu, and defines another action: 
      explainAction to be performed for explain.

    This action is to be defined by the user of this view 
    (i.e. usually the owning browser)

    In addition, uncomment/comment are added to the controlMenu.
    These are smalltalk specific - if you plan to edit other language code,
    you need a different kind of CodeView for that.

    If used with a model, accept sends the changeMsg to it (as defined in EditTextView).
    (however, it is possible to define both changeMsg and acceptAction)

    See how doIt/printIt/inspectIt are handled in the superclass: Workspace.

    Caveat:
        in this version, CodeView does not yet support MVC setups for doIt
        and explain.
        If required, simulate this by setting the doItAction and
        explainAction, to notify the model manually about whats going on.

    [instance variables:]
        commentStrings          <Array>         an array with 2 entries;
                                                the first defining the EOL-comment string,
                                                the 2nd (another array) defining opening
                                                and closing comment strings.
                                                Default to ST/X comments,
                                                can be changed in an instance for other
                                                programming languages.

    [author:]
        Claus Gittinger

    [see also:]
        Workspace EditTextView TextView
"
! !

!CodeView methodsFor:'accessing'!

explainAction:aBlock
    "set the action to be performed on explain"

    explainAction := aBlock
!

formatAction:aBlock
    "set the action to be performed on format"

    formatAction := aBlock

    "Created: / 17.2.1998 / 17:05:13 / cg"
!

pointerOverWordAction:aBlock
    pointerOverWordAction := aBlock.
    pointerOverWordAction notNil ifTrue:[
        self enableMotionEvents.
    ] ifFalse:[
        self disableMotionEvents
    ]


! !

!CodeView methodsFor:'event handling'!

buttonMotion:state x:x y:y
    |col line word|

    pointerOverWordAction notNil ifTrue:[
        state == 0 ifTrue:[
            line := self visibleLineOfY:y.
            col := self colOfX:x inVisibleLine:line.
            line := self visibleLineToAbsoluteLine:line.

            self wordAtLine:line col:col do:[:selectLine :beginCol :endLine :endCol :flag |
                word := self listAt:selectLine from:beginCol to:endCol.
                word notNil ifTrue:[
                    pointerOverWordAction value:word value:line value:col
                ]
            ].
            ^ self
        ].
    ].
    super buttonMotion:state x:x y:y

!

keyPress:key x:x y:y
    "catch keyboard shortcuts"

    <resource: #keyboard (#Explain #Help 
			  #CommentSelection #UncommentSelection)>

    (key == #Format)  ifTrue:[^ self format].
    (key == #Explain) ifTrue:[^ self explain].
    (key == #Help)    ifTrue:[^ self explain].
    (key == #CommentSelection)    ifTrue:[^ self commentSelection].
    (key == #UncommentSelection)  ifTrue:[^ self uncommentSelection].

    super keyPress:key x:x y:y

    "Modified: / 17.2.1998 / 17:05:23 / cg"
! !

!CodeView methodsFor:'menu & menu actions'!

accept
    "redefined accept action;
     save cursor and selection to allow restore in case of an error
     (we are typically compiling here ... and the compiler may show
     errors by highlighting them)"

    acceptEnabled == false ifTrue:[
        device beep.
        ^ self
    ].

    codeStartPosition := 1.
    [
        AbortSignal handle:[:ex |
            self cursor:Cursor normal.
            "redraw selection in normal color"
            self selectFromLine:selectionStartLine col:selectionStartCol 
                         toLine:selectionEndLine col:selectionEndCol.
            ex return
        ] do:[
            super accept.
        ]
    ] valueNowOrOnUnwindDo:[
        self unselect.
    ]

    "Modified: 7.3.1997 / 11:06:13 / cg"
!

editMenu
    "return the popUpMenu;
     to make this independent from what is defined in superclasses,
     get the superclass menu and add my functions."

    <resource: #keyboard (#CommentSelection #UncommentSelection 
                          #Accept #Explain)>
    <resource: #programMenu>

    |m sub sensor|

    m := super editMenu.

    ((sensor := self sensor) notNil and:[sensor ctrlDown]) ifFalse:[
        "
         codeViews do support #accept
         ... add it after #inspectIt
        "
        m addLabels:(resources array:#('-' 'accept'))
          selectors:#(nil accept)
          accelerators:#(nil #Accept)
          after:#inspectIt.

        (acceptEnabled == false 
        or:[acceptAction isNil]) ifTrue:[
            m disable:#accept
        ].

        "
         and add #explain after $gotoLine in the extra menu
        "
        sub := m subMenuAt:#others.
        sub notNil ifTrue:[
            sub addLabels:(resources array:#('-' 'explain'))
                selectors:#(nil explain)
                accelerators:#(nil Explain)
                after:#gotoLine.

            (self hasSelection not
            or:[explainAction isNil]) ifTrue:[
                sub disable:#explain 
            ].
        ].
    ].
    ^ m.

    "Modified: / 29.7.1998 / 16:14:52 / cg"
!

explain
    "explain action;
     evaluate the explainBlock passing whole contents and 
     selection as arguments."

    |text|

    explainAction notNil ifTrue:[
	text := self selection.
	text notNil ifTrue:[
	    explainAction value:(self contents) value:(text asString)
	]
    ]
!

format
    "format action;
     evaluate the formatBlock passing whole contents as argument."

    |text|

    formatAction notNil ifTrue:[
	text := self contents.
	text notNil ifTrue:[
	    formatAction value:(text asString)
	]
    ]

    "Created: / 17.2.1998 / 17:06:18 / cg"
    "Modified: / 17.2.1998 / 18:25:33 / cg"
! !

!CodeView class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libwidg/CodeView.st,v 1.41 1999-02-19 18:11:03 cg Exp $'
! !