"
 COPYRIGHT (c) 1995 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"

SelectionInList subclass:#MultiSelectionInList
	instanceVariableNames:''
	classVariableNames:''
	poolDictionaries:''
	category:'Interface-Support-Models'
!

!MultiSelectionInList class methodsFor:'documentation'!

copyright
"
 COPYRIGHT (c) 1995 by Claus Gittinger
	      All Rights Reserved

 This software is furnished under a license and may be used
 only in accordance with the terms of that license and with the
 inclusion of the above copyright notice.   This software may not
 be provided or otherwise made available to, or used by, any
 other person.  No title to or ownership of the software is
 hereby transferred.
"
!

documentation
"
    Like a selectionInList, but allows for multiple selected items.
    For use as a model for SelectionInListViews, with multipleSelectOk set to true.

    [author:]
        Claus Gittinger
"
! !

!MultiSelectionInList methodsFor:'accessing-values'!

selection
    "return the selections value (i.e. the entry numbers in the list)"

    |l|

    l := self list.
    l isNil ifTrue:[^ self zeroIndex].    "/ mhmh - no list; what should we do here ?

    ^ selectionIndexHolder value 
        collect:[:index |
            l at:index
        ]

    "Created: 26.10.1995 / 16:52:27 / cg"
    "Modified: 20.4.1996 / 13:14:29 / cg"
!

selection:anObjectList 
    "set the selection to be anObjectList."

    |l indizes|

    "/
    "/ for your convenience: allow 0 and nil as empty
    "/ selections
    "/
    (anObjectList isNil or:[anObjectList == 0]) ifTrue:[
        ^ self selectionIndex:#()
    ].

    l := self list.
    l isNil ifTrue:[^ self].   "/ mhmh - no list; what should we do here ?

    indizes := OrderedCollection new.
    anObjectList do:[:o |
        |idx|

        idx := l indexOf:o ifAbsent:0.
        idx ~~ 0 ifTrue:[
            indizes add:idx
        ].
    ].
    ^ self selectionIndex:indizes

    "Created: 26.10.1995 / 16:40:24 / cg"
    "Modified: 25.4.1996 / 09:07:44 / cg"
! !

!MultiSelectionInList methodsFor:'queries'!

zeroIndex
    "return the selectionIndex returned when nothing is selected.
     Here, an empty collection is returned."

    ^ Array new

    "Modified: 20.4.1996 / 13:12:58 / cg"
! !

!MultiSelectionInList methodsFor:'selections'!

selections
    "obsolete - almost the same as selection"

    |selectionIndices|

    self obsoleteMethodWarning.

    selectionIndices := selectionIndexHolder value.
    (selectionIndices isNil
     or:[selectionIndices == 0     
     or:[selectionIndices isEmpty]]) ifFalse:[
        ^ selectionIndices collect:[:index | listHolder value at:index]
    ].
    ^ Array new

    "Modified: 25.4.1996 / 09:09:45 / cg"
! !

!MultiSelectionInList class methodsFor:'documentation'!

version
    ^ '$Header: /cvs/stx/stx/libwidg/MultiSelectionInList.st,v 1.12 1996-04-25 16:43:12 cg Exp $'
! !