"

 COPYRIGHT (c) 1997 by eXept Software AG / Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

"{ NameSpace: Smalltalk }"

SelectionInListView subclass:#SelectionInTreeView

	instanceVariableNames:'validateDoubleClickBlock selectionHolder rootHolder imageWidth

		showLines showLinesForRoot listOfNodes imageInset textInset

		labelOffsetY lineMask itemClass lineColor computeResources

		showRoot showDirectoryIndicator closeIndicator openIndicator

		showDirectoryIndicatorForRoot imageOpened imageClosed imageItem

		discardMotionEvents registeredImages supportsExpandAll

		buildInArray drawVLinesFromLevel highlightMode editorWidget

		editorIndex editValueFgColor validateExpandabilityBlock'

	classVariableNames:'DefaultHilightMode SelectionInset'

	poolDictionaries:''

	category:'Views-Trees'

!

!SelectionInTreeView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1997 by eXept Software AG / Claus Gittinger

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    somewhat like a SelectionInListView; but specialized for hierarchical (i.e. tree-like)

    lists and adds the functions to show/hide subtrees. 

    Requires SelectionInTree as model and TreeItem (or compatible) list entries.

    Notice: 

        This class obsoletes SelectionInHierarchyView, which is no longer

        maintained but kept for backward compatibility.

    Notice2: 

        Even for this class, an improved replacement now exists:

        HierarchicalListView.

        Please consider using that one.

        (however, this class is kept for backward compatibility).

    [see also:]

        SelectionInTree

        TreeItem

        SelectionInListView

        FileSelectionTree

    [author:]

        Claus Atzkern

"

!

examples

"

    shows the tree of smalltalk classes:

                                                                        [exBegin]

      |top sel|

      top := StandardSystemView new; extent:300@300.

      sel := SelectionInTreeView new.

      sel root:(TreeItem newAsTreeFromSmalltalkClass:Object).

      sel action:[:nr | Transcript show:'selected:'; showCR:nr].

      top add:(ScrollableView forView:sel) in:((0.0 @ 0.0 ) corner:( 1.0 @ 1.0)).

      top open.

                                                                        [exEnd]

    same, including nil-subclasses (i.e. really all classes):

                                                                        [exBegin]

      |top sel|

      top := StandardSystemView new; extent:300@300.

      sel := SelectionInTreeView new.

      sel root:(TreeItem newAsTreeFromSmalltalkClass:nil).

      sel action:[:nr | Transcript show:'selected:'; showCR:nr].

      sel lineColor:(Color red).

      top add:(ScrollableView forView:sel) in:((0.0 @ 0.0 ) corner:( 1.0 @ 1.0)).

      top open.

                                                                        [exEnd]

    shows the tree of smalltalk classes; show directory indication and no

    lines.

                                                                        [exBegin]

      |top sel|

      top := StandardSystemView new; extent:300@300.

      sel := SelectionInTreeView new.

      sel showLines:false.

      sel showDirectoryIndicator:true.

      sel root:(TreeItem newAsTreeFromSmalltalkClass:Object).

      sel action:[:nr | Transcript show:'selected:'; showCR:nr].

      top add:(ScrollableView forView:sel) in:((0.0 @ 0.0 ) corner:( 1.0 @ 1.0)).

      top open.

                                                                        [exEnd]

"

! !

!SelectionInTreeView class methodsFor:'constants'!

minImageInset

    "returns minimum inset from directory indication to image

    "

  ^ 6

! !

!SelectionInTreeView class methodsFor:'defaults'!

defaultModelClass

    "returns the default model

    "

    ^ SelectionInTree

!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style (#'selection.highlightMode')>

    SelectionInset     := 4.

    DefaultHilightMode := StyleSheet at:'selection.highlightMode' default:#line.

    "

     self updateStyleCache

    "

! !

!SelectionInTreeView class methodsFor:'resources'!

closeIndicator

    "returns a little [+] bitmap"

    ^ HierarchicalListView closeIndicator

!

imageClosed

    "returns a closed file-directory bitmap"

    ^ HierarchicalListView collapsedIcon

!

imageItem

    "returns a regular file bitmap"

    ^ HierarchicalListView emptyIcon

!

imageOpened

    "returns an opened file-directory bitmap"

    ^ HierarchicalListView expandedIcon

!

openIndicator

    "returns a little [-] bitmap"

    ^ HierarchicalListView openIndicator

! !

!SelectionInTreeView methodsFor:'accessing'!

highlightMode

    "get the mode how to draw a selected line:

        #line           draw whole line selected

        #label          draw label selected

    "

    ^ highlightMode

!

highlightMode:aMode

    "set the mode how to draw a selected line:

        #line           draw whole line selected

        #label          draw label selected

    "

    |mode|

    (mode := aMode) == #label ifFalse:[

        mode := #line

    ].

    mode ~~ highlightMode ifTrue:[

        highlightMode := mode.

        self invalidate

    ]

!

itemClass

    "returns current itemClass used

    "

    ^ itemClass

!

itemClass:anItemClass

    "set itemClass to be used

    "

    (anItemClass notNil and:[anItemClass ~~ itemClass]) ifTrue:[

        itemClass := anItemClass.

        computeResources := true.

        self refetchDeviceResources.

    ].

!

lineColor

    "returns user configured line color or nil

    "

    ^ lineColor

!

lineColor:aColor

    "returns user configured line color or nil

    "

    |col|

    col := aColor = fgColor ifTrue:[nil] ifFalse:[aColor].

    col = lineColor ifFalse:[

        lineColor := col.

        lineColor notNil ifTrue:[lineColor := lineColor onDevice:device].

        self invalidate

    ]

!

nodeAtIndex:anIndex

    "returns node at an index or nil

    "

    (anIndex notNil and:[anIndex between:1 and:listOfNodes size]) ifTrue:[

        ^ listOfNodes at:anIndex

    ].

  ^ nil

!

root

    "gets the root of the model; the first item into list.

    "

    ^ self nodeAtIndex:1

!

root:aRoot

    "sets the root of the model; the first item into list.

    "

    aRoot notNil ifTrue:[aRoot expand].

    model root:aRoot

!

textInset

    "get the left inset of the text label

    "

    ^ textInset

!

textInset:anInset

    "set the left inset of the text label

    "

    anInset ~~ textInset ifTrue:[

        anInset >= 0 ifTrue:[

            textInset := anInset.

            self invalidate

        ] ifFalse:[

            self error

        ]

    ].

! !

!SelectionInTreeView methodsFor:'accessing-behavior'!

drawVLinesFromLevel

    "returns the level vertical lines are drawn from;

     starting at 1 up to n

    "

    ^ drawVLinesFromLevel

!

drawVLinesFromLevel:aLevel

    "set the level vertical lines are drawn from;

     starting at 1 up to n

    "

    |lv|

    lv := (aLevel ? 1) max:1.

    lv ~~ drawVLinesFromLevel ifTrue:[

        drawVLinesFromLevel := lv.

        self invalidate

    ]

!

supportsExpandAll

    ^ supportsExpandAll

!

supportsExpandAll:aBool

    supportsExpandAll := aBool

!

validateDoubleClickBlock

    "return the conditionBlock; this block is evaluated before a doubleClick action

     on a node will be performed. In case of returning false, the doubleClick will

     not be handled.

   "

   ^ validateDoubleClickBlock

!

validateDoubleClickBlock:aOneArgBlock

    "set the conditionBlock; this block is evaluated before a doubleClick action

     on a node will be performed. In case of returning false, the doubleClick will

     not be handled.

   "

   validateDoubleClickBlock := aOneArgBlock

!

validateExpandabilityBlock

    "return the expand conditionBlock; this block is evaluated before an expand due to

     a doubleClick on a node will be performed. In case of returning false, 

     the node will not be expanded.

   "

   ^ validateExpandabilityBlock

!

validateExpandabilityBlock:aOneArgBlock

    "set the expand conditionBlock; this block is evaluated before an expand due to

     a doubleClick on a node will be performed. In case of returning false, 

     the node will not be expanded.

   "

   validateExpandabilityBlock := aOneArgBlock

! !

!SelectionInTreeView methodsFor:'accessing-channels'!

rootHolder

    "get the holder which keeps the hierarchical list entry or nil

    "

    ^ rootHolder

!

rootHolder:aValueHolder

    "set the holder which keeps the hierarchical list entry or nil

    "

    rootHolder notNil ifTrue:[

        rootHolder removeDependent:self

    ].

    (rootHolder := aValueHolder) notNil ifTrue:[

        rootHolder addDependent:self.

        self rootFromModel.

    ].

!

selectionHolder

    "get the holder which keeps a list of selected items or nil

    "

    ^ selectionHolder

!

selectionHolder:aHolder

    "set the holder which keeps a list of selected items or nil

    "

    selectionHolder notNil ifTrue:[

        selectionHolder removeDependent:self

    ].

    (selectionHolder := aHolder) notNil ifTrue:[

        selectionHolder addDependent:self.

        self selectionFromModel

    ].

! !

!SelectionInTreeView methodsFor:'accessing-images'!

imageClosed

    "return the value of the instance variable 'imageClosed'.

     That's the (default) bitmap image shown for closed folders

     (initialized to a file-directory bitmap)"

    ^ imageClosed

    "Created: 3.7.1997 / 12:34:31 / cg"

!

imageItem

    "return the value of the instance variable 'imageItem'.

     That's the (default) bitmap image shown for regular items

     (initialized to a plain-file bitmap)"

    ^ imageItem

    "Created: 3.7.1997 / 12:34:34 / cg"

!

imageOnMyDevice:anImage

    "associate image to device and returns the new image."

    anImage isNil ifTrue:[^ nil].

    ^ anImage onDevice:device.

    "Modified: / 12.8.1998 / 12:46:38 / cg"

!

imageOpened

    "return the value of the instance variable 'imageOpened'.

     That's the (default) bitmap image shown for opened folders

     (initialized to an open file-directory bitmap)"

    ^ imageOpened

    "Created: 3.7.1997 / 12:34:28 / cg"

! !

!SelectionInTreeView methodsFor:'accessing-look'!

showDirectoryIndicator

    "returns true if directories has an open/closed indicator

    "

  ^ showDirectoryIndicator

!

showDirectoryIndicator:aState

    "set or clear open/closed indicator for directories

    "

    "show or hide lines

    "

    aState ~~ showDirectoryIndicator ifTrue:[

        showDirectoryIndicator := aState.

        self recomputeDirectoryIndicator.

        self invalidate

    ].

!

showDirectoryIndicatorForRoot

    "returns true if root directory has an open/closed indicator if

     the common showDirectoryIndicator is enabled

    "

    ^ showDirectoryIndicatorForRoot