"

 COPYRIGHT (c) 1998 by eXept Software AG

 COPYRIGHT (c) 2017 Jan Vrany

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

"{ NameSpace: Smalltalk }"

TerminalView subclass:#VT100TerminalView

	instanceVariableNames:'currentParam parameters lastCursorLine'

	classVariableNames:'TraceCSI'

	poolDictionaries:''

	category:'Views-TerminalViews'

!

!VT100TerminalView class methodsFor:'documentation'!

ansiEscapes

"

   see also: http://www.vt100.net/docs/vt100-ug/chapter3.html

                              ANSI ESCAPE SEQUENCES

===============================================================================

Wherever you see '#', that should be replaced by the appropriate number.

        ESC code sequence                       Function

       -------------------              ---------------------------

Cursor Controls:

         ESC[#;#H or ESC[#;#f           Moves cusor to line #, column #

         ESC[#A                         Moves cursor up # lines

         ESC[#B                         Moves cursor down # lines

         ESC[#C                         Moves cursor forward # spaces

         ESC[#D                         Moves cursor back # spaces

         ESC[#;#R                       Reports current cursor line & column

         ESC[s                          Saves cursor position for recall later

         ESC[u                          Return to saved cursor position

Erase Functions:

         ESC[2J                         Clear screen and home cursor

         ESC[K                          Clear to end of line

Set Graphics Rendition:

         ESC[#;#;....;#m                Set display attributes where # is

                                            0 for normal display

                                            1 for bold on

                                            4 underline (mono only)

                                            5 blink on

                                            7 reverse video on

                                            8 nondisplayed (invisible)

                                            30 black foreground 

                                            31 faint red foreground 

                                            32 faint green foreground 

                                            33 faint yellow foreground 

                                            34 faint blue foreground 

                                            35 faint magenta foreground 

                                            36 faint cyan foreground 

                                            37 faint white (grey) foreground

                                            39 reset to default foreground

                                            40 black background

                                            41 red background

                                            42 green background

                                            43 yellow background

                                            44 blue background

                                            45 magenta background

                                            46 cyan background

                                            47 white background

                                            49 reset to default background

                                            90 grey foreground 

                                            91 bright red foreground 

                                            92 bright green foreground 

                                            99 bright yellow foreground 

                                            94 bright blue foreground 

                                            95 bright magenta foreground 

                                            96 bright cyan foreground 

                                            97 bright white foreground

                                           100 grey background 

                                           101 bright red background 

                                           102 bright green background 

                                           109 bright yellow background 

                                           104 bright blue background 

                                           105 bright magenta background 

                                           106 bright cyan background 

                                           107 bright white background

         ESC[=#;7h or                   Put screen in indicated mode where # is

         ESC[=h or                          0 for 40 x 25 black & white

         ESC[=0h or                         1 for 40 x 25 color

         ESC[?7h                            2 for 80 x 25 b&w

                                            3 for 80 x 25 color

                                            4 for 320 x 200 color graphics

                                            5 for 320 x 200 b & w graphics

                                            6 for 640 x 200 b & w graphics

                                            7 to wrap at end of line 

         ESC[=#;7l or ESC[=l or         Resets mode # set with above command

         ESC[=0l or ESC[?7l

Keyboard Reassignments:

         ESC[#;#;...p                   Keyboard reassignment. The first ASCII

         or ESC[""string""p               code defines which code is to be 

         or ESC[#;""string"";#;           changed. The remaining codes define

            #;""string"";#p               what it is to be changed to.

         E.g. Reassign the Q and q keys to the A and a keys (and vice versa).

         ESC [65;81p                    A becomes Q

         ESC [97;113p                   a becomes q

         ESC [81;65p                    Q becomes A

         ESC [113;97p                   q becomes a

         E.g. Reassign the F10 key to a DIR command.

         ESC [0;68;""dir"";13p            The 0;68 is the extended ASCII code 

                                        for the F10 key and 13 is the ASCII

                                        code for a carriage return.

         Other function key codes       F1=59,F2=60,F3=61,F4=62,F5=63

                                        F6=64,F7=65,F8=66,F9=67,F10=68

"

!

copyright

"

 COPYRIGHT (c) 1998 by eXept Software AG

 COPYRIGHT (c) 2017 Jan Vrany

              All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    A VT100 / XTerm terminal emulator.

    Most of the functionality is inherited from my superclass,

    I redefine/specialize certain methods for VT100 / XTerm escape sequences

    and VT100 / XTerm keyboard codes

    == Keyboard Debugging ==

    In case some keys does not work as expected, do the folowing:

        1. Turn on keyboard debugging by evaluating:

              DebugKeyboard := false

        2. Check what it actually sends to the program.

        3. Open proper XTerm and run:

              export TERM=xterm

              tput smkx; cat

           Then press desired key and see what is its keycode. 

        4. Update #vt100KeyCodes / #xtermKeyCodes accordingly

    BUGS:

        VT100 wrapMode (at right margin) is not supported

        this may lead to wrong display when a vi is started in a small window.

    [start with:]

        VT100TerminalView openShell

    [see also:]

        VT52TerminalView

        TelnetTool

        http://vt100.net/docs/vt220-rm/chapter4.html

"

! !

!VT100TerminalView methodsFor:'defaults'!

colorAtIndex:idx bright:bright

    |rgb|

    rgb := #(

                #( 0 0 0 )      "/ black                        fg: ESC[30m / bg: ESC[40m

                #(170 0 0)      "/ dark red                         ESC[31m / bg: ESC[41m

                #(0 170 0)      "/ dark green

                #(170 85 0)     "/ dark yellow

                #(0 0 170)      "/ dark blue

                #(170 0 170)    "/ dark magenta

                #(0 170 170 )   "/ dark cyan

                #(170 170 170)  "/ dark white eg. light grey).      ESC[37m / bg: ESC[47m

                #( 85 85 85 )   "/ bright black eg. darkGray    fg: ESC[90m / bg: ESC[100m  

                #(255 85 85)    "/ bright red

                #(85 255 85)    "/ bright green

                #(255 255 85)   "/ bright yellow

                #(85 85 255)    "/ bright blue

                #(255 85 255)   "/ bright magenta

                #(85 255 255 )  "/ bright cyan

                #(255 255 255)  "/ white                            ESC[97m / bg: ESC[107m

    ).

    ^ Color 

        perform: #'redByte:greenByte:blueByte:' 

        withArguments:(rgb at:(idx + (bright ifTrue:[8] ifFalse:[0]))).

    "Modified (comment): / 30-05-2017 / 08:48:49 / cg"

!

vt100AlternativeKeyCodes

    "return the alternative vt100 keyCode table"

    ^ IdentityDictionary withKeysAndValues:

        #(

             #CursorUp    '\eOA'

             #CursorDown  '\eOB'

             #CursorRight '\eOC'

             #CursorLeft  '\eOD'

             #Home        '\eOH'

             #Escape      '\e'

             #BackSpace   '\b'

             #Return      '\r'

             #Delete      '\0177'

             #Tab         '\t'

             #F1          '\eOP'

             #F2          '\eOQ'

             #F3          '\eOR'

             #F4          '\eOS'

             #F5          '\eOt'

             #F6          '\eOu'

             #F7          '\eOv'

             #F8          '\eOl'

             #F9          '\eOw'

         )

!

vt100KeyCodes

    "return a vt100 keyCode table"

    ^ IdentityDictionary withKeysAndValues:

        #(

             #CursorUp    '\e[A'

             #CursorDown  '\e[B'

             #CursorRight '\e[C'

             #CursorLeft  '\e[D'

             #Home        '\e[H'

             #End         '\e[F'

             #Escape      '\e'

             #BackSpace   '\b'

             #Return      '\r'

             #Delete      '\e[3~'

             #Tab         '\t'

             #F1          '\eOP'

             #F2          '\eOQ'

             #F3          '\eOR'

             #F4          '\eOS'

             #F5          '\eOt'

             #F6          '\eOu'

             #F7          '\eOv'

             #F8          '\eOl'

             #F9          '\eOw'

         )

    "Created: / 10-06-1998 / 15:13:01 / cg"

    "Modified: / 05-05-1999 / 15:01:32 / cg"

    "Modified (comment): / 20-06-2017 / 21:25:51 / Jan Vrany <jan.vrany@fit.cvut.cz>"

! !

!VT100TerminalView methodsFor:'functions'!

addLines

    "Add the appropriate number of blank lines (param 1) 

     at the cursor position."

    self addLines:((parameters at:1) max:1).

    self endOfSequence

    "Created: / 10.6.1998 / 14:48:03 / cg"

!

addLines:aNumber

    "Add aNumber blank lines at the position indicated by the cursor."

    aNumber timesRepeat:[

        self insertLine:'' before:cursorLine

    ]

    "Created: / 10.6.1998 / 14:49:30 / cg"

!

clearLines:arg

    "Clear some part of the current line, as indicated by the first parameter:

     0 - clear to EOL

     1 - clear from beginning to cursorCol

     2 - clear entire line

    "

    arg = 0 ifTrue: [^self doClearToEndOfLine].

    arg = 1 ifTrue: [^self doClearFromBeginningOfLine].

    arg = 2 ifTrue: [^self doClearEntireLine]

    "Created: / 10.6.1998 / 14:44:22 / cg"

    "Modified: / 21.7.1998 / 20:07:42 / cg"

!

deleteCharacters

    "Delete the appropriate number of characters (param 1)

     at the cursor position."

    |n|

    n := parameters at: 1.

    n isNil ifTrue:[^ self].

    n := n max: 1.

    self deleteFromLine:cursorLine col:cursorCol toLine:cursorLine col:cursorCol+n-1.

    "Created: / 12.6.1998 / 21:19:02 / cg"

    "Modified: / 12.6.1998 / 21:19:15 / cg"

!

deleteLines

    "Delete the appropriate number of lines (param 1)

     at the cursor position."

    |n|

    n := ((parameters at: 1) max: 1).

self halt:'untested code'.

    self deleteFromLine:cursorLine toLine:cursorLine+n-1.

!

displayMode:p1

    "ESC-[-<param1>-m 

     Set the current display mode (emphasis) as specified by param 1."

"/    self endEntry.    -- not needed (does not affect characters on screen or buffered or cursor position

    p1 == 0 ifTrue:[

        self normal.

        ^ self.

    ].

    p1 == 1 ifTrue:[

        "/ ESC-[-1-m  -> bold

        "/ workaround: windows bold fonts are

        "/ wider, leading to ugly looking output

        "/ Therefore, use red color instead of bold

        device isWindowsPlatform ifTrue:[

            self color:(Color red:80).

        ] ifFalse:[

            self bold.

        ].

        ^ self.

    ].

    p1 == 2 ifTrue:[

        "/ faint - unsupported

        ^ self.

    ].

    p1 == 3 ifTrue:[

        "/ ESC-[-3-m  -> italic

        self italic.

        ^ self.

    ].

    p1 == 4 ifTrue:[

        "/ ESC-[-4-m  -> underline

        self underline.

        ^ self.

    ].

    p1 == 5 ifTrue:[

        "/ ESC-[-5-m  -> blink

        self color:Color blue.

        ^ self.

    ].

    p1 == 6 ifTrue:[

        "/ ESC-[-5-m  -> blink rapid - unsupported

        ^ self.

    ].

    p1 == 7 ifTrue:[

        "/ ESC-[-7-m  -> reverse

        self reverse.

        ^ self.

    ].

    p1 == 8 ifTrue:[

        "/ ESC-[-8-m  -> invisible

        ^ self.

    ].

    p1 == 9 ifTrue:[

        "/ ESC-[-9-m  -> crossed out - unsupported

        ^ self.

    ].

    p1 == 10 ifTrue:[

        "/ ESC-[-10-m  -> primary font - unsupported

        ^ self.

    ].

    (p1 between:11 and:19) ifTrue:[

        "/ alternate fonts - unsupported

        ^ self.

    ].

    p1 == 20 ifTrue:[

        "/ fraktur - unsupported

        ^ self.

    ].

    p1 == 21 ifTrue:[

        "/ ESC-[-21-m  -> not bold

        self notBold.

        ^ self.

    ].

    p1 == 23 ifTrue:[

        "/ ESC-[-23-m  -> not italic

        self notItalic.

        ^ self.

    ].

    p1 == 24 ifTrue:[

        "/ ESC-[-24-m  -> not underline

        self notUnderline.

        ^ self.

    ].

    p1 == 25 ifTrue:[

        "/ ESC-[-25-m  -> not blinking - unsupported

        ^ self.

    ].

    p1 == 28 ifTrue:[

        "/ ESC-[-28-m  -> not invisible/reveal - unsupported

        ^ self.

    ].

    p1 == 29 ifTrue:[

        "/ ESC-[-29-m  -> not crossed out - unsupported

        ^ self.

    ].

    (p1 between:30 and:37) ifTrue:[

        "/ ESC-[-30-m  -> black fg color

        "/ ESC-[-31-m  -> red   fg color

        "/ ...

        "/ ESC-[-37-m  -> white fg color

        noColors ifFalse:[

            self color:(self colorAtIndex:(p1-30+1) bright:false).

        ].

        ^ self.

    ].

    p1 == 38 ifTrue:[

        "/ xterm 256 color - unsupported

        ^ self

    ].

    p1 == 39 ifTrue:[

        "/ normal fg color

        self color:nil.

        ^ self

    ].

    (p1 between:40 and:47) ifTrue:[

        "/ ESC-[-40-m  -> black bg color

        "/ ...

        "/ ESC-[-47-m  -> white bg color

        noColors ifFalse:[

            self bgColor:(self colorAtIndex:(p1-40+1) bright:false).

        ].

        ^ self.

    ].

    p1 == 48 ifTrue:[

        "/ xterm 256 bg color - unsupported

        ^ self

    ].

    p1 == 49 ifTrue:[

        "/ normal bg color

        self bgColor:nil.

        ^ self

    ].

    (p1 between:90 and:97) ifTrue:[

        "/ fg color high intensity