"

 COPYRIGHT (c) 1999 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

"{ Package: 'stx:libwidg2' }"

"{ NameSpace: Smalltalk }"

ListModelView subclass:#SelectionInListModelView

	instanceVariableNames:'selection multipleSelectOk actionBlock doubleClickActionBlock

		selectConditionBlock buttonMotionAction buttonReleaseAction

		highlightMode useIndex ignoreReselect toggleSelect hilightFgColor

		hilightBgColor hilightFgColorNoFocus hilightBgColorNoFocus

		hilightLevel hilightFrameColor hilightStyle dropSource editorView

		openEditorAction closeEditorAction highlightEnterItem enterItem

		cursorItem lineMask keyActionStyle returnKeyActionStyle strikeOut

		modelChangedDuringButtonPress selectOnButtonPress

		selectOnMenuButton minimumEditorHeight extraSpaceAtBottomForDrop'

	classVariableNames:'DefaultHilightStyle DefaultHilightBackgroundColor

		DefaultHilightForegroundColor DefaultHilightLevel

		DefaultHilightFrameColor DefaultHilightBackgroundColorNoFocus

		DefaultHilightForegroundColorNoFocus DefaultHilightMode'

	poolDictionaries:''

	category:'Views-Lists'

!

!SelectionInListModelView class methodsFor:'documentation'!

copyright

"

 COPYRIGHT (c) 1999 by eXept Software AG

	      All Rights Reserved

 This software is furnished under a license and may be used

 only in accordance with the terms of that license and with the

 inclusion of the above copyright notice.   This software may not

 be provided or otherwise made available to, or used by, any

 other person.  No title to or ownership of the software is

 hereby transferred.

"

!

documentation

"

    SelectionInListModelView is mostly like SelectionInListView,

    but derives from the ListModelView and thus the list is kept

    in the list.

    ATTENTION (warning by cg):

        in contrast to its inappropriate name, this class COMPLETELY ignores the model

        instance variable - all is through the list/listHolder.

    [Instance variables:]

        selection               <misc>       the current selection. nil, a number or collection of numbers

        multipleSelectOk        <Boolean>    allow/disallow multiple selections( default:false )

        selectMenuButton        <Boolean>    enable/disable selection will change on menu pressed

        buttonReleaseAction     <Action>     called if the mouse button is released

        buttonMotionAction      <Action>     called during mouse motion with one argument the point

                                             under the mouse.

        actionBlock             <Block>      action evaluated on single click (0/1/2 arguments)

        doubleClickActionBlock  <Block>      action evaluated on double click (0/1/2 arguments)

        selectConditionBlock    <Block>      action evaluated before selection changed (0/1/2 arguments)

        keyActionStyle          <Symbol>     controls how to respond to keyboard selects

        returnKeyActionStyle    <Symbol>     controls how to respond to return key

        useIndex                <Boolean>    representation of the model selection

        ignoreReselect          <Boolean>    if set, a click on an already selected entry is ignored

        toggleSelect            <Boolean>    a click on an entry unselects it and vice versa

        highlightMode           <Symbol>     how to draw the selection

        hilightFgColor          <Color>      foregroundColor of highlighted items

        hilightBgColor          <Color>      backgroundColor of highlighted items

        hilightLevel            <Integer>    level to draw selections (i.e. for 3D effect)

        hilightFrameColor       <Color>      rectangle around highlighted items

        hilightStyle            <Boolean>    actions on widget are enabled/disabled

        strikeOut               <Boolean>    turn on/off strikeOut mode

        dropTarget              <DropTarget> keeps information about the drop operation

        dropSource              <DropSource> keeps information about the drag operation

        editorView              <View>       editor on current selected item

        openEditorAction        <Action>     action to get an editor on the current selection from user

        closeEditorAction       <Action>     action invoked before the editor is closed.

        enterItem               <Item/nil>   item over which the mouse pointer is located

                                             or nil

        highlightEnterItem      <Boolean>    enable or disable highlight of enterItem

    [author:]

        Claus Atzkern

    [see also:]

        ListModelView

        HierarchicalListView

"

!

examples

"

                                                                        [exBegin]

    |top list view|

    list := List new.

    1 to:100 do:[:i| list add:('element: ', i printString) ].

    top  := StandardSystemView new; extent:300@300.

    view := ScrollableView for:SelectionInListModelView miniScroller:true

                        origin:0.0@0.0 corner:1.0@1.0 in:top.

    view list:list.

    top  open.

                                                                        [exEnd]

                                                                        [exBegin]

    |top list view|

    list := List new.

    1 to:100 do:[:i| list add:('element: ', i printString) ].

    top  := StandardSystemView new; extent:300@300.

    view := ScrollableView for:SelectionInListModelView miniScroller:true

                        origin:0.0@0.0 corner:1.0@1.0 in:top.

    view list:list.

    view openEditorAction:[:ln :aGC| |field|

        field := EditField new.

        field level:0.

        field acceptOnLostFocus:true.

        field acceptAction:[:x| list at:ln put:(field contents) ].

        field font:(aGC font).

        field contents:(list at:ln).

        field

    ].

    top open.

                                                                        [exEnd]

                                                                        [exBegin]

    |top list view item|

    list := HierarchicalList new.

    item := HierarchicalItem::Example labeled:'Test'.

    item expand.

    list showRoot:false.

    list root:item.

    top  := StandardSystemView new; extent:300@300.

    view := ScrollableView for:SelectionInListModelView miniScroller:true

                        origin:0.0@0.0 corner:1.0@1.0 in:top.

    view list:list.

    view doubleClickAction:[:i| (list at:i) toggleExpand ].

    top  open.

                                                                        [exEnd]

  ca

    |top list view|

    list := List new.

    1 to:100 do:[:i| list add:('element: ', i printString) ].

    top  := StandardSystemView extent:300@300.

    view := ScrollableView for:SelectionInListModelView miniScroller:true

                        origin:0.0@0.0 corner:1.0@1.0 in:top.

    view minimumEditorHeight:100.

    view openEditorAction:[:ln :aGC| |f|

        f := SimpleView in:aGC.

        f viewBackground:(Color red).

        f

    ].

    view list:list.

    top  open.

"

! !

!SelectionInListModelView class methodsFor:'defaults'!

updateStyleCache

    "extract values from the styleSheet and cache them in class variables"

    <resource: #style   (

                        #'selection.hilightForegroundColor' #'selection.hilightBackgroundColor'

                        #'selection.hilightForegroundColorNoFocus' #'selection.hilightBackgroundColorNoFocus'

                        #'selection.hilightFrameColor'      #'selection.hilightLevel'

                        #'selection.foregroundColor'        #'selection.backgroundColor'

                        #'selection.shadowColor'            #'selection.lightColor'

                        #'selection.font'                   

                        #'selection.hilightStyle'

                        #'selection.highlightMode'

                        #'text.foregroundColor'

                        )>

    DefaultHilightForegroundColor  := StyleSheet colorAt:'selection.hilightForegroundColor'.

    DefaultHilightBackgroundColor  := StyleSheet colorAt:'selection.hilightBackgroundColor'.

    DefaultHilightForegroundColorNoFocus  := StyleSheet colorAt:'selection.hilightForegroundColorNoFocus'.

    DefaultHilightBackgroundColorNoFocus  := StyleSheet colorAt:'selection.hilightBackgroundColorNoFocus'.

    DefaultHilightFrameColor       := StyleSheet colorAt:'selection.hilightFrameColor'.

    DefaultHilightLevel            := StyleSheet at:'selection.hilightLevel' default:0.

    DefaultHilightStyle            := StyleSheet at:'selection.hilightStyle' default:(StyleSheet name).

    DefaultHilightMode             := StyleSheet at:'selection.hilightMode' default:#label. "/ or #line

    DefaultForegroundColor         := StyleSheet colorAt:'selection.foregroundColor'.

    DefaultBackgroundColor         := StyleSheet colorAt:'selection.backgroundColor'.

    DefaultShadowColor             := StyleSheet colorAt:'selection.shadowColor'.

    DefaultLightColor              := StyleSheet colorAt:'selection.lightColor'.

    DefaultForegroundColor isNil ifTrue:[

        DefaultForegroundColor := StyleSheet colorAt:'text.foregroundColor' default:Color black

    ].

    DefaultFont := SelectionInListView defaultFont. 

    "

     self updateStyleCache

    "

    "Modified: / 14-08-2010 / 11:55:20 / cg"

! !

!SelectionInListModelView methodsFor:'accessing'!

cursorLine

    "returns the index of the cursor line or 0

    "

    |index|

    cursorItem isNil ifTrue:[^ 0 ].

    index := self identityIndexOf:cursorItem.

    index == 0 ifTrue:[ cursorItem := nil ].

    ^ index

!

list:aList

    self deselectWithoutRedraw.

    ^ super list:aList

! !

!SelectionInListModelView methodsFor:'accessing-actions'!

action

    "get the action block to be performed on select

     The arguments to the block are:

	- no argument

	-  1 argument     index or item

	-  2 argument     index or item, self

    "

    ^ actionBlock

!

action:anUpToTwoArgBlock

    "set the action block to be performed on select

     The arguments to the block are:

        - no argument

        -  1 argument     index or item

        -  2 argument     index or item, self

    "

    actionBlock := anUpToTwoArgBlock

!

doubleClickAction

    "get the action block to be performed on doubleclick.

     The arguments to the block are:

	- no argument

	-  1 argument     selectedIndex

	-  2 argument     selectedIndex, self

    "

    ^ doubleClickActionBlock

!

doubleClickAction:anUpToTwoArgBlock

    "set the action block to be performed on doubleclick.

     The arguments to the block are:

        - no argument

        -  1 argument     selectedIndex

        -  2 argument     selectedIndex, self

    "

    doubleClickActionBlock := anUpToTwoArgBlock

!

keyActionStyle

    "defines how the view should respond to alpha-keys pressed.

     Possible values are:

	#select               -> will select next entry starting with that

				 character and perform the click-action

	#selectAndDoubleclick -> will select next & perform double-click action

	#pass                 -> will pass key to superclass (i.e. no special treatment)

	nil                   -> will ignore key

     the default (set in #initialize) is #select

    "

    ^ keyActionStyle

!

keyActionStyle:aSymbol

    "defines how the view should respond to alpha-keys pressed.

     Possible values are:

	#select               -> will select next entry starting with that

				 character and perform the click-action

	#selectAndDoubleclick -> will select next & perform double-click action

	#pass                 -> will pass key to superclass (i.e. no special treatment)

	nil                   -> will ignore key

     the default (set in #initialize) is #select

    "

    keyActionStyle := aSymbol

!

returnKeyActionStyle

    "defines how the view should respond to a return key pressed.

     Possible values are:

	#doubleClick          -> perform double-click action

	#pass                 -> will pass key to superclass (i.e. no special treatment)

	nil                   -> will ignore key

     the default (set in #initialize) is #doubleClick

    "

    ^ returnKeyActionStyle

!

returnKeyActionStyle:aSymbol

    "defines how the view should respond to a return key pressed.

     Possible values are:

	#doubleClick          -> perform double-click action

	#pass                 -> will pass key to superclass (i.e. no special treatment)

	nil                   -> will ignore key

     the default (set in #initialize) is #doubleClick

    "

    returnKeyActionStyle := aSymbol

!

selectConditionBlock

    "set the conditionBlock; this block is evaluated before a selection

     change is performed; the change will not be done, if the evaluation

     returns false

     The arguments to the block are:

	- no argument

	-  1 argument     index

	-  2 argument     index, isForAdd

    "

    ^ selectConditionBlock

!

selectConditionBlock:anUpToTwoArgBlock

    "set the conditionBlock; this block is evaluated before a selection

     change is performed; the change will not be done, if the evaluation

     returns false.

     The arguments to the block are:

        - no argument

        -  1 argument     index

        -  2 argument     index, isForAdd

    "

    selectConditionBlock := anUpToTwoArgBlock.

! !

!SelectionInListModelView methodsFor:'accessing-attributes'!

highlightEnterItem

    "enable or disable to highlight the item over which the mouse pointer is located

    "

    ^ highlightEnterItem

!

highlightEnterItem:aBool

    "enable or disable to highlight the item over which the mouse pointer is located

    "

    highlightEnterItem ~~ aBool ifTrue:[

	highlightEnterItem := aBool.

	self pointerEntersItem:nil.

	highlightEnterItem ifTrue:[

	    self enableMotionEvents

	].

    ].

!

highlightMode

    "get the mode how to draw a selected line:

	#line           draw whole line selected

	#label          draw label selected

	#dropMode       set during drop

    "

    ^ highlightMode

!

highlightMode:aMode

    "set the mode how to draw a selected line:

	#line           draw whole line selected

	#label          draw label selected

	#dropMode       set during drop

    "

    highlightMode ~~ aMode ifTrue:[

	highlightMode := aMode.

	self invalidateSelection.

    ].

!

highlightWithUnderline

    ^ false

!

hilightBackgroundColor

    "returns the color used for the hilighted background

    "

    ^ hilightBgColor

!

hilightForegroundColor

    "returns the color used for the hilighted foreground

    "

    ^ hilightFgColor

!

strikeout

    "turn on/off strikeOut mode

    "

    ^ strikeOut

!

strikeout:aBoolean

    "turn on/off strikeOut mode

    "

    strikeOut ~~ aBoolean ifTrue:[

	strikeOut := aBoolean.

	self invalidateSelection.

    ].

! !

!SelectionInListModelView methodsFor:'accessing-behavior'!

ignoreReselect

    "controls if clicking on an already selected item should

     be ignored or should perform the select action again.

     By default, these are ignored"

    ^ ignoreReselect

!

ignoreReselect:aBoolean

    "set/clear the ignoreReselect flag -

     if set, a click on an already selected entry is ignored.

     Otherwise the notification is done, even if no

     change in the selection occurs.

     (for example, in browser to update a method).

     Setting ignoreReselect to false makes sense if data is shown

     which may change by itself (i.e. without the user doing anything)

     For example, the inspector uses this, and redisplays the value,

     if the selection is the same.

     The default is true, meaning that a click on an already selected

     does not lead to a notification via the actionBlock/change mechanism.

    "

    ignoreReselect := aBoolean

!

multipleSelectOk

    "return true if multiple selections are allowed; the default is false"

    ^ multipleSelectOk

!

multipleSelectOk:aBoolean