@ECHO OFF

::  _____                 _ _ _        _ _         ____   __               

:: /  ___|               | | | |      | | |       / /\ \ / /               

:: \ `--. _ __ ___   __ _| | | |_ __ _| | | __   / /  \ V /                

::  `--. \ '_ ` _ \ / _` | | | __/ _` | | |/ /  / /   /   \                

:: /\__/ / | | | | | (_| | | | || (_| | |   <  / /   / /^\ \               

:: \____/|_| |_| |_|\__,_|_|_|\__\__,_|_|_|\_\/_/    \/   \/               

::                                                                         

::  _    _ _                  _                            _               

:: | |  | (_)                | |                          | |              

:: | |  | |_ _ __    ______  | |     __ _ _   _ _ __   ___| |__   ___ _ __ 

:: | |/\| | | '_ \  |______| | |    / _` | | | | '_ \ / __| '_ \ / _ \ '__|

:: \  /\  / | | | |          | |___| (_| | |_| | | | | (__| | | |  __/ |   

::  \/  \/|_|_| |_|          \_____/\__,_|\__,_|_| |_|\___|_| |_|\___|_|

:: ==================================

:: The startup script for smalltalk =

:: ==================================

:: This script is vastly improved previous smalltalk.bat.

:: In previous versions, smalltalk used to be the executable itself.

:: This lead to problems on systems, where things like the PATH or STX_LIBDIR should be set in advance.

:: Now, here is a place to do such things ...

:: ==========

:: Contents =

:: ==========

:: Every section is separated by these words: Next section follows =

:: 1 - Versions; batch files switches; setting on ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

:: 2 - Configuration

:: 3 - PowerShell detection

:: 4 - Timer section

:: 5 - Adjusting according to the configuration

:: 6 - Checking variable and logic consistency

:: 7 - Verify existence of paths and files from configuration

:: 8 - A work-flow based on the configuration

:: 9 - Running the command

:: 10 - User defined functions

:: 11 - Support information (like help, about, version)

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *******************************************************************************************

:: Beginning                                                                                 *

:: *******************************************************************************************

:: ==========

:: Versions =

:: ==========

:: This script

SET "batch_script_version=1.6.8"

:: Smalltalk/X

SET "stx_version_default=6.2.6"

:: Do not change following line, $STX_VERSION_DEFAULT serves

:: as placeholder and it's being replaced during installation

:: process (`rake install`)

SET "stx_version=%stx_version_default%"

:: ====================

:: Comments and style =

:: ====================

:: USING :: instead of REM is a hack for now supported and it makes the bat execution much faster

:: The reason is: REM is a command that has to be processed by cmd.exe, but the :: is a sign followed

:: by :.  The first : makes the interpreter ignore the line altogether.

:: If Microsoft should drop support of :: hack. Change you have to change all :: back to REM

:: =========================================

:: Batch file accepts following parameters =

:: =========================================

:: Enclosing the input parameter with double quotes is a correct way how to do it

IF "%~1"=="--help" ECHO: & ECHO "stx.com help, for the laucher use --help-launcher." & ECHO: & GOTO stx_help

IF "%~1"=="-h" ECHO: & ECHO "stx.com help, for the laucher use --help-launcher." & ECHO: & GOTO stx_help

IF "%~1"=="/h" ECHO: & ECHO "stx.com help, for the laucher use --help-launcher." & GOTO stx_help

IF "%~1"=="/?" ECHO: & ECHO "stx.com help, for the laucher use --help-launcher." & GOTO stx_help

IF "%~1"=="--help-launcher" ECHO: & GOTO stx_help_launcher

IF "%~1"=="-h-l" ECHO: & GOTO stx_help_launcher

IF "%~1"=="/h-l" ECHO: & GOTO stx_help_launcher

IF "%~1"=="--about" (

    ECHO: & CALL :stx_about %batch_script_version% %stx_version%

    GOTO :EOF

)

IF "%~1"=="-a" (

    ECHO: & CALL :stx_about %batch_script_version% %stx_version%

    GOTO :EOF

)

IF "%~1"=="/a" (

    ECHO: & CALL :stx_about %batch_script_version% %stx_version%

    GOTO :EOF

)

IF "%~1"=="--version" (

    ECHO: & CALL :stx_version %batch_script_version% %stx_version%

    GOTO :EOF

)

IF "%~1"=="-v" (

    ECHO: & CALL :stx_version %batch_script_version% %stx_version%

    GOTO :EOF

)

IF "%~1"=="/v" (

    ECHO: & CALL :stx_version %batch_script_version% %stx_version%

    GOTO :EOF

)

:: ==================

:: Batch file flags =

:: ==================

:: Here for the correct deletion of the filled variables when script finishes

:: ENABLEEXTENSIONS - enable or disable command processor extensions. These

:: arguments takes precedence over the CMD /E:ON or /E:OFF

:: ENABLEDELAYEDEXPANSION - enable or disable delayed environment variable

:: expansion. These arguments takes precedence over the CMD /V:ON or /V:OFF switches.

VERIFY OTHER 2>nul

SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION

IF ERRORLEVEL 1 (

    REM No color as expansion is not yet enabled

    ECHO "Unable to enable extensions.  Fix it."

    SET "exit_value=1"

    GOTO exit_sequence 

)

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *******************************************************************************************

:: Configuration                                                                             *

:: *******************************************************************************************

:: Now all the variables except the for configuration file are in the configuration file.

:: For more see variable configuration_file_path

:: ==================================

:: Clearing the shell prior the run =

:: ==================================

::CLS

:: ===========================================

:: Reading variables from external .cfg file =

:: ===========================================

:: The only variable that can not be validated (be careful when changing it^!)

:: The reason is that it is before the validation process

SET "configuration_file_path=%~dp0"

SET "configuration_file=smalltalk.cfg"

SET "configuration_file_with_path=!configuration_file_path!!configuration_file!"

IF NOT EXIST !configuration_file_with_path! (

    SET "message="Smalltalk configuration file: !configuration_file! not found. Fix it.""

    SET "__numeric.exit_value=1"

    CALL :exit_sequence !message!

    GOTO :EOF

)

:: EOL stops comments from being parsed

:: otherwise split lines at the = char into two tokens

FOR /F "EOL=# delims== tokens=1,*" %%A IN (!configuration_file_with_path!) DO (

    REM proper lines have both a and b set

    REM if okay, assign property to some kind of namespace

    REM so some.property becomes test.some.property in batch-land

    IF NOT "%%A"=="" IF NOT "%%B"=="" SET "stx.%%A=%%B"

)

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: =============

:: Start timer =

:: =============

IF "!stx.__binary.use_timer!"=="TRUE" (

    CALL :time_in_seconds __start

    ECHO:

    ECHO "[INFO] Start timer. START at: !__start! [seconds]"

    ECHO:

)

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: To see stx. namespace uncomment below

:: SET "stx."

:: =================================================

:: Expanding variables from the configuration file =

:: =================================================

:: Variable needs expanding if shell pseudo-variable is used e.g. ...dp0

:: ===================

:: Stx bin directory =

:: ===================

IF NOT "!stx.stx_bin_dir!"=="" (

    CALL :expand_path !stx.stx_bin_dir! stx.stx_bin_dir

    IF ERRORLEVEL 1 (

        ECHO "[ERROR] -> stx.stx_bin_dir <- variable error in  check your configuration file -> !stx.stx_bin_dir! <-"

        GOTO :EOF 

    )

)

:: ===================================

:: Stx quick start and image details =

:: ===================================

IF NOT "!stx.image_path!"=="" (

    CALL :expand_path !stx.image_path! stx.image_path

    IF ERRORLEVEL 1 (

        ECHO "[ERROR] -> stx.image_path <- variable error in  check your configuration file -> !stx.image_path! <-"

        GOTO :EOF 

    )

)

:: =============

:: Stx logging =

:: =============

IF NOT "!stx.log_directory!"=="" (

    CALL :expand_path !stx.log_directory! stx.log_directory

    IF ERRORLEVEL 1 (

        ECHO "[ERROR] -> stx.log_directory <- variable error in  check your configuration file -> !stx.log_directory! <-"

        GOTO :EOF 

    )

)

:: ==================================================================================

:: Script's internal variables                                                      =

:: WARNING: DO NOT TOUCH THE SET VALUES BELOW UNLESS YOU KNOW WHAT YOU ARE DOING!!! =

:: ==================================================================================

:: minimal powershell version, otherwise fall-back is triggered

:: The path for powershell contains v1.0 for all powershell versions!!!!

SET "minimal_powershell_version=2.0"

:: this variable is directly accessed also in powershell file

SET "powershell_version_all_functionality=3.0"

SET "PowerShellVersion="""

SET "RuntimeVersion="""

:: Setting powershell script path and filename

SET "powershell_script_path=%~dp0"

SET "powershell_file=smalltalk.ps1"

SET "powershell_script_file=!powershell_script_path!!powershell_file!"

:: Fallback option must be always active

SET "__binary.powershell_detected=FALSE"

:: Default value is not to use stx command-line switches

SET "stx_manual_switch_detected=FALSE"

:: default script exit value ^(^=0 - everything OK, ^<^>0 - not OK^)

SET "__numeric.exit_value=0"

:: Make sure variable is undefined

SET "internal_runtime_options="

:: Used for switches enter by user at command-line,

:: making sure variable is undefined at the beginning

:: This variable is accessed directly from powershell file

SET "stx_switch="

:: Make sure variable is undefined

SET "stx_date_time="

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *******************************************************************************************

:: PowerShell detection                                                                      *

:: *******************************************************************************************

:: =============================================

:: Calling user function :powershell_detection =

:: =============================================

CALL :powershell_detection __binary.powershell_detected PowerShellVersion RuntimeVersion

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *******************************************************************************************

:: Adjusting according to the configuration                                                  *

:: *******************************************************************************************

:: =============

:: Shell Color =

:: =============

IF "!stx.__binary.colored_stdout!"=="TRUE" (

    IF "!__binary.powershell_detected!"=="TRUE" (

        SET "use_color=TRUE"

    ) ELSE (

        SET "use_color=FALSE"

    )

) ELSE (

    SET "use_color=FALSE"

)

:: ============

:: Image name =

:: ============

SET "default_image_name="!stx.image_name:"=!!stx.image_suffix:"=!""

:: ============================

:: Add encoding to the suffix =

:: ============================

:: Allowed values ASCII, UTF8 (default), UTF16 (in Microsoft world that is called Unicode), UTF32

:: Note: If UTF16 is used you can view log file while StX is running, in all other cases you have to close StX before viewing the file

IF "!stx.log_file_encoding!"=="ASCII" (

    SET "stx.log_suffix="_ascii!stx.log_suffix:"=!""

) ELSE IF "!stx.log_file_encoding!"=="UTF8" (

    SET "stx.log_suffix="_utf8!stx.log_suffix:"=!""

) ELSE IF "!stx.log_file_encoding!"=="UTF16" (

    SET "stx.log_suffix="_utf16!stx.log_suffix:"=!""

) ELSE IF "!stx.log_file_encoding!"=="UTF32" (

    SET "stx.log_suffix="_utf32!stx.log_suffix:"=!""

) ELSE (

    SET "message="Invalid log file encoding: !stx.log_file_encoding!. Fix it and run the script again.""

    SET "__numeric.exit_value=1"

    CALL :exit_sequence !message!

    GOTO :EOF

)

:: =================================================

:: UTF16 alias Microsoft's Unicode name conversion =

:: =================================================

IF "!stx.log_file_encoding!"=="UTF16" (

    SET "stx.log_file_encoding=Unicode"

)

:: =================

:: Log file format =

:: =================

:: Using wmic os get as it is probably the only locales independent way to get time on Windows

:: Date: Using date ISO 8601 format YYYY-MM-DD with time part

:: Time: Using time and date format independent of locales

:: Note: back ticks are there for powershell compatibility

IF "!stx.__binary.log_add_datepart!"=="TRUE" (

    FOR /F %%A IN ('wmic os get LocalDateTime ^| find "."') DO SET "dts=%%A"

    SET "stx_date_time=!dts:~0,4!-!dts:~4,2!-!dts:~6,2!"

    IF "!stx.__binary.log_add_timepart!"=="TRUE" (

        SET "stx_date_time=!stx_date_time!_!dts:~8,2!"`;"!dts:~10,2!"`;"!dts:~12,2!"

    )

    SET "log_filename="!stx.log_name:"=!_!stx_date_time!!stx.log_suffix:"=!""

) ELSE (

    FOR /F %%A IN ('wmic os get LocalDateTime ^| find "."') DO SET "dts=%%A"

    IF "!stx.__binary.log_add_timepart!"=="TRUE" (

        SET "stx_date_time=!dts:~8,2!"`;"!dts:~10,2!"`;"!dts:~12,2!"

        SET "log_filename="!stx.log_name:"=!_!stx_date_time!!stx.log_suffix:"=!""

    ) ELSE (

        SET "log_filename="!stx.log_name:"=!!stx.log_suffix:"=!""

    )

)

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: Next section follows 

:: ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

:: *******************************************************************************************

:: Checking variable and logic consistency                                                   *

:: *******************************************************************************************

:: ==============================================

:: Checking the PowerShell file (.ps1) presence =

:: ==============================================

IF NOT EXIST "!powershell_script_file!" (

    SET "message="PowerShell file missing: !powershell_script_path!smalltalk.ps1.  Fix it.""

    SET "__numeric.exit_value=1"

    CALL :exit_sequence !message!

    GOTO :EOF

)

:: =======================

:: Variables' validation =

:: =======================

IF "!stx.verify_variables_syntax!"=="TRUE" (

    REM must be used (inside IF^^!)

    REM =====================================================================

    REM Validate __binary for TRUE^/FALSE and if it does not contain spaces =

    REM =====================================================================

    REM Checks if the variable contains correctly written TRUE^/FALSE

    REM additionally it also checks if additional space was not added by mistake

    REM var -7 extracts the last 7 characters from var

    FOR /F "tokens=3 delims=^." %%A IN ('SET stx.__binary.') DO (

        SET "temp_test=%%A"

        IF "!temp_test:~-5!"=="=TRUE" (

            IF NOT "!temp_test!"=="!temp_test: =!" (

                SET "__numeric.exit_value=1"

                SET "first_message="Incorrect configuration additional space detected.""

                SET "first_message="Correct the variable: __binary.!temp_test!""

                CALL :exit_sequence !first_message! !second_message!

                GOTO :EOF

            )

        ) ELSE IF "!temp_test:~-6!"=="=FALSE" (

            IF NOT "!temp_test!"=="!temp_test: =!" (

                SET "__numeric.exit_value=1"

                SET "first_message="Incorrect configuration additional space detected.""

                SET "second_message="Correct the variable: __binary.!temp_test!""

                CALL :exit_sequence !first_message! !second_message!

                GOTO :EOF

            )

        ) ELSE (

            IF NOT "!temp_test!"=="!temp_test: =!" (

                SET "__numeric.exit_value=1"

                SET "first_message="Incorrect configuration additional space detected.""

                SET "second_message="Correct the variable: __binary.!temp_test!""

                CALL :exit_sequence !first_message! !second_message!

                GOTO :EOF

            ) ELSE (

                SET "first_message="Incorrect configuration mistake in TRUE^/FALSE detected.""

                SET "second_message="Correct the variable: __binary.!temp_test!""

                SET "__numeric.exit_value=1"

                CALL :exit_sequence !first_message! !second_message!

                GOTO :EOF

            )

        )

    )

    REM must be used (inside IF^^!)

    REM  ===================================================================

    REM  Validate if __binary values are numeric and do not contain spaces =

    REM  ===================================================================

    REM 1. FOR - variable extraction bla value

    REM 2. FOR - extracting integer value

    REM 3. FOR - testing integer

    FOR /F "tokens=3 delims=^." %%A IN ('SET stx.__numeric.') DO (

        SET "temp_test=%%A"

        FOR /F "tokens=2 delims==" %%B IN ("!temp_test!") DO SET "test_integer=%%B"

        SET "ugh="&FOR /F "delims=0123456789" %%C IN ("!test_integer!") DO SET "ugh=%%~C"

        IF defined ugh (

            IF NOT "!temp_test!"=="!temp_test: =!" (

                SET "__numeric.exit_value=1"

                SET "first_message="Incorrect configuration additional space detected.""

                SET "second_message="Correct the variable: __binary.!temp_test!""

                CALL :exit_sequence !first_message! !second_message!

                GOTO :EOF

            ) ELSE (

                SET "__numeric.exit_value=1"

                SET "message="Incorrect configuration detected - integer value is not an integer.""

                CALL :exit_sequence !message!

                GOTO :EOF

            )

        ) ELSE (

              IF NOT "!temp_test!"=="!temp_test: =!" (

                  SET "__numeric.exit_value=1"

                  SET "first_message="Incorrect configuration additional space detected.""

                  SET "second_message="Correct the variable: __binary.!temp_test!""

                  CALL :exit_sequence !first_message! !second_message!

                  GOTO :EOF

              )

        )

    )

    REM must be used (inside IF^^!)

    REM ===============================================================

    REM Validate path variables to contain double quotes or backslash =

    REM ===============================================================

    REM ========================================================

    REM Check beginning of the string to contain double quotes =

    REM ========================================================

    REM Checking image variables

    SET "correct_substring=!stx.image_name:~0,1!"

    IF NOT !correct_substring!==^" (

        SET "__numeric.exit_value=1"

        SET "message="Incorrect configuration detected missing double quotes at stx.image_name variable: - !stx.image_name! -""

        CALL :exit_sequence !message!

        GOTO :EOF

    )

    SET "correct_substring=!stx.image_suffix:~0,1!"

    IF NOT !correct_substring!==^" (

        SET "__numeric.exit_value=1"

        SET "message="Incorrect configuration detected missing double quotes at stx.image_suffix variable: - !stx.image_suffix! -""

        CALL :exit_sequence !message!

        GOTO :EOF

    )